mirror of
https://github.com/historicalsource/infocom-sampler
synced 2024-05-14 23:18:40 +03:00
1528 lines
45 KiB
Plaintext
1528 lines
45 KiB
Plaintext
"PARSER for
|
||
SAMPLER
|
||
(c) Copyright 1984 Infocom, Inc. All Rights Reserved."
|
||
|
||
"Parser global variable convention: All parser globals will
|
||
begin with 'P-'. Local variables are not restricted in any
|
||
way.
|
||
"
|
||
|
||
<SETG SIBREAKS ".,\"">
|
||
|
||
;<GLOBAL GWIM-DISABLE <>> ;"not referenced, removed 2/27/85 by SEM"
|
||
|
||
<GLOBAL PRSA <>>
|
||
|
||
<GLOBAL PRSI <>>
|
||
|
||
<GLOBAL PRSO <>>
|
||
|
||
<GLOBAL P-TABLE 0>
|
||
|
||
<GLOBAL P-ONEOBJ 0>
|
||
|
||
<GLOBAL P-SYNTAX 0>
|
||
|
||
;<GLOBAL P-CCSRC 0>
|
||
<GLOBAL P-CCTBL <TABLE 0 0 0 0>>
|
||
|
||
;"pointers used by CLAUSE-COPY (source/destination beginning/end pointers)"
|
||
<CONSTANT CC-SBPTR 0>
|
||
<CONSTANT CC-SEPTR 1>
|
||
<CONSTANT CC-DBPTR 2>
|
||
<CONSTANT CC-DEPTR 3>
|
||
|
||
<GLOBAL P-LEN 0>
|
||
|
||
<GLOBAL P-DIR 0>
|
||
|
||
<GLOBAL HERE 0>
|
||
|
||
<GLOBAL WINNER 0>
|
||
|
||
<GLOBAL P-LEXV <ITABLE BYTE 120>>
|
||
;"INBUF - Input buffer for READ"
|
||
|
||
<GLOBAL P-INBUF <ITABLE BYTE 100>>
|
||
;"Parse-cont variable"
|
||
|
||
<GLOBAL P-CONT <>>
|
||
|
||
<GLOBAL P-IT-OBJECT <>>
|
||
<GLOBAL P-IT-LOC <>>
|
||
|
||
;"Orphan flag"
|
||
|
||
<GLOBAL P-OFLAG <>>
|
||
|
||
<GLOBAL P-MERGED <>>
|
||
|
||
<GLOBAL P-ACLAUSE <>>
|
||
|
||
<GLOBAL P-ANAM <>>
|
||
|
||
<GLOBAL P-AADJ <>>
|
||
;"Parser variables and temporaries"
|
||
|
||
<CONSTANT P-PHRLEN 3>
|
||
|
||
<CONSTANT P-ORPHLEN 7>
|
||
|
||
<CONSTANT P-RTLEN 3>
|
||
;"Byte offset to # of entries in LEXV"
|
||
|
||
<CONSTANT P-LEXWORDS 1>
|
||
;"Word offset to start of LEXV entries"
|
||
|
||
<CONSTANT P-LEXSTART 1>
|
||
;"Number of words per LEXV entry"
|
||
|
||
<CONSTANT P-LEXELEN 2>
|
||
|
||
<CONSTANT P-WORDLEN 4>
|
||
;"Offset to parts of speech byte"
|
||
|
||
<CONSTANT P-PSOFF 4>
|
||
;"Offset to first part of speech"
|
||
|
||
<CONSTANT P-P1OFF 5>
|
||
;"First part of speech bit mask in PSOFF byte"
|
||
|
||
<CONSTANT P-P1BITS 3>
|
||
|
||
<CONSTANT P-ITBLLEN 9>
|
||
|
||
<GLOBAL P-ITBL <TABLE 0 0 0 0 0 0 0 0 0 0>>
|
||
|
||
<GLOBAL P-OTBL <TABLE 0 0 0 0 0 0 0 0 0 0>>
|
||
|
||
<GLOBAL P-VTBL <TABLE 0 0 0 0>>
|
||
|
||
<GLOBAL P-OVTBL <TABLE 0 0 0 0>>
|
||
|
||
<GLOBAL P-NCN 0>
|
||
|
||
<CONSTANT P-VERB 0>
|
||
|
||
<CONSTANT P-VERBN 1>
|
||
|
||
<CONSTANT P-PREP1 2>
|
||
|
||
<CONSTANT P-PREP1N 3>
|
||
|
||
<CONSTANT P-PREP2 4>
|
||
|
||
<CONSTANT P-PREP2N 5>
|
||
|
||
<CONSTANT P-NC1 6>
|
||
|
||
<CONSTANT P-NC1L 7>
|
||
|
||
<CONSTANT P-NC2 8>
|
||
|
||
<CONSTANT P-NC2L 9>
|
||
|
||
<GLOBAL QUOTE-FLAG <>>
|
||
|
||
" Grovel down the input finding the verb, prepositions, and noun clauses.
|
||
If the input is <direction> or <walk> <direction>, fall out immediately
|
||
setting PRSA to ,V?WALK and PRSO to <direction>. Otherwise, perform
|
||
all required orphaning, syntax checking, and noun clause lookup."
|
||
|
||
<ROUTINE PARSER ("AUX" (PTR ,P-LEXSTART) WRD (VAL 0) (VERB <>)
|
||
(OF-FLAG <>) LEN (DIR <>) (NW 0) (LW 0) NUM SCNT (CNT -1))
|
||
<REPEAT ()
|
||
<COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN> <RETURN>)
|
||
(T <PUT ,P-ITBL .CNT 0>)>>
|
||
<SETG P-ADVERB <>>
|
||
<SETG P-MERGED <>>
|
||
<SETG P-NAM <>>
|
||
<PUT ,P-PRSO ,P-MATCHLEN 0>
|
||
<PUT ,P-PRSI ,P-MATCHLEN 0>
|
||
<PUT ,P-BUTS ,P-MATCHLEN 0>
|
||
<SETG L-WINNER ,WINNER> ;"for AGAIN"
|
||
<COND (<AND <NOT ,QUOTE-FLAG> <N==? ,WINNER ,PLAYER>>
|
||
<SETG WINNER ,PLAYER>
|
||
<COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
|
||
<SETG HERE <LOC ,WINNER>>)>
|
||
<SETG LIT <LIT? ,HERE>>)>
|
||
<COND (<NOT <ZERO? ,P-CONT>>
|
||
<SET PTR ,P-CONT>
|
||
<COND (<AND <NOT ,SUPER-BRIEF>
|
||
<==? ,PLAYER ,WINNER>
|
||
<NOT <VERB? SAY>>>
|
||
<CRLF>)>
|
||
<SETG P-CONT <>>)
|
||
(T
|
||
<SETG WINNER ,PLAYER>
|
||
<SETG QUOTE-FLAG <>>
|
||
<COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
|
||
<SETG HERE <LOC ,WINNER>>)>
|
||
<SETG LIT <LIT? ,HERE>>
|
||
<COND (<NOT ,SUPER-BRIEF> <CRLF>)>
|
||
<TELL ">">
|
||
<READ ,P-INBUF ,P-LEXV>)>
|
||
<SETG P-LEN <GETB ,P-LEXV ,P-LEXWORDS>>
|
||
<COND (<0? ,P-LEN>
|
||
<TELL "I beg your pardon?" CR>
|
||
<COND (<AND ,TUTORIAL-MODE <NOT ,BEG-FLAG>>
|
||
<SETG BEG-FLAG T>
|
||
<TELL "|
|
||
(That message meant that you didn't type anything at the prompt.)" CR>)>
|
||
<RFALSE>)>
|
||
<SET LEN ,P-LEN>
|
||
<SETG P-DIR <>>
|
||
<SETG P-NCN 0>
|
||
<SETG P-GETFLAGS 0>
|
||
<REPEAT ()
|
||
<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
|
||
<SETG QUOTE-FLAG <>>
|
||
<RETURN>)
|
||
(<OR <SET WRD <GET ,P-LEXV .PTR>>
|
||
<SET WRD <NUMBER? .PTR>>>
|
||
<COND (<AND <==? .WRD ,W?TO>
|
||
<EQUAL? .VERB ,ACT?TELL ;,ACT?ASK>>
|
||
<SET WRD ,W?QUOTE>)
|
||
(<AND <==? .WRD ,W?THEN>
|
||
<NOT .VERB>
|
||
<NOT ,QUOTE-FLAG> ;"Last NOT added 7/3">
|
||
<PUT ,P-ITBL ,P-VERB ,ACT?TELL>
|
||
<PUT ,P-ITBL ,P-VERBN 0>
|
||
<SET WRD ,W?QUOTE>)>
|
||
<COND (<OR <EQUAL? .WRD ,W?THEN ,W?PERIOD>
|
||
<EQUAL? .WRD ,W?QUOTE>>
|
||
<COND (<EQUAL? .WRD ,W?QUOTE>
|
||
<COND (<NOT <ZERO? ,QUOTE-FLAG>>
|
||
<SETG QUOTE-FLAG <>>)
|
||
(T <SETG QUOTE-FLAG T>)>)>
|
||
<OR <0? ,P-LEN>
|
||
<SETG P-CONT <+ .PTR ,P-LEXELEN>>>
|
||
<PUTB ,P-LEXV ,P-LEXWORDS ,P-LEN>
|
||
<RETURN>)
|
||
(<AND <SET VAL
|
||
<WT? .WRD
|
||
,PS?DIRECTION
|
||
,P1?DIRECTION>>
|
||
<EQUAL? .VERB <> ,ACT?WALK>
|
||
<OR <==? .LEN 1>
|
||
<AND <==? .LEN 2>
|
||
<EQUAL? .VERB ,ACT?WALK>>
|
||
<AND <EQUAL? <SET NW
|
||
<GET ,P-LEXV
|
||
<+ .PTR ,P-LEXELEN>>>
|
||
,W?THEN
|
||
,W?PERIOD
|
||
,W?QUOTE>
|
||
<NOT <L? .LEN 2>>>
|
||
<AND ,QUOTE-FLAG
|
||
<==? .LEN 2>
|
||
<EQUAL? .NW ,W?QUOTE>>
|
||
<AND <G? .LEN 2>
|
||
<EQUAL? .NW ,W?COMMA ,W?AND>>>>
|
||
<SET DIR .VAL>
|
||
<COND (<EQUAL? .NW ,W?COMMA ,W?AND>
|
||
<PUT ,P-LEXV
|
||
<+ .PTR ,P-LEXELEN>
|
||
,W?THEN>)>
|
||
<COND (<NOT <G? .LEN 2>>
|
||
<SETG QUOTE-FLAG <>>
|
||
<RETURN>)>)
|
||
(<AND <SET VAL <WT? .WRD ,PS?VERB ,P1?VERB>>
|
||
<NOT .VERB>>
|
||
<SET VERB .VAL>
|
||
<PUT ,P-ITBL ,P-VERB .VAL>
|
||
<PUT ,P-ITBL ,P-VERBN ,P-VTBL>
|
||
<PUT ,P-VTBL 0 .WRD>
|
||
<PUTB ,P-VTBL 2 <GETB ,P-LEXV
|
||
<SET NUM
|
||
<+ <* .PTR 2> 2>>>>
|
||
<PUTB ,P-VTBL 3 <GETB ,P-LEXV <+ .NUM 1>>>)
|
||
(<OR <SET VAL <WT? .WRD ,PS?PREPOSITION 0>>
|
||
<AND <OR <EQUAL? .WRD ,W?ALL ,W?ONE ;,W?A>
|
||
<WT? .WRD ,PS?ADJECTIVE>
|
||
<WT? .WRD ,PS?OBJECT>>
|
||
<SET VAL 0>>>
|
||
<COND (<AND <G? ,P-LEN 1> ;"was >0 until 3/11/85"
|
||
<==? <GET ,P-LEXV
|
||
<+ .PTR ,P-LEXELEN>>
|
||
,W?OF>
|
||
<0? .VAL>
|
||
<NOT
|
||
<EQUAL? .WRD ,W?ALL ,W?ONE ,W?A>>>
|
||
<SET OF-FLAG T>)
|
||
(<AND <NOT <0? .VAL>>
|
||
<OR <0? ,P-LEN>
|
||
<EQUAL? <GET ,P-LEXV <+ .PTR 2>>
|
||
,W?THEN ,W?PERIOD>>>
|
||
<COND (<L? ,P-NCN 2>
|
||
<PUT ,P-ITBL ,P-PREP1 .VAL>
|
||
<PUT ,P-ITBL ,P-PREP1N .WRD>)>)
|
||
(<==? ,P-NCN 2>
|
||
<TELL
|
||
"There were too many nouns in that sentence." CR>
|
||
<RFALSE>)
|
||
(T
|
||
<SETG P-NCN <+ ,P-NCN 1>>
|
||
<OR <SET PTR <CLAUSE .PTR .VAL .WRD>>
|
||
<RFALSE>>
|
||
<COND (<L? .PTR 0>
|
||
<SETG QUOTE-FLAG <>>
|
||
<RETURN>)>)>)
|
||
(<EQUAL? .WRD ,W?OF>
|
||
<COND (<OR <NOT .OF-FLAG>
|
||
<EQUAL?
|
||
<GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
|
||
,W?PERIOD ,W?THEN>>
|
||
<CANT-USE .PTR>
|
||
<RFALSE>)
|
||
(T
|
||
<SET OF-FLAG <>>)>)
|
||
(<WT? .WRD ,PS?BUZZ-WORD>)
|
||
(<AND <EQUAL? .VERB ,ACT?TELL>
|
||
<WT? .WRD ,PS?VERB ,P1?VERB>>
|
||
<TELL
|
||
"To give commands to another character, type the character's name followed
|
||
by a comma followed by the command itself. For example:|
|
||
|
|
||
FLOYD, GIVE ME THE BEDISTOR|" CR>
|
||
<RFALSE>)
|
||
(T
|
||
<CANT-USE .PTR>
|
||
<RFALSE>)>)
|
||
(T
|
||
<UNKNOWN-WORD .PTR>
|
||
<RFALSE>)>
|
||
<SET LW .WRD>
|
||
<SET PTR <+ .PTR ,P-LEXELEN>>>
|
||
<COND (.DIR
|
||
<SETG PRSA ,V?WALK>
|
||
<SETG PRSO .DIR>
|
||
<SETG P-WALK-DIR .DIR>
|
||
<SETG P-OFLAG <>>
|
||
<RETURN T>)>
|
||
<SETG L-WALK-DIR ,P-WALK-DIR>
|
||
<SETG P-WALK-DIR <>>
|
||
<COND (<NOT <ZERO? ,P-OFLAG>> <ORPHAN-MERGE>)>
|
||
<COND (<AND <SYNTAX-CHECK> <SNARF-OBJECTS> <MANY-CHECK> <TAKE-CHECK>>
|
||
T)>>
|
||
|
||
<GLOBAL BEG-FLAG <>>
|
||
|
||
<GLOBAL P-WALK-DIR <>>
|
||
<GLOBAL L-WALK-DIR <>>
|
||
|
||
;"Check whether word pointed at by PTR is the correct part of speech.
|
||
The second argument is the part of speech (,PS?<part of speech>). The
|
||
3rd argument (,P1?<part of speech>), if given, causes the value
|
||
for that part of speech to be returned."
|
||
|
||
<ROUTINE WT? (PTR BIT "OPTIONAL" (B1 5) "AUX" (OFFS ,P-P1OFF) TYP)
|
||
<COND (<BTST <SET TYP <GETB .PTR ,P-PSOFF>> .BIT>
|
||
<COND (<G? .B1 4> <RTRUE>)
|
||
(T
|
||
<SET TYP <BAND .TYP ,P-P1BITS>>
|
||
<COND (<NOT <==? .TYP .B1>> <SET OFFS <+ .OFFS 1>>)>
|
||
<GETB .PTR .OFFS>)>)>>
|
||
|
||
;" Scan through a noun clause, leave a pointer to its starting location"
|
||
|
||
<ROUTINE CLAUSE (PTR VAL WRD "AUX" OFF NUM (ANDFLG <>) (FIRST?? T) NW (LW 0))
|
||
<SET OFF <* <- ,P-NCN 1> 2>>
|
||
<COND (<NOT <==? .VAL 0>>
|
||
<PUT ,P-ITBL <SET NUM <+ ,P-PREP1 .OFF>> .VAL>
|
||
<PUT ,P-ITBL <+ .NUM 1> .WRD>
|
||
<SET PTR <+ .PTR ,P-LEXELEN>>)
|
||
(T <SETG P-LEN <+ ,P-LEN 1>>)>
|
||
<COND (<0? ,P-LEN> <SETG P-NCN <- ,P-NCN 1>> <RETURN -1>)>
|
||
<PUT ,P-ITBL <SET NUM <+ ,P-NC1 .OFF>> <REST ,P-LEXV <* .PTR 2>>>
|
||
<COND (<EQUAL? <GET ,P-LEXV .PTR> ,W?THE ,W?A ,W?AN>
|
||
<PUT ,P-ITBL .NUM <REST <GET ,P-ITBL .NUM> 4>>)>
|
||
<REPEAT ()
|
||
<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
|
||
<PUT ,P-ITBL <+ .NUM 1> <REST ,P-LEXV <* .PTR 2>>>
|
||
<RETURN -1>)>
|
||
<COND (<OR <SET WRD <GET ,P-LEXV .PTR>>
|
||
<SET WRD <NUMBER? .PTR>>>
|
||
<COND (<0? ,P-LEN> <SET NW 0>)
|
||
(T <SET NW <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>>)>
|
||
<COND (<EQUAL? .WRD ,W?AND ,W?COMMA> <SET ANDFLG T>)
|
||
(<EQUAL? .WRD ,W?ALL ,W?ONE>
|
||
<COND (<==? .NW ,W?OF>
|
||
<SETG P-LEN <- ,P-LEN 1>>
|
||
<SET PTR <+ .PTR ,P-LEXELEN>>)>)
|
||
(<OR <EQUAL? .WRD ,W?THEN ,W?PERIOD>
|
||
<AND <WT? .WRD ,PS?PREPOSITION>
|
||
<GET ,P-ITBL ,P-VERB>
|
||
;"ADDED 4/27 FOR TURTLE,UP"
|
||
<NOT .FIRST??>>>
|
||
<SETG P-LEN <+ ,P-LEN 1>>
|
||
<PUT ,P-ITBL
|
||
<+ .NUM 1>
|
||
<REST ,P-LEXV <* .PTR 2>>>
|
||
<RETURN <- .PTR ,P-LEXELEN>>)
|
||
(<WT? .WRD ,PS?OBJECT>
|
||
<COND (<AND <WT? .WRD
|
||
,PS?ADJECTIVE
|
||
,P1?ADJECTIVE>
|
||
<NOT <==? .NW 0>>
|
||
<WT? .NW ,PS?OBJECT>>)
|
||
(<AND <NOT .ANDFLG>
|
||
<NOT <EQUAL? .NW ,W?BUT ,W?EXCEPT>>
|
||
<NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
|
||
<PUT ,P-ITBL
|
||
<+ .NUM 1>
|
||
<REST ,P-LEXV <* <+ .PTR 2> 2>>>
|
||
<RETURN .PTR>)
|
||
(T <SET ANDFLG <>>)>)
|
||
(<AND <OR ,P-MERGED
|
||
,P-OFLAG
|
||
<NOT <EQUAL? <GET ,P-ITBL ,P-VERB> 0>>>
|
||
<OR <WT? .WRD ,PS?ADJECTIVE>
|
||
<WT? .WRD ,PS?BUZZ-WORD>>>)
|
||
(<AND .ANDFLG
|
||
<OR <WT? .WRD ,PS?DIRECTION>
|
||
<WT? .WRD ,PS?VERB>>>
|
||
<SET PTR <- .PTR 4>>
|
||
<PUT ,P-LEXV <+ .PTR 2> ,W?THEN>
|
||
<SETG P-LEN <+ ,P-LEN 2>>)
|
||
(<WT? .WRD ,PS?PREPOSITION> T)
|
||
(T
|
||
<CANT-USE .PTR>
|
||
<RFALSE>)>)
|
||
(T <UNKNOWN-WORD .PTR> <RFALSE>)>
|
||
<SET LW .WRD>
|
||
<SET FIRST?? <>>
|
||
<SET PTR <+ .PTR ,P-LEXELEN>>>>
|
||
|
||
<ROUTINE NUMBER? (PTR "AUX" CNT BPTR CHR (SUM 0) (TIM <>))
|
||
<SET CNT <GETB <REST ,P-LEXV <* .PTR 2>> 2>>
|
||
<SET BPTR <GETB <REST ,P-LEXV <* .PTR 2>> 3>>
|
||
<REPEAT ()
|
||
<COND (<L? <SET CNT <- .CNT 1>> 0> <RETURN>)
|
||
(T
|
||
<SET CHR <GETB ,P-INBUF .BPTR>>
|
||
<COND (<==? .CHR 58>
|
||
<SET TIM .SUM>
|
||
<SET SUM 0>)
|
||
(<G? .SUM 10000> <RFALSE>)
|
||
(<AND <L? .CHR 58> <G? .CHR 47>>
|
||
<SET SUM <+ <* .SUM 10> <- .CHR 48>>>)
|
||
(T <RFALSE>)>
|
||
<SET BPTR <+ .BPTR 1>>)>>
|
||
<PUT ,P-LEXV .PTR ,W?INTNUM>
|
||
<COND (<G? .SUM 1000> <RFALSE>)
|
||
(.TIM
|
||
<COND (<L? .TIM 8> <SET TIM <+ .TIM 12>>)
|
||
(<G? .TIM 23> <RFALSE>)>
|
||
<SET SUM <+ .SUM <* .TIM 60>>>)>
|
||
<SETG P-NUMBER .SUM>
|
||
,W?INTNUM>
|
||
|
||
<GLOBAL P-NUMBER 0>
|
||
;<GLOBAL P-DIRECTION 0> ;"not referenced, removed 2/27/85 by SEM"
|
||
|
||
|
||
|
||
;"New ORPHAN-MERGE for TRAP Retrofix 6/21/84"
|
||
|
||
;<ROUTINE ORPHAN-MERGE ("AUX" (CNT -1) TEMP VERB BEG END (ADJ <>) WRD)
|
||
<SETG P-OFLAG <>>
|
||
<COND (<WT? <GET <GET ,P-ITBL ,P-VERBN> 0> ,PS?ADJECTIVE ,P1?ADJECTIVE>
|
||
<SET ADJ T>)>
|
||
<COND (<AND <NOT <0? <SET VERB <GET ,P-ITBL ,P-VERB>>>>
|
||
<NOT .ADJ>
|
||
<NOT <==? .VERB <GET ,P-OTBL ,P-VERB>>>>
|
||
<RFALSE>)
|
||
(<==? ,P-NCN 2> <RFALSE>)
|
||
(<==? <GET ,P-OTBL ,P-NC1> 1>
|
||
<COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
|
||
<GET ,P-OTBL ,P-PREP1>>
|
||
<0? .TEMP>>
|
||
<COND (.ADJ
|
||
<PUT ,P-OTBL ,P-NC1 <REST ,P-LEXV 2>>
|
||
<PUT ,P-OTBL ,P-NC1L <REST ,P-LEXV 6>>)
|
||
(T
|
||
<PUT ,P-OTBL ,P-NC1 <GET ,P-ITBL ,P-NC1>>
|
||
<PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)>)
|
||
(T <RFALSE>)>)
|
||
(<==? <GET ,P-OTBL ,P-NC2> 1>
|
||
<COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
|
||
<GET ,P-OTBL ,P-PREP2>>
|
||
<0? .TEMP>>
|
||
<COND (.ADJ
|
||
<PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
|
||
<PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>
|
||
<PUT ,P-OTBL ,P-NC2 <GET ,P-ITBL ,P-NC1>>
|
||
<PUT ,P-OTBL ,P-NC2L <GET ,P-ITBL ,P-NC1L>>
|
||
<SETG P-NCN 2>)
|
||
(T <RFALSE>)>)
|
||
(<NOT <ZERO? ,P-ACLAUSE>>
|
||
<COND (<AND <NOT <==? ,P-NCN 1>> <NOT .ADJ>>
|
||
<SETG P-ACLAUSE <>>
|
||
<RFALSE>)
|
||
(T
|
||
<SET BEG <GET ,P-ITBL ,P-NC1>>
|
||
<COND (.ADJ <SET BEG <REST ,P-LEXV 2>> <SET ADJ <>>)>
|
||
<SET END <GET ,P-ITBL ,P-NC1L>>
|
||
<REPEAT ()
|
||
<SET WRD <GET .BEG 0>>
|
||
<COND (<==? .BEG .END>
|
||
<COND (.ADJ <ACLAUSE-WIN .ADJ> <RETURN>)
|
||
(T <SETG P-ACLAUSE <>> <RFALSE>)>)
|
||
(<AND <NOT .ADJ>
|
||
<OR <BTST <GETB .WRD ,P-PSOFF>
|
||
,PS?ADJECTIVE>
|
||
<EQUAL? .WRD ,W?ALL ,W?ONE>>>
|
||
<SET ADJ .WRD>)
|
||
(<OR <BTST <GETB .WRD ,P-PSOFF> ,PS?OBJECT>
|
||
<==? .WRD ,W?ONE>>
|
||
<COND (<NOT <EQUAL? .WRD ,P-ANAM ,W?ONE>>
|
||
<RFALSE>)
|
||
(T <ACLAUSE-WIN .ADJ> <RETURN>)>)>
|
||
<SET BEG <REST .BEG ,P-WORDLEN>>
|
||
<COND (<EQUAL? .END 0>
|
||
<SET END .BEG>
|
||
<SETG P-NCN 1>
|
||
<PUT ,P-ITBL ,P-NC1 <BACK .BEG 4>>
|
||
<PUT ,P-ITBL ,P-NC1L .BEG>)>>)>)>
|
||
<REPEAT ()
|
||
<COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN>
|
||
<SETG P-MERGED T>
|
||
<RTRUE>)
|
||
(T <PUT ,P-ITBL .CNT <GET ,P-OTBL .CNT>>)>>
|
||
T>
|
||
|
||
;"New ACLAUSE-WIN for TRAP retrofix 6/21/84"
|
||
|
||
;<ROUTINE ACLAUSE-WIN (ADJ)
|
||
<PUT ,P-ITBL ,P-VERB <GET ,P-OTBL ,P-VERB>>
|
||
<SETG P-CCSRC ,P-OTBL>
|
||
<CLAUSE-COPY ,P-ACLAUSE <+ ,P-ACLAUSE 1> .ADJ>
|
||
<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
|
||
<SETG P-ACLAUSE <>>
|
||
<RTRUE>>
|
||
|
||
;"Newer ORPHAN-MERGE, ACLAUSE-WIN, and NCLAUSE-WIN 3/5/85"
|
||
<ROUTINE ORPHAN-MERGE ("AUX" (CNT -1) TEMP VERB BEG END (ADJ <>) WRD)
|
||
<SETG P-OFLAG <>>
|
||
<COND (<WT? <SET WRD <GET <GET ,P-ITBL ,P-VERBN> 0>>
|
||
,PS?ADJECTIVE ,P1?ADJECTIVE>
|
||
<SET ADJ T>)
|
||
(<AND <WT? .WRD ,PS?OBJECT ,P1?OBJECT>
|
||
<EQUAL? ,P-NCN 0>>
|
||
<PUT ,P-ITBL ,P-VERB 0>
|
||
<PUT ,P-ITBL ,P-VERBN 0>
|
||
<PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
|
||
<PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>
|
||
<SETG P-NCN 1>)>
|
||
<COND (<AND <NOT <0? <SET VERB <GET ,P-ITBL ,P-VERB>>>>
|
||
<NOT .ADJ>
|
||
<NOT <==? .VERB <GET ,P-OTBL ,P-VERB>>>>
|
||
<RFALSE>)
|
||
(<==? ,P-NCN 2> <RFALSE>)
|
||
(<==? <GET ,P-OTBL ,P-NC1> 1>
|
||
<COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
|
||
<GET ,P-OTBL ,P-PREP1>>
|
||
<0? .TEMP>>
|
||
<COND (.ADJ
|
||
<PUT ,P-OTBL ,P-NC1 <REST ,P-LEXV 2>>
|
||
<COND (<0? <GET ,P-ITBL ,P-NC1L>>
|
||
<PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>
|
||
<COND (<0? ,P-NCN> <SETG P-NCN 1>)>)
|
||
(T
|
||
<PUT ,P-OTBL ,P-NC1 <GET ,P-ITBL ,P-NC1>>
|
||
;<PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)>
|
||
<PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)
|
||
(T <RFALSE>)>)
|
||
(<==? <GET ,P-OTBL ,P-NC2> 1>
|
||
<COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
|
||
<GET ,P-OTBL ,P-PREP2>>
|
||
<0? .TEMP>>
|
||
<COND (.ADJ
|
||
<PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
|
||
<COND (<0? <GET ,P-ITBL ,P-NC1L>>
|
||
<PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>)>
|
||
<PUT ,P-OTBL ,P-NC2 <GET ,P-ITBL ,P-NC1>>
|
||
<PUT ,P-OTBL ,P-NC2L <GET ,P-ITBL ,P-NC1L>>
|
||
<SETG P-NCN 2>)
|
||
(T <RFALSE>)>)
|
||
(,P-ACLAUSE
|
||
<COND (<AND <NOT <==? ,P-NCN 1>> <NOT .ADJ>>
|
||
<SETG P-ACLAUSE <>>
|
||
<RFALSE>)
|
||
(T
|
||
<SET BEG <GET ,P-ITBL ,P-NC1>>
|
||
<COND (.ADJ <SET BEG <REST ,P-LEXV 2>> <SET ADJ <>>)>
|
||
<SET END <GET ,P-ITBL ,P-NC1L>>
|
||
<REPEAT ()
|
||
<SET WRD <GET .BEG 0>>
|
||
<COND (<==? .BEG .END>
|
||
<COND (.ADJ <ACLAUSE-WIN .ADJ> <RETURN>)
|
||
(T <SETG P-ACLAUSE <>> <RFALSE>)>)
|
||
(<AND <NOT .ADJ>
|
||
<OR <BTST <GETB .WRD ,P-PSOFF>
|
||
,PS?ADJECTIVE> ;"same as WT?"
|
||
<EQUAL? .WRD ,W?ALL ,W?ONE>>>
|
||
<SET ADJ .WRD>)
|
||
(<==? .WRD ,W?ONE>
|
||
<ACLAUSE-WIN .ADJ>
|
||
<RETURN>)
|
||
(<BTST <GETB .WRD ,P-PSOFF> ,PS?OBJECT>
|
||
<COND (<EQUAL? .WRD ,P-ANAM>
|
||
<ACLAUSE-WIN .ADJ>)
|
||
(T
|
||
<NCLAUSE-WIN>)>
|
||
<RETURN>)>
|
||
<SET BEG <REST .BEG ,P-WORDLEN>>
|
||
<COND (<EQUAL? .END 0>
|
||
<SET END .BEG>
|
||
<SETG P-NCN 1>
|
||
<PUT ,P-ITBL ,P-NC1 <BACK .BEG 4>>
|
||
<PUT ,P-ITBL ,P-NC1L .BEG>)>>)>)>
|
||
<PUT ,P-VTBL 0 <GET ,P-OVTBL 0>>
|
||
<PUTB ,P-VTBL 2 <GETB ,P-OVTBL 2>>
|
||
<PUTB ,P-VTBL 3 <GETB ,P-OVTBL 3>>
|
||
<PUT ,P-OTBL ,P-VERBN ,P-VTBL>
|
||
<PUTB ,P-VTBL 2 0>
|
||
;<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
|
||
<REPEAT ()
|
||
<COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN>
|
||
<SETG P-MERGED T>
|
||
<RTRUE>)
|
||
(T <PUT ,P-ITBL .CNT <GET ,P-OTBL .CNT>>)>>
|
||
T>
|
||
|
||
<ROUTINE ACLAUSE-WIN (ADJ)
|
||
<PUT ,P-ITBL ,P-VERB <GET ,P-OTBL ,P-VERB>>
|
||
<PUT ,P-CCTBL ,CC-SBPTR ,P-ACLAUSE>
|
||
<PUT ,P-CCTBL ,CC-SEPTR <+ ,P-ACLAUSE 1>>
|
||
<PUT ,P-CCTBL ,CC-DBPTR ,P-ACLAUSE>
|
||
<PUT ,P-CCTBL ,CC-DEPTR <+ ,P-ACLAUSE 1>>
|
||
<CLAUSE-COPY ,P-OTBL ,P-OTBL .ADJ>
|
||
<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
|
||
<SETG P-ACLAUSE <>>
|
||
<RTRUE>>
|
||
|
||
<ROUTINE NCLAUSE-WIN ()
|
||
<PUT ,P-CCTBL ,CC-SBPTR ,P-NC1>
|
||
<PUT ,P-CCTBL ,CC-SEPTR ,P-NC1L>
|
||
<PUT ,P-CCTBL ,CC-DBPTR ,P-ACLAUSE>
|
||
<PUT ,P-CCTBL ,CC-DEPTR <+ ,P-ACLAUSE 1>>
|
||
<CLAUSE-COPY ,P-ITBL ,P-OTBL>
|
||
<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
|
||
<SETG P-ACLAUSE <>>
|
||
<RTRUE>>
|
||
|
||
;"Print undefined word in input.
|
||
PTR points to the unknown word in P-LEXV"
|
||
|
||
<ROUTINE WORD-PRINT (CNT BUF)
|
||
<REPEAT ()
|
||
<COND (<DLESS? CNT 0> <RETURN>)
|
||
(ELSE
|
||
<PRINTC <GETB ,P-INBUF .BUF>>
|
||
<SET BUF <+ .BUF 1>>)>>>
|
||
|
||
<ROUTINE UNKNOWN-WORD (PTR "AUX" BUF)
|
||
#DECL ((PTR BUF) FIX)
|
||
<COND (<VERB? SAY>
|
||
<TELL "Nothing happens." CR>
|
||
<RFALSE>)>
|
||
<TELL "I don't know the word \"">
|
||
<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
|
||
<GETB <REST ,P-LEXV .BUF> 3>>
|
||
<TELL "\"." CR>
|
||
<COND (<AND <NOT ,UNKNOWN-FLAG> ,TUTORIAL-MODE>
|
||
<SETG UNKNOWN-FLAG T>
|
||
<TELL CR
|
||
"(Here is an example in which a word you typed wasn't in the vocabulary
|
||
of the story. Infocom's interactive fiction recognizes more than 600 words
|
||
(some over 1000) in your inputs, far more than most games, but there are
|
||
limits. In fact, many words used in the story's description won't be
|
||
recognized in your inputs. These words are included merely to enhance your
|
||
mental imagery of locations and events. If a word you use isn't understood,
|
||
it is not important to reaching your goal in the story.)" CR>)>
|
||
<SETG QUOTE-FLAG <>>
|
||
<SETG P-OFLAG <>>>
|
||
|
||
|
||
<GLOBAL UNKNOWN-FLAG <>>
|
||
<GLOBAL CANT-USE-FLAG <>>
|
||
|
||
<ROUTINE CANT-USE (PTR "AUX" BUF)
|
||
#DECL ((PTR BUF) FIX)
|
||
<COND (<VERB? SAY>
|
||
<TELL "Nothing happens." CR>
|
||
<RFALSE>)>
|
||
<TELL "I can't use the word \"">
|
||
<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
|
||
<GETB <REST ,P-LEXV .BUF> 3>>
|
||
<TELL "\" here." CR>
|
||
<COND (<AND <NOT ,CANT-USE-FLAG> ,TUTORIAL-MODE>
|
||
<SETG CANT-USE-FLAG T>
|
||
<TELL CR
|
||
"(This message means that the game knows the word you were using but
|
||
couldn't understand the way you used it in the sentence you typed.
|
||
Perhaps you should try something with a similar meaning.)" CR>)>
|
||
<SETG QUOTE-FLAG <>>
|
||
<SETG P-OFLAG <>>>
|
||
|
||
;" Perform syntax matching operations, using P-ITBL as the source of
|
||
the verb and adjectives for this input. Returns false if no
|
||
syntax matches, and does it's own orphaning. If return is true,
|
||
the syntax is saved in P-SYNTAX."
|
||
|
||
<GLOBAL P-SLOCBITS 0>
|
||
|
||
<CONSTANT P-SYNLEN 8>
|
||
|
||
<CONSTANT P-SBITS 0>
|
||
|
||
<CONSTANT P-SPREP1 1>
|
||
|
||
<CONSTANT P-SPREP2 2>
|
||
|
||
<CONSTANT P-SFWIM1 3>
|
||
|
||
<CONSTANT P-SFWIM2 4>
|
||
|
||
<CONSTANT P-SLOC1 5>
|
||
|
||
<CONSTANT P-SLOC2 6>
|
||
|
||
<CONSTANT P-SACTION 7>
|
||
|
||
<CONSTANT P-SONUMS 3>
|
||
|
||
<ROUTINE SYNTAX-CHECK ("AUX" SYN LEN NUM OBJ
|
||
(DRIVE1 <>) (DRIVE2 <>) PREP VERB TMP)
|
||
<COND (<0? <SET VERB <GET ,P-ITBL ,P-VERB>>>
|
||
<TELL "I can't find a verb in that sentence!" CR>
|
||
<COND (<NOT <ZERO? ,TUTORIAL-MODE>>
|
||
<TELL "|
|
||
(You must begin each sentence with a verb or a special command, like
|
||
\"INVENTORY\", for it to be understood.)" CR>)>
|
||
<RFALSE>)>
|
||
<SET SYN <GET ,VERBS <- 255 .VERB>>>
|
||
<SET LEN <GETB .SYN 0>>
|
||
<SET SYN <REST .SYN>>
|
||
<REPEAT ()
|
||
<SET NUM <BAND <GETB .SYN ,P-SBITS> ,P-SONUMS>>
|
||
<COND (<G? ,P-NCN .NUM> T)
|
||
(<AND <NOT <L? .NUM 1>>
|
||
<0? ,P-NCN>
|
||
<OR <0? <SET PREP <GET ,P-ITBL ,P-PREP1>>>
|
||
<==? .PREP <GETB .SYN ,P-SPREP1>>>>
|
||
<SET DRIVE1 .SYN>)
|
||
(<==? <GETB .SYN ,P-SPREP1> <GET ,P-ITBL ,P-PREP1>>
|
||
<COND (<AND <==? .NUM 2> <==? ,P-NCN 1>>
|
||
<SET DRIVE2 .SYN>)
|
||
(<==? <GETB .SYN ,P-SPREP2>
|
||
<GET ,P-ITBL ,P-PREP2>>
|
||
<SYNTAX-FOUND .SYN>
|
||
<RTRUE>)>)>
|
||
<COND (<DLESS? LEN 1>
|
||
<COND (<OR .DRIVE1 .DRIVE2> <RETURN>)
|
||
(T
|
||
<TELL "I don't understand that sentence." CR>
|
||
<COND (<AND ,TUTORIAL-MODE <NOT ,BAD-SYNTAX>>
|
||
<SETG BAD-SYNTAX T>
|
||
<TELL "|
|
||
(This warning message means that the type of sentence you entered was
|
||
not one that the game normally understands. You should first try to
|
||
rephrase it somewhat differently. If that doesn't work, the idea that
|
||
you are trying to get across is unknown and therefore unimportant to
|
||
the successful completion of the game.)" CR>)>
|
||
<RFALSE>)>)
|
||
(T <SET SYN <REST .SYN ,P-SYNLEN>>)>>
|
||
<COND (<AND .DRIVE1
|
||
<SET OBJ
|
||
<GWIM <GETB .DRIVE1 ,P-SFWIM1>
|
||
<GETB .DRIVE1 ,P-SLOC1>
|
||
<GETB .DRIVE1 ,P-SPREP1>>>>
|
||
<PUT ,P-PRSO ,P-MATCHLEN 1>
|
||
<PUT ,P-PRSO 1 .OBJ>
|
||
<SYNTAX-FOUND .DRIVE1>)
|
||
(<AND .DRIVE2
|
||
<SET OBJ
|
||
<GWIM <GETB .DRIVE2 ,P-SFWIM2>
|
||
<GETB .DRIVE2 ,P-SLOC2>
|
||
<GETB .DRIVE2 ,P-SPREP2>>>>
|
||
<PUT ,P-PRSI ,P-MATCHLEN 1>
|
||
<PUT ,P-PRSI 1 .OBJ>
|
||
<SYNTAX-FOUND .DRIVE2>)
|
||
(<EQUAL? .VERB ,ACT?FIND>
|
||
<TELL "That question can't be answered." CR>
|
||
<GENERIC-COMPLAIN>
|
||
<RFALSE>)
|
||
(<NOT <==? ,WINNER ,PLAYER>>
|
||
<CANT-ORPHAN>)
|
||
(<G? <GET ,P-OCLAUSE ,P-MATCHLEN> 23>
|
||
<PUT ,P-OCLAUSE ,P-MATCHLEN 0>
|
||
<TELL
|
||
"You'd better try typing your sentence from the beginning." CR>
|
||
<RFALSE>)
|
||
(T
|
||
<ORPHAN .DRIVE1 .DRIVE2>
|
||
<TELL "What do you want to ">
|
||
<SET TMP <GET ,P-OTBL ,P-VERBN>>
|
||
<COND (<==? .TMP 0> <TELL "tell">)
|
||
(<0? <GETB ,P-VTBL 2>>
|
||
<PRINTB <GET .TMP 0>>)
|
||
(T
|
||
<WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
|
||
<PUTB ,P-VTBL 2 0>)>
|
||
<COND (.DRIVE2
|
||
<CLAUSE-PRINT ,P-NC1 ,P-NC1L>)>
|
||
<SETG P-OFLAG T>
|
||
<PREP-PRINT <COND (.DRIVE1 <GETB .DRIVE1 ,P-SPREP1>)
|
||
(T <GETB .DRIVE2 ,P-SPREP2>)>>
|
||
<TELL "?" CR>
|
||
<COND (<AND <NOT ,WHAT-TOLD> ,TUTORIAL-MODE>
|
||
<SETG WHAT-TOLD T>
|
||
<TELL CR
|
||
"(Here's an example of a case in which the game felt that a sentence
|
||
was incomplete and couldn't, or wouldn't, figure out how to complete
|
||
it. Simply answer the question asked or retype the entire sentence.
|
||
Remember that in Infocom's interactive fiction, you can type complete
|
||
sentences rather than two-word commands. \"PLACE THE LAMP AND THE SWORD
|
||
IN THE TROPHY CASE\" is a perfectly reasonable kind of thing to type.)" CR>)>
|
||
<RFALSE>)>>
|
||
|
||
<GLOBAL BAD-SYNTAX <>>
|
||
<GLOBAL WHAT-TOLD <>>
|
||
|
||
<ROUTINE CANT-ORPHAN ()
|
||
<TELL "\"I don't understand! What are you referring to?\"" CR>
|
||
<RFALSE>>
|
||
|
||
|
||
;<ROUTINE ORPHAN (D1 D2 "AUX" (CNT -1))
|
||
<PUT ,P-OCLAUSE ,P-MATCHLEN 0>
|
||
<SETG P-CCSRC ,P-ITBL>
|
||
<REPEAT ()
|
||
<COND (<IGRTR? CNT ,P-ITBLLEN> <RETURN>)
|
||
(T <PUT ,P-OTBL .CNT <GET ,P-ITBL .CNT>>)>>
|
||
<COND (<==? ,P-NCN 2> <CLAUSE-COPY ,P-NC2 ,P-NC2L>)>
|
||
<COND (<NOT <L? ,P-NCN 1>> <CLAUSE-COPY ,P-NC1 ,P-NC1L>)>
|
||
<COND (.D1
|
||
<PUT ,P-OTBL ,P-PREP1 <GETB .D1 ,P-SPREP1>>
|
||
<PUT ,P-OTBL ,P-NC1 1>)
|
||
(.D2
|
||
<PUT ,P-OTBL ,P-PREP2 <GETB .D2 ,P-SPREP2>>
|
||
<PUT ,P-OTBL ,P-NC2 1>)>>
|
||
|
||
;"New ORPHAN installed 3/5/85"
|
||
<ROUTINE ORPHAN (D1 D2 "AUX" (CNT -1))
|
||
<COND (<NOT ,P-MERGED>
|
||
<PUT ,P-OCLAUSE ,P-MATCHLEN 0>)>
|
||
<PUT ,P-OVTBL 0 <GET ,P-VTBL 0>>
|
||
<PUTB ,P-OVTBL 2 <GETB ,P-VTBL 2>>
|
||
<PUTB ,P-OVTBL 3 <GETB ,P-VTBL 3>>
|
||
<REPEAT ()
|
||
<COND (<IGRTR? CNT ,P-ITBLLEN> <RETURN>)
|
||
(T <PUT ,P-OTBL .CNT <GET ,P-ITBL .CNT>>)>>
|
||
<COND (<==? ,P-NCN 2>
|
||
<PUT ,P-CCTBL ,CC-SBPTR ,P-NC2>
|
||
<PUT ,P-CCTBL ,CC-SEPTR ,P-NC2L>
|
||
<PUT ,P-CCTBL ,CC-DBPTR ,P-NC2>
|
||
<PUT ,P-CCTBL ,CC-DEPTR ,P-NC2L>
|
||
<CLAUSE-COPY ,P-ITBL ,P-OTBL>)>
|
||
<COND (<NOT <L? ,P-NCN 1>>
|
||
<PUT ,P-CCTBL ,CC-SBPTR ,P-NC1>
|
||
<PUT ,P-CCTBL ,CC-SEPTR ,P-NC1L>
|
||
<PUT ,P-CCTBL ,CC-DBPTR ,P-NC1>
|
||
<PUT ,P-CCTBL ,CC-DEPTR ,P-NC1L>
|
||
<CLAUSE-COPY ,P-ITBL ,P-OTBL>)>
|
||
<COND (.D1
|
||
<PUT ,P-OTBL ,P-PREP1 <GETB .D1 ,P-SPREP1>>
|
||
<PUT ,P-OTBL ,P-NC1 1>)
|
||
(.D2
|
||
<PUT ,P-OTBL ,P-PREP2 <GETB .D2 ,P-SPREP2>>
|
||
<PUT ,P-OTBL ,P-NC2 1>)>>
|
||
|
||
<ROUTINE CLAUSE-PRINT (BPTR EPTR "OPTIONAL" (THE? T))
|
||
<BUFFER-PRINT <GET ,P-ITBL .BPTR> <GET ,P-ITBL .EPTR> .THE?>>
|
||
|
||
<ROUTINE BUFFER-PRINT (BEG END CP "AUX" (NOSP <>) WRD (FIRST?? T) (PN <>))
|
||
<REPEAT ()
|
||
<COND (<==? .BEG .END> <RETURN>)
|
||
(T
|
||
<COND (.NOSP <SET NOSP <>>)
|
||
(T <TELL " ">)>
|
||
<COND (<==? <SET WRD <GET .BEG 0>> ,W?PERIOD>
|
||
<SET NOSP T>)
|
||
(<EQUAL? .WRD ,W?FLOYD>
|
||
<CAPITALIZE .BEG>
|
||
<SET PN T>)
|
||
(T
|
||
<COND (<AND .FIRST?? <NOT .PN> .CP>
|
||
<TELL "the ">)>
|
||
<COND (<OR ,P-OFLAG ,P-MERGED> <PRINTB .WRD>)
|
||
(<AND <==? .WRD ,W?IT>
|
||
<==? ,P-IT-LOC ,HERE>>
|
||
<PRINTD ,P-IT-OBJECT>)
|
||
(T
|
||
<WORD-PRINT <GETB .BEG 2>
|
||
<GETB .BEG 3>>)>
|
||
<SET FIRST?? <>>)>)>
|
||
<SET BEG <REST .BEG ,P-WORDLEN>>>>
|
||
|
||
<ROUTINE CAPITALIZE (PTR)
|
||
<PRINTC <- <GETB ,P-INBUF <GETB .PTR 3>> 32>>
|
||
<WORD-PRINT <- <GETB .PTR 2> 1> <+ <GETB .PTR 3> 1>>>
|
||
|
||
<ROUTINE PREP-PRINT (PREP "AUX" WRD)
|
||
<COND (<NOT <0? .PREP>>
|
||
<TELL " ">
|
||
<SET WRD <PREP-FIND .PREP>>
|
||
<PRINTB .WRD>)>>
|
||
|
||
;<ROUTINE CLAUSE-COPY (BPTR EPTR "OPTIONAL" (INSRT <>) "AUX" BEG END)
|
||
<SET BEG <GET ,P-CCSRC .BPTR>>
|
||
<SET END <GET ,P-CCSRC .EPTR>>
|
||
<PUT ,P-OTBL
|
||
.BPTR
|
||
<REST ,P-OCLAUSE
|
||
<+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN> 2>>>
|
||
<REPEAT ()
|
||
<COND (<==? .BEG .END>
|
||
<PUT ,P-OTBL
|
||
.EPTR
|
||
<REST ,P-OCLAUSE
|
||
<+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN>
|
||
2>>>
|
||
<RETURN>)
|
||
(T
|
||
<COND (<AND .INSRT <==? ,P-ANAM <GET .BEG 0>>>
|
||
<CLAUSE-ADD .INSRT>)>
|
||
<CLAUSE-ADD <GET .BEG 0>>)>
|
||
<SET BEG <REST .BEG ,P-WORDLEN>>>>
|
||
|
||
;"New CLAUSE-COPY put in 3/5/85"
|
||
<ROUTINE CLAUSE-COPY (SRC DEST "OPTIONAL" (INSRT <>) "AUX" BEG END)
|
||
<SET BEG <GET .SRC <GET ,P-CCTBL ,CC-SBPTR>>>
|
||
<SET END <GET .SRC <GET ,P-CCTBL ,CC-SEPTR>>>
|
||
<PUT .DEST
|
||
<GET ,P-CCTBL ,CC-DBPTR>
|
||
<REST ,P-OCLAUSE
|
||
<+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN> 2>>>
|
||
<REPEAT ()
|
||
<COND (<==? .BEG .END>
|
||
<PUT .DEST
|
||
<GET ,P-CCTBL ,CC-DEPTR>
|
||
<REST ,P-OCLAUSE
|
||
<+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN>
|
||
2>>>
|
||
<RETURN>)
|
||
(T
|
||
<COND (<AND .INSRT <==? ,P-ANAM <GET .BEG 0>>>
|
||
<CLAUSE-ADD .INSRT>)>
|
||
<CLAUSE-ADD <GET .BEG 0>>)>
|
||
<SET BEG <REST .BEG ,P-WORDLEN>>>>
|
||
|
||
<ROUTINE CLAUSE-ADD (WRD "AUX" PTR)
|
||
<SET PTR <+ <GET ,P-OCLAUSE ,P-MATCHLEN> 2>>
|
||
<PUT ,P-OCLAUSE <- .PTR 1> .WRD>
|
||
<PUT ,P-OCLAUSE .PTR 0>
|
||
<PUT ,P-OCLAUSE ,P-MATCHLEN .PTR>>
|
||
|
||
<ROUTINE PREP-FIND (PREP "AUX" (CNT 0) SIZE)
|
||
<SET SIZE <* <GET ,PREPOSITIONS 0> 2>>
|
||
<REPEAT ()
|
||
<COND (<IGRTR? CNT .SIZE> <RFALSE>)
|
||
(<==? <GET ,PREPOSITIONS .CNT> .PREP>
|
||
<RETURN <GET ,PREPOSITIONS <- .CNT 1>>>)>>>
|
||
|
||
<ROUTINE SYNTAX-FOUND (SYN)
|
||
<SETG P-SYNTAX .SYN>
|
||
<SETG PRSA <GETB .SYN ,P-SACTION>>>
|
||
|
||
<GLOBAL P-GWIMBIT 0>
|
||
|
||
<ROUTINE GWIM (GBIT LBIT PREP "AUX" OBJ)
|
||
<COND (<==? .GBIT ,RMUNGBIT>
|
||
<RETURN ,ROOMS>)>
|
||
<SETG P-GWIMBIT .GBIT>
|
||
<SETG P-SLOCBITS .LBIT>
|
||
<PUT ,P-MERGE ,P-MATCHLEN 0>
|
||
<COND (<GET-OBJECT ,P-MERGE <>>
|
||
<SETG P-GWIMBIT 0>
|
||
<COND (<==? <GET ,P-MERGE ,P-MATCHLEN> 1>
|
||
<COND (<EQUAL? <SET OBJ <GET ,P-MERGE 1>> ,ME>
|
||
<RFALSE>)>
|
||
<TELL "(">
|
||
<COND (<NOT <0? .PREP>>
|
||
<PRINTB <SET PREP <PREP-FIND .PREP>>>
|
||
<COND (<==? .PREP ,W?OUT>
|
||
<TELL " of">)>
|
||
<COND (<==? .OBJ ,HANDS>
|
||
<TELL " your hands)" CR>)
|
||
(T
|
||
<TELL " the ">)>)>
|
||
<COND (<NOT <==? .OBJ ,HANDS>>
|
||
<TELL D .OBJ ")" CR>)>
|
||
<COND (<AND <NOT ,GWIM-TOLD> ,TUTORIAL-MODE>
|
||
<SETG GWIM-TOLD T>
|
||
<TELL CR
|
||
"(This last statement in parentheses was part of the story, not the
|
||
tutorial. The story recognized that something was missing from the
|
||
sentence you typed and attempted to figure out what it might have
|
||
been. In this case, it figured that the " D .OBJ " was the
|
||
only reasonable thing to use.|
|
||
|
|
||
Unlike many other \"adventure games\", you may type complex sentences when
|
||
playing Infocom's interactive fiction. Such sentences as \"PUT THE LAMP
|
||
AND THE SWORD IN THE TROPHY CASE\" or \"UNLOCK THE WOODEN DOOR USING THE
|
||
RUSTY OLD KEY\" are perfectly reasonable. Let's continue.)" CR CR>)>
|
||
.OBJ)>)
|
||
(T <SETG P-GWIMBIT 0> <RFALSE>)>>
|
||
|
||
<GLOBAL GWIM-TOLD <>>
|
||
|
||
<ROUTINE SNARF-OBJECTS ("AUX" PTR)
|
||
<COND (<NOT <==? <SET PTR <GET ,P-ITBL ,P-NC1>> 0>>
|
||
<SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC1>>
|
||
<OR <SNARFEM .PTR <GET ,P-ITBL ,P-NC1L> ,P-PRSO> <RFALSE>>
|
||
<OR <0? <GET ,P-BUTS ,P-MATCHLEN>>
|
||
<SETG P-PRSO <BUT-MERGE ,P-PRSO>>>)>
|
||
<COND (<NOT <==? <SET PTR <GET ,P-ITBL ,P-NC2>> 0>>
|
||
<SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC2>>
|
||
<OR <SNARFEM .PTR <GET ,P-ITBL ,P-NC2L> ,P-PRSI> <RFALSE>>
|
||
<COND (<NOT <0? <GET ,P-BUTS ,P-MATCHLEN>>>
|
||
<COND (<==? <GET ,P-PRSI ,P-MATCHLEN> 1>
|
||
<SETG P-PRSO <BUT-MERGE ,P-PRSO>>)
|
||
(T <SETG P-PRSI <BUT-MERGE ,P-PRSI>>)>)>)>
|
||
<RTRUE>>
|
||
|
||
<ROUTINE BUT-MERGE (TBL "AUX" LEN BUTLEN (CNT 1) (MATCHES 0) OBJ NTBL)
|
||
<SET LEN <GET .TBL ,P-MATCHLEN>>
|
||
<PUT ,P-MERGE ,P-MATCHLEN 0>
|
||
<REPEAT ()
|
||
<COND (<DLESS? LEN 0> <RETURN>)
|
||
(<ZMEMQ <SET OBJ <GET .TBL .CNT>> ,P-BUTS>)
|
||
(T
|
||
<PUT ,P-MERGE <+ .MATCHES 1> .OBJ>
|
||
<SET MATCHES <+ .MATCHES 1>>)>
|
||
<SET CNT <+ .CNT 1>>>
|
||
<PUT ,P-MERGE ,P-MATCHLEN .MATCHES>
|
||
<SET NTBL ,P-MERGE>
|
||
<SETG P-MERGE .TBL>
|
||
.NTBL>
|
||
|
||
<GLOBAL P-NAM <>>
|
||
|
||
<GLOBAL P-ADJ <>>
|
||
|
||
<GLOBAL P-ADVERB <>>
|
||
|
||
<GLOBAL P-ADJN <>>
|
||
|
||
<GLOBAL P-PRSO <ITABLE NONE 50>>
|
||
|
||
<GLOBAL P-PRSI <ITABLE NONE 50>>
|
||
|
||
<GLOBAL P-BUTS <ITABLE NONE 50>>
|
||
|
||
<GLOBAL P-MERGE <ITABLE NONE 50>>
|
||
|
||
<GLOBAL P-OCLAUSE <ITABLE NONE 50>>
|
||
|
||
<GLOBAL P-MATCHLEN 0>
|
||
|
||
<GLOBAL P-GETFLAGS 0>
|
||
|
||
<CONSTANT P-ALL 1>
|
||
|
||
<CONSTANT P-ONE 2>
|
||
|
||
<CONSTANT P-INHIBIT 4>
|
||
|
||
<GLOBAL P-CSPTR <>>
|
||
<GLOBAL P-CEPTR <>>
|
||
|
||
;"Next GLOBAL 6/21/84 for WHICH retrofix"
|
||
<GLOBAL P-AND <>>
|
||
|
||
<ROUTINE SNARFEM (PTR EPTR TBL "AUX" (BUT <>) LEN WV WRD NW)
|
||
;"Next SETG 6/21/84 for WHICH retrofix"
|
||
<SETG P-AND <>>
|
||
<SETG P-GETFLAGS 0>
|
||
<SETG P-CSPTR .PTR>
|
||
<SETG P-CEPTR .EPTR>
|
||
<PUT ,P-BUTS ,P-MATCHLEN 0>
|
||
<PUT .TBL ,P-MATCHLEN 0>
|
||
<SET WRD <GET .PTR 0>>
|
||
<REPEAT ()
|
||
<COND (<==? .PTR .EPTR> <RETURN <GET-OBJECT <OR .BUT .TBL>>>)
|
||
(T
|
||
<SET NW <GET .PTR ,P-LEXELEN>>
|
||
<COND (<==? .WRD ,W?ALL>
|
||
<SETG P-GETFLAGS ,P-ALL>
|
||
<COND (<==? .NW ,W?OF>
|
||
<SET PTR <REST .PTR ,P-WORDLEN>>)>)
|
||
(<EQUAL? .WRD ,W?BUT ,W?EXCEPT>
|
||
<OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
|
||
<SET BUT ,P-BUTS>
|
||
<PUT .BUT ,P-MATCHLEN 0>)
|
||
(<EQUAL? .WRD ,W?A ,W?ONE>
|
||
<COND (<NOT ,P-ADJ>
|
||
<SETG P-GETFLAGS ,P-ONE>
|
||
<COND (<==? .NW ,W?OF>
|
||
<SET PTR <REST .PTR ,P-WORDLEN>>)>)
|
||
(T
|
||
<SETG P-NAM ,P-ONEOBJ>
|
||
<OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
|
||
<AND <0? .NW> <RTRUE>>)>)
|
||
(<AND <EQUAL? .WRD ,W?AND ,W?COMMA>
|
||
<NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
|
||
;"Next SETG 6/21/84 for WHICH retrofix"
|
||
<SETG P-AND T>
|
||
<OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
|
||
T)
|
||
(<WT? .WRD ,PS?BUZZ-WORD>)
|
||
(<EQUAL? .WRD ,W?AND ,W?COMMA>)
|
||
(<==? .WRD ,W?OF>
|
||
<COND (<0? ,P-GETFLAGS>
|
||
<SETG P-GETFLAGS ,P-INHIBIT>)>)
|
||
(<AND <SET WV <WT? .WRD ,PS?ADJECTIVE ,P1?ADJECTIVE>>
|
||
<ADJ-CHECK>>
|
||
<SETG P-ADJ .WV>
|
||
<SETG P-ADJN .WRD>)
|
||
(<WT? .WRD ,PS?OBJECT ,P1?OBJECT>
|
||
<SETG P-NAM .WRD>
|
||
<SETG P-ONEOBJ .WRD>)>)>
|
||
<COND (<NOT <==? .PTR .EPTR>>
|
||
<SET PTR <REST .PTR ,P-WORDLEN>>
|
||
<SET WRD .NW>)>>>
|
||
|
||
<ROUTINE ADJ-CHECK ()
|
||
<COND (<NOT ,P-ADJ>
|
||
<RTRUE>)
|
||
(<EQUAL? ,P-ADJ ,A?SQUARE ,A?ROUND>
|
||
<RFALSE>)
|
||
(T
|
||
<RTRUE>)>>
|
||
|
||
<CONSTANT SH 128>
|
||
|
||
<CONSTANT SC 64>
|
||
|
||
<CONSTANT SIR 32>
|
||
|
||
<CONSTANT SOG 16>
|
||
|
||
<CONSTANT STAKE 8>
|
||
|
||
<CONSTANT SMANY 4>
|
||
|
||
<CONSTANT SHAVE 2>
|
||
|
||
<ROUTINE GET-OBJECT (TBL
|
||
"OPTIONAL" (VRB T)
|
||
"AUX" BITS LEN XBITS TLEN (GCHECK <>) (OLEN 0) OBJ)
|
||
<SET XBITS ,P-SLOCBITS>
|
||
<SET TLEN <GET .TBL ,P-MATCHLEN>>
|
||
<COND (<BTST ,P-GETFLAGS ,P-INHIBIT> <RTRUE>)>
|
||
<COND (<AND <NOT ,P-NAM> ,P-ADJ <WT? ,P-ADJN ,PS?OBJECT ,P1?OBJECT>>
|
||
<SETG P-NAM ,P-ADJN>
|
||
<SETG P-ADJ <>>)>
|
||
<COND (<AND <NOT ,P-NAM>
|
||
<NOT ,P-ADJ>
|
||
<NOT <==? ,P-GETFLAGS ,P-ALL>>
|
||
<0? ,P-GWIMBIT>>
|
||
<COND (.VRB
|
||
<TELL
|
||
"There seems to be a noun missing in that sentence!" CR>
|
||
<COND (<AND ,TUTORIAL-MODE <NOT ,NOUN-MISS>>
|
||
<SETG NOUN-MISS T>
|
||
<TELL "|
|
||
(This message means that the game thought that your sentence should have
|
||
another noun in it somewhere. The most common cause of this is an incomplete
|
||
sentence such as \"PUT THE LAMP IN\", where the game was expecting another
|
||
noun. At other times, the game has misunderstood one of the other words
|
||
in your sentence. Try another way of expressing your idea.)" CR>)>)>
|
||
<RFALSE>)>
|
||
<COND (<OR <NOT <==? ,P-GETFLAGS ,P-ALL>> <0? ,P-SLOCBITS>>
|
||
<SETG P-SLOCBITS -1>)>
|
||
<SETG P-TABLE .TBL>
|
||
<PROG ()
|
||
<COND (.GCHECK <GLOBAL-CHECK .TBL>)
|
||
(T
|
||
<COND (<NOT <ZERO? ,LIT>>
|
||
<FCLEAR ,PLAYER ,TRANSBIT>
|
||
<DO-SL ,HERE ,SOG ,SIR>
|
||
<FSET ,PLAYER ,TRANSBIT>)>
|
||
<DO-SL ,PLAYER ,SH ,SC>)>
|
||
<SET LEN <- <GET .TBL ,P-MATCHLEN> .TLEN>>
|
||
<COND (<BTST ,P-GETFLAGS ,P-ALL>)
|
||
(<AND <BTST ,P-GETFLAGS ,P-ONE>
|
||
<NOT <0? .LEN>>>
|
||
<COND (<NOT <==? .LEN 1>>
|
||
<PUT .TBL 1 <GET .TBL <RANDOM .LEN>>>
|
||
<TELL "(How about the ">
|
||
<PRINTD <GET .TBL 1>>
|
||
<TELL "?)" CR>)>
|
||
<PUT .TBL ,P-MATCHLEN 1>)
|
||
(<OR <G? .LEN 1>
|
||
<AND <0? .LEN> <NOT <==? ,P-SLOCBITS -1>>>>
|
||
<COND (<==? ,P-SLOCBITS -1>
|
||
<SETG P-SLOCBITS .XBITS>
|
||
<SET OLEN .LEN>
|
||
<PUT .TBL
|
||
,P-MATCHLEN
|
||
<- <GET .TBL ,P-MATCHLEN> .LEN>>
|
||
<AGAIN>)
|
||
(T
|
||
<COND (<0? .LEN> <SET LEN .OLEN>)>
|
||
<COND (<NOT <==? ,WINNER ,PLAYER>>
|
||
<CANT-ORPHAN>
|
||
<RFALSE>)
|
||
(<AND ,P-NAM
|
||
<VERB? EXAMINE TAKE LAMP-ON
|
||
BURN DROP FIND>
|
||
<SET OBJ <GET .TBL <+ .TLEN 1>>>
|
||
<SET OBJ
|
||
<APPLY
|
||
<GETP .OBJ ,P?GENERIC> .OBJ>>>
|
||
<PUT .TBL 1 .OBJ>
|
||
<PUT .TBL ,P-MATCHLEN 1>
|
||
<SETG P-NAM <>>
|
||
<SETG P-ADJ <>>
|
||
<RTRUE>)
|
||
(<G? <GET ,P-OCLAUSE ,P-MATCHLEN> 23>
|
||
<PUT ,P-OCLAUSE ,P-MATCHLEN 0>
|
||
<TELL
|
||
"You'd better try typing your sentence again from the beginning." CR>)
|
||
(<AND .VRB ,P-NAM>
|
||
<WHICH-PRINT .TLEN .LEN .TBL>
|
||
<SETG P-ACLAUSE
|
||
<COND (<==? .TBL ,P-PRSO> ,P-NC1)
|
||
(T ,P-NC2)>>
|
||
<SETG P-AADJ ,P-ADJ>
|
||
<SETG P-ANAM ,P-NAM>
|
||
<ORPHAN <> <>>
|
||
<SETG P-OFLAG T>)
|
||
(.VRB
|
||
<TELL
|
||
"There seems to be a noun missing in that sentence!" CR>)>
|
||
<SETG P-NAM <>>
|
||
<SETG P-ADJ <>>
|
||
<RFALSE>)>)
|
||
(<AND <0? .LEN> .GCHECK>
|
||
<COND (.VRB
|
||
<SETG P-SLOCBITS .XBITS>
|
||
<COND (<NOT <ZERO? ,LIT>>
|
||
;"Changed 6/10/83 - MARC"
|
||
<OBJ-FOUND ,NOT-HERE-OBJECT .TBL>
|
||
<SETG P-XNAM ,P-NAM>
|
||
<SETG P-XADJ ,P-ADJ>
|
||
<SETG P-XADJN ,P-ADJN>
|
||
<SETG P-NAM <>>
|
||
<SETG P-ADJ <>>
|
||
<SETG P-ADJN <>>
|
||
<RTRUE>)
|
||
(T
|
||
<TELL "It's too dark to see!" CR>
|
||
<COND (<NOT <ZERO? ,TUTORIAL-MODE>>
|
||
<TELL "|
|
||
(It's dark here in the broom closet. The game won't let you refer
|
||
to objects that you cannot see!)" CR>)>)>)>
|
||
<SETG P-NAM <>>
|
||
<SETG P-ADJ <>>
|
||
<RFALSE>)
|
||
(<0? .LEN> <SET GCHECK T> <AGAIN>)>
|
||
<SETG P-SLOCBITS .XBITS>
|
||
<SETG P-XNAM ,P-NAM> ;"for elevator hacking"
|
||
<SETG P-NAM <>>
|
||
<SETG P-ADJ <>>
|
||
<RTRUE>>>
|
||
|
||
<GLOBAL NOUN-MISS <>>
|
||
|
||
;<ROUTINE MOBY-FIND (TBL "AUX" FOO LEN)
|
||
;"not referenced, removed 2/27/85 by SEM"
|
||
<SETG P-SLOCBITS -1>
|
||
<SETG P-NAM ,P-XNAM>
|
||
<SETG P-ADJ ,P-XADJ>
|
||
<PUT .TBL ,P-MATCHLEN 0>
|
||
<SET FOO <FIRST? ,ROOMS>>
|
||
<REPEAT ()
|
||
<COND (<NOT .FOO> <RETURN>)
|
||
(T
|
||
<SEARCH-LIST .FOO .TBL ,P-SRCALL>
|
||
<SET FOO <NEXT? .FOO>>)>>
|
||
<COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 0>
|
||
<DO-SL ,LOCAL-GLOBALS 1 1>)>
|
||
<COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 0>
|
||
<DO-SL ,ROOMS 1 1>)>
|
||
<COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 1>
|
||
<SETG P-MOBY-FOUND <GET .TBL 1>>)>
|
||
<SETG P-NAM <>>
|
||
<SETG P-ADJ <>>
|
||
.LEN>
|
||
|
||
;<GLOBAL P-MOBY-FOUND <>>
|
||
<GLOBAL P-XNAM <>>
|
||
<GLOBAL P-XADJ <>>
|
||
<GLOBAL P-XADJN <>>
|
||
|
||
<ROUTINE WHICH-PRINT (TLEN LEN TBL "AUX" OBJ RLEN)
|
||
<SET RLEN .LEN>
|
||
<TELL "Which">
|
||
<COND (;"P-AND added to OR on 6/21/84 for WHICH retrofix"
|
||
<OR ,P-OFLAG
|
||
,P-MERGED
|
||
,P-AND>
|
||
<TELL " ">
|
||
<PRINTB ,P-NAM>)
|
||
(<==? .TBL ,P-PRSO>
|
||
<CLAUSE-PRINT ,P-NC1 ,P-NC1L <>>)
|
||
(T <CLAUSE-PRINT ,P-NC2 ,P-NC2L <>>)>
|
||
<TELL " do you mean, ">
|
||
<REPEAT ()
|
||
<SET TLEN <+ .TLEN 1>>
|
||
<SET OBJ <GET .TBL .TLEN>>
|
||
<TELL "the " D .OBJ>
|
||
<COND (<==? .LEN 2>
|
||
<COND (<NOT <==? .RLEN 2>> <TELL ",">)>
|
||
<TELL " or ">)
|
||
(<G? .LEN 2> <TELL ", ">)>
|
||
<COND (<L? <SET LEN <- .LEN 1>> 1>
|
||
<TELL "?" CR>
|
||
<RETURN>)>>
|
||
<COND (<AND <NOT ,WHICH-TOLD> ,TUTORIAL-MODE>
|
||
<SETG WHICH-TOLD T>
|
||
<TELL CR
|
||
"(This demonstrates another feature of our interactive fiction: the ability
|
||
to use adjectives in sentences. In this case, the word \"">
|
||
<PRINTB ,P-NAM>
|
||
<TELL "\" was confusing because there were ">
|
||
<TELL <GET ,NUM-TBL .RLEN>>
|
||
<TELL " of them in your location. You can answer the
|
||
question posed either by typing the entire sentence or, more easily,
|
||
by typing an adjective that will clear up the confusion. Do one of
|
||
those things now.)" CR>)>>
|
||
|
||
<GLOBAL NUM-TBL <TABLE 0 "one" "two" "three">>
|
||
|
||
<GLOBAL WHICH-TOLD <>>
|
||
|
||
|
||
<ROUTINE GLOBAL-CHECK (TBL "AUX" LEN RMG RMGL (CNT 0) OBJ OBITS FOO)
|
||
<SET LEN <GET .TBL ,P-MATCHLEN>>
|
||
<SET OBITS ,P-SLOCBITS>
|
||
<COND (<SET RMG <GETPT ,HERE ,P?GLOBAL>>
|
||
<SET RMGL <- <PTSIZE .RMG> 1>>
|
||
<REPEAT ()
|
||
<COND (<THIS-IT? <SET OBJ <GETB .RMG .CNT>> .TBL>
|
||
<OBJ-FOUND .OBJ .TBL>)>
|
||
<COND (<IGRTR? CNT .RMGL> <RETURN>)>>)>
|
||
<COND (<SET RMG <GETPT ,HERE ,P?PSEUDO>>
|
||
<SET RMGL <- </ <PTSIZE .RMG> 4> 1>>
|
||
<SET CNT 0>
|
||
<REPEAT ()
|
||
<COND (<==? ,P-NAM <GET .RMG <* .CNT 2>>>
|
||
<PUTP ,PSEUDO-OBJECT
|
||
,P?ACTION
|
||
<GET .RMG <+ <* .CNT 2> 1>>>
|
||
<SET FOO
|
||
<BACK <GETPT ,PSEUDO-OBJECT ,P?ACTION> 5>>
|
||
<PUT .FOO 0 <GET ,P-NAM 0>>
|
||
<PUT .FOO 1 <GET ,P-NAM 1>>
|
||
<OBJ-FOUND ,PSEUDO-OBJECT .TBL>
|
||
<RETURN>)
|
||
(<IGRTR? CNT .RMGL> <RETURN>)>>)>
|
||
<COND (<==? <GET .TBL ,P-MATCHLEN> .LEN>
|
||
<SETG P-SLOCBITS -1>
|
||
<SETG P-TABLE .TBL>
|
||
<DO-SL ,GLOBAL-OBJECTS 1 1>
|
||
<SETG P-SLOCBITS .OBITS>
|
||
<COND (<AND <0? <GET .TBL ,P-MATCHLEN>>
|
||
<EQUAL? ,PRSA ,V?LOOK-INSIDE ,V?SEARCH ,V?EXAMINE>>
|
||
<DO-SL ,ROOMS 1 1>)>)>>
|
||
|
||
<ROUTINE DO-SL (OBJ BIT1 BIT2 "AUX" BTS)
|
||
<COND (<BTST ,P-SLOCBITS <+ .BIT1 .BIT2>>
|
||
<SEARCH-LIST .OBJ ,P-TABLE ,P-SRCALL>)
|
||
(T
|
||
<COND (<BTST ,P-SLOCBITS .BIT1>
|
||
<SEARCH-LIST .OBJ ,P-TABLE ,P-SRCTOP>)
|
||
(<BTST ,P-SLOCBITS .BIT2>
|
||
<SEARCH-LIST .OBJ ,P-TABLE ,P-SRCBOT>)
|
||
(T <RTRUE>)>)>>
|
||
|
||
<CONSTANT P-SRCBOT 2>
|
||
|
||
<CONSTANT P-SRCTOP 0>
|
||
|
||
<CONSTANT P-SRCALL 1>
|
||
|
||
<ROUTINE SEARCH-LIST (OBJ TBL LVL "AUX" FLS NOBJ)
|
||
<COND (<SET OBJ <FIRST? .OBJ>>
|
||
<REPEAT ()
|
||
<COND (<AND <NOT <==? .LVL ,P-SRCBOT>>
|
||
<GETPT .OBJ ,P?SYNONYM>
|
||
<THIS-IT? .OBJ .TBL>>
|
||
<OBJ-FOUND .OBJ .TBL>)>
|
||
<COND (<AND <OR <NOT <==? .LVL ,P-SRCTOP>>
|
||
<FSET? .OBJ ,SEARCHBIT>
|
||
<FSET? .OBJ ,SURFACEBIT>>
|
||
<SET NOBJ <FIRST? .OBJ>>
|
||
<OR <FSET? .OBJ ,OPENBIT>
|
||
<FSET? .OBJ ,TRANSBIT>>>
|
||
<SET FLS
|
||
<SEARCH-LIST .OBJ
|
||
.TBL
|
||
<COND (<FSET? .OBJ ,SURFACEBIT>
|
||
,P-SRCALL)
|
||
(<FSET? .OBJ ,SEARCHBIT>
|
||
,P-SRCALL)
|
||
(T ,P-SRCTOP)>>>)>
|
||
<COND (<SET OBJ <NEXT? .OBJ>>) (T <RETURN>)>>)>>
|
||
|
||
<ROUTINE OBJ-FOUND (OBJ TBL "AUX" PTR)
|
||
<SET PTR <GET .TBL ,P-MATCHLEN>>
|
||
<PUT .TBL <+ .PTR 1> .OBJ>
|
||
<PUT .TBL ,P-MATCHLEN <+ .PTR 1>>>
|
||
|
||
<ROUTINE TAKE-CHECK ()
|
||
<AND <ITAKE-CHECK ,P-PRSO <GETB ,P-SYNTAX ,P-SLOC1>>
|
||
<ITAKE-CHECK ,P-PRSI <GETB ,P-SYNTAX ,P-SLOC2>>>>
|
||
|
||
<ROUTINE ITAKE-CHECK (TBL IBITS "AUX" PTR OBJ TAKEN)
|
||
#DECL ((TBL) TABLE (IBITS PTR) FIX (OBJ) OBJECT
|
||
(TAKEN) <OR FALSE FIX ATOM>)
|
||
<COND (<AND <SET PTR <GET .TBL ,P-MATCHLEN>>
|
||
<OR <BTST .IBITS ,SHAVE>
|
||
<BTST .IBITS ,STAKE>>>
|
||
<REPEAT ()
|
||
<COND (<L? <SET PTR <- .PTR 1>> 0> <RETURN>)
|
||
(T
|
||
<SET OBJ <GET .TBL <+ .PTR 1>>>
|
||
<COND (<==? .OBJ ,IT> <SET OBJ ,P-IT-OBJECT>)>
|
||
<COND (<AND <NOT <HELD? .OBJ>>
|
||
<NOT <==? .OBJ ,HANDS>>
|
||
<EQUAL? ,WINNER ,PLAYER>> ;"JW 3/85"
|
||
<SETG PRSO .OBJ>
|
||
<COND (<FSET? .OBJ ,TRYTAKEBIT>
|
||
<SET TAKEN T>)
|
||
(<NOT <==? ,WINNER ,ADVENTURER>>
|
||
<SET TAKEN <>>)
|
||
(<AND <BTST .IBITS ,STAKE>
|
||
<NOT ,TUTORIAL-MODE>
|
||
<==? <ITAKE <>> T>>
|
||
<SET TAKEN <>>)
|
||
(T <SET TAKEN T>)>
|
||
<COND (<AND .TAKEN <BTST .IBITS ,SHAVE>>
|
||
<COND (<EQUAL? .OBJ
|
||
,NOT-HERE-OBJECT>
|
||
<TELL
|
||
"You don't have that!" CR>
|
||
<RFALSE>)>
|
||
<TELL "You don't have the ">
|
||
<PRINTD .OBJ>
|
||
<TELL "." CR>
|
||
<RFALSE>)
|
||
(<AND <NOT .TAKEN>
|
||
<==? ,WINNER ,ADVENTURER>>
|
||
<TELL "(Taken)" CR>)>)>)>>)
|
||
(T)>>
|
||
|
||
<ROUTINE MANY-CHECK ("AUX" (LOSS <>) TMP)
|
||
<COND (<AND <G? <GET ,P-PRSO ,P-MATCHLEN> 1>
|
||
<NOT <BTST <GETB ,P-SYNTAX ,P-SLOC1> ,SMANY>>>
|
||
<SET LOSS 1>)
|
||
(<AND <G? <GET ,P-PRSI ,P-MATCHLEN> 1>
|
||
<NOT <BTST <GETB ,P-SYNTAX ,P-SLOC2> ,SMANY>>>
|
||
<SET LOSS 2>)>
|
||
<COND (.LOSS
|
||
<TELL "You can't use multiple ">
|
||
<COND (<==? .LOSS 2> <TELL "in">)>
|
||
<TELL "direct objects with \"">
|
||
<SET TMP <GET ,P-ITBL ,P-VERBN>>
|
||
<COND (<0? .TMP> <TELL "tell">)
|
||
(<OR ,P-OFLAG ,P-MERGED>
|
||
<PRINTB <GET .TMP 0>>)
|
||
(T
|
||
<WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>)>
|
||
<TELL "\"." CR>
|
||
<GENERIC-COMPLAIN>
|
||
<RFALSE>)
|
||
(T)>>
|
||
|
||
<ROUTINE ZMEMQ (ITM TBL "OPTIONAL" (SIZE -1) "AUX" (CNT 1))
|
||
<COND (<NOT .TBL> <RFALSE>)>
|
||
<COND (<NOT <L? .SIZE 0>> <SET CNT 0>)
|
||
(ELSE <SET SIZE <GET .TBL 0>>)>
|
||
<REPEAT ()
|
||
<COND (<==? .ITM <GET .TBL .CNT>> <RTRUE>)
|
||
(<IGRTR? CNT .SIZE> <RFALSE>)>>>
|
||
|
||
<ROUTINE ZMEMQB (ITM TBL SIZE "AUX" (CNT 0))
|
||
<REPEAT ()
|
||
<COND (<==? .ITM <GETB .TBL .CNT>> <RTRUE>)
|
||
(<IGRTR? CNT .SIZE> <RFALSE>)>>>
|
||
|
||
;<GLOBAL ALWAYS-LIT <>>
|
||
|
||
<ROUTINE LIT? (RM "OPTIONAL" (RMBIT T) "AUX" OHERE (LIT <>))
|
||
;<COND (<AND ,ALWAYS-LIT <EQUAL? ,WINNER ,PLAYER>>
|
||
<RTRUE>)>
|
||
<SETG P-GWIMBIT ,ONBIT>
|
||
<SET OHERE ,HERE>
|
||
<SETG HERE .RM>
|
||
<COND (<AND .RMBIT
|
||
<FSET? .RM ,ONBIT>>
|
||
<SET LIT T>)
|
||
(T
|
||
<PUT ,P-MERGE ,P-MATCHLEN 0>
|
||
<SETG P-TABLE ,P-MERGE>
|
||
<SETG P-SLOCBITS -1>
|
||
<COND (<==? .OHERE .RM>
|
||
<DO-SL ,WINNER 1 1>
|
||
<COND (<AND <NOT <EQUAL? ,WINNER ,PLAYER>>
|
||
<IN? ,PLAYER .RM>>
|
||
<DO-SL ,PLAYER 1 1>)>)>
|
||
<DO-SL .RM 1 1>
|
||
<COND (<G? <GET ,P-TABLE ,P-MATCHLEN> 0> <SET LIT T>)>)>
|
||
<SETG HERE .OHERE>
|
||
<SETG P-GWIMBIT 0>
|
||
.LIT>
|
||
|
||
;<ROUTINE PRSO-PRINT ("AUX" PTR) ;"not referenced, removed 2/27/85 by SEM"
|
||
<COND (<OR ,P-MERGED
|
||
<==? <GET <SET PTR <GET ,P-ITBL ,P-NC1>> 0> ,W?IT>>
|
||
<TELL " " D ,PRSO>)
|
||
(T <BUFFER-PRINT .PTR <GET ,P-ITBL ,P-NC1L> <>>)>>
|
||
|
||
;<ROUTINE PRSI-PRINT ("AUX" PTR) ;"not referenced, removed 2/27/85 by SEM"
|
||
<COND (<OR ,P-MERGED
|
||
<==? <GET <SET PTR <GET ,P-ITBL ,P-NC2>> 0> ,W?IT>>
|
||
<TELL " " D ,PRSO>)
|
||
(T <BUFFER-PRINT .PTR <GET ,P-ITBL ,P-NC2L> <>>)>>
|
||
|
||
;"former CRUFTY routine, re-written by SWG"
|
||
|
||
<ROUTINE THIS-IT? (OBJ TBL "AUX" SYNS)
|
||
<COND (<FSET? .OBJ ,INVISIBLE> <RFALSE>)
|
||
(<AND ,P-NAM
|
||
<NOT <ZMEMQ ,P-NAM
|
||
<SET SYNS <GETPT .OBJ ,P?SYNONYM>>
|
||
<- </ <PTSIZE .SYNS> 2> 1>>>>
|
||
<RFALSE>)
|
||
(<AND ,P-ADJ
|
||
<OR <NOT <SET SYNS <GETPT .OBJ ,P?ADJECTIVE>>>
|
||
<NOT <ZMEMQB ,P-ADJ .SYNS <- <PTSIZE .SYNS> 1>>>>>
|
||
<RFALSE>)
|
||
(<AND <NOT <0? ,P-GWIMBIT>> <NOT <FSET? .OBJ ,P-GWIMBIT>>>
|
||
<RFALSE>)>
|
||
<RTRUE>>
|
||
|
||
<ROUTINE GENERIC-COMPLAIN ()
|
||
<COND (<NOT <ZERO? ,TUTORIAL-MODE>>
|
||
<TELL CR
|
||
"(Here is an example of something the game might print when it doesn't
|
||
understand what you are saying. When this happens, try something slightly
|
||
different. If nothing you are doing seems to work, try a different idea
|
||
altogether.)" CR>)>> |