commit 3a4d17d26aec57cc3598dfe23bfc431276a56f3b
Author: historicalsource <historicalsoftware@textfiles.com>
Date:   Sun Apr 14 00:26:43 2019 -0400

    Revision 63 (Original Source)

diff --git a/README.md b/README.md
new file mode 100644
index 0000000..4ee2b48
--- /dev/null
+++ b/README.md
@@ -0,0 +1 @@
+# spellbreaker
diff --git a/c1.zil b/c1.zil
new file mode 100644
index 0000000..c9def43
--- /dev/null
+++ b/c1.zil
@@ -0,0 +1,1903 @@
+"C1 for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+<OBJECT BURIN
+	(IN PLAYER)
+	(DESC "magic burin")
+	(SYNONYM BURIN SCRIBE ENGRAVE)
+	(ADJECTIVE SHARP MAGIC)
+	(FLAGS TAKEBIT MAGICBIT TOUCHBIT TOOLBIT WEAPONBIT)
+	(ACTION BURIN-F)>
+
+<ROUTINE BURIN-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a magical burin, used for inscribing objects with words or runes
+of magical import. Such a burin also gives you the ability to write
+spell scrolls." CR>)
+	       (<VERB? WHAT>
+		<TELL
+"A burin is an engraving and writing tool." CR>)>>
+
+<ROOM DULL-ROOM
+      (IN ROOMS)
+      (DESC "Nondescript Room")
+      (OUT PER DULL-ROOM-EXIT)
+      (SOUTH PER DULL-ROOM-EXIT)
+      (ACTION DULL-ROOM-F)
+      (FLAGS RLANDBIT)>
+
+<ROUTINE DULL-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a drab, nondescript room. The only exit leads south." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROUTINE DULL-ROOM-EXIT ()
+	 <COND (<EQUAL? ,DULL-ROOM-RETURN ,CASTLE>
+		<MAGIC-DOOR-EXIT>)
+	       (ELSE ,DULL-ROOM-RETURN)>>
+
+<GLOBAL DULL-ROOM-RETURN <>>
+
+"EARTH"
+
+<OBJECT EARTH-CUBE
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE AQ ;C1 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "moles")
+	(FLAGS INVISIBLE TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE EARTH-ROOM)>
+
+<ROOM EARTH-ROOM
+      (IN ROOMS)
+      (DESC "Packed Earth")
+      (NORTH PER MAGIC-BOX-EXIT)
+      (EAST TO HALL-OF-STONE)
+      (WEST TO CAVE-ENTRANCE)
+      (SOUTH TO CLIFF-MIDDLE)
+      (DOWN PER MIDAIR-EXIT)
+      (CUBE EARTH-CUBE)
+      (ACTION EARTH-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GLOBAL-HOLE)
+      (THINGS
+       <PSEUDO (PACKED EARTH RANDOM-PSEUDO)
+	       (<> MUD RANDOM-PSEUDO)
+	       (<> SOD RANDOM-PSEUDO)
+	       (LEATHER THONG RANDOM-PSEUDO)
+	       (LEATHER THONGS PLURAL-PSEUDO)>)>
+
+<ROUTINE EARTH-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a small room crudely constructed of packed earth, mud, and sod.
+Crudely framed openings of wood tied with leather thongs lead off in each
+of the four cardinal directions, and a muddy hole leads down." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM HALL-OF-STONE
+      (IN ROOMS)
+      (DESC "Hall of Stone")
+      (NORTH TO SOUTH-SNAKE-ROOM)
+      (SOUTH TO RUINS-ROOM)
+      (ACTION HALL-OF-STONE-F)
+      (FLAGS RLANDBIT)
+      (THINGS
+       <PSEUDO (MOULDERING RUIN RUINS-PSEUDO)
+	       (STONE BLOCKS RUINS-PSEUDO)
+	       (DRESSED STONE RUINS-PSEUDO)>)>
+
+<ROUTINE HALL-OF-STONE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a long hall built of crudely dressed stone. The blocks are as tall
+as you and the ceiling invisible in the gloom above. Dirt trickles from gaps
+in the walls and ceiling. The atmosphere is oppressive, and there is a dry,
+stale smell all around. The corridor extends north and south from here." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <TELL
+"It smells dry and stale." CR>)>)>>
+
+<ROOM NORTH-SNAKE-ROOM
+      (IN ROOMS)
+      (DESC "North of Serpent")
+      (SOUTH PER SNAKE-ROOM-EXIT)
+      (NORTH TO TEMPLE-ROOM)
+      (EAST PER SNAKE-ROOM-EXIT)
+      (WEST PER SNAKE-ROOM-EXIT)
+      (ACTION SNAKE-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL SNAKE)
+      (THINGS <PSEUDO (SNAKE EYE SNAKE-EYE-PSEUDO)
+		      (SERPENT EYE SNAKE-EYE-PSEUDO)
+		      (SNAKE MOUTH RANDOM-PSEUDO)
+		      (SERPENT MOUTH RANDOM-PSEUDO)
+		      (SNAKE SCALES SNAKE-SCALES-PSEUDO)
+		      (SERPENT SCALES SNAKE-SCALES-PSEUDO)>)>
+
+<ROUTINE SNAKE-EYE-PSEUDO ()
+	 <REDIRECT ,PSEUDO-OBJECT ,EYES>>
+
+<ROUTINE SNAKE-SCALES-PSEUDO ()
+	 <COND (<OR <VERB? EXAMINE>
+		    <HOSTILE-VERB?>>
+		<HACK-SNAKE>)>>
+
+<ROUTINE HACK-SNAKE ()
+	 <TELL "The steel-like scales are ">
+	 <COND (<VERB? RUB>
+		<TELL "cool to the touch">)
+	       (ELSE
+		<TELL
+		 "impervious to your puny strength">)>
+	 <TELL ,PERIOD>>
+
+<ROOM SOUTH-SNAKE-ROOM
+      (IN ROOMS)
+      (DESC "Smooth Room")
+      (NORTH PER SNAKE-ROOM-EXIT)
+      (SOUTH TO HALL-OF-STONE)
+      (EAST PER SNAKE-ROOM-EXIT)
+      (WEST PER SNAKE-ROOM-EXIT)
+      (ACTION SNAKE-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL SNAKE)
+      (THINGS <PSEUDO (SNAKE EYE SNAKE-EYE-PSEUDO)
+		      (SERPENT EYE SNAKE-EYE-PSEUDO)
+		      (SNAKE MOUTH RANDOM-PSEUDO)
+		      (SERPENT MOUTH RANDOM-PSEUDO)
+		      (SNAKE SCALES SNAKE-SCALES-PSEUDO)
+		      (SERPENT SCALES SNAKE-SCALES-PSEUDO)>)>
+
+<ROUTINE SNAKE-ROOM-EXIT ()
+	 <COND (<EQUAL? ,SHRINK-FLAG ,SNAKE>
+		<COND (<EQUAL? ,P-WALK-DIR ,P?NORTH ,P?SOUTH>
+		       <TELL
+"The snake is pleasurably stretching its
+mouth and rippling its scaly body in the unaccustomed space.
+It barely hisses as you go by." CR CR>
+		       <COND (<EQUAL? ,HERE ,SOUTH-SNAKE-ROOM>
+			      ,NORTH-SNAKE-ROOM)
+			     (ELSE
+			      ,SOUTH-SNAKE-ROOM)>)
+		      (ELSE
+		       <TELL
+"Avoiding the snake, you carefully head "
+ <COND (<EQUAL? ,P-WALK-DIR ,P?EAST> "east")
+			   (ELSE "west")> ". The corridor is smooth
+and circular. It eventually leads back to where you started." CR CR>
+		       ,HERE)>)
+	       (<EQUAL? ,P-WALK-DIR ,P?NORTH ,P?SOUTH>
+		<TELL
+"The serpent completely fills the passage." CR>
+		<RFALSE>)
+	       (ELSE
+		<TELL
+"The serpent fills the entire corridor. There is no space to
+squeeze by." CR>
+		<RFALSE>)>>
+
+<ROUTINE SNAKE-ROOM-F (RARG "AUX" N?)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"Here a long north-south corridor meets an east-west cross corridor
+whose walls are polished to almost mirror smoothness.
+Just to your ">
+		<COND (<SET N? <EQUAL? ,HERE ,NORTH-SNAKE-ROOM>>
+		       <TELL "south">)
+		      (ELSE <TELL "north">)>
+		<COND (<EQUAL? ,SHRINK-FLAG ,SNAKE>
+		       <TELL
+" is a large snake whose head pokes out of one side of
+the cross corridor and the tip of whose tail pokes out the other side.
+You can see that ahead is more of the crudely built main hall, and beyond
+that is a dark area.">)
+		      (ELSE
+		       <TELL
+" is a huge scaly mass which fills the entire cross
+corridor. Its thickness is more than three times your height and
+its length is unguessable.">)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT <FSET? ,SOUTH-SNAKE-ROOM ,TOUCHBIT>>
+		       <QUEUE I-SNAKE 1>)>)>>
+
+<OBJECT SNAKE
+	(IN LOCAL-GLOBALS)
+	(DESC "serpent")
+	(SYNONYM SERPENT SNAKE MASS CREATURE)
+	(ADJECTIVE HUGE LARGE SCALY MONSTER)
+	(ACTION SNAKE-F)
+	(SIZE 200)
+	(FLAGS NDESCBIT PERSON THE TAKEBIT TRYTAKEBIT VEHBIT)>
+
+<ROUTINE SNAKE-F ()
+	 <COND (<EQUAL? ,WINNER ,SNAKE>
+		<COND (<TIME-FROZEN?>
+		       <IMMOBILE>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"\"Sssss...\" You can't understand the " 'SNAKE ,PERIOD>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<COND (<EQUAL? ,SNAKE ,SHRINK-FLAG>
+		       <TELL
+"The snake is no longer gargantuan. Its tail sticks
+out one side of the corridor and its head the other, no longer filling
+the corridor.">)
+		      (ELSE
+		       <TELL
+"It is huge, filling the entire corridor it occupies.">
+		       <COND (<NOT <TIME-FROZEN?>>
+		       <TELL " It stares at you
+balefully, hissing like a small steam engine. It appears completely
+unconcerned that it has swallowed its own tail.">)>)>
+		<COND (<TIME-FROZEN?>
+		       <TELL " ">
+		       <IMMOBILE>
+		       <RTRUE>)>
+		<CRLF>)
+	       (<VERB? BOARD CLIMB-FOO CLIMB-UP CLIMB-OVER CLIMB-ON>
+		<TELL
+"The scales are too slippery">
+		<COND (<NOT <TIME-FROZEN?>>
+		       <TELL ", and the serpent's eye fixes you with
+a stare that removes much of your interest in getting that close">)
+		      (ELSE
+		       <TELL ". ">
+		       <IMMOBILE>
+		       <RTRUE>)>
+		<TELL ,PERIOD>)
+	       (<VERB? LISTEN>
+		<TELL
+"It sounds like a leaky steam engine." CR>)
+	       (<HOSTILE-VERB?>
+		<HACK-SNAKE>)
+	       (<VERB? THROW-OFF>
+		<COND (<NOT <EQUAL? ,SHRINK-FLAG ,SNAKE>>
+		       <MOVE ,PRSO ,HERE>
+		       <TELL
+CTHE ,PRSO " hits the snake and drops to the floor." CR>)
+		      (ELSE
+		       <PERFORM ,V?THROW ,PRSO>
+		       <RTRUE>)>)
+	       (<VERB? GIVE>
+		<UNINTERESTED ,SNAKE>)
+	       (<VERB? RUB>
+		<HACK-SNAKE>)
+	       (<VERB? TAKE>
+		<TELL
+"The creature is taller than a house, and longer than the tallest tree
+is tall." CR>)
+	       (<VERB? FROTZ>
+		<TELL
+"The snake glows dimly as the spell stretches to cover it, but then the
+glow winks out." CR>)
+	       (<VERB? LISKON>
+		<COND (<EQUAL? ,SHRINK-FLAG ,SNAKE>
+		       <TELL ,NOTHING-HAPPENS>)
+		      (<NOT <PRE-LISKON>>
+		       <SETG SHRINK-FLAG ,SNAKE>
+		       <QUEUE I-LISKON 15>
+		       <TELL
+"The serpent shrinks. You can see it thinning out, filling
+less and less of the corridor. At first it doesn't seem to be growing
+any shorter, but then you realize that this isn't true.
+It has swallowed so much of its own tail that it makes up
+the deficiency by disgorging more tail. Finally, just before the spell
+stops, the tail tip slips out of the snake's mouth and almost disappears
+down the western corridor." CR>)>)
+	       (<VERB? SNAVIG>
+		<SETG AWAKE 5>
+		<QUEUE I-TIRED 5>
+		<TELL
+"The spell strains to change you into a serpent, but you're just too
+small. Finally, you snap back to your normal appearance, and you feel
+very, very tired." CR>)
+	       (<VERB? GIRGOL>
+		<COND (<EQUAL? ,SHRINK-FLAG ,SNAKE>
+		       <TELL ,NOTHING-HAPPENS>)>)
+	       (<VERB? YOMIN>
+		<TELL CTHE ,SNAKE " is ">
+		<COND (<EQUAL? ,SHRINK-FLAG ,SNAKE>
+		       <TELL
+"almost overcome by the sheer joy of being
+able to writhe and stretch." CR>)
+		      (ELSE
+		       <TELL
+"bored, constricted, and caged. It's in a surly mood, thinking of
+its past. It was once a simple temple snake, well fed on sacrifices. It
+was too well fed, for it grew great, and its pride grew as well. For
+declaring itself the greatest of snakes, it was prisoned here, forced to
+swallow its own tail in mimicry of the true master of serpents. That was an
+age ago." CR>)>)
+	       (<VERB? ESPNIS>
+		<TELL
+"The snake yawns briefly, but the spell is too attenuated by the creature's
+huge mass to do more." CR>)>>
+
+<ROOM TEMPLE-ROOM
+      (IN ROOMS)
+      (DESC "Temple")
+      (SOUTH TO NORTH-SNAKE-ROOM)
+      (ACTION TEMPLE-ROOM-F)
+      (FLAGS RLANDBIT)
+      (THINGS
+       <PSEUDO (BLACK PILLAR RUINS-PSEUDO)
+	       (BASALT PILLAR RUINS-PSEUDO)
+	       (BROKEN PILLAR RUINS-PSEUDO)
+	       (MOULDERING RUIN RUINS-PSEUDO)
+	       (HUGE FRAGMENT RUINS-PSEUDO)
+	       (<> RAFTER RUINS-PSEUDO)
+	       (<> BATS PLURAL-PSEUDO)
+	       (<> BAT RANDOM-PSEUDO)
+	       (BAT GUANO RANDOM-PSEUDO)>)>
+
+<ROUTINE TEMPLE-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a ruined temple to a forgotten god. Black basalt pillars
+reach to the ceiling, but some are broken and lie in huge fragments on the
+ground. The air is stale and filled with the odor of decay. Bats roost in
+the rafters, the only remaining worshippers. Before the temple "
+<COND (,IDOL-ASLEEP? "rests")(T "stands")> " a tall basalt
+idol in the form of a huge rodent. Its fang-bedecked mouth is ">
+		<COND (,IDOL-YAWNING?
+		       <TELL "open in an embarrassing yawn.">)
+		      (,IDOL-ASLEEP?
+		       <TELL "closed tightly.">)
+		      (ELSE
+		       <TELL "open slightly, exposing teeth and tongue.">)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? SMELL>
+			    <EQUAL? ,PRSO <> ,GLOBAL-ROOM>>
+		       <TELL
+"It smells of decay, rot, and centuries-long accumulation of bat
+guano." CR>)>)>>
+
+<OBJECT IDOL
+	(IN TEMPLE-ROOM)
+	(DESC "rodent idol")
+	(SYNONYM IDOL GOD SCULPTURE STATUE)
+	(ADJECTIVE RODENT FORGOTTEN HUGE BASALT TALL)
+	(ACTION IDOL-F)
+	(FLAGS NDESCBIT ;SEARCHBIT VEHBIT TAKEBIT SURFACEBIT
+	       THE TRYTAKEBIT CONTBIT OPENBIT)>
+
+<GLOBAL IDOL-SLEEPED? <>>	;"HIT WITH SLEEP SPELL?"
+<GLOBAL IDOL-YAWNING? <>>	;"YAWNING?"
+<GLOBAL IDOL-ASLEEP? <>>	;"SOUND ASLEEP"
+
+<ROUTINE IDOL-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<FSET ,MOUTH ,SEARCHBIT>
+		<COND (<OR <VERB? CLIMB-DOWN DISEMBARK>
+			   <AND <VERB? WALK>
+				<EQUAL? ,P-WALK-DIR ,P?DOWN>>>
+		       <MOVE ,PLAYER ,HERE>
+		       <TELL
+"You climb off the idol." CR>)
+		      (<VERB? WALK>
+		       <TELL
+,YOU-HAVE-TO " climb down first." CR>)
+		      (<AND <VERB? BOARD CLIMB-FOO CLIMB-ON CLIMB-UP THROUGH>
+			    <EQUAL? ,PRSO ,IDOL>>
+		       <TELL
+"You are clinging to the idol already." CR>)
+		      (<VERB? LEAP>
+		       <MOVE ,PLAYER ,HERE>
+		       <TELL
+"You carelessly leap off the idol." CR>)
+		      (<AND <VERB? TAKE>
+			    <FSET? ,PRSO ,TAKEBIT>
+			    <NOT-IN-VEHICLE?>>
+		       <CANT-REACH-THAT>)
+		      (<VERB? DROP>
+		       <COND (<EQUAL? ,PRSO ,OPAL ,IDOL> <RFALSE>)
+			     (<IDROP>
+			      <MOVE ,PRSO ,HERE>
+			      <TELL "Dropped." CR>)
+			     (ELSE <RTRUE>)>)>)
+	       (<NOT .RARG>
+		<FSET ,IDOL ,SEARCHBIT>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"The idol is carved of black basalt. It is about twenty feet tall and
+represents a gigantic and ferocious rodent-like creature with sharp teeth
+and one staring">
+		       <COND (<AND <IN? ,OPAL ,IDOL>
+				   <NOT ,OPAL-LOOSE?>>
+			      <TELL " opalescent eye">)
+			     (ELSE
+			      <TELL ", empty eye socket">)>
+		       <TELL ".">
+		       <COND (<NOT <IN? ,PLAYER ,IDOL>>
+			      <TELL
+" The sculpture is rough enough to offer climbing holds.">)>
+		       <COND (,IDOL-YAWNING?
+			      <TELL
+" Oddly, the idol is yawning, its mouth gaping open.">)
+			     (,IDOL-ASLEEP?
+			      <TELL
+" The idol is sculpted as though sound asleep.">)>
+		       <CRLF>)
+		      (<AND <VERB? GIVE SEARCH TELL HELLO TAKE WAVE-AT>
+			    <FSET? ,IDOL ,PERSON>>
+		       <COND (<VERB? TELL>
+			      <END-QUOTE>)>
+		       <JIGS-UP ,IDOL-CRUSHES-YOU>)
+		      (<VERB? TAKE>
+		       <TELL
+"The idol reaches all the way to the ceiling and is made of basalt. This
+is beyond your strength." CR>)
+		      (<HOSTILE-VERB?>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <JIGS-UP ,IDOL-CRUSHES-YOU>)
+			     (ELSE
+			      <TELL ,WASTE-OF-TIME>)>)
+		      (<VERB? LOOK-INSIDE>
+		       <PERFORM ,PRSA ,MOUTH>
+		       <RTRUE>)
+		      (<VERB? KISS RUB>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <JIGS-UP ,IDOL-CRUSHES-YOU>)
+			     (ELSE
+			      <TELL
+"The idol is stonelike to the touch." CR>)>)
+		      (<VERB? BOARD CLIMB-FOO CLIMB-ON CLIMB-UP>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <JIGS-UP ,IDOL-CRUSHES-YOU>)
+			     (ELSE
+			      <MOVE ,PLAYER ,IDOL>
+			      <COND (,IDOL-ASLEEP?
+				     <TELL
+"Okay, you are now on the sleeping idol." CR>)
+				    (ELSE
+				     <TELL
+"You can find enough holds to climb all the way up to the head, where you
+gaze warily at the idol's mouth." CR>)>)>)
+		      (<VERB? MALYON>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <TELL "It looks pretty animated to me." CR>)
+			     (ELSE
+			      <FSET ,MOUTH ,SEARCHBIT>
+			      <TELL
+"The idol quivers, comes to life,">
+			      <COND (<ROB ,MOUTH <> ,AIR-CUBE>
+				     <REMOVE ,AIR-CUBE>
+				     <SETG LIT <LIT? ,HERE>>
+				     <TELL " swallows,">)>
+			      <COND (,IDOL-ASLEEP?
+				     <TELL " gets to its feet">)>
+			      <TELL " and ">
+			      <COND (<IN? ,PLAYER ,IDOL>
+				     <TELL
+"notices you climbing on it (no doubt from
+the itching). It grabs for you, and you try to escape. Its razor-sharp
+claws snatch you up to its greedy mouth">
+				     <COND (<IN? ,AIR-CUBE ,MOUTH>
+					    <TELL
+", where you can see the white
+cube on its tongue as you are swallowed">)>
+				     <TELL ".">
+				     <JIGS-UP>)
+				    (ELSE
+				     <SETG IDOL-SLEEPED? <>>
+				     <SETG IDOL-YAWNING? <>>
+				     <SETG IDOL-ASLEEP? <>>
+				     <QUEUE I-UNMALYON-IDOL 4>
+				     <QUEUE I-IDOL 2>
+				     <QUEUE I-FULL-YAWN 0>
+				     <QUEUE I-IDOL-ASLEEP 0>
+				     <FSET ,IDOL ,PERSON>
+				     <TELL "begins ">
+				     <TELL-IDOL-ACTION>
+				     <TELL
+" suspiciously (and hungrily) around. Fortunately it doesn't
+notice you." CR>)>)>)
+		      (<VERB? LISKON>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <TELL
+"While the idol appears to be made of \"malyoned\" basalt, it must actually
+be made of something denser, as this spell has no effect on
+it." CR>)>)
+		      (<VERB? ESPNIS>
+		       <TELL CTHE ,IDOL>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <SETG IDOL-SLEEPED? T>
+			      <QUEUE I-FULL-YAWN 2>
+			      <QUEUE I-IDOL-ASLEEP 3>
+			      <TELL
+" suddenly looks very tired and begins to yawn. You can see the idol
+fighting it but losing." CR>)
+			     (ELSE
+			      <TELL
+" doesn't seem to be very wakeful to me." CR>)>)
+		      (<VERB? YOMIN>
+		       <COND (<FSET? ,IDOL ,PERSON>
+			      <COND (<OR ,IDOL-SLEEPED?
+					 ,IDOL-YAWNING?
+					 ,IDOL-ASLEEP?>
+				     <TELL
+"You sense a great tiredness, as though these few exertions dissipated
+a thousand years of strength." CR>)
+				    (ELSE
+				     <TELL
+"You sense a raging anger at the abandonment of its temple, a desire for
+the destruction of its former worshippers, and an incandescent hatred for
+bats." CR>)>)>)
+		      (<AND <VERB? SNAVIG>
+			    <FSET? ,IDOL ,PERSON>>
+		       <JIGS-UP
+"You grow huge, fanged and angry. Then you turn into basalt. The
+outcome is fatal.">)>)>>
+
+<GLOBAL IDOL-CRUSHES-YOU
+"The idol notices you! It crushes you to jelly, even though you aren't a bat.">
+
+<OBJECT TEETH
+	(IN IDOL)
+	(DESC "fangs")
+	(SYNONYM TEETH FANGS FANG)
+	(ADJECTIVE IDOL\'S RAZOR SHARP)
+	(FLAGS NOABIT NDESCBIT)
+	(ACTION TEETH-F)>
+
+<ROUTINE TEETH-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "They are razor sharp." CR>)
+	       (<VERB? MUNG ATTACK>
+		<TELL "The teeth are stone hard." CR>)>>
+
+<OBJECT MOUTH
+	(IN IDOL)
+	(DESC "mouth")
+	(SYNONYM MOUTH MAW)
+	(ADJECTIVE IDOL\'S GAPING)
+	(ACTION MOUTH-F)
+	(CONTFCN MOUTH-F)
+	(CAPACITY 10)
+	(FLAGS NDESCBIT ;SEARCHBIT OPENBIT CONTBIT)>
+
+<ROUTINE MOUTH-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<VERB? TAKE>
+		       <COND (<NOT <IN? ,PLAYER ,IDOL>>
+			      <TELL
+,YOU-HAVE-TO " climb up to the mouth first." CR>)
+			     (<FSET? ,IDOL ,PERSON>
+			      <TELL
+"The outcome would be fatal." CR>)
+			     (,IDOL-ASLEEP?
+			      <TELL
+"The idol's mouth is shut tightly." CR>)
+			     (<AND <EQUAL? ,PRSO ,AIR-CUBE>
+				   <IN? ,AIR-CUBE ,MOUTH>>
+			      <COND (,IDOL-YAWNING?
+				     <COND (<EQUAL? <ITAKE> T>
+					    <TELL ,TAKEN>)>
+				     <RTRUE>)
+				    (ELSE
+				     <TELL
+"You can see the cube, tantalizingly close, but your ">
+				     <COND (<EQUAL? ,SHRINK-FLAG ,WINNER>
+					    <TELL
+"arm is too short to reach">)
+					   (ELSE
+					    <TELL
+"hand is too big to fit between the razor-sharp teeth">)>
+				     <TELL
+". If only its mouth were open! Glancing at the size of the fangs, maybe
+it's just as well." CR>)>)>)
+		      (<VERB? MOVE PUSH>
+		       <CANT-REACH-THAT>)>)
+	       (<NOT .RARG>
+		<FSET ,MOUTH ,SEARCHBIT>
+		<COND (<VERB? EXAMINE LOOK-INSIDE>
+		       <COND (<OR <IN? ,PLAYER ,IDOL>
+				  ,IDOL-ASLEEP?>
+			      <TELL CTHE ,MOUTH " is ">
+			      <COND (<NOT <FSET? ,MOUTH ,OPENBIT>>
+				     <TELL "shut tight.">)
+				    (,IDOL-YAWNING?
+				     <TELL
+"wide open in an almost parodic yawn. The tongue stretches
+out of the mouth, and the fangs are far apart.">
+				     <MOUTH-CONTENTS>)
+				    (ELSE
+				     <TELL
+"slightly open. In the narrow space between the fangs you can
+see a fat, pointed tongue.">
+				     <MOUTH-CONTENTS>)>)
+			     (ELSE
+			      <TELL
+,YOU-CANT-SEE "much from here.">)>
+		       <CRLF>)
+		      (<VERB? CLIMB-UP>
+		       <PERFORM ,V?CLIMB-UP ,IDOL>
+		       <RTRUE>)
+		      (<VERB? OPEN CLOSE>
+		       <TELL
+"Not a chance." CR>)
+		      (<VERB? REACH-IN>
+		       <WONT-FIT>)
+		      (<AND <VERB? PUT> <EQUAL? ,MOUTH ,PRSI>>
+		       <COND (<AND <NOT ,IDOL-YAWNING?>
+				   <OR <G? <GETP ,PRSO ,P?SIZE> 5>
+				       <GETP ,PRSO ,P?NAME>>>
+			      <WONT-FIT>)
+			     (ELSE
+			      <FCLEAR ,AIR-CUBE ,NDESCBIT>
+			      <RFALSE>)>)
+		      (<VERB? REZROV>
+		       <TELL
+"There's no hinge there; it's not a door!" CR>)>)>>
+
+<ROUTINE WONT-FIT ()
+	 <TELL "It won't fit." CR>>
+
+<ROUTINE MOUTH-CONTENTS ("AUX" STR)
+	 <SET STR " Sitting on the tongue">
+	 <COND (<IN? ,AIR-CUBE ,MOUTH>
+		<TELL .STR " is " A ,AIR-CUBE ".">
+		<SET STR " Also in the mouth">)>
+	 <CLEVER-CONTENTS ,MOUTH .STR ,AIR-CUBE>>
+
+<OBJECT OPAL
+	(IN IDOL)
+	(DESC "opal eye")
+	(SYNONYM EYE)
+	(ADJECTIVE OPAL)
+	(ACTION OPAL-F)
+	(SIZE 10)
+	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT AN)>
+
+<OBJECT OPAL-SHARD
+	(DESC "opal shard")
+	(SYNONYM EYE SHARD FRAGMENT)
+	(ADJECTIVE OPAL BROKEN)
+	(FLAGS TAKEBIT AN)>
+
+<ROUTINE OPAL-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<IN? ,OPAL ,IDOL>
+		       <TELL
+"The eye glows opalescently in the light.">
+		       <COND (<NOT <IN? ,PLAYER ,IDOL>>
+			      <TELL
+" It is near the top of the idol, nearly twenty feet up, but it still looks
+large even at this distance.">)
+			     (ELSE
+			      <TELL
+" The color may be attributed to the fact that the eye is actually
+an opal of enormous size.">)>
+		       <CRLF>)
+		      (ELSE
+		       <TELL
+"This is the largest opal you have ever seen." CR>)>)
+	       (<VERB? TAKE>
+		<COND (,OPAL-LOOSE? <RFALSE>)
+		      (<NOT <IN? ,PLAYER ,IDOL>>
+		       <CANT-REACH-THAT>)
+		      (<IN? ,OPAL ,IDOL>
+		       <TELL
+"You scratch at the setting for a while without success." CR>)>)
+	       (<AND <VERB? PRY>
+		     <EQUAL? ,PRSO ,OPAL>
+		     <IN? ,OPAL ,IDOL>>
+		<COND (<AND <NOT <IN? ,PLAYER ,IDOL>>
+			    <NOT ,IDOL-ASLEEP?>>
+		       <CANT-REACH-IT>)
+		      (<EQUAL? ,PRSI ,KNIFE ,BURIN ,SHEARS>
+		       <COND (<NOT <IN? ,PRSI ,WINNER>>
+			      <NOT-HOLDING ,PRSI>)
+			     (,OPAL-LOOSE?
+			      <TELL ,IT-IS-ALREADY
+"tottering, ready to fall, and trying to pry it again just
+hastens the inevitable" ,PERIOD>)
+			     (ELSE
+			      <SETG OPAL-LOOSE? T>
+			      <QUEUE I-OPAL-SMASHES 2>
+			      <TELL
+"The opal pops out of the eye socket. It is teetering on the edge of the
+cruel and pointy nose of the idol, ready to fall." CR>)>)
+		      (ELSE
+		       <TELL
+CTHE ,PRSI " doesn't appear equal to the task." CR>)>)
+	       (<AND <HELD? ,OPAL>
+		     <OR <VERB? THROW MUNG>
+			 <AND <VERB? DROP>
+			      <IN? ,WINNER ,IDOL>>>>
+		<REMOVE ,OPAL>
+		<MOVE ,OPAL-SHARD ,HERE>
+		<TELL "Broken." CR>)>>
+
+<GLOBAL OPAL-LOOSE? <>>
+
+<ROUTINE RUINS-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<EQUAL? ,HERE ,PAST-RUINS-ROOM>
+		       <TELL
+"This place is abandoned and falling into ruin." CR>)
+		      (ELSE
+		       <TELL
+"This place has been abandoned for centuries. It is a mouldering
+ruin." CR>)>)>>
+
+<OBJECT ZIPPER
+	(IN RUINS-ROOM)
+	(DESC "zipper")
+	(SYNONYM ZIPPER HOLE POCKET POUCH)
+	(ADJECTIVE SILVER DIMLY LIT)
+	(ACTION ZIPPER-F)
+	(CONTFCN ZIPPER-F)
+	(GENERIC GENERIC-HOLE-F)
+	(FLAGS NDESCBIT VEHBIT TAKEBIT CONTBIT MAGICBIT)
+	(CAPACITY 1000)>
+
+<GLOBAL ZIPPER-SCROLL? <>>
+
+<ROUTINE ZIPPER-F ("OPTIONAL" (RARG <>) "AUX" OLIT ZLIT)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are in a zipper. Clammy dark mist surrounds you. ">
+		<COND (<FSET? ,ZIPPER ,OPENBIT>
+		       <TELL
+"The zipper is open. ">
+		       <CANT-SEE-OUTSIDE>)
+		      (ELSE
+		       <TELL-OPEN-CLOSED ,ZIPPER>)>)
+	       (<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<AND <VERB? TAKE PUT>
+			    <NOT <IN? ,WINNER ,ZIPPER>>
+			    <NOT <HELD? ,ZIPPER>>>
+		       <DONT-HAVE-THAT>)
+		      (<AND <VERB? READ EXAMINE>
+			    <NOT <IN? ,WINNER ,ZIPPER>>>
+		       <MAKE-OUT>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <NOT-IN-VEHICLE?>
+			    <OR <VERB? TAKE>
+				<NOT <FSET? ,ZIPPER ,OPENBIT>>>>
+		       <TELL "That's outside." CR>)
+		      (<AND <VERB? LOOK-INSIDE> <EQUAL? ,PRSO ,ZIPPER>>
+		       <PERFORM ,V?LOOK>
+		       <RTRUE>)
+		      (<VERB? BOARD REACH-IN>
+		       <TELL ,YOU-ARE ,PERIOD>)
+		      (<VERB? SIT>
+		       <TELL
+"There isn't a good place to sit here." CR>)
+		      (<OR <VERB? EXIT>
+			   <AND <VERB? WALK> <EQUAL? ,P-WALK-DIR ,P?OUT>>
+			   <AND <VERB? THROUGH> <EQUAL? ,PRSO ,ZIPPER>>>
+		       <PERFORM ,V?DISEMBARK>
+		       <RTRUE>)
+		      (<AND <VERB? OPEN REZROV>
+			    <EQUAL? ,PRSO ,ZIPPER>
+			    <NOT <FSET? ,ZIPPER ,OPENBIT>>>
+		       <FSET ,ZIPPER ,OPENBIT>
+		       <TELL
+"Opening the zipper reveals the outside world." CR>)
+		      (<AND <VERB? CLOSE>
+			    <EQUAL? ,PRSO ,ZIPPER>
+			    <FSET? ,ZIPPER ,OPENBIT>>
+		       <FCLEAR ,ZIPPER ,OPENBIT>
+		       <TELL
+,YOU-ARE-NOW "in a private little world of your own." CR>)
+		      (<VERB? WALK>
+		       <TELL
+"There's nowhere to go in here." CR>)
+		      (<OR <VERB? DISEMBARK>
+			   <AND <VERB? DROP> <EQUAL? ,PRSO ,ZIPPER>>>
+		       <COND (<FSET? ,ZIPPER ,OPENBIT>
+			      <SETG LIT <LIT? ,HERE>>
+			      <MOVE ,PLAYER <LOC ,ZIPPER>>
+			      <MOVE ,ZIPPER ,PLAYER>
+			      <TELL
+"You get out of the hole." CR>)
+			     (ELSE
+			      <TELL
+,YOU-HAVE-TO " open the " 'ZIPPER " first." CR>)>)>)
+	       (<NOT .RARG>
+		<SET OLIT ,LIT>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"This is a silver zipper about two feet long, with very fine teeth. ">
+		       <TELL-OPEN-CLOSED ,ZIPPER>)
+		      (<AND <VERB? OPEN REZROV>
+			    <NOT <FSET? ,ZIPPER ,OPENBIT>>>
+		       <FSET ,ZIPPER ,OPENBIT>
+		       <COND (<NOT ,LIT> <SETG LIT <LIT? ,HERE>>)>
+		       <TELL
+"Opening the zipper reveals a ">
+		       <COND (<LIT? ,ZIPPER <>> <TELL "bright">)
+			     (ELSE <TELL "dim">)>
+		       <TELL "ly lit hole.">
+		       <COND (<AND <NOT .OLIT> ,LIT>
+			      <TELL " Enough rays escape to dimly light
+the area.">)>
+		       <CRLF>)
+		      (<AND <VERB? CLOSE> <FSET? ,ZIPPER ,OPENBIT>>
+		       <FCLEAR ,ZIPPER ,OPENBIT>
+		       <SETG LIT <LIT? ,HERE>>
+		       <TELL
+"The zipper now looks like an ordinary zipper.">
+		       <COND (<AND .OLIT <NOT ,LIT>>
+			      <TELL " " ,NOW-BLACK>)>
+		       <CRLF>)
+		      (<VERB? LOOK-INSIDE>
+		       <COND (<FSET? ,ZIPPER ,OPENBIT>
+			      <TELL "It's ">
+			      <COND (<SET ZLIT <LIT? ,ZIPPER <>>>
+				     <TELL "bright">)
+				    (ELSE
+				     <TELL "dark">)>
+			      <TELL " inside, ">
+			      <COND (<FIRST? ,ZIPPER>
+				     <COND (.ZLIT <TELL "and">)
+					   (ELSE <TELL "but">)>
+				     <TELL " you can see ">
+				     <PRINT-CONTENTS ,ZIPPER>)
+				    (.ZLIT <TELL "and empty">)
+				    (ELSE
+				     <TELL "and you can't see anything">)>
+			      <TELL ,PERIOD>)
+			     (ELSE
+			      <TELL-OPEN-CLOSED ,ZIPPER>)>)
+		      (<VERB? REACH-IN>
+		       <COND (<NOT <FSET? ,ZIPPER ,OPENBIT>>
+			      <TELL-OPEN-CLOSED ,ZIPPER>)
+			     (<NOT ,ZIPPER-SCROLL?>
+			      <SETG ZIPPER-SCROLL? T>
+			      <MOVE ,GIRGOL-SCROLL ,ZIPPER>
+			      <THIS-IS-IT ,GIRGOL-SCROLL>
+			      <TELL
+"Odd, you can't really feel anything for a moment, but then, almost as
+though something was thrust into your hand, there's something there. Oops,
+it slipped away again." CR>)>)
+		      (<VERB? BOARD>
+		       <COND (<NOT <HELD? ,ZIPPER>>
+			      <DONT-HAVE-THAT>)
+			     (<FSET? ,ZIPPER ,OPENBIT>
+			      <COND (<OR <EQUAL? ,HERE
+						 ,OCEAN-ROOM ,LOST-IN-OCEAN
+						 ,OCEAN-FLOOR>
+					 <EQUAL? ,HERE ,IN-CHANNEL ,IN-PIPE
+						 ,IN-PIPE-2>
+					 <EQUAL? ,HERE ,IN-SEWER ,RUINED-PIPE
+						 ,PAST-CABINET>
+					 <EQUAL? ,HERE ,CABINET>>
+				     <TELL
+"An impossible maneuver under the circumstances." CR>
+				     <RTRUE>)>
+			      <COND (<NOT ,ZIPPER-SCROLL?>
+				     <SETG ZIPPER-SCROLL? T>
+				     <MOVE ,GIRGOL-SCROLL ,ZIPPER>)>
+			      <MOVE ,ZIPPER ,HERE>
+			      <MOVE ,PLAYER ,ZIPPER>
+			      <SET ZLIT <LIT? ,ZIPPER <>>>
+			      <SETG LIT T>
+			      <TELL
+"It's just big enough to fit in with the zipper fully open. You crawl into
+a ">
+			      <COND (.ZLIT <TELL "bright">)
+				    (ELSE <TELL "dark">)>
+			      <TELL
+", strange place almost like a big sack. You can sort of stand up, but
+there isn't much room to move around. ">
+			      <CANT-SEE-OUTSIDE>
+			      ;<JIGS-UP
+"You can just fit with the zipper fully open. You crawl into
+a strange place almost like a big sack. You find that you are
+in a sort of stasis, and can't move. Your mental processes move
+slower and slower, and ultimately they stop.">)
+			     (ELSE
+			      <TELL-OPEN-CLOSED ,ZIPPER>)>)
+		      (<AND <VERB? PUT>
+			    <EQUAL? ,PRSI ,ZIPPER>>
+		       <COND (<IN? ,ZIPPER ,BOTTLE>
+			      <CANT-REACH-THAT>)
+			     (<AND <NOT ,ZIPPER-SCROLL?>
+				   <FSET? ,PRSO ,ONBIT>>
+			      <SETG ZIPPER-SCROLL? T>
+			      <MOVE ,GIRGOL-SCROLL ,ZIPPER>
+			      <RFALSE>)>)>)>>
+
+<ROUTINE CANT-SEE-OUTSIDE ()
+	 <TELL
+,YOU-CANT-SEE "your outside surroundings, though. It's as though a mist
+was in the way." CR>>
+
+<ROOM RUINS-ROOM
+      (IN ROOMS)
+      (DESC "Ruins Room")
+      (NORTH TO HALL-OF-STONE)
+      (SOUTH "The ruins end here.")
+      (DOWN TO RUINED-PIPE IF SMALL-FLAG)
+      (ACTION RUINS-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL WATER)
+      (THINGS
+       <PSEUDO (MOULDERING RUIN RUINS-PSEUDO)
+	       (CYCLOPEAN BLOCKS RUINS-PSEUDO)
+	       (STONE BLOCKS RUINS-PSEUDO)
+	       (CARVED STATUE RUINS-PSEUDO)
+	       (UNIMAGINABLE CONSTRUCT RUINS-PSEUDO)
+	       (BROKEN PILLAR RUINS-PSEUDO)
+	       (FALLEN PILLAR RUINS-PSEUDO)
+	       (COLLAPSED PORTICO RUINS-PSEUDO)>)>
+
+<ROUTINE RUINS-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"Here the main corridor opens into a vast underground space. Your light
+can barely illuminate a fraction of it. All around are cyclopean blocks
+of stone, crudely carved statues, and constructs of unimaginable
+purpose. Nearby the portico of a building has collapsed, and a pillar
+has smashed the pavement and exposed a small channel filled with swiftly
+rushing water. Water stains indicate that at one time the water flooded
+the entire area.">
+		<COND (<FSET? ,ZIPPER ,NDESCBIT>
+		       <TELL
+" Wedged against a pillar, as though by rushing water, is a zipper.">)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? PUT>
+			    <EQUAL? ,PRSI ,WATER>>
+		       <PERFORM ,PRSA ,PRSO ,RUINS-CHANNEL>
+		       <RTRUE>)
+		      (<AND <VERB? THROUGH BOARD>
+			    <EQUAL? ,PRSO ,WATER>>
+		       <PERFORM ,PRSA ,RUINS-CHANNEL>
+		       <RTRUE>)>)>>
+
+<OBJECT RUINS-CHANNEL
+	(IN RUINS-ROOM)
+	(DESC "channel")
+	(SYNONYM CHANNEL)
+	(ADJECTIVE CERAMIC)
+	(FLAGS NDESCBIT VEHBIT OPENBIT)
+	(ACTION CHANNEL-F)>
+
+<OBJECT RUINS-INFLOW
+	(IN RUINS-ROOM)
+	(DESC "inflow pipe")
+	(SYNONYM PIPE PIPES)
+	(ADJECTIVE INFLOW RUINED INPUT)
+	(FLAGS NDESCBIT AN VEHBIT)
+	(ACTION INFLOW-F)>
+
+<OBJECT RUINS-OUTFLOW
+	(IN RUINS-ROOM)
+	(DESC "outflow pipe")
+	(SYNONYM PIPE PIPES)
+	(ADJECTIVE OUTFLOW RUINED OUTPUT)
+	(FLAGS NDESCBIT AN VEHBIT)
+	(ACTION OUTFLOW-F)>
+
+<GLOBAL ROCK-FLAG <>>
+
+<ROOM CLIFF-TOP
+      (IN ROOMS)
+      (DESC "Cliff Top")
+      (DOWN TO CLIFF-MIDDLE)
+      (UP PER CLIFF-TOP-EXIT) ;"BOULDER-1"
+      (ACTION CLIFF-TOP-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (GLOBAL GLOBAL-ROCKS GLOBAL-CLIFF HUT)
+      (THINGS <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)>)>
+
+<ROUTINE CLIFF-TOP-EXIT ("AUX" (H <>) DIR)
+	 <COND (<EQUAL? ,HERE ,MOUNTAIN-TOP>
+		<SET H T>
+		<SET DIR "down">)
+	       (ELSE
+	        <SET DIR "up">)>
+	 <COND (,ROCK-FLAG
+		<COND (.H ,BOULDER-3)(ELSE ,BOULDER-1)>)
+	       (<TIME-FROZEN?>
+		<TELL
+"Even frozen in place, the rocks are so jumbled that you can't climb "
+.DIR " them. You would need full mountaineering equipment even to try." CR>
+		<RFALSE>)
+	       (,ROCK-SLIDE-COUNT
+		<TELL
+,I-DONT-THINK-THAT "you can climb " .DIR " an avalanche." CR>
+		<RFALSE>)
+	       (ELSE
+		<TELL
+"The pile of rocks looks so unsteady that attempting to climb over it
+could set off an avalanche." CR>
+		<RFALSE>)>>
+
+<ROUTINE CLIFF-TOP-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the upper end of a narrow, winding path up a sheer cliff. From here
+you can see that any further extension of the path was destroyed by a
+rock slide at some relatively recent time. There are many rocks ">
+		<COND (,ROCK-FLAG
+		       <TELL
+"suspended in midair above you. Some are quite close.">)
+		      (,ROCK-SLIDE-COUNT
+		       <TELL
+"tumbling towards you from above.">)
+		      (ELSE
+		       <TELL
+"precariously
+balanced above you. " ,IT-LOOKS-LIKE "the slightest disturbance could bring them
+down on you.">)>
+		<COND (<NOT <FSET? ,MOUNTAIN-TOP ,TOUCHBIT>>
+		       <TELL
+" Frustratingly, you can see the remains of a small building just
+beyond the dangerous area, but there is no way to get there from here.">)
+		      (ELSE
+		       <TELL
+" The hermit's hut is above.">)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? WALK>
+			    <NOT <EQUAL? ,P-WALK-DIR
+					 ,P?UP ,P?DOWN>>>
+		       <TELL
+"The only path leads up or down. There is only a sheer cliff elsewhere." CR>)
+		      (<AND <VERB? LESOCH> <NOT ,PRSO>>
+		       <PERFORM ,V?LESOCH ,GLOBAL-ROCKS>
+		       <RTRUE>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<AND <EQUAL? ,ROCK-SLIDE-COUNT 0>
+			    <NOT ,ROCK-FLAG>>
+		       <SETG SLIDE-PROB 10>
+		       <QUEUE I-AVALANCHE? -1>)>)>>
+
+<ROUTINE STOP-AVALANCHE ()
+	 <SETG TIME-STOPPED? ,HERE>
+	 <SETG ROCK-FLAG T>
+	 <QUEUE I-GIRGOL 12>
+	 <TELL ,AT-FIRST>
+	 <ROCKS-STOPPED>>
+
+<ROUTINE ROCKS-STOPPED ()
+	 <TELL "that the rocks are no
+longer falling. Dust hangs suspended in the air. Rocks appear wired in place.
+The mountainside that threatened to bury you floats serenely in midair." CR>>
+
+<ROOM BOULDER-1
+      (IN ROOMS)
+      (DESC "Boulder")
+      (UP TO BOULDER-2)
+      (DOWN TO CLIFF-TOP)
+      (ACTION BOULDER-ROOM-F)
+      (GLOBAL GLOBAL-ROCKS)
+      (FLAGS RLANDBIT)>
+
+<ROOM BOULDER-2
+      (IN ROOMS)
+      (DESC "Boulder")
+      (UP TO BOULDER-3)
+      (DOWN TO BOULDER-1)
+      (ACTION BOULDER-ROOM-F)
+      (GLOBAL GLOBAL-ROCKS)
+      (FLAGS RLANDBIT)>
+
+<ROOM BOULDER-3
+      (IN ROOMS)
+      (DESC "Boulder")
+      (UP TO MOUNTAIN-TOP)
+      (DOWN TO BOULDER-2)
+      (ACTION BOULDER-ROOM-F)
+      (GLOBAL GLOBAL-ROCKS)
+      (FLAGS RLANDBIT)>
+
+<ROUTINE BOULDER-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are clinging to a boulder that is floating in midair.
+There are many other boulders around, also floating, and lots of dust
+and dirt, also not moving. ">
+		<COND (<EQUAL? ,HERE ,BOULDER-1>
+		       <TELL
+"One particularly large boulder with good handholds is above you. Below
+you is the cliff face.">)
+		      (<EQUAL? ,HERE ,BOULDER-2>
+		       <TELL
+"A nice oblong boulder is above, and another large one is below you.">)
+		      (<EQUAL? ,HERE ,BOULDER-3>
+		       <TELL
+"Below you is a long oblong boulder. Above you there are no more boulders,
+but there is a continuation of the trail that you were on.">)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? CLIMB-UP CLIMB-FOO>
+		       <DO-WALK ,P?UP>)
+		      (<VERB? CLIMB-DOWN>
+		       <DO-WALK ,P?DOWN>)>)>>
+
+<ROOM MOUNTAIN-TOP
+      (IN ROOMS)
+      (DESC "Mountain Top")
+      (IN PER HUT-ROOM-EXIT)
+      (WEST PER HUT-ROOM-EXIT)
+      (DOWN PER CLIFF-TOP-EXIT ;CLIFF-TOP)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (ACTION MOUNTAIN-TOP-F)
+      (GLOBAL GLOBAL-ROCKS GLOBAL-CLIFF HUT)
+      (THINGS <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)>)>
+
+<ROUTINE MOUNTAIN-TOP-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the top of the mountain. There is ">
+		<COND (,HERMIT-APPEASED?
+		       <TELL "an imposing">)
+		      (ELSE
+		       <TELL "a crudely built">)>
+		<TELL " stone hut nearby
+to the west." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? CLIMB-UP CLIMB-FOO>
+		       <DO-WALK ,P?UP>)
+		      (<VERB? CLIMB-DOWN>
+		       <DO-WALK ,P?DOWN>)>)>>
+
+<ROUTINE HUT-ROOM-EXIT ()
+	 <COND (<EQUAL? ,HERE ,HUT-ROOM>
+		,MOUNTAIN-TOP)
+	       (ELSE
+		,HUT-ROOM)>>
+
+<ROOM HUT-ROOM
+      (IN ROOMS)
+      (DESC "Stone Hut")
+      (OUT PER HUT-ROOM-EXIT ;MOUNTAIN-TOP)
+      (EAST PER HUT-ROOM-EXIT ;MOUNTAIN-TOP)
+      (FLAGS RLANDBIT ONBIT)
+      (ACTION HUT-ROOM-F)
+      (GLOBAL HUT)
+      (THINGS
+       <PSEUDO (<> KEYSTONE KEYSTONE-PSEUDO)
+	       (<> MOSS RANDOM-PSEUDO)
+	       (<> MUD RANDOM-PSEUDO)
+	       (OLD FUR RANDOM-PSEUDO)>)>
+
+<ROUTINE KEYSTONE-PSEUDO ()
+	 <REDIRECT ,PSEUDO-OBJECT ,LIFE-CUBE>>
+
+<ROUTINE HUT-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<PERFORM ,V?EXAMINE ,HUT>
+		<TELL
+"Squatting on the floor is a wild-haired, bearded hermit who is ">
+		<COND (,HERMIT-APPEASED?
+		       <TELL "admiring his perfect hut">)
+		      (T
+		       <TELL "looking at you with ill-concealed dislike">)>
+		<TELL ,PERIOD>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? POINT>
+			    <EQUAL? ,PRSO ,HUT ,HERMIT ,LIFE-CUBE>>
+		       <ASK-HERMIT-ABOUT ,PRSO>)
+		      (<AND <VERB? TAKE RUB WRITE MOVE>
+			    <EQUAL? ,PRSO ,LIFE-CUBE>
+			    <NOT ,HERMIT-APPEASED?>>
+		       <TELL
+"The hermit springs between you and the cube. \"Not so fast! That thing
+holds up the whole hut. It's the keystone. Don't touch it.\"" CR>)
+		      (<AND <VERB? MALYON>
+			    <EQUAL? ,PRSO ,LIFE-CUBE>
+			    <NOT ,HERMIT-APPEASED?>>
+		       <FSET ,HUT ,RMUNGBIT>
+		       <FSET ,HUT-ROOM ,RMUNGBIT>
+		       <JIGS-UP
+"The cube comes alive, wiggles free of the wall, and the hut collapses
+on top of you.">)>)>>
+
+<OBJECT HUT
+	(IN LOCAL-GLOBALS)
+	(DESC "stone hut")
+	(SYNONYM HUT BUILDING STONE ENTRANCE)
+	(ADJECTIVE STONE CRUDE SMALL)
+	(FLAGS NDESCBIT VEHBIT OPENBIT)
+	(ACTION HUT-F)>
+
+<ROUTINE HUT-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "The hut is ">
+		<COND (<EQUAL? ,HERE ,CLIFF-TOP>
+		       <TELL "barely visible." CR>
+		       <RTRUE>)
+		      (,HERMIT-APPEASED?
+		       <TELL
+"beautifully constructed out of carefully dressed granite blocks
+and strong mortar.">)
+		      (ELSE
+		       <TELL "made of irregular stones">)>
+		<COND (<EQUAL? ,HERE ,HUT-ROOM>
+		       <COND (,HERMIT-APPEASED?
+			      <TELL
+" The construction of the hut is somewhat at odds with the
+squalor of its contents.">)
+			     (ELSE
+			      <TELL
+". The walls are chinked with moss, mud, small stones,">
+			      <COND (<AND <IN? ,LIFE-CUBE ,HUT-ROOM>
+					  <FSET? ,LIFE-CUBE ,NDESCBIT>>
+				     <TELL
+" a " ,WHITE-CUBE ",">)>
+			      <TELL
+" and an occasional old fur.">)>
+		       <TELL " There is an exit to the east." CR>)
+		      (ELSE
+		       <COND (<NOT ,HERMIT-APPEASED?>
+			      <TELL
+" much like those lying all around you.">)>
+		       <TELL " There is an entrance to the west." CR>)>)
+	       (<EQUAL? ,HERE ,CLIFF-TOP>
+		<TELL ,TOO-FAR>)
+	       (<AND <VERB? LOOK-INSIDE>
+		     <EQUAL? ,HERE ,MOUNTAIN-TOP>>
+		<TELL
+,YOU-CANT-SEE "very much from out here. Why not go in?" CR>)
+	       (<AND <VERB? REACH-IN>
+		     <EQUAL? ,MOUNTAIN-TOP ,HERE>>
+		<TELL
+"You reach in and hear a yell of surprise from inside." CR>)
+	       (<VERB? THROUGH BOARD>
+		<COND (<EQUAL? ,HERE ,HUT-ROOM>
+		       <TELL ,YOU-ARE>
+		       <TELL ,PERIOD>)
+		      (ELSE
+		       <GOTO ,HUT-ROOM>)>)
+	       (<VERB? DISEMBARK DROP>
+		<COND (<NOT <EQUAL? ,HERE ,HUT-ROOM>>
+		       <TELL ,YOU-ARE>
+		       <TELL ,PERIOD>)
+		      (ELSE
+		       <GOTO ,MOUNTAIN-TOP>)>)
+	       (<VERB? CASKLY>
+		<COND (<NOT ,HERMIT-APPEASED?>
+		       <SETG HERMIT-APPEASED? T>
+		       <FCLEAR ,LIFE-CUBE ,NDESCBIT>
+		       <TELL
+"The hut begins to melt, the stones dripping down like wax and the dirt
+spraying in all directions. ">
+		       <COND (<EQUAL? ,HERE ,HUT-ROOM>
+			      <TELL
+"\"Now you've done it, you meddlesome mage!\"
+screams the hermit.">)
+			     (ELSE
+			      <TELL "You hear a scream from inside the hut.">)>
+		       <TELL
+" But then the stones start flowing back into place, and
+the dirt speeds into place between them, and all is changed. The hut looks
+considerably different">
+		       <COND (<EQUAL? ,HERE ,HUT-ROOM>
+			      <TELL
+", and the cube, no longer necessary, sits in lonely
+splendor on the ground between you and the hermit">)>
+		       <TELL ,PERIOD>)>)>>
+
+<GLOBAL HERMIT-APPEASED? <>>
+
+<OBJECT HERMIT
+	(IN HUT-ROOM)
+	(DESC "hermit")
+	(SYNONYM HERMIT MAN)
+	(ADJECTIVE OLD)
+	(FLAGS NDESCBIT PERSON THE)
+	(ACTION HERMIT-F)>
+
+<ROUTINE HERMIT-F ()
+	 <COND (<EQUAL? ,WINNER ,HERMIT>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (<VERB? TELL-ME-ABOUT>
+		       <ASK-HERMIT-ABOUT ,PRSO>)
+		      (ELSE
+		       <TELL
+"He's a taciturn old buzzard and doesn't respond." CR>
+		<END-QUOTE>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The old man is clothed in goatskin rags. He has a long, tangled beard
+and dirty matted hair." CR>)
+	       (<VERB? SMELL>
+		<TELL
+"His last bath may well have been before you were born." CR>)
+	       (<VERB? SHOW>
+		<COND (<GETPT ,PRSO ,P?NAME>
+		       <TELL
+"The hermit remarks \"You've got one, too. What do you want with mine,
+then?\"" CR>)
+		      (<EQUAL? ,PRSO ,ZORKMID>
+		       <MATERIALISM>)
+		      (<EQUAL? ,PRSO ,BREAD ,FISH>
+		       <TELL
+"\"That looks pretty good. I eat mostly berries, moss, and goat meat.\"" CR>)
+		      (ELSE
+		       <UNINTERESTED ,HERMIT>)>)
+	       (<VERB? GIVE>
+		<COND (<EQUAL? ,PRSO ,BREAD ,FISH>
+		       <REMOVE ,PRSO>
+		       <TELL
+"The hermit devours the " 'PRSO " with gusto. He belches. \"That
+was a nice change,\" he remarks." CR>)>)
+	       (<AND <VERB? ASK-FOR>
+		     <EQUAL? ,PRSO ,HERMIT>
+		     <EQUAL? ,PRSI ,LIFE-CUBE>>
+		<COND (,HERMIT-APPEASED?
+		       <TELL
+"\"Sure, take it.\" He's distracted by his admiration for his newly
+perfected dwelling." CR>)
+		      (ELSE
+		       <TELL
+"\"Not on your life. It's holding up the whole hut. It's perfect
+for that chink. You don't know how long it took me to find it.\"" CR>)>)
+	       (<VERB? TRADE BUY>
+		<MATERIALISM>)
+	       (<VERB? YOMIN>
+		<TELL
+"The hermit is worried that you will rob him. He is very suspicious.
+He's been up here on the mountain for so long that his brains are slightly
+curdled." CR>)>>
+
+<ROUTINE MATERIALISM ()
+	 <TELL
+"\"Materialism! That's another thing I was trying to get away from!\" The
+hermit looks glum." CR>>
+
+<ROUTINE ASK-HERMIT-ABOUT (OBJ)
+	 <COND (<EQUAL? .OBJ ,GLOBAL-ROCKS>
+		<TELL
+"\"I like avalanches. They keep people away. Usually.\"" CR>)
+	       (<EQUAL? .OBJ ,ZORKMID>
+		<MATERIALISM>)
+	       (<EQUAL? .OBJ ,LIFE-CUBE ,HUT ,HERMIT>
+		<TELL
+"\"I've been living up here for many years. Wanted to get
+away from people. Too much noise, too much talk, too much jabber-jabber
+all the time. I've been building this hut for years, too.
+Couldn't find the right keystone. It would always collapse after a while,
+so I never moved into it. I kept hoping to get it right some day;
+no training in stonemasonry. One day there was a presence
+on the mountain, like a cloud had come over. Then there was smoke,
+orange smoke, I think. The next day I found that stone sitting on top
+of a rock not five minutes' walk from here. It was perfect.\"" CR>)>>
+
+<OBJECT GLOBAL-CLIFF
+	(IN LOCAL-GLOBALS)
+	(DESC "cliff")
+	(SYNONYM CLIFF TRAIL TRACK PATH)
+	(ADJECTIVE SHEER)
+	(FLAGS NDESCBIT)
+	(ACTION GLOBAL-CLIFF-F)>
+
+<GLOBAL ROCKS-PRECARIOUS "The rocks look very precariously balanced">
+
+<ROUTINE GLOBAL-CLIFF-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL ,ROCKS-PRECARIOUS ,PERIOD>)
+	       (<VERB? CLIMB-UP CLIMB-FOO FOLLOW>
+		<DO-WALK ,P?UP>)
+	       (<VERB? CLIMB-DOWN>
+		<DO-WALK ,P?DOWN>)>>
+
+<OBJECT GLOBAL-ROCKS
+	(IN LOCAL-GLOBALS)
+	(DESC "rock")
+	(SYNONYM ROCK ROCKS BOULDER AVALANCHE)
+	(ADJECTIVE JUMBLED SCREE PILE MOLTEN LARGE)
+	(FLAGS NDESCBIT)
+	(ACTION GLOBAL-ROCKS-F)>
+
+<ROUTINE GLOBAL-ROCKS-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<EQUAL? ,HERE ,BOULDER-1 ,BOULDER-2 ,BOULDER-3>
+		       <PERFORM ,V?LOOK>
+		       <RTRUE>)
+		      (<EQUAL? ,HERE
+			       ,VOLCANO-BASE ,VOLCANO-ROOM ,OUTCROPPING-ROOM>
+		       <TELL
+"The rocks look hot and are melted to all their neighbors." CR>)
+		      (<OR <EQUAL? ,HERE
+				   ,CLIFF-TOP ,CLIFF-MIDDLE ,CLIFF-BOTTOM>
+			   <EQUAL? ,HERE ,MOUNTAIN-TOP ,CAVE-ENTRANCE>>
+		       <COND (<OR ,ROCK-FLAG <TIME-FROZEN?>>
+			      <TELL "You can see ">
+			      <ROCKS-STOPPED>)
+			     (<QUEUED? I-AVALANCHE>
+			      <ROCKS-TUMBLING>)
+			     (ELSE
+			      <TELL ,ROCKS-PRECARIOUS ,PERIOD>)>)>)
+	       (<VERB? CLIMB-FOO CLIMB-UP CLIMB-ON>
+		<DO-WALK ,P?UP>)
+	       (<VERB? RUB MOVE PUSH LESOCH KICK MALYON>
+		<COND (<EQUAL? ,HERE ,VOLCANO-BASE
+			       ,VOLCANO-ROOM ,OUTCROPPING-ROOM>
+		       <TELL-TOO-HOT>
+		       <TELL ,PERIOD>
+		       <RTRUE>)
+		      (<OR <TIME-FROZEN?>
+			   <NOT <EQUAL? ,HERE ,CLIFF-TOP ,MOUNTAIN-TOP>>>
+		       <RFALSE>)
+		      (<VERB? MALYON>
+		       <TELL "You animate">)
+		      (<VERB? LESOCH>
+		       <TELL
+"The wind whips up to a frenzy and touches">)
+		      (ELSE
+		       <TELL
+"You gingerly touch">)>
+		<TELL " a rock, which tilts a little. Another rock slides into
+the gap, triggering a larger one to fall. Suddenly, the entire mountainside
+begins to tumble down." CR>
+		<DEQUEUE I-AVALANCHE?>
+		<QUEUE I-AVALANCHE -1>
+		<RTRUE>)
+	       (<VERB? TAKE>
+		<COND (<AND <EQUAL? ,HERE ,CLIFF-TOP ,MOUNTAIN-TOP>
+			    <NOT <TIME-FROZEN?>>>
+		       <COND (<NOT <QUEUED? I-AVALANCHE>>
+			      <TELL
+"Taken, but you drop it immediately when you see that your intemperate
+action has triggered a rock slide." CR>
+			      <SETG ROCK-SLIDE-COUNT 0>
+			      <DEQUEUE I-AVALANCHE?>
+			      <QUEUE I-AVALANCHE -1>
+			      <RTRUE>)>)
+		      (<EQUAL? ,HERE ,VOLCANO-BASE
+			       ,VOLCANO-ROOM ,OUTCROPPING-ROOM>
+		       <TELL-TOO-HOT>
+		       <TELL " or solidly fixed to the
+ground here." CR>)
+		      (ELSE
+		       <TELL
+"None of the rocks look interesting enough to take." CR>)>)>>
+
+<ROUTINE TELL-TOO-HOT ()
+	 <TELL CTHE ,PRSO " is too hot to touch">>
+
+<ROOM CLIFF-MIDDLE
+      (IN ROOMS)
+      (DESC "Cliff Middle")
+      (UP TO CLIFF-TOP)
+      (DOWN TO CLIFF-BOTTOM)
+      (ACTION CLIFF-MIDDLE-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (GLOBAL GLOBAL-ROCKS GLOBAL-CLIFF)
+      (THINGS <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)>)>
+
+<ROUTINE CLIFF-MIDDLE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"A narrow ledge, barely wide enough to stand on, interrupts the cliff
+here." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? WALK>
+			    <NOT <EQUAL? ,P-WALK-DIR
+					 ,P?UP ,P?DOWN>>>
+		       <TELL
+"The path leads up or down. There is a sheer cliff elsewhere." CR>)>)>>
+
+<ROOM CLIFF-BOTTOM
+      (IN ROOMS)
+      (DESC "Cliff Bottom")
+      (UP TO CLIFF-MIDDLE)
+      (DOWN "You're at the bottom already.")
+      (WEST TO CAVE-ENTRANCE)
+      (EAST "There's no path that way.")
+      (SOUTH "There's no path that way.")
+      (ACTION CLIFF-BOTTOM-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (GLOBAL GLOBAL-ROCKS GLOBAL-CLIFF)
+      (THINGS <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)>)>
+
+<ROUTINE CLIFF-BOTTOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the bottom of a sheer cliff which towers above you. Jumbled rockfalls
+are all around you. A goat track (at best) leads up, and a well-worn
+trail heads west." CR>)>>
+
+<OBJECT GLOBAL-CAVE
+	(IN LOCAL-GLOBALS)
+	(DESC "cave")
+	(SYNONYM CAVE CAVERN)
+	(ADJECTIVE DARK)
+	(FLAGS NDESCBIT)
+	(ACTION GLOBAL-CAVE-F)>
+
+<ROUTINE GLOBAL-CAVE-F ()
+	 <COND (<AND <VERB? EXAMINE> <NOT <EQUAL? ,HERE ,CAVE-ENTRANCE>>>
+		<PERFORM ,V?LOOK>
+		<RTRUE>)
+	       (<VERB? THROUGH>
+		<COND (<EQUAL? ,HERE ,CAVE-ENTRANCE>
+		       <GOTO ,OGRE-CAVE>)
+		      (ELSE
+		       <TELL ,YOU-ARE ,PERIOD>)>)
+	       (ELSE
+		<REDIRECT ,GLOBAL-CAVE ,GLOBAL-ROOM>)>>
+
+<ROOM CAVE-ENTRANCE
+      (IN ROOMS)
+      (DESC "Cave Entrance")
+      (EAST TO CLIFF-BOTTOM)
+      (IN TO OGRE-CAVE)
+      (NORTH TO OGRE-CAVE)
+      (UP "There's no path that way.")
+      (ACTION CAVE-ENTRANCE-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (GLOBAL GLOBAL-CLIFF GLOBAL-CAVE GLOBAL-ROCKS)
+      (THINGS
+       <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)
+	       (<> LITTER RANDOM-PSEUDO)
+	       (LITTER BONES PLURAL-PSEUDO)
+	       (OLD HIDES PLURAL-PSEUDO)
+	       (<> BRUSH PLANTS-PSEUDO)>)>
+
+<ROUTINE CAVE-ENTRANCE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"A well-worn trail terminates here where a cave enters the cliff-side to
+the north. Outside the cave is a litter of bones, old hides and brush.
+The smell that issues from the cave is mephitic. To the east is the
+bottom of a sheer cliff." CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<QUEUE I-OGRE -1>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? LISTEN> <NOT ,PRSO>>
+		       <OGRE-NOISES>)
+		      (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <TELL
+"It smells horrific. The sanitary habits of ogres are appalling." CR>)>)>>
+
+<GLOBAL SNEEZY? <>>
+
+<ROOM OGRE-CAVE
+      (IN ROOMS)
+      (DESC "Cave")
+      (OUT TO CAVE-ENTRANCE)
+      (SOUTH TO CAVE-ENTRANCE)
+      (DOWN PER OGRE-BEDROOM-EXIT)
+      (ACTION OGRE-CAVE-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GLOBAL-CAVE GLOBAL-ROCKS)
+      (THINGS <PSEUDO (LOOSE DIRT RANDOM-PSEUDO)
+		      (HARD DIRT RANDOM-PSEUDO)>)>
+
+<ROUTINE OGRE-CAVE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a natural fissure in the rock which was enlarged with crude skill
+into a spacious and comfortable room, at least if you're fond of caves.
+The floor is dirt, hard packed in some parts, loose in others.
+A low passage leads down. ">
+		<OGRE-DESC>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT <QUEUED? I-OGRE-KILLS-YOU>>
+		       <QUEUE I-OGRE-KILLS-YOU 12>)>
+		<COND (<NOT ,LIT>
+		       <JIGS-UP
+"In the dark you have blundered into something large, smelly, and mean.
+It is annoyed by your intrusion and pounds you to a pulp.">)
+		      (<AND <EQUAL? ,OHERE ,OGRE-BEDROOM>
+			    <NOT ,SNEEZY?>
+			    <NOT <EQUAL? ,ESPNIS? ,OGRE>>
+			    <NOT <TIME-FROZEN?>>>
+		       <I-OGRE-KILLS-YOU T>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? LISTEN> <NOT ,PRSO>>
+		       <PERFORM ,V?LISTEN ,OGRE>
+		       <RTRUE>)
+		      (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <SMELL-OGRE-CAVE>)
+		      (<OR <VERB? WAVE>
+			   ;<AND <VERB? DROP>
+				<EQUAL? ,PRSO ,CLUB>>>
+		       <GIVE-TO-OGRE>)
+		      (<AND <VERB? THROUGH> <EQUAL? ,PRSO ,CORRIDOR>>
+		       <DO-WALK ,P?DOWN>)>)>>
+
+<ROUTINE SMELL-OGRE-CAVE ()
+	 <TELL
+"It smells even worse inside than it did outside, as hard as that is to
+credit." CR>>
+
+<ROUTINE OGRE-BEDROOM-EXIT ()
+	 <COND (<OR ,SNEEZY?
+		    <TIME-FROZEN?>
+		    <EQUAL? ,ESPNIS? ,OGRE>>
+		<TELL
+"You saunter nonchalantly past the " <COND (,SNEEZY?
+					    "convulsively sneezing")
+					   (<TIME-FROZEN?>
+					    "immobile")
+					   (ELSE "sleeping")>
+" ogre." CR CR>
+		,OGRE-BEDROOM)
+	       (ELSE
+		<TELL
+"The ogre moves quickly to bar your way">
+		;<COND (<IN? ,CLUB ,OGRE>
+		       <TELL
+", waving his club menacingly">)>
+		<COND (<EQUAL? ,SHRINK-FLAG ,OGRE>
+		       <TELL
+". He may be small, but he's still dangerous">)>
+		<TELL ,PERIOD>
+		<RFALSE>)>>
+
+<ROOM OGRE-BEDROOM
+      (IN ROOMS)
+      (DESC "Ogre Lair")
+      (UP TO OGRE-CAVE)
+      (OUT TO OGRE-CAVE)
+      (ACTION OGRE-BEDROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GLOBAL-CAVE)
+      (THINGS
+       <PSEUDO (FILTHY FUR RANDOM-PSEUDO)
+	       (MOLDY FUR RANDOM-PSEUDO)
+	       (FILTHY FURS PLURAL-PSEUDO)
+	       (MOLDY FURS PLURAL-PSEUDO)
+	       (CRUDE BED RANDOM-PSEUDO)>)>
+
+<ROUTINE OGRE-BEDROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This small but cozy hole is the ogre's lair. Moldy, filthy furs piled
+in one corner make a crude bed. There is a rocky crawl up to the main
+part of the cave." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? LISTEN> <NOT ,PRSO>>
+		       <OGRE-NOISES>)
+		      (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <SMELL-OGRE-CAVE>)
+		      (<AND <VERB? THROUGH>
+			    <EQUAL? ,PRSO ,CORRIDOR>>
+		       <DO-WALK ,P?UP>)>)>>
+
+<OBJECT MAGIC-BOX
+	(IN OGRE-BEDROOM)
+	(DESC "gold box")
+	(SYNONYM BOX LATCH LID SYMBOL)
+	(ADJECTIVE GOLD DECORATION)
+	(FLAGS TAKEBIT CONTBIT MAGICBIT SEARCHBIT)
+	(CAPACITY 10)
+	(ACTION MAGIC-BOX-F)>
+
+<ROUTINE MAGIC-BOX-EXIT ("AUX" L)
+	 <SET L <LOC ,MAGIC-BOX>>
+	 <COND (<AND .L
+		     <IN? .L ,ROOMS>
+		     <NOT <GETP .L ,P?CUBE>>
+		     <EQUAL? <GETP ,HERE ,P?CUBE> ,MAGIC-BOX-CUBE>>
+		<COND (<EQUAL? .L ,CASTLE>
+		       <MAGIC-DOOR-EXIT>)
+		      (ELSE .L)>)
+	       (ELSE
+		<TELL
+"Oddly, although there appears to be an exit there, you can't seem to
+force your way through it." CR>
+		<RFALSE>)>>
+
+<GLOBAL MAGIC-BOX-CUBE <>>
+
+<ROUTINE MAGIC-BOX-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The gold box is small, richly ornamented with allegorical figures of ">
+		<MAGIC-BOX-CREATURE>
+		<TELL " and cryptic symbols. It has
+a small latch which ">
+		<COND (<FSET? ,MAGIC-BOX ,OPENBIT>
+		       <TELL "could hold">)
+		      (ELSE
+		       <TELL "holds">)>
+		<TELL " closed the lid." CR>)
+	       (<VERB? LOCK UNLOCK>
+		<TELL "There's no lock, only a latch." CR>)
+	       (<AND <VERB? PUT> <EQUAL? ,PRSI ,MAGIC-BOX>>
+		<COND (<NOT <IN? ,MAGIC-BOX ,WINNER>>
+		       <NOT-HOLDING ,PRSI>)
+		      (<NOT <FSET? ,MAGIC-BOX ,OPENBIT>>
+		       <TELL
+,YOU-HAVE-TO " open the " 'PRSI " first." CR>)
+		      (<FIRST? ,MAGIC-BOX>
+		       <TELL
+"There is already something in it." CR>)
+		      (<NOT <GETPT ,PRSO ,P?NAME>>
+		       <COND (<L? <GETP ,PRSO ,P?SIZE>
+				  <GETP ,MAGIC-BOX ,P?CAPACITY>>
+			      <TELL "Strangely, you can't fit it in." CR>)
+			     (ELSE
+			      <TELL ,DOESNT-FIT>)>)
+		      (ELSE
+		       <MOVE ,PRSO ,MAGIC-BOX>
+		       <COND (<OR <EQUAL? ,PRSO ,MAGIC-BOX-CUBE>
+				  <AND <EQUAL? ,MAGIC-BOX-CUBE ,TIME-CUBE>
+				       <NOT <GETP ,PRSO ,P?CUBE>>>>
+			      <TELL "Done." CR>)
+			     (ELSE
+			      <COND (<EQUAL? ,HERE ,SCALES-ROOM>
+				     <USE-SPELL>)>
+			      <SETG MAGIC-BOX-CUBE ,PRSO>
+			      <TELL
+"When you insert " THE ,PRSO " into the box, there is a brief burst of
+light, and the decorations on the box change subtly. They now depict ">
+			      <MAGIC-BOX-CREATURE>
+			      <TELL ,PERIOD>)>)>)>>
+
+<ROUTINE MAGIC-BOX-CREATURE ("AUX" STR)
+	 <COND (<SET STR <GETP ,MAGIC-BOX-CUBE ,P?TEXT>>
+		<TELL .STR>)
+	       (ELSE <TELL "turtles">)>>
+
+<OBJECT OGRE
+	(IN OGRE-CAVE)
+	(DESC "ogre")
+	(SYNONYM OGRE)
+	(ADJECTIVE MOUNTAIN)
+	(FLAGS PERSON THE NDESCBIT BRIEFBIT CONTBIT OPENBIT)
+	(ACTION OGRE-F)
+	(DESCFCN OGRE-DESC)
+	(CONTFCN OGRE-F)>
+
+<ROUTINE OGRE-DESC ("OPTIONAL" RARG OBJ)
+	 <TELL "A " <COND (<EQUAL? ,SHRINK-FLAG ,OGRE>
+			   "small but nasty")
+			  (ELSE "large")> " ogre ">
+	 <COND (<TIME-FROZEN?>
+		<TELL
+"stands immobile in the passage, caught in mid-sneeze.">)
+	       (<EQUAL? ,ESPNIS? ,OGRE>
+		<TELL
+"snores noisily here.">)
+	       (,SNEEZY?
+		<TELL
+"rolls uncomfortably on the floor, sneezing loudly.">)
+	       (ELSE
+		;<COND (<IN? ,CLUB ,OGRE>
+		       <TELL "with a club ">)>
+		<TELL "bars the passage.">)>
+	 <CRLF>>
+
+<ROUTINE OGRE-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? ,WINNER ,OGRE>
+		<COND (<OR <TIME-FROZEN?>
+			   <EQUAL? ,ESPNIS? ,OGRE>>
+		       <TELL
+"There is no reply." CR>)
+		      (ELSE
+		       <TELL
+CTHE ,OGRE " grunts nastily at you." CR>)>
+		<END-QUOTE>)
+	       ;(<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<AND <VERB? MALYON> <EQUAL? ,PRSO ,CLUB>>
+		       <COND (<IMMOBILIZED?> <RTRUE>)
+			     (ELSE
+			      <TELL
+"The club comes alive, writhing and kicking and trying to get away, but
+the ogre grips it purposefully and glares at you until it quiets down." CR>)>)
+		      (<AND <VERB? TAKE RUB>
+			    <IN? ,PRSO ,OGRE>>
+		       <TELL
+"The ogre has " THE ,PRSO " gripped tight." CR>)>)
+	       (ELSE
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"This is a fairly typical mountain ogre. His carbuncles are a brilliant
+purple, and his hair is matted down with something slick and
+unpleasant-smelling. His eyes are watering and his nose is running,
+which doesn't make him any more attractive. His whole body is covered by
+dirty brown fur. He looks like a particularly ill-favored
+bear.">
+		       ;<COND (<IN? ,CLUB ,OGRE>
+			      <TELL
+" He is carrying a large and well-used club.">)>
+		       <COND (<TIME-FROZEN?>
+			      <TELL
+" He and all his surroundings are frozen in place.">)>
+		       <COND (<EQUAL? ,SHRINK-FLAG ,OGRE>
+			      <TELL
+" He is currently six inches of concentrated ugliness.">)>
+		       <CRLF>)
+		      (<AND <VERB? GIVE WAVE-AT> <EQUAL? ,PRSI ,OGRE>>
+		       <GIVE-TO-OGRE>)
+		      (<VERB? LISTEN>
+		       <TELL CTHE ,OGRE " sounds ">
+		       <COND (<TIME-FROZEN?>
+			      <TELL "very quiet." CR>)
+			     (<EQUAL? ,ESPNIS? ,OGRE>
+			      <TELL "like he is snoring." CR>)
+			     (ELSE
+			      <COND (<VISIBLE? ,WEED>
+				     <COND (<FSET? ,WEED ,RMUNGBIT>
+					    <TELL "extremely ">)
+					   (ELSE
+					    <TELL "somewhat ">)>)>
+			      <TELL "congested and sneezy." CR>)>)
+		      (<HOSTILE-VERB?>
+		       <COND (<EQUAL? ,ESPNIS? ,OGRE>
+			      <SETG ESPNIS? <>>
+			      <DEQUEUE I-ESPNIS>
+			      <TELL
+"The ogre wakes at the first touch!" CR>)>
+		       <COND (<TIME-FROZEN?>
+			      <TELL
+"There is no effect. It's like attacking a statue." CR>)
+			     (,SNEEZY?
+			      <TELL
+CTHE ,OGRE "'s hide is thick, and your attack only tickles him." CR>)
+			     (ELSE
+			      <TELL
+CTHE ,OGRE " contemptuously fends you off." CR>)>)
+		      ;(<AND <VERB? ESPNIS>
+			    <NOT <EQUAL? ,ESPNIS? ,OGRE>>>
+		       <OGRE-LOSES-CLUB>
+		       <RFALSE>)
+		      (<VERB? SMELL>
+		       <TELL
+"You would put your nasal cavity at great risk." CR>)
+		      (<VERB? YOMIN>
+		       <COND (<EQUAL? ,ESPNIS? ,PRSO>
+			      <TELL
+CTHE ,PRSO " is asleep." CR>)
+			     (ELSE
+			      <TELL
+"You get the impression of discomfort and annoyance. This is apparently
+not just for the usual ogreish reasons (general nastiness, bad temper,
+and lice) but because the ogre is suffering from hay fever." CR>)>)
+		      (<VERB? SNAVIG>
+		       <SETG CHANGED? ,OGRE>
+		       <QUEUE I-SNAVIG 12>
+		       <TELL
+"You become just as ugly, bellicose, and sneezy as the ogre.">
+		       <COND (<AND <NOT <EQUAL? ,ESPNIS? ,OGRE>>
+				   <NOT <TIME-FROZEN?>>>
+			      <TELL
+" The ogre is even less inclined to let you by.">)>
+		       <CRLF>)>)>>
+
+<ROUTINE GIVE-TO-OGRE ()
+	 <COND (<OR <TIME-FROZEN?>
+		    <EQUAL? ,ESPNIS? ,OGRE>>
+		<TELL
+"He is in no position to respond." CR>)
+	       (<EQUAL? ,PRSO ,WEED>
+		<TELL
+"The ogre shrinks back and lets go an explosive sneeze">
+		;<COND (<IN? ,CLUB ,OGRE>
+		       <TELL ", but his club is
+still at the ready">)>
+		<TELL ,PERIOD>)
+	       ;(<EQUAL? ,PRSO ,CLUB>
+		<MOVE ,CLUB ,OGRE>
+		<FSET ,CLUB ,NDESCBIT>
+		<TELL
+		 "He grabs it." CR>)
+	       (ELSE
+		<UNINTERESTED ,OGRE>)>>
+
+;<OBJECT CLUB
+	(IN OGRE)
+	(DESC "club")
+	(SYNONYM CLUB)
+	(SIZE 10)
+	(FLAGS WEAPONBIT TAKEBIT TRYTAKEBIT NDESCBIT)>
diff --git a/c2.zil b/c2.zil
new file mode 100644
index 0000000..c3dec03
--- /dev/null
+++ b/c2.zil
@@ -0,0 +1,1386 @@
+"C2 for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+"WATER"
+
+<OBJECT WATER-CUBE
+	(IN MAGIC-BOX)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE BQ ;C2 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "dolphins")
+	(FLAGS TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE WATER-ROOM)>
+
+<ROOM WATER-ROOM
+      (IN ROOMS)
+      (DESC "Water Room")
+      (CUBE WATER-CUBE)
+      (NORTH TO OUBLIETTE)
+      (EAST PER MAGIC-BOX-EXIT)
+      (SOUTH TO OCEAN-ROOM)
+      (ACTION WATER-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL WATER)
+      (THINGS
+       <PSEUDO (<> CORAL RANDOM-PSEUDO)
+	       (DAMP MOSS RANDOM-PSEUDO)
+	       (<> MUD RANDOM-PSEUDO)
+	       (SHIMMERING FILM RANDOM-PSEUDO)
+	       (<> BUBBLE RANDOM-PSEUDO)>)>
+
+<ROUTINE WATER-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a damp, mossy room. Its floor is mud, and its walls and ceiling are
+coral. In the gaps in the coral you can see a shimmering film which you
+realize is actually the outer edge of a huge bubble of air enclosing you.
+On the north, east and south sides of the room are curtains of bubbles."
+CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+"OCEAN PROBLEM -- SAVE LOST CUBE AND GET ONE FROM GROUPER"
+
+<ROOM OCEAN-ROOM
+      (IN ROOMS)
+      (DESC "Mid-Ocean")
+      (ACTION OCEAN-ROOM-F)
+      (FLAGS RWATERBIT OUTSIDE ONBIT)
+      (GLOBAL WATER)>
+
+<ROUTINE OCEAN-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are swimming in mid-ocean.">
+		<CLEVER-CONTENTS ,HERE " Floating nearby" ,GROUPER>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<EQUAL? ,OHERE ,WATER-ROOM>
+		       <MOVE ,GROUPER ,HERE>
+		       <QUEUE I-GROUPER 2>
+		       <QUEUE I-CUBE-SINKS 3>
+		       <MOVE ,WATER-CUBE ,HERE>
+		       <FSET ,WATER-CUBE ,NDESCBIT>
+		       <TELL
+"You step out of the room and drop precipitously into the Flathead Ocean,
+making a terrific splash. " CTHE ,WATER-CUBE ", lost in the shock of the
+fall, makes a smaller splash. It is a little less buoyant than you and
+begins to sink slowly beneath the waves.">
+		       <SOAK-PLAYER>
+		       <CRLF>
+		       <CRLF>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<FUN-IN-OCEAN>)
+	       (<EQUAL? .RARG ,M-END>
+		<SOAK-IF-OPENED>)>>
+
+<ROUTINE FUN-IN-OCEAN ()
+	 <COND (<VERB? WALK SWIM>
+		<COND (<EQUAL? ,HERE ,LOST-IN-OCEAN>
+		       <GOTO ,LOST-IN-OCEAN>)
+		      (<EQUAL? ,P-WALK-DIR ,P?DOWN>
+		       <COND (<EQUAL? ,CHANGED? ,GROUPER>
+			      <YOU-SWIM>
+			      <GOTO ,OCEAN-FLOOR>)
+			     (ELSE
+			      <HOLD-BREATH>)>)
+		      (<EQUAL? ,P-WALK-DIR ,P?UP>
+		       <TELL
+"Only if you sprout wings first." CR>)
+		      (ELSE
+		       <GOTO ,LOST-IN-OCEAN>)>)
+	       (<VERB? TAKE>
+		<COND (<EQUAL? ,CHANGED? ,GROUPER>
+		       <TELL
+"Your fins are not well designed to hold things." CR>)
+		      (<G? ,P-MULT 1>
+		       <TELL
+"They were floating in opposite directions, and you get a chance
+at only one of them." CR>
+		       <RFATAL>)>)
+	       (<AND <VERB? DROP> <HELD? ,PRSO>>
+		<QUEUE I-FLOTSAM 2>
+		<MOVE ,PRSO ,HERE>
+		<FSET ,PRSO ,NDESCBIT>
+		<SOAK-OBJ? ,PRSO>
+		<TELL CTHE ,PRSO>
+		<COND (<EQUAL? ,PRSO ,BOTTLE>
+		       <TELL
+" is now floating nearby">)
+		      (ELSE
+		       <TELL
+" begins to sink beneath the waves">)>
+		<TELL ,PERIOD>)
+	       (<AND <VERB? EAT>
+		     <EQUAL? ,CHANGED? ,GROUPER>
+		     <FSET? ,PRSO ,TAKEBIT>>
+		<SETG ATE-AS-GROUPER? T>
+		<REMOVE ,PRSO>
+		<TELL
+"Opening your maw, you swallow "><THE-PRSO>)>>
+
+<ROUTINE HOLD-BREATH ()
+	 <TELL
+"You take a deep breath and swim downward, but you can't hold it long enough
+to reach the bottom." CR>>
+
+<ROUTINE YOU-SWIM ()
+	 <TELL "You swim ">
+	 <COND (<EQUAL? ,HERE ,OCEAN-ROOM>
+		<TELL "downward">)
+	       (ELSE <TELL "upward">)>
+	 <COND (<IN? ,GROUPER ,HERE>
+		<COND (<EQUAL? ,HERE ,OCEAN-ROOM>
+		       <MOVE ,GROUPER ,OCEAN-FLOOR>
+		       <TELL ", followed">)
+		      (ELSE <TELL ", watched">)>
+		<TELL " by the nervous grouper">)>
+	 <TELL ,PERIOD CR>>
+
+<ROOM LOST-IN-OCEAN
+      (IN ROOMS)
+      (DESC "Open Ocean")
+      (FLAGS RWATERBIT OUTSIDE ONBIT)
+      (ACTION LOST-IN-OCEAN-F)
+      (GLOBAL WATER)>
+
+<ROUTINE LOST-IN-OCEAN-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are lost in the middle of the open ocean. There is no land in sight.">
+		<CLEVER-CONTENTS ,HERE " Floating nearby">
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<FUN-IN-OCEAN>)
+	       (<EQUAL? .RARG ,M-END>
+		<SOAK-IF-OPENED>)>>
+
+<ROOM OCEAN-FLOOR
+      (IN ROOMS)
+      (DESC "Ocean Floor")
+      (UP TO OCEAN-ROOM)
+      (ACTION OCEAN-FLOOR-F)
+      (FLAGS RWATERBIT ONBIT)
+      (GLOBAL WATER)>
+
+<ROUTINE OCEAN-FLOOR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are deep beneath the waves, near a small pile of rocks and broken
+coral that make up the nest of a grouper." CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT <EQUAL? ,CHANGED? ,GROUPER>>
+		       <JIGS-UP
+"You have reemerged beneath the ocean. There is no air here.
+You drown.">)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? WALK SWIM>
+		       <COND (<EQUAL? ,CHANGED? ,GROUPER>
+			      <COND (<EQUAL? ,P-WALK-DIR ,P?UP>
+				     <YOU-SWIM>
+				     <GOTO ,OCEAN-ROOM>)
+				    (<EQUAL? ,P-WALK-DIR ,P?DOWN>
+				     <TELL
+"You hit your nose against the sand." CR>)
+				    (ELSE
+				     <TELL
+"You swim in circles for a while." CR>)>)
+			     (<OR <NOT ,PRSO>
+				  <EQUAL? ,PRSO ,P?UP>
+				  <EQUAL? ,P-WALK-DIR ,P?UP>>
+			      <TELL
+"You swim upward, desperately trying to hold your breath until you
+reach the surface. It's a losing battle. " ,YOU-CANT "hold it any
+longer, take a breath, and it's pure, sweet air! You have reached the
+surface." CR CR>
+			      <GOTO ,OCEAN-ROOM>)
+			     (ELSE
+			      <TELL
+"You swim about for a short distance." CR>)>)
+		      (<VERB? DROP> <RFALSE>)
+		      (<EQUAL? ,CHANGED? ,GROUPER>
+		       <FUN-IN-OCEAN>)>)>>
+
+<GLOBAL ATE-AS-GROUPER? <>>
+
+<OBJECT GROUPER-NEST
+	(IN OCEAN-FLOOR)
+	(DESC "grouper nest")
+	(SYNONYM NEST CORAL ROCKS PILE)
+	(ADJECTIVE GROUPER BROKEN PILE)
+	(FLAGS NDESCBIT OPENBIT CONTBIT SEARCHBIT TRYTAKEBIT)
+	(CAPACITY 20)>
+
+<OBJECT BOTTLE
+	(IN OCEAN-ROOM)
+	(DESC "bottle")
+	(SYNONYM BOTTLE)
+	(ADJECTIVE FLOATING)
+	(FLAGS NDESCBIT TAKEBIT CONTBIT TRANSBIT SEARCHBIT)
+	(CAPACITY 6)
+	(ACTION BOTTLE-F)>
+
+<ROUTINE BOTTLE-F ("AUX" F)
+	 <COND (<VERB? FILL>
+		<COND (<NOT <IN? ,BOTTLE ,WINNER>>
+		       <NOT-HOLDING ,BOTTLE>)
+		      (<IN? ,LOCAL-WATER ,BOTTLE>
+		       <TELL ,IT-IS-ALREADY "full" ,PERIOD>)
+		      (<EQUAL? ,PRSI <> ,WATER>
+		       <COND (<NOT <GLOBAL-IN? ,WATER ,HERE>>
+			      <TELL "There's no water here." CR>
+			      <RTRUE>)>
+		       <MOVE ,LOCAL-WATER ,BOTTLE>
+		       <TELL
+CTHE ,BOTTLE " is now full of ">
+		       <COND (<EQUAL? ,HERE
+				      ,OCEAN-ROOM
+				      ,OCEAN-FLOOR
+				      ,LOST-IN-OCEAN>
+			      <FSET ,LOCAL-WATER ,RMUNGBIT>
+			      <TELL "salt ">)
+			     (ELSE
+			      <FCLEAR ,LOCAL-WATER ,RMUNGBIT>)>
+		       <TELL "water">
+		       <COND (<NOT <FSET? ,BOTTLE ,OPENBIT>>
+			      <TELL ", and it's closed again">)>
+		       <COND (<SET F <SOAK-STUFF ,BOTTLE>>
+			      <TELL
+". The water has ruined something in the bottle">)>
+		       <TELL ,PERIOD>)
+		      (ELSE
+		       <YOU-CANT-X-PRSI "fill the bottle with">)>)
+	       (<AND <VERB? POUR>
+		     <EQUAL? ,PRSO ,BOTTLE>
+		     <IN? ,LOCAL-WATER ,BOTTLE>>
+		<REMOVE ,LOCAL-WATER>
+		<TELL
+CTHE ,BOTTLE " is now empty of water." CR>)
+	       (<VERB? LOOK-INSIDE OPEN>
+		<FCLEAR ,LISKON-SCROLL ,NDESCBIT>
+		<RFALSE>)>>
+
+<OBJECT GROUPER
+	(IN OCEAN-ROOM)
+	(DESC "grouper")
+	(LDESC
+"A large grouper swims nearby.")
+	(SYNONYM FISH GROUPER)
+	(ADJECTIVE LARGE)
+	(FLAGS PERSON THE)
+	(SIZE 100)
+	(ACTION GROUPER-F)>
+
+<ROUTINE GROUPER-F ()
+	 <COND (<EQUAL? ,WINNER ,GROUPER>
+		<END-QUOTE>
+		<TELL
+"The grouper stares at you, goggle-eyed and interested, but wary." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The grouper is a large fish with an enormous mouth. This specimen
+is large but not exceptional. It probably weighs about as much as you." CR>)
+	       (<VERB? FOLLOW>
+		<COND (<AND <IN? ,GROUPER ,OCEAN-FLOOR>
+			    <IN? ,PLAYER ,OCEAN-ROOM>>
+		       <DO-WALK ,P?DOWN>)>)
+	       (<VERB? WAVE-AT GIVE SHOW>
+		<TELL
+"The grouper looks interested but is afraid to come close." CR>)
+	       (<AND <VERB? LISKON>
+		     <NOT <PRE-LISKON>>>
+		<REMOVE ,GROUPER>
+		<DEQUEUE I-GROUPER>
+		<DEQUEUE I-GROUPER-IN-NEST>
+		<TELL
+"The grouper dwindles to the size of a sea bass. Startled and upset,
+it swims rapidly away." CR>)
+	       (<VERB? SNAVIG>
+		<SETG CHANGED? ,GROUPER>
+		<SETG ATE-AS-GROUPER? <>>
+		<QUEUE I-SNAVIG 12>
+		<TELL
+"You change.">
+		<COND (<ROB ,PLAYER ,OCEAN-FLOOR>
+		       <TELL " You can no longer carry anything.">)>
+		<TELL
+" The grouper stares at you with fishy eyes like yours, twiddles
+fins like yours, opens a huge mouth like yours, and flicking a
+tail like yours, swims suspiciously around you." CR>)
+	       (<VERB? ESPNIS>
+		<TELL
+"As groupers rarely if ever sleep, this has no effect." CR>)
+	       (<VERB? YOMIN>
+		<TELL
+"The mind of a grouper is hard to focus on, but you get a vision of ">
+		<COND (<OR <IN? ,BREAD ,GROUPER>
+			   <IN? ,FISH ,GROUPER>>
+		       <TELL
+"curiosity and expectation: is there any more food to be had?">)
+		      (ELSE
+		       <TELL
+"hunger and curiosity. The last time the grouper saw something like
+you, it was interesting.">)>
+		<CRLF>)
+	       (<HOSTILE-VERB?>
+		<TELL
+"The grouper is startled but returns after
+a few moments, its curiosity unsated." CR>)>>
+
+\
+
+"OUBLIETTE PROBLEM - GET OUT ONE OF TWO WAYS!"
+
+<ROOM OUBLIETTE
+      (IN ROOMS)
+      (DESC "Oubliette")
+      (DOWN PER OUBLIETTE-DOWN-EXIT)
+      (UP PER OUBLIETTE-UP-EXIT) ;"PRISON"
+      (ACTION OUBLIETTE-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL TRAP-DOOR WATER)>
+
+<GLOBAL WATER-FLAG 0> ;"how full is oubliette?"
+<GLOBAL FREEZE-FLAG 0> ;"how much ice is there?"
+<GLOBAL FREEZE-COUNT 0> ;"how near death from hypothermia?"
+
+<ROUTINE OUBLIETTE-DOWN-EXIT ()
+	 <COND (,SMALL-FLAG 
+		<COND (,WATER-FLAG
+		       <TELL "The channel is frozen over." CR>
+		       <RFALSE>)
+		      (ELSE ,IN-CHANNEL)>)
+	       (,WATER-FLAG
+		<COND (<IN? ,WINNER ,ICEBERG>
+		       <TELL ,YOU-HAVE-TO " get in the water first" ,PERIOD>)
+		      (ELSE
+		       <HOLD-BREATH>)>
+		<RFALSE>)
+	       (ELSE
+		<TELL "You'd never fit." CR>
+		<RFALSE>)>>
+
+<ROUTINE OUBLIETTE-UP-EXIT ()
+	 <COND (<G? ,WATER-FLAG 3>
+		<COND (<FSET? ,TRAP-DOOR ,OPENBIT>
+		       <COND (<IN? ,PLAYER ,ICEBERG>
+			      <MOVE ,PLAYER ,HERE>
+			      ,PRISON)
+			     (ELSE
+			      <TELL
+"You still can't quite reach the trap door opening. " ,YOU-CANT "get enough
+momentum thrusting upward out of the water." CR>
+			      <RFALSE>)>)
+		      (ELSE
+		       <THIS-IS-IT ,TRAP-DOOR>
+		       <TELL-OPEN-CLOSED ,TRAP-DOOR>
+		       <RFALSE>)>)
+	       (ELSE
+		<COND (<G? ,WATER-FLAG 0>
+		       <TELL
+"The oubliette is only " <GET ,WATER-HEIGHTS ,WATER-FLAG> " full. ">)>
+		<TELL
+CTHE ,TRAP-DOOR " is far over your head. ">
+		<CANT-REACH-IT>
+		<RFALSE>)>>
+
+<ROUTINE OUBLIETTE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is an oubliette. ">
+		<COND (<G? ,WATER-FLAG 0>
+		       <TELL
+"It is " <GET ,WATER-HEIGHTS ,WATER-FLAG> " full of icy water. Sheer walls
+enclose it on all sides. In the ceiling is">)
+		      (ELSE
+		       <TELL
+"Sheer walls rise for twenty feet above you and lean
+inward to">)>
+		<TELL " a narrow opening">
+		<COND (<NOT <FSET? ,TRAP-DOOR ,OPENBIT>>
+		       <TELL " covered with wooden planks">)>
+		<COND (<ZERO? ,WATER-FLAG>
+		       <COND (<ZERO? ,FREEZE-FLAG>
+			      <TELL ". A small but fast-flowing ">)
+			     (<EQUAL? ,FREEZE-FLAG 1>
+			      <TELL ". A partially frozen ">)
+			     (ELSE
+			      <TELL ". A completely frozen ">)>
+		       <TELL
+"channel of water runs along the bottom of the chamber between two pipes">)
+		      (<L? ,WATER-FLAG 4>
+		       <TELL ". The water level is ">
+		       <COND (<QUEUED? I-OUBLIETTE-FILLS>
+			      <TELL "rising">)
+			     (ELSE <TELL "falling">)>)>
+		<TELL ,PERIOD>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? PUT>
+			    <ZERO? ,WATER-FLAG>
+			    <EQUAL? ,PRSI ,WATER>>
+		       <PERFORM ,PRSA ,PRSO ,OUBLIETTE-CHANNEL>
+		       <RTRUE>)
+		      (<AND <G? ,WATER-FLAG 0>
+			    <OR <VERB? DROP THROW>
+				<AND <VERB? PUT>
+				     <EQUAL? ,PRSI ,WATER>>>>
+		       <COND (<IDROP>
+			      <REMOVE ,PRSO>
+			      <TELL "Splash! Dropped." CR>)
+			     (ELSE <RTRUE>)>)
+		      (<AND <G? ,WATER-FLAG 0>
+			    <OR <EQUAL? ,PRSO
+					,INFLOW ,OUTFLOW ,OUBLIETTE-CHANNEL>
+				<EQUAL? ,PRSI
+					,INFLOW ,OUTFLOW ,OUBLIETTE-CHANNEL>>>
+		       <TELL "It's under water!" CR>)
+		      (<AND <VERB? THROUGH BOARD>
+			    <EQUAL? ,PRSO ,WATER>>
+		       <COND (<IN? ,PLAYER ,ICEBERG>
+			      <PERFORM ,V?DISEMBARK ,ICEBERG>)
+			     (<G? ,WATER-FLAG 0>
+			      <TELL ,YOU-ARE ,PERIOD>)
+			     (ELSE
+			      <PERFORM ,PRSA ,OUBLIETTE-CHANNEL>)>
+		       <RTRUE>)
+		      (<AND <VERB? CLIMB-ON>
+			    <EQUAL? ,PRSO ,TRAP-DOOR>>
+		       <DO-WALK ,P?UP>
+		       <RTRUE>)
+		      (<AND <VERB? LEAP>
+			    <EQUAL? ,PRSO ,WATER>
+			    <IN? ,PLAYER ,ICEBERG>>
+		       <PERFORM ,V?DISEMBARK>
+		       <RTRUE>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<G? ,WATER-FLAG 0>
+		       <TELL "You ">
+		       <COND (<EQUAL? ,OHERE ,WATER-ROOM>
+			      <TELL "emerge in">)
+			     (ELSE
+			      <TELL "plunge into the">)>
+		       <TELL
+" freezing water and frantically swim to the surface.">
+		       <SOAK-PLAYER>
+		       <CRLF>
+		       <CRLF>)>
+		<SETG FREEZE-COUNT 0>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<SETG FREEZE-COUNT 0>)
+	       (<EQUAL? .RARG ,M-END>
+		<COND (<AND <G? ,WATER-FLAG 0>
+			    <NOT <IN? ,PLAYER ,ICEBERG>>>
+		       <SOAK-PLAYER T>
+		       <SETG FREEZE-COUNT <+ ,FREEZE-COUNT 1>>
+		       <COND (<EQUAL? ,FREEZE-COUNT 5>
+			      <TELL CR
+"Your body is becoming numb from the cold of the water." CR>)
+			     (<EQUAL? ,FREEZE-COUNT 10>
+			      <HYPOTHERMIA>)>)>)>>
+
+<ROUTINE HYPOTHERMIA ()
+	 <CRLF>
+	 <JIGS-UP
+"The nearly freezing water has overcome you. You die of
+hypothermia.">>
+
+<OBJECT ICEBERG
+	(DESC "ice floe")
+	(SYNONYM ICEFLOE FLOE ICEBERG BERG)
+	(ADJECTIVE ICE SMALL FLAT)
+	(ACTION ICEBERG-F)
+	(FLAGS AN VEHBIT OPENBIT CONTBIT SURFACEBIT)
+	(CAPACITY 200)>
+
+<ROUTINE ICEBERG-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<COND (<OR <VERB? CLIMB-DOWN DISEMBARK>
+			   <AND <VERB? LEAP>
+				<EQUAL? ,PRSO ,WATER>>>
+		       <MOVE ,WINNER ,HERE>
+		       <TELL
+"You reenter the freezing water." CR>)>)
+	       (<NOT .RARG>
+		<COND (<AND <VERB? BOARD SIT CLIMB-FOO CLIMB-ON STAND-ON>
+			    <NOT <IN? ,WINNER ,ICEBERG>>>
+		       <SETG FREEZE-COUNT 0>
+		       <MOVE ,WINNER ,ICEBERG>
+		       <TELL
+"You scramble onto the ice floe." CR>)
+		      (<VERB? RUB>
+		       <TELL "It's cold." CR>)>)>>
+
+<GLOBAL WATER-HEIGHTS
+	<PLTABLE "one-quarter" "half" "three-quarters" "completely">>
+
+<OBJECT INFLOW
+	(IN OUBLIETTE)
+	(DESC "inflow pipe")
+	(SYNONYM PIPE PIPES)
+	(ADJECTIVE INFLOW INPUT)
+	(FLAGS NDESCBIT AN)
+	(ACTION INFLOW-F)>
+
+<ROUTINE TELL-ABOUT-PIPE ()
+	 <TELL
+CTHE ,PRSO " is ceramic, about a foot in diameter, and ">>
+
+<ROUTINE INFLOW-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL-ABOUT-PIPE>
+		<COND (<EQUAL? ,HERE ,OUBLIETTE ,IN-CHANNEL>
+		       <TELL "is here
+to let water into the channel, presumably for drinking and sanitary
+purposes">)
+		      (ELSE
+		       <TELL "water is rushing through it">)>
+		<TELL ,PERIOD>)
+	       (<AND <VERB? THROUGH BOARD>
+		     ,SMALL-FLAG>
+		<TELL
+"The current is too swift." CR>)
+	       (ELSE
+		<FLOW-HACKS>)>>
+
+<ROUTINE FLOW-HACKS ()
+	 <COND (<VERB? THROUGH BOARD>
+		<TELL
+"It's much too small for you to fit." CR>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL
+"It's dark and filled with rushing water, so you can't see much." CR>)
+	       (<VERB? REACH-IN>
+		<TELL
+"The pipe extends as far as you can reach." CR>)
+	       (<AND <VERB? PUT>
+		     <HELD? ,PRSO>>
+		<SWEPT-AWAY ,PRSO>)
+	       (<AND <VERB? PLUG>
+		     <HELD? ,PRSI>>
+		<SWEPT-AWAY ,PRSI>)>>
+
+<OBJECT OUTFLOW
+	(IN OUBLIETTE)
+	(DESC "outflow pipe")
+	(SYNONYM PIPE PIPES)
+	(ADJECTIVE OUTFLOW OUTPUT)
+	(FLAGS NDESCBIT AN VEHBIT)
+	(ACTION OUTFLOW-F)>
+
+<ROUTINE OUTFLOW-F ("AUX" OUB?)
+	 <SET OUB? <EQUAL? ,HERE ,IN-CHANNEL ,OUBLIETTE>>
+	 <COND (<VERB? EXAMINE>
+		<TELL-ABOUT-PIPE>
+		<COND (.OUB?
+		       <TELL
+"permits water in the channel to exit the oubliette">)
+		      (ELSE
+		       <TELL "has water flowing out of it">)>
+		<TELL ,PERIOD>)
+	       (<AND <VERB? THROUGH BOARD>
+		     ,SMALL-FLAG>
+		<COND (<NOT <EQUAL? ,HERE ,OUBLIETTE ,RUINS-ROOM>>
+		       <TELL
+"It's almost inevitable, given the speed of the current." CR CR>)>
+		<GOTO <COND (.OUB? ,IN-PIPE)
+			    (ELSE ,IN-SEWER)>>)
+	       (ELSE <FLOW-HACKS>)>>
+
+<ROOM IN-CHANNEL
+      (IN ROOMS)
+      (DESC "In Channel")
+      (UP TO OUBLIETTE)
+      (WEST TO IN-PIPE)
+      (EAST "The current is too strong." ;IN-PIPE-2)
+      (ACTION IN-CHANNEL-F)
+      (FLAGS RWATERBIT)
+      (GLOBAL WATER WATER-PIPE)>
+
+<ROUTINE IN-CHANNEL-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are in a fast flowing stream of very cold water. " ,LONG-PIPE-DESC-2 CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<FUN-IN-PIPE>)
+	       (<EQUAL? .RARG ,M-END>
+		<SOAK-IF-OPENED>)>>
+
+<ROUTINE SOAK-PLAYER ("OPTIONAL" (END? <>))
+	 <COND (<SOAK-STUFF ,PLAYER>
+		<COND (<NOT .END?> <TELL " ">)>
+		<TELL
+"Some of your possessions have been damaged by the water.">
+		<COND (.END? <CRLF>)>
+		<RTRUE>)>>
+
+<ROUTINE SOAK-IF-OPENED ()
+	 <COND (<AND <VERB? OPEN>
+		     <SOAK-STUFF ,PRSO>>
+		<TELL
+"Oh, no! Something has been damaged as water rushed into ">
+		<THE-PRSO>)>>
+
+<OBJECT WATER-PIPE
+	(IN LOCAL-GLOBALS)
+	(DESC "pipe")
+	(SYNONYM PIPE CHANNEL)
+	(ADJECTIVE CERAMIC INFLOW OUTFLOW)
+	(FLAGS NDESCBIT VEHBIT)
+	(ACTION WATER-PIPE-F)>
+
+<ROUTINE WATER-PIPE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL-ABOUT-PIPE>
+		<TELL "water flows from one end of it to the other.">
+		<COND (<EQUAL? ,HERE ,IN-PIPE-2>
+		       <TELL " A chunk has broken out of the pipe here.">)>
+		<CRLF>)
+	       (<AND <VERB? PUT>
+		     <HELD? ,PRSO>
+		     <EQUAL? ,PRSI ,WATER-PIPE>>
+		<SWEPT-AWAY ,PRSO>)
+	       (<AND <VERB? PLUG>
+		     <HELD? ,PRSI>>
+		<SWEPT-AWAY ,PRSI>)
+	       (<VERB? THROUGH BOARD>
+		<TELL ,YOU-ARE>
+		<TELL ,PERIOD>)
+	       (<VERB? DISEMBARK LEAVE>
+		<COND (<EQUAL? ,HERE ,IN-CHANNEL ,RUINED-PIPE>
+		       <DO-WALK ,P?UP>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "There is no way out here." CR>)>)>>
+
+<ROUTINE SWEPT-AWAY (OBJ)
+	 <REMOVE .OBJ>
+	 <TELL
+"It drops into the water and is swept away by the current." CR>>
+
+<OBJECT OUBLIETTE-CHANNEL
+	(IN OUBLIETTE)
+	(DESC "channel")
+	(SYNONYM CHANNEL)
+	(ADJECTIVE CERAMIC)
+	(FLAGS NDESCBIT VEHBIT OPENBIT)
+	(ACTION CHANNEL-F)>
+
+<ROUTINE CHANNEL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL-ABOUT-PIPE>
+		<COND (<EQUAL? ,PRSO ,OUBLIETTE-CHANNEL>
+		       <TELL "water rushes
+through it from an inflow pipe at one end to an outflow pipe at the
+other">)
+		      (ELSE
+		       <TELL "smashed at the
+top where a huge pillar destroyed the paving above it">)>
+		<TELL ,PERIOD>)
+	       (<VERB? THROUGH BOARD>
+		<COND (,SMALL-FLAG
+		       <GOTO <COND (<EQUAL? ,PRSO ,OUBLIETTE-CHANNEL>
+				    ,IN-CHANNEL)
+				   (ELSE ,RUINED-PIPE)>>)
+		      (ELSE
+		       <TELL
+"Trying to wet your tootsies, eh? Well, you dabble your feet in the water
+for a while, but they get pretty cold, and water splashes on the floor." CR>)>)
+	       (<AND <VERB? PUT> <HELD? ,PRSO>>
+		<SWEPT-AWAY ,PRSO>)
+	       (<AND <VERB? PLUG> <HELD? ,PRSI>>
+		<SWEPT-AWAY ,PRSI>)
+	       (<AND <VERB? CASKLY> <EQUAL? ,PRSO ,RUINS-CHANNEL>>
+		<TELL
+"This channel was made as perfectly as the technology of the times allowed,
+and even as a ruin, its essence is still perfect." CR>)>>
+
+<ROOM IN-PIPE
+      (IN ROOMS)
+      (DESC "In Pipe")
+      (EAST "The current is too strong." ;IN-CHANNEL)
+      (WEST TO IN-PIPE-2)
+      (ACTION IN-PIPE-F)
+      (FLAGS RWATERBIT)
+      (GLOBAL WATER WATER-PIPE)
+      (THINGS <PSEUDO (MOSSY SLIME MOSS-PSEUDO)
+		      (<> MOSS MOSS-PSEUDO)>)>
+
+<ROUTINE MOSS-PSEUDO ()
+	 <COND (<VERB? EXAMINE RUB>
+		<TELL "It's green and slimy." CR>)>>
+
+<ROUTINE IN-PIPE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL ,LONG-PIPE-DESC ,LONG-PIPE-DESC-2 CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<FUN-IN-PIPE>)
+	       (<EQUAL? .RARG ,M-END>
+		<SOAK-IF-OPENED>)>>
+
+<ROOM IN-PIPE-2
+      (IN ROOMS)
+      (DESC "In Pipe")
+      (EAST "The current is too strong." ;IN-PIPE)
+      (WEST TO RUINED-PIPE)
+      (ACTION IN-PIPE-2-F)
+      (FLAGS RWATERBIT)
+      (GLOBAL WATER WATER-PIPE)
+      (THINGS <PSEUDO (MOSSY SLIME MOSS-PSEUDO)
+		      (<> MOSS MOSS-PSEUDO)>)>
+
+<GLOBAL LONG-PIPE-DESC
+"You are inside a small ceramic pipe nearly filled with fast-flowing cold
+water. The walls of the pipe are slippery and overgrown with mossy slime
+wherever an irregularity shields the growth from the force of the water. ">
+
+<GLOBAL LONG-PIPE-DESC-2
+"Going east (against the current) would be nearly impossible. Going west
+is almost unavoidable.">
+
+<ROUTINE IN-PIPE-2-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL ,LONG-PIPE-DESC
+"On the north side of the pipe is such an irregularity: a large chunk has
+been knocked out of the pipe, and the slime and moss grows abundantly. ">
+		<COND (<IN? ,CHANGE-CUBE ,CHUNK>
+		       <TELL
+"Inside, covered with moss and slime, is something large, white, and
+apparently cubical. ">)>
+		<TELL ,LONG-PIPE-DESC-2 CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<FUN-IN-PIPE>)
+	       (<EQUAL? .RARG ,M-END>
+		<SOAK-IF-OPENED>)>>
+
+<OBJECT CHUNK
+	(IN IN-PIPE-2)
+	(DESC "crack")
+	(SYNONYM CRACK CHUNK)
+	(ADJECTIVE MOSSY SLIMY)
+	(FLAGS NDESCBIT OPENBIT CONTBIT TRANSBIT SEARCHBIT)
+	(ACTION CHUNK-F)>
+
+<ROUTINE CHUNK-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"A weak spot in the pipe has broken away here, making a smallish crack that
+has filled with slime and moss.">
+		<COND (<IN? ,CHANGE-CUBE ,CHUNK>
+		       <TELL
+" There is a large white object partially obscured by the growth. It
+is held in the crack by the force of the current.">)>
+		<CRLF>)
+	       (<VERB? REACH-IN RUB>
+		<TELL "You reach into the crack and touch ">
+		<COND (<IN? ,CHANGE-CUBE ,CHUNK>
+		       <TELL
+"the cube. Don't you want to take it, too?">)
+		      (ELSE <TELL "moss.">)>
+		<CRLF>)
+	       (<VERB? THROUGH BOARD>
+		<TELL
+"It's too small to enter. It's large enough to reach into, though." CR>)
+	       (<AND <VERB? PUT> <EQUAL? ,PRSI ,CHUNK>>
+		<COND (<FIRST? ,PRSI>
+		       <TELL ,NO-ROOM CR>)
+		      (<GETPT ,PRSO ,P?NAME>
+		       <REMOVE ,PRSO>
+		       <TELL
+"You put " THE ,PRSO " in the crack, but the moss won't hold it in any
+longer, and the current carries it away before you can retrieve it." CR>)>)>>	
+
+<ROOM RUINED-PIPE
+      (IN ROOMS)
+      (DESC "Ruined Pipe")
+      (EAST "The current is too strong." ;IN-PIPE-2)
+      (WEST TO IN-SEWER)
+      (UP TO RUINS-ROOM)
+      (OUT TO RUINS-ROOM)
+      (ACTION RUINED-PIPE-F)
+      (FLAGS RWATERBIT)
+      (GLOBAL WATER WATER-PIPE)>
+
+<ROUTINE RUINED-PIPE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"The pipe here is smashed from the top where a huge pillar has toppled
+over onto it. Cyclopean ruins are all around you. The cracks and fissures
+in the pipe might make it possible to climb out here. The water is fast
+and loud around you." CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<FUN-IN-PIPE>)
+	       (<EQUAL? .RARG ,M-END>
+		<SOAK-IF-OPENED>)>>
+
+<ROUTINE FUN-IN-PIPE ()
+	 <QUEUE I-DOWNSTREAM 3>
+	 <COND (<EQUAL? ,OHERE ,OUBLIETTE ,RUINS-ROOM>
+		<TELL "You enter the cold, fast-flowing water.">
+		<SOAK-PLAYER>
+		<CRLF>
+		<CRLF>)>>
+
+<ROOM IN-SEWER
+      (IN ROOMS)
+      (DESC "In Pipe")
+      (EAST "The current is too strong." ;RUINED-PIPE)
+      (ACTION IN-SEWER-F)
+      (FLAGS RWATERBIT)
+      (GLOBAL WATER WATER-PIPE)>
+
+<ROUTINE IN-SEWER-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<JIGS-UP
+"The water swirls down the pipe, its angle of descent increasing until
+it tumbles over a precipice. You are buffeted back and forth, flipping
+over, headfirst one second, feetfirst the next. At last, dizzy and
+confused, you are dashed against the rocks at the bottom of the cistern.">)>>
+
+<ROOM PRISON
+      (IN ROOMS)
+      (DESC "Dungeon")
+      (DOWN PER PRISON-DOWN-EXIT ;OUBLIETTE)
+      (UP TO GUARD-TOWER)
+      (EAST TO CELL-HALL-EAST)
+      (ACTION PRISON-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL TRAP-DOOR STAIRS EAST-WALL)
+      (THINGS <PSEUDO (<> SLIME MOSS-PSEUDO)
+		      (<> MOSS MOSS-PSEUDO)
+		      (<> FUNGUS MOSS-PSEUDO)>)>
+
+<ROUTINE PRISON-DOWN-EXIT ()
+	 <COND (<FSET? ,TRAP-DOOR ,OPENBIT>
+		<COND (,WATER-FLAG ,OUBLIETTE)
+		      (ELSE
+		       <JIGS-UP
+"You fall to your death on the stones below.">
+		       <RFALSE>)>)
+	       (ELSE
+		<TELL-OPEN-CLOSED ,TRAP-DOOR>
+		<RFALSE>)>>
+
+<ROUTINE PRISON-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a dark, dank, forgotten dungeon. It is overgrown with moss, fungus,
+and slime. The floor is slippery. At your feet ">
+		<COND (<FSET? ,TRAP-DOOR ,OPENBIT>
+		       <TELL "an open trap door leads down into blackness.">)
+		      (ELSE
+		       <TELL "is a closed trap door.">)>
+		<TELL
+" A corridor leads east and stairs lead up." CR>)>>
+
+<OBJECT TRAP-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "trap door")
+	(SYNONYM DOOR OPENING)
+	(ADJECTIVE TRAP OAK NARROW)
+	(FLAGS DOORBIT)
+	(ACTION TRAP-DOOR-F)>
+
+<ROUTINE TRAP-DOOR-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a sturdy oak trap door, but it is obviously rarely used, as it
+is covered with mold, cobwebs, and dirt. ">
+		<TELL-OPEN-CLOSED ,TRAP-DOOR>)
+	       (<VERB? OPEN CLOSE>
+		<COND (<NOT <EQUAL? ,HERE ,OUBLIETTE>> <RFALSE>)
+		      (<OR <L? ,WATER-FLAG 4>
+			   <NOT <IN? ,PLAYER ,ICEBERG>>>
+		       <CANT-REACH-IT>)
+		      (ELSE
+		       <OPEN-CLOSE>)>)
+	       (<AND <VERB? REZROV> <NOT <FSET? ,TRAP-DOOR ,OPENBIT>>>
+		<FSET ,TRAP-DOOR ,OPENBIT>
+		<TELL
+"The trap door creaks open upon rusty hinges." CR>)
+	       (<VERB? THROUGH BOARD>
+		<DO-WALK <COND (<EQUAL? ,HERE ,PRISON>
+				,P?DOWN)
+			       (ELSE ,P?UP)>>)>>
+
+<ROOM CELL-HALL-EAST
+      (IN ROOMS)
+      (DESC "Dungeon East End")
+      (LDESC
+"The hall ends at a blank wall, but a cell lies to the north. There
+is no door on the cell.")
+      (WEST TO PRISON)
+      (NORTH TO CELL-EAST)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (<> CELL CELL-PSEUDO)>)>
+
+<ROOM CELL-EAST
+      (IN ROOMS)
+      (DESC "Dungeon Cell")
+      (LDESC
+"This was once a very luxurious cell, obviously for the imprisonment of a
+highborn or powerful person. Its rich hangings are now rotten rags; its
+furniture is smashed to kindling, except for one massive oak cabinet.
+The cell door has been blown away by an explosion, or perhaps a \"rezrov\"
+spell.")
+      (SOUTH TO CELL-HALL-EAST)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (<> CELL CELL-PSEUDO)
+		      (ROTTEN RAGS PLURAL-PSEUDO)
+		      (RICH HANGINGS PLURAL-PSEUDO)>)>
+
+<OBJECT CABINET
+	(IN CELL-EAST)
+	(DESC "massive cabinet")
+	(SYNONYM CABINET BUREAU)
+	(ADJECTIVE MASSIVE LARGE HUGE OAK)
+	(FLAGS NDESCBIT CONTBIT VEHBIT LOCKED)
+	(CAPACITY 20)
+	(ACTION CABINET-F)>
+
+<OBJECT PAST-CABINET
+	(IN PAST-CELL-EAST)
+	(DESC "massive cabinet")
+	(SYNONYM CABINET BUREAU)
+	(ADJECTIVE MASSIVE LARGE HUGE OAK)
+	(FLAGS NDESCBIT CONTBIT VEHBIT LOCKED)
+	(CAPACITY 20)
+	(ACTION CABINET-F)>
+
+<ROUTINE CABINET-F ("OPTIONAL" (RARG <>) "AUX" L)
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<SET L <LOC ,WINNER>>
+		<COND (<AND <VERB? LOOK>
+			    <NOT <FSET? .L ,OPENBIT>>>
+		       <TELL-OPEN-CLOSED .L>)
+		      (<VERB? WALK>
+		       <TELL
+,YOU-HAVE-TO " get out of the " 'CABINET " first" ,PERIOD>)
+		      (<AND <VERB? DISEMBARK>
+			    <NOT <FSET? .L ,OPENBIT>>>
+		       <TELL-OPEN-CLOSED .L>)
+		      (<AND <VERB? OPEN>
+			    <NOT <FSET? ,PRSO ,OPENBIT>>>
+		       <FSET ,PRSO ,OPENBIT>
+		       <TELL "Opened." CR>)>)
+	       (<NOT .RARG>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"This massive cabinet fills most of one wall. It's made of oak and looks ">
+		       <COND (<EQUAL? ,HERE ,CELL-EAST>
+			      <TELL
+"better preserved than anything else in the room. Its lock is corroded and
+unusable. ">)
+			     (ELSE
+			      <TELL
+"quite sturdy. It has a strong lock. ">)>
+		       <TELL-OPEN-CLOSED ,PRSO>)
+		      (<VERB? BOARD>
+		       <COND (<NOT <FSET? ,PRSO ,OPENBIT>>
+			      <TELL-OPEN-CLOSED ,PRSO>)
+			     (<NOT ,SHRINK-FLAG>
+			      <TELL
+"You're too big. It isn't very deep." CR>)>)
+		      (<VERB? HIDE>
+		       <TELL ,NO-ROOM CR>)
+		      (<AND <VERB? OPEN>
+			    <FSET? ,PRSO ,LOCKED>>
+		       <TELL
+"The cabinet is locked." CR>)
+		      (<AND <VERB? LOCK UNLOCK>
+			    <EQUAL? ,HERE ,CELL-EAST>>
+		       <TELL
+"The lock has corroded into a mass of rust." CR>)
+		      (<AND <VERB? UNLOCK>
+			    <EQUAL? ,PRSI ,KEY>>
+		       <COND (,FAKE-KEY
+			      <TELL
+"As you insert the key into the lock, it disappears, and a vision of Belboz
+materializes before you!" CR>
+			      <FORLORN-ENCYSTMENT>)
+			     (ELSE
+			      <FCLEAR ,PRSO ,LOCKED>
+			      <TELL "Unlocked." CR>)>)
+		      (<AND <VERB? LOCK>
+			    <EQUAL? ,PRSI ,KEY>>
+		       <COND (<FSET? ,PRSO ,RMUNGBIT>
+			      <TELL "The lock has been burst." CR>)
+			     (<NOT <FSET? ,PRSO ,LOCKED>>
+			      <FCLEAR ,CABINET ,OPENBIT>
+			      <FSET ,PRSO ,LOCKED>
+			      <TELL "Locked." CR>)
+			     (ELSE
+			      <TELL "It already is." CR>)>)
+		      (<AND <VERB? REZROV>
+			    <NOT <FSET? ,PRSO ,OPENBIT>>>
+		       <FSET ,PRSO ,RMUNGBIT>
+		       <FCLEAR ,PRSO ,LOCKED>
+		       <FSET ,PRSO ,OPENBIT>
+		       <TELL
+"The cabinet bursts open">
+		       <COND (<AND <NOT <IN? ,PLAYER ,CABINET>>
+				   <FIRST? ,PRSO>>
+			      <TELL ", revealing ">
+			      <PRINT-CONTENTS ,PRSO>)>
+		       <TELL "!" CR>)>)>>
+
+<OBJECT KEY
+	(IN BELBOZ)
+	(DESC "wrought iron key")
+	(SYNONYM KEY)
+	(ADJECTIVE WROUGHT IRON)
+	(SIZE 1)
+	(FLAGS TAKEBIT TOOLBIT NDESCBIT)>
+
+<OBJECT DEAD-BOOK
+	(IN CABINET)
+	(DESC "moldy book")
+	(SYNONYM BOOK)
+	(ADJECTIVE ROTTEN MOLDY OLD)
+	(FLAGS TAKEBIT READBIT SCROLLBIT CONTBIT OPENBIT
+	       SEARCHBIT RMUNGBIT MAGICBIT)
+	(ACTION DEAD-BOOK-F)>
+
+<ROUTINE DEAD-BOOK-F ("AUX" SPELL)
+	 <COND (<VERB? EXAMINE READ OPEN>
+		<TELL
+"This book has been almost completely destroyed by mold and rot. You
+can tell only that it was once a " 'SPELL-BOOK ".">
+		<COND (<FSET? ,PRSO ,RMUNGBIT>
+		       <TELL " None of the spells are
+legible any longer.">)
+		      (<IN? ,SNAVIG-SPELL ,DEAD-BOOK>
+		       <TELL " Only one spell is still readable. It says
+\"" 'SNAVIG-SPELL ": " <GETP ,SNAVIG-SPELL ,P?TEXT> ".\"">)>
+		<CRLF>)
+	       (<VERB? CASKLY>
+		<COND (<FSET? ,DEAD-BOOK ,RMUNGBIT>
+		       <TELL
+"The book glows brightly for a moment. ">
+		       <COND (<FSET? ,HERE ,RWATERBIT>
+			      <TELL "The water quenches it immediately">)
+			     (ELSE
+			      <FCLEAR ,DEAD-BOOK ,RMUNGBIT>
+			      <MOVE ,SNAVIG-SPELL ,DEAD-BOOK>
+			      <SETG SCORE <+ ,SCORE ,DEAD-BOOK-SCORE>>
+			      <SETG DEAD-BOOK-SCORE 0>
+			      <TELL "The mold and rot retreat
+as you watch. While not good as new, the book looks much better">)>
+		       <TELL ,PERIOD>)>)
+	       (<VERB? GNUSTO>
+		<COND (<NOT <IN? ,PRSO ,WINNER>>
+		       <TELL
+"You must be holding the book to copy from it!" CR>)
+		      (<SET SPELL <FIRST? ,PRSO>>
+		       <PERFORM ,V?GNUSTO .SPELL>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "There's no spell in ">
+		       <THE-PRSO>)>)>>
+
+<GLOBAL DEAD-BOOK-SCORE 15>
+
+<ROUTINE CELL-PSEUDO ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL ,IT-LOOKS-LIKE "a prison cell." CR>)
+	       (<VERB? THROUGH>
+		<DO-WALK ,P?NORTH>)
+	       (<VERB? EXIT>
+		<DO-WALK ,P?SOUTH>)>>
+
+<ROOM GUARD-TOWER
+      (IN ROOMS)
+      (DESC "Guard Tower")
+      (DOWN TO PRISON)
+      (UP "You'll need to flap your wings harder than that.")
+      (ACTION GUARD-TOWER-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (THINGS
+       <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)
+	       (GUARD TOWER RANDOM-PSEUDO)
+	       (DISTANT VOLCANO MOUNTAIN-PSEUDO)
+	       (<> TARN RANDOM-PSEUDO)
+	       (<> TARNS PLURAL-PSEUDO)
+	       (TWISTED TREE RANDOM-PSEUDO)
+	       (LOW TREES PLURAL-PSEUDO)>)>
+
+<ROUTINE GUARD-TOWER-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the guard tower of a crumbling castle. It overlooks a
+mountainous landscape of tarns, tumbled rock, and twisted low trees. The
+vegetation is in browns, blacks, and ochres. The only real color is
+provided by a distant volcano which lights the lowering clouds with
+bright red and yellow coruscations. The only exit is down." CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<SETG SEEN-TOWER? T>
+		<MOVE ,ROC ,HERE>
+		<SETG ROC-COUNT 0>
+		<QUEUE I-ROC -1>)>>
+
+<GLOBAL SEEN-TOWER? <>>
+
+<ROUTINE ROC-GRABS-PLAYER ("OPTIONAL" (FALL? <>))
+	 <MOVE ,ROC ,HERE>
+	 <MOVE ,PLAYER ,ROC>
+	 <SETG ROC-FLY-COUNT 0>
+	 <SETG FALLING? <>>
+	 <DEQUEUE I-FALLING>
+	 <QUEUE I-ROC-FLY -1>
+	 <CRLF>
+	 <COND (.FALL?
+		<TELL
+"Suddenly, from above, you are hit by a crashing blow! You twist and see that
+a huge bird has taken you in its talons. The">)
+	       (ELSE
+		<TELL
+"The bird dives for you, its talons outstretched. As it nears, you
+realize that rather than vulture or even condor size, the">)>
+	 <TELL " bird is nearly
+the size of an elephant. It closes its huge claws gently around
+you, squawks (nearly suffocating you with its fetid breath), and takes
+off towards the west." CR>>
+
+<OBJECT ROC
+	(DESC "roc")
+	(SYNONYM ROC BIRD DOT TALONS)
+	(ADJECTIVE HUGE LARGE TINY BLACK)
+	(FLAGS THE PERSON VEHBIT CONTBIT OPENBIT)
+	(DESCFCN ROC-DESC)
+	(ACTION ROC-F)>
+
+<ROUTINE DESCRIBE-ROC ()
+	 <TELL <GET ,ROC-DESCS <- ,ROC-COUNT 1>> CR>>
+
+<ROUTINE ROC-DESC (RARG OBJ)
+	 <COND (<EQUAL? ,HERE ,GUARD-TOWER> <RTRUE>)
+	       (<EQUAL? ,HERE ,ROC-NEST>
+		<TELL
+"The roc perches on the side of the nest, watching you intently." CR>)>>
+
+<ROUTINE ROC-GRIPS-YOU-FIRMLY ("OPTIONAL" (SPELL? <>))
+	 <TELL
+"The roc grips you firmly in its talons. Your ">
+	 <COND (.SPELL? <TELL "attempts to cast a spell">)
+	       (ELSE <TELL "struggles">)>
+	 <TELL " just make it hold you tighter." CR>>
+
+<ROUTINE ROC-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? ,WINNER ,ROC>
+		<TELL
+"The roc is intent upon its ">
+		<COND (<EQUAL? ,HERE ,ROC-NEST>
+		       <COND (<IN? ,BABY-ROC ,HERE> 
+			      <TELL "chick">)
+			     (ELSE <TELL "egg">)>)
+		      (ELSE <TELL "mission">)>
+		<TELL ,PERIOD>
+		<END-QUOTE>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? DROP> <DROP-IN-AIR>)
+		      (<VERB? BOARD>
+		       <COND (<EQUAL? ,PRSO ,ROC>
+			      <TELL "It would rather carry you." CR>)
+			     (ELSE
+			      <ROC-GRIPS-YOU-FIRMLY>)>)
+		      (<SPELL-VERB?>
+		       <ROC-GRIPS-YOU-FIRMLY T>)
+		      (<VERB? WALK LEAP DISEMBARK CLIMB-DOWN SIT>
+		       <ROC-GRIPS-YOU-FIRMLY>)>)
+	       (<NOT .RARG>
+		<COND (<AND <HOSTILE-VERB?>
+			    <IN? ,PLAYER ,ROC>>
+		       <TELL
+"The roc twists its ugly head around, squawks at you warningly, and
+continues flying." CR>)
+		      (<VERB? EXAMINE>
+		       <COND (<IN? ,PLAYER ,ROC>
+			      <TELL
+"The roc is a female of enormous size. It resembles a huge raptor, such
+as an eagle or perhaps a falcon, but the size of a house. It doesn't
+smell very good and is infested with fleas." CR>)
+			     (<AND <EQUAL? ,HERE ,GUARD-TOWER>
+				   <G? ,ROC-COUNT 0>>
+			      <TELL ,IT-LOOKS-LIKE "a ">
+			      <DESCRIBE-ROC>)
+			     (ELSE
+			      <TELL
+"The roc is a huge raptor and resembles an eagle." CR>)>)
+		      (<AND <EQUAL? ,HERE ,GUARD-TOWER>
+			    <L? ,ROC-COUNT 4>>
+		       <TELL ,TOO-FAR>)
+		      (<VERB? GIVE>
+		       <COND (<EQUAL? ,PRSO ,FISH>
+			      <GOBBLES-IT>)
+			     (ELSE
+			      <UNINTERESTED ,ROC>)>)
+		      (<VERB? SMELL>
+		       <TELL
+"The roc smells like old, rotting meat. As it's a scavenger,
+this is to be expected." CR>)
+		      (<VERB? BOARD SIT CLIMB-UP CLIMB-FOO>
+		       <COND (<NOT <IN? ,PLAYER ,ROC>>
+			      <TELL
+"The roc isn't interested in carrying you any more." CR>)>)
+		      (<VERB? YOMIN>
+		       <TELL
+"You sense a strong maternal urge." CR>)
+		      (<VERB? ESPNIS SNAVIG LISKON GIRGOL>
+		       <ROC-SQUAWKS>)>)>>
+
+<ROUTINE GOBBLES-IT ()
+	 <REMOVE ,PRSO>
+	 <TELL
+CTHE ,PRSI " gobbles it down." CR>>
+
+<ROOM ROC-NEST
+      (IN ROOMS)
+      (DESC "In Roc Nest")
+      (ACTION ROC-NEST-F)
+      (OUT "The nest is perched on a pinnacle of rock. It's a long way down.")
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (THINGS
+       <PSEUDO (<> MOUNTAIN MOUNTAIN-PSEUDO)
+	       (ROC NEST NEST-PSEUDO)
+	       (TREE TRUNK RANDOM-PSEUDO)
+	       (SMALL BUSH RANDOM-PSEUDO)
+	       (BLACK FEATHER RANDOM-PSEUDO)
+	       (ROC GUANO RANDOM-PSEUDO)>)>
+
+<ROUTINE NEST-PSEUDO ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<OR <NOT <EQUAL? ,HERE ,MIDAIR ,ROC-NEST>>
+			   <NOT <ZERO? ,NS-COUNT>>
+			   <NOT <ZERO? ,EW-COUNT>>>
+		       <TELL
+,YOU-CANT-SEE "a nest here." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL ,IT-LOOKS-LIKE "a ">
+		       <COND (<EQUAL? ,HERE ,ROC-NEST>
+			      <TELL "huge mass of trees woven together.">)
+			     (ELSE
+			      <TELL "giant bird's nest.">
+			      <COND (<FIRST? ,ROC-NEST>
+				     <TELL
+" There are some things in the nest.">)>)>
+		       <CRLF>)>)
+	       (<VERB? DROP DISEMBARK LEAVE>
+		<DO-WALK <COND (<IN? ,PLAYER ,MAGIC-CARPET> ,P?UP)
+			       (ELSE ,P?OUT)>>)>>
+
+<ROUTINE ROC-NEST-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This nest is made from skillfully woven tree trunks, small bushes, and
+large amounts of mud and roc guano for glue. Giant black feathers are
+everywhere. In the center of the nest ">
+		<COND (<FSET? ,EGG ,RMUNGBIT>
+		       <TELL
+"is a hungry baby roc and the fragments of a hatched egg">)
+		      (ELSE
+		       <TELL "is an egg the size of a small wagon">)>
+		<COND (<AND <NOT <FSET? ,CONNECTIVITY-CUBE ,TOUCHBIT>>
+			    <NOT <FSET? ,EGG ,RMUNGBIT>>>
+		       <TELL
+". Nestled beneath the egg is a " ,WHITE-CUBE>)>
+		<TELL ,PERIOD>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? LEAP>
+			    <EQUAL? ,PRSO <> ,ROOMS>>
+		       <DO-WALK ,P?OUT>)
+		      (<VERB? LOOK-DOWN>
+		       <TELL
+"It's a long, unclimbable way down." CR>)
+		      (<AND <VERB? TAKE>
+			    <EQUAL? ,PRSO ,CONNECTIVITY-CUBE>
+			    <NOT <FSET? ,EGG ,RMUNGBIT>>
+			    <IN? ,ROC ,HERE>
+			    <NOT <EQUAL? ,TIME-STOPPED? ,HERE>>>
+		       <TELL
+"The roc, convinced you are threatening its precious egg, drives you away
+before you can snatch the cube." CR>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<AND <NOT <IN? ,ROC ,HERE>>
+			    <NOT <FSET? ,EGG ,RMUNGBIT>>
+			    <NOT <QUEUED? I-ROC-HATCHES>>>
+		       <QUEUE I-ROC-HATCHES 5>)
+		      (<IN? ,BABY-ROC ,HERE>
+		       <JIGS-UP
+"You arrive in the roc's nest. The baby roc,
+ravenous like all young birds, gobbles you down.">)>)>>
+
+<OBJECT EGG
+	(IN ROC-NEST)
+	(DESC "roc egg")
+	(SYNONYM EGG)
+	(ADJECTIVE ROC)
+	(FLAGS NDESCBIT)
+	(ACTION EGG-F)>
+
+<ROUTINE EGG-F ("AUX" (MOM? <>))
+	 <COND (<FSET? ,EGG ,RMUNGBIT>
+		<TELL "There isn't much of the egg left to deal with." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+,IT-LOOKS-LIKE "it's going to hatch soon." CR>)
+	       (<VERB? LOOK-UNDER>
+		<TELL
+"There's dirt, guano, detritus, and ">
+		<COND (<FSET? ,CONNECTIVITY-CUBE ,TOUCHBIT>
+		       <TELL "feathers">)
+		      (ELSE
+		       <TELL "a " 'CONNECTIVITY-CUBE>)>
+		<TELL " there." CR>)
+	       (<OR <HOSTILE-VERB?> <VERB? OPEN>>
+		<COND (<IMMOBILIZED?> <RTRUE>)
+		      (<IN? ,ROC ,HERE>
+		       <TELL
+"The mother roc prevents you." CR>)
+		      (ELSE
+		       <DEQUEUE I-ROC-HATCHES>
+		       <I-ROC-HATCHES T>)>)
+	       (<VERB? ESPNIS SNAVIG LISKON GIRGOL>
+		<ROC-SQUAWKS>)>>
+
+<ROUTINE ROC-SQUAWKS ("AUX" (MOM? <>))
+	 <COND (<IN? ,ROC ,HERE> <SET MOM? T>)>
+	 <COND (<OR .MOM? <IN? ,BABY-ROC ,HERE>>
+		<TELL
+"The ">
+		<COND (.MOM? <TELL "mother">)
+		      (ELSE <TELL "baby">)>
+		<TELL
+" roc hears you preparing the spell and squawks at you so
+raucously that your concentration is destroyed, and the spell misfires." CR>)>>
+
+<OBJECT BABY-ROC
+	(DESC "roc chick")
+	(SYNONYM CHICK ROC)
+	(ADJECTIVE ROC SMALL BABY)
+	(FLAGS PERSON THE NDESCBIT)
+	(ACTION BABY-ROC-F)>
+
+<ROUTINE BABY-ROC-F ("AUX" (MOM? <>))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The roc chick is much larger than you, nearly featherless, and very
+hungry." CR>)
+	       (<VERB? TAKE>
+		<TELL "It's only about three times your size." CR>)
+	       (<AND <VERB? GIVE>
+		     <HELD? ,PRSO>>
+		<GOBBLES-IT>)
+	       (<HOSTILE-VERB?>
+		<TELL
+"The baby roc defends itself quite successfully." CR>)
+	       (<VERB? YOMIN>
+		<TELL "You sense ravenous hunger." CR>)
+	       (<VERB? ESPNIS SNAVIG LISKON GIRGOL>
+		<ROC-SQUAWKS>)>>
diff --git a/c3.zil b/c3.zil
new file mode 100644
index 0000000..a71f2a7
--- /dev/null
+++ b/c3.zil
@@ -0,0 +1,2284 @@
+"C3 for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+"AIR"
+
+<OBJECT AIR-CUBE
+	(IN MOUTH)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE CQ ;C3 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "eagles")
+	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE AIR-ROOM)>
+
+<ROOM AIR-ROOM
+      (IN ROOMS)
+      (DESC "Air Room")
+      (CUBE AIR-CUBE)
+      (NORTH TO GLACIER-ROOM)
+      (WEST TO BAZAAR)
+      (SOUTH PER MIDAIR-EXIT) ;"EITHER WARNING OR MIDAIR"
+      (DOWN PER MAGIC-BOX-EXIT)
+      (ACTION AIR-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GLOBAL-HOLE)
+      (THINGS <PSEUDO (FLUFFY CLOUD CLOUD-PSEUDO)
+		      (FLUFFY CLOUDS CLOUD-PSEUDO)>)>
+
+<ROUTINE MIDAIR-EXIT ()
+	 <COND (<OR ,FALL-WARNING? <IN? ,PLAYER ,MAGIC-CARPET>>
+		,MIDAIR)
+	       (ELSE
+		<SETG FALL-WARNING? T>
+		<TELL
+"You pull back at the edge, noticing just in time that the hole in the
+floor opens into thin air which goes a long way down before anything
+solid is reached." CR>
+		<RFALSE>)>>
+
+<GLOBAL FALL-WARNING? <>>
+
+<ROUTINE AIR-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are on a large fluffy white cloud. In fact, you are
+surrounded by clouds. They blow past, wind seeming to boil them around
+you from all sides. There is a bit of clear air to the north, momentary
+gaps in the clouds to the south and west, and an alarming one below
+you." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM GLACIER-ROOM
+      (IN ROOMS)
+      (DESC "Glacier")
+      (ACTION GLACIER-ROOM-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (THINGS
+       <PSEUDO (TRACKLESS GLACIER GLACIER-PSEUDO)
+	       (<> ICE GLACIER-PSEUDO)
+	       (<> SNOW GLACIER-PSEUDO)
+	       (<> CREVASSE GLACIER-PSEUDO)
+	       (FLATHEAD MOUNTAIN MOUNTAIN-PSEUDO)>)>
+
+<ROUTINE GLACIER-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are in the midst of a trackless glacier in the Flathead Mountains.
+Snow blows around you, the wind complaining of its own discomfort. This
+is a desolate and dangerous place, for there are crevasses everywhere
+under the deceptive blanket of snow." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? WALK>
+		       <COND (<PROB 75>
+			      <JIGS-UP
+"You have just walked into a crevasse.">)
+			     (ELSE
+			      <GOTO ,GLACIER-ROOM>)>)>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<SETG FREEZE-COUNT 0>)
+	       (<EQUAL? .RARG ,M-END>
+		<SETG FREEZE-COUNT <+ ,FREEZE-COUNT 1>>
+		<COND (<EQUAL? ,FREEZE-COUNT 5>
+		       <TELL CR
+"Your body is becoming numb from the cold." CR>)
+		      (<EQUAL? ,FREEZE-COUNT 10>
+		       <CRLF>
+		       <JIGS-UP
+"The freezing weather has overcome you. You die of hypothermia.">)>)>>
+
+<ROUTINE GLACIER-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The ice glints so brightly that you are almost blinded." CR>)
+	       (<VERB? TINSOT>
+		<TELL
+"Coals to Newcastle, if you ask me." CR>)>>
+
+<ROOM EMPORIUM
+      (IN ROOMS)
+      (DESC "Emporium")
+      (ACTION EMPORIUM-F)
+      (WEST TO BAZAAR IF EMPORIUM-DOOR IS OPEN)
+      (OUT TO BAZAAR IF EMPORIUM-DOOR IS OPEN)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL EMPORIUM-DOOR)
+      (THINGS
+       <PSEUDO (<> SIGN SIGN-PSEUDO)
+	       (<> SIGNS SIGN-PSEUDO)
+	       (<> PILE CARPET-PSEUDO)
+	       (<> CARPET CARPET-PSEUDO)
+	       (WOVEN RUGS CARPET-PSEUDO)
+	       (ORNATE RUGS CARPET-PSEUDO)>)>
+
+<ROUTINE CARPET-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"They are beautiful examples of the weaver's art." CR>)
+	       (<VERB? TAKE>
+		<TELL
+"You might be accused of thievery." CR>)
+	       (<VERB? BUY>
+		<TELL ,MORE-SPECIFIC ,PERIOD>)>>
+
+<ROUTINE SIGN-PSEUDO ()
+	 <COND (<VERB? READ EXAMINE>
+		<TELL
+"The sign might as well be Greek." CR>)>>
+
+<ROUTINE EMPORIUM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the middle of a huge emporium. Signs in a language unknown to you
+grace the displays. Most of the objects displayed are ornately woven rugs.
+There is an exit into the street to the west."
+CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<QUEUE I-KICKED-OUT 50>
+		<QUEUE I-MERCHANT -1>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<COND (<OR <HELD? ,MAGIC-CARPET>
+			   <HELD? ,RANDOM-CARPET>>
+		       <FSET ,EMPORIUM-DOOR ,LOCKED>
+		       <FCLEAR ,EMPORIUM-DOOR ,OPENBIT>)>
+		<DEQUEUE I-MERCHANT>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? NO YES>
+		       <TELL
+"\"Words are trifles! Let me see your zorkmids!\" chides the merchant." CR>)
+		      (<SPELL-VERB?>
+		       <TELL
+"The spell trickles away to nothing. The merchant smiles. \"Do you think
+you are the first magician to try to use lawless, thieving magic on a
+humble merchant?\"">
+		       <KICKED-OUT>
+		       <RTRUE>)>)>>
+
+<OBJECT EMPORIUM-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "shop door")
+	(SYNONYM DOOR)
+	(ADJECTIVE SHOP)
+	(ACTION EMPORIUM-DOOR-F)
+	(FLAGS DOORBIT OPENBIT)>
+
+<ROUTINE EMPORIUM-DOOR-F ()
+	 <COND (<AND <VERB? OPEN KNOCK REZROV THROUGH>
+		     <FSET? ,EMPORIUM-DOOR ,LOCKED>>
+		<MERCHANT-AT-DOOR>)
+	       (<VERB? THROUGH>
+		<DO-WALK <COND (<EQUAL? ,HERE ,BAZAAR> ,P?EAST)
+			       (ELSE ,P?WEST)>>)>>
+
+<ROUTINE MERCHANT-AT-DOOR ()
+	 <TELL
+,DOOR-LOCKED ", apparently by powerful magic. When you attempt
+entry, the merchant opens a small panel in the door and recognizes you.
+\"We're closed for lunch!\" He slams the panel shut." CR>>
+
+<ROUTINE EMPORIUM-EXIT ()
+	 <COND (<FSET? ,EMPORIUM-DOOR ,LOCKED>
+		<THIS-IS-IT ,EMPORIUM-DOOR>
+		<MERCHANT-AT-DOOR>
+		<RFALSE>)
+	       (<FSET? ,EMPORIUM-DOOR ,OPENBIT>
+	        ,EMPORIUM)
+	       (ELSE
+		<TELL-OPEN-CLOSED ,EMPORIUM-DOOR>
+		<RFALSE>)>>
+
+
+<OBJECT ZORKMID
+	(IN MOUNTAIN-TOP)
+	(DESC "gold coin")
+	(SYNONYM ZORKMID ZM MONEY COIN)
+	(ADJECTIVE GOLD INTNUM PRICE)
+	(ACTION ZORKMID-F)
+	(FLAGS TAKEBIT TRYTAKEBIT)>
+
+<ROUTINE ZORKMID-F ()
+	 <COND (<VERB? EXAMINE READ>
+		<TELL
+"This is a gold 500 zorkmid piece." CR>)>>
+
+<OBJECT MERCHANT
+	(IN EMPORIUM)
+	(DESC "merchant")
+	(SYNONYM MERCHANT SALESMAN MAN)
+	(ADJECTIVE YOUNG EARNEST)
+	(FLAGS THE PERSON OPENBIT CONTBIT TRANSBIT)
+	(CONTFCN MERCHANT-F)
+	(DESCFCN MERCHANT-DESC)
+	(ACTION MERCHANT-F)>
+
+<ROUTINE MERCHANT-DESC (RARG OBJ)
+	 <TELL
+"A young and earnest-looking merchant stands near a pile
+of carpets">
+	 <COND (<FIRST? ,MERCHANT>
+		<TELL ". He is carrying in his arms a ">
+		<COND (<IN? ,MAGIC-CARPET ,MERCHANT>
+		       <TELL
+'MAGIC-CARPET " with a design of cubes on it">
+		       <COND (<IN? ,RANDOM-CARPET ,MERCHANT>
+			      <TELL " and a ">)>)>
+		<COND (<IN? ,RANDOM-CARPET ,MERCHANT>
+		       <TELL
+'RANDOM-CARPET " that's shabby and badly made">)>)>
+	 <TELL ,PERIOD>>
+
+<GLOBAL MERCHANT-FLAG <>>
+
+<ROUTINE MERCHANT-F ("OPTIONAL" (RARG <>) "AUX" PREV)
+	 <SETG MERCHANT-FLAG T>
+	 <COND (<EQUAL? ,WINNER ,MERCHANT>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (<VERB? HELLO>
+		       <TELL
+"\"Greetings to you! May I be of assistance?\"" CR>)
+		      (<OR <VERB? TELL-ME-ABOUT>
+			   <AND <VERB? GIVE SELL>
+				<EQUAL? ,PRSI ,ME>>>
+		       <ASK-ABOUT-CARPET ,PRSO>)
+		      (<ZERO? ,YOUR-OFFER>
+		       <TELL
+"\"Would you care to purchase a fine carpet?\"" CR>)
+		      (ELSE
+		       <TELL
+"\"Come, come. I haven't all day.\"" CR>)>)
+	       (<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<VERB? EXAMINE> <RFALSE>)
+		      (<VERB? BUY>
+		       <COND (<EQUAL? ,PRSI ,OPAL ,ZORKMID>
+			      <SETG ASKED-FOR ,PRSO>
+			      <PERFORM ,V?GIVE ,PRSI ,MERCHANT>
+			      <RTRUE>)
+			     (<AND <ZERO? ,YOUR-OFFER>
+				   <ZERO? ,MERCHANT-COUNT>>
+			      <SETG ASKED-FOR ,PRSO>
+			      <MAKE-NEW-OFFER>)
+			     (ELSE
+			      <ASK-ABOUT-CARPET ,PRSO>)>)
+		      (<VERB? TAKE POINT RUB ADMIRE POINT>
+		       <ASK-ABOUT-CARPET ,PRSO>)
+		      (<NOT <VERB? FIND>>
+		       <TELL
+"\"Your obvious eagerness to do business is matched only by your boorish
+manners.\"" CR>)>)
+	       (<NOT .RARG>
+		<COND (<AND <VERB? EXAMINE>
+			    <EQUAL? ,PRSO ,MERCHANT>>
+		       <TELL
+"The merchant is extremely anxious to please. He looks as if it might be
+his first day on the job. He's a young fellow wearing purple trousers
+which bulge alarmingly at the knees, an orange-striped shirt and a
+small hat. He has a detestable moustache." CR>)
+		      (<VERB? BARGAIN>
+		       <TELL
+"\"This is precisely my intention!\"" CR>)
+		      (<AND <VERB? GIVE SHOW> <EQUAL? ,PRSI ,MERCHANT>>
+		       <COND (<EQUAL? ,PRSO ,MAGIC-CARPET>
+			      <PERFORM ,V?TAKE ,RANDOM-CARPET>
+			      <RTRUE>)
+			     (<EQUAL? ,PRSO ,RANDOM-CARPET>
+			      <PERFORM ,V?TAKE ,MAGIC-CARPET>
+			      <RTRUE>)
+			     (<NOT <G? ,MERCHANT-WANTS ,YOUR-OFFER>>
+			      <TELL
+"\"But we've already made a deal! I can't accept anything additional!\"" CR>)
+			     (<OR <EQUAL? ,PRSO ,OPAL>
+				  <EQUAL? ,PRSO ,ZORKMID ,INTNUM>>
+			      <NEW-OFFER>)
+			     (<NOT <ZERO? <GETP ,PRSO ,P?CUBE>>>
+			      <TELL
+"\"A mere gewgaw, hardly worth a single zorkmid!\"" CR>)
+			     (<OR <FSET? ,PRSO ,MAGICBIT>
+				  <FSET? ,PRSO ,SCROLLBIT>>
+			      <TELL
+"\"That sort of thing is worthless to me. I am a simple man with no
+interest in magic!\"" CR>)
+			     (ELSE
+			      <TELL
+"\"You insult me. You insult my wife, you insult my children, you insult
+even my lowliest, mangiest dog.\"" CR>)>)>)>>
+
+"ask for a carpet"
+
+<ROUTINE ASK-ABOUT-CARPET (OBJ)
+	 <COND (<ZERO? ,YOUR-OFFER>
+		<COND (<OR <VERB? ASK-ABOUT ASK-FOR TELL-ME-ABOUT>
+			   <VERB? ADMIRE POINT>
+			   <NOT <EQUAL? .OBJ ,MAGIC-CARPET ,RANDOM-CARPET>>>
+		       <TELL
+"\"I see you have excellent taste. Let me tell you about these fine carpets">
+		       <COND (<NOT <EQUAL? .OBJ ,MAGIC-CARPET ,RANDOM-CARPET>>
+			      <TELL " instead">)
+			     (ELSE <SETG ASKED-FOR .OBJ>)>
+		       <TELL
+". They are my pride and joy, next of course to my nieces and nephews, but
+I digress... These carpets are the best you will find anywhere.\"" CR>)
+		      (ELSE
+		       <SETG ASKED-FOR .OBJ>
+		       <TELL
+"\"This is a valuable carpet. What will you offer for it? I'm not in
+business for my health.\"" CR>)>)
+	       (<L? ,YOUR-OFFER ,MERCHANT-WANTS>
+		<TELL
+"\"A serious offer, now! Enough of this game-playing!\"" CR>)
+	       (<AND <EQUAL? .OBJ ,MAGIC-CARPET>
+		     <IN? .OBJ ,MERCHANT>>
+		<COND (<EQUAL? ,ASKED-FOR ,MAGIC-CARPET>
+		       <COND (<IN? ,RANDOM-CARPET ,PLAYER>
+			      <TELL
+"\"How silly of me! You wanted this one with the cubes, didn't you?\" He
+gives it to you">)
+			     (ELSE
+			      <TELL
+"He grudgingly gives you the " 'MAGIC-CARPET>)>
+		       <COND (<IN? ,PLAYER ,RANDOM-CARPET>
+			      <MOVE ,PLAYER ,HERE>)>
+		       <MOVE ,RANDOM-CARPET ,MERCHANT>
+		       <MOVE ,MAGIC-CARPET ,PLAYER>
+		       <SCORE-OBJECT ,MAGIC-CARPET>
+		       <COND (<NOT <IN? ,RANDOM-CARPET ,MERCHANT>>
+			      <TELL ", retrieving the " 'RANDOM-CARPET>)>
+		       <TELL ,PERIOD>)
+		      (<EQUAL? ,ASKED-FOR ,RANDOM-CARPET>
+		       <TELL
+"\"No going back on our deal! I'll report you to the merchants'
+association!\"" CR>)>)
+	       (<AND <EQUAL? .OBJ ,RANDOM-CARPET>
+		     <IN? .OBJ ,MERCHANT>>
+		<SETG ASKED-FOR ,RANDOM-CARPET>
+		<TELL
+"He hurriedly gives you the " 'RANDOM-CARPET>
+		<COND (<NOT <IN? ,MAGIC-CARPET ,MERCHANT>>
+		       <TELL ", retrieving the " 'MAGIC-CARPET>)>
+		<COND (<IN? ,PLAYER ,MAGIC-CARPET>
+		       <MOVE ,PLAYER ,HERE>)>
+		<MOVE ,MAGIC-CARPET ,MERCHANT>
+		<MOVE ,RANDOM-CARPET ,PLAYER>
+		<TELL ,PERIOD>)
+	       (ELSE
+		<TELL "\"Yes? What about " THE .OBJ "?\"" CR>)>>
+
+"process new offer to merchant"
+
+<ROUTINE NEW-OFFER ("AUX" NEW OBJ)
+	 <COND (<EQUAL? ,PRSO ,ZORKMID ,INTNUM>
+		<SET OBJ ,ZORKMID>
+		<COND (<ZERO? ,P-NUMBER>
+		       <COND (<ZERO? ,YOUR-OFFER>
+			      <TELL
+"\"Five hundred zorkmids? Possibly a true coin...\" He
+tries to hide his interest. ">)>
+		       <SET NEW 500>)
+		      (ELSE
+		       <SET NEW ,P-NUMBER>)>)
+	       (ELSE
+		<SET OBJ ,PRSO>
+		<SET NEW ,MERCHANT-WANTS>)>
+	 <COND (<NOT ,ASKED-FOR>
+		<SETG ASKED-FOR ,RANDOM-CARPET>
+		<TELL
+"The merchant's eyes light up. \"No doubt you wish to purchase this lovely "
+'RANDOM-CARPET ". A wise choice!\"" CR>)
+	       (<NOT <G? ,MERCHANT-WANTS .NEW>>
+		<SETG YOUR-OFFER .NEW>
+		<TELL
+"\"Done, then!\" The merchant takes " THE .OBJ ". ">
+		<COND (<NOT <EQUAL? .OBJ ,ZORKMID>>
+		       <TELL "He examines it skeptically. \"I don't
+really think this is worth the price, no, it won't do at all...\" He
+hefts it in his hand. \"Well, I believe in accommodating our out-of-town
+visitors. Otherwise, we don't get any repeat customers, right? I can always
+put this trinket on the mantelpiece and regale my family with the story.\"
+He smiles unctuously. ">)
+		      (<G? ,YOUR-OFFER 500>
+		       <TELL
+"\"What do you take me for? This is only a 500 zorkmid piece! Trying to
+cheat me is trying to cheat my children! This I cannot accept! Out with
+you!\"">
+		       <KICKED-OUT>
+		       <RTRUE>)>
+		<MOVE .OBJ ,MERCHANT>
+		<MOVE ,RANDOM-CARPET ,PLAYER>
+		<TELL
+"\"I don't know what my family will eat tonight, but they say I'm
+softhearted. I only want to get back to my lunch, so you've got a deal. You
+should have told me you were an expert.\" He gives you a carpet. \"Now
+go before my family sees what a fool I've been...\"" CR>)
+	       (<AND <NOT <L? .NEW 100>>
+		     <NOT <L? .NEW <+ 50 ,YOUR-OFFER>>>>
+		<MAKE-NEW-OFFER .NEW>)
+	       (ELSE
+		<COND (<ZERO? ,YOUR-OFFER>
+		       <SETG YOUR-OFFER .NEW>)>
+		<TELL
+"\"Now, really, you must bargain in good faith. My patience is not infinite,
+as my lunch even now is congealing.\"" CR>)>>
+
+<ROUTINE MAKE-NEW-OFFER ("OPTIONAL" (NEW 0))
+	 <SETG YOUR-OFFER .NEW>
+	 <SETG MERCHANT-COUNT <+ ,MERCHANT-COUNT 1>>
+	 <COND (<NOT <G? ,MERCHANT-COUNT <GET ,MERCHANT-SAYS 0>>>
+		<SETG MERCHANT-WANTS <- ,MERCHANT-WANTS 100>>
+		<COND (<NOT <G? ,MERCHANT-WANTS ,YOUR-OFFER>>
+		       <SETG MERCHANT-WANTS ,YOUR-OFFER>
+		       <NEW-OFFER>)
+		      (ELSE
+		       <TELL <GET ,MERCHANT-SAYS
+				  ,MERCHANT-COUNT>
+			     CR>)>)
+	       (ELSE
+		<TELL
+"\"That does it! Out you go! Down the road to the rag-pickers, you
+thief!\"">
+		<KICKED-OUT>
+		<RTRUE>)>>
+
+<GLOBAL ASKED-FOR <>>
+
+<ROUTINE KICKED-OUT ("AUX" (L <LOC ,PLAYER>))
+	 <COND (<FSET? .L ,VEHBIT>
+		<MOVE ,PLAYER ,HERE>
+		<MOVE .L ,PLAYER>)> 
+	 <TELL " He throws you into the street and bars the door." CR CR>
+	 <FCLEAR ,EMPORIUM-DOOR ,OPENBIT>
+	 <FSET ,EMPORIUM-DOOR ,LOCKED>
+	 <GOTO ,BAZAAR>>
+
+<ROUTINE I-KICKED-OUT ()
+	 <COND (<EQUAL? ,HERE ,EMPORIUM>
+		<TELL CR
+"The merchant says, \"Time is money, and you've wasted too much of mine!\"">
+		<KICKED-OUT>)>>
+
+<GLOBAL YOUR-OFFER 0>
+<GLOBAL MERCHANT-WANTS 900>
+<GLOBAL MERCHANT-COUNT 0>
+<GLOBAL MERCHANT-SAYS
+	<PLTABLE
+"\"These carpets are the epitome of the weaver's art, woven
+by skilled native craftsmen with pride in their work. The Flatheads themselves
+have carpets like these. Their worth is nearly incalculable, but because
+today is my aged mother's birthday, we are offering them at an absurdly low
+price. A mere eight hundred zorkmids each!\""
+
+"\"You obviously didn't hear me. I didn't say we were giving them away.
+But my father is also hard of hearing and
+thus I have a warm spot in my heart for those similarly afflicted, so I will
+accept a pittance, as charity: seven hundred zorkmids.\""
+
+"\"My word! Let me see your teeth... No, not shark's teeth after all. Perhaps
+your rapaciousness has led you astray. Down the block you may find old rags
+and such to make a fine floor covering for your hovel. Here you must pay what
+the product is worth. Six hundred, or I send you down the street.\""
+
+"\"This grows tedious. Because I am a busy man and my lunch is growing cold,
+I will sell you a rug below my own cost. These rugs are imported at great
+expense over burning deserts, steep mountains and bandit-infested plains.
+My own cousin, who was watching out for the family interests in the caravan,
+was lost bringing this very shipment here. The caravan master, in his
+absence, no doubt robbed us blind, as you propose to do. Done at five hundred,
+then!\" He reaches toward you expectantly.">>
+
+<ROOM BAZAAR
+      (IN ROOMS)
+      (DESC "Bazaar")
+      (EAST PER EMPORIUM-EXIT)
+      (IN PER EMPORIUM-EXIT)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (ACTION BAZAAR-F)
+      (GLOBAL EMPORIUM-DOOR)
+      (THINGS
+       <PSEUDO ;(RAGGED URCHIN URCHIN-PSEUDO)
+	       (<> SIGN SIGN-PSEUDO)
+	       (<> SHOP SHOP-PSEUDO)
+	       (<> EMPORIUM SHOP-PSEUDO)>)>
+
+<ROUTINE SHOP-PSEUDO ()
+	 <COND (<VERB? THROUGH>
+		<DO-WALK ,P?EAST>)>>
+
+;<ROUTINE URCHIN-PSEUDO ()
+	 <COND (<OR <VERB? EXAMINE FOLLOW GIVE FIND>
+		    <HOSTILE-VERB?>>
+		<TELL "What urchin? You don't see an urchin." CR>)>>
+
+<ROUTINE BAZAAR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a crowded, noisy bazaar. Directly in front of you to the east
+is a shop. Above its door is a sign in an unknown tongue. " ,YOU-CANT "read
+it, but it is illustrated with a picture of a very ornate rug. ">
+		<COND (<FSET? ,EMPORIUM-DOOR ,LOCKED>
+		       <THIS-IS-IT ,EMPORIUM-DOOR>
+		       <TELL ,DOOR-LOCKED ,PERIOD>)
+		      (<NOT <FSET? ,EMPORIUM-DOOR ,OPENBIT>>
+		       <TELL-OPEN-CLOSED ,EMPORIUM-DOOR>)
+		      (ELSE
+		       <TELL "The door beckons invitingly." CR>)>)
+	       ;(<EQUAL? .RARG ,M-ENTER>
+		<QUEUE I-URCHIN 2>)>>
+
+<OBJECT RANDOM-CARPET
+	(DESC "scruffy red carpet")
+	(SYNONYM CARPET RUG)
+	(ADJECTIVE SHABBY SCRUFFY RED UGLY)
+	(FLAGS TAKEBIT VEHBIT CONTBIT OPENBIT SURFACEBIT SEARCHBIT)
+	(CAPACITY 200)
+	(GENERIC GENERIC-CARPET-F)
+	(ACTION RANDOM-CARPET-F)>
+
+<ROUTINE TAKE-ON-CARPET (CARP)
+	 <COND (<EQUAL? ,PRSO ,MAGIC-CARPET>
+		<GET-OFF-FIRST>)
+	       (<NOT-IN-VEHICLE?>
+		<CANT-REACH-THAT>)>>
+
+<ROUTINE NOT-SITTING ()
+	 <COND (,SITTING?
+		<MOVE ,PLAYER ,HERE>
+		<SETG SITTING? <>>
+		<TELL
+" You are no longer sitting on the carpet.">)>>
+
+<ROUTINE NOW-SITTING ()
+	 <COND (<AND ,SITTING? <IN? ,PLAYER ,PRSO>>
+		<TELL ,YOU-ARE ,PERIOD>
+		<RFALSE>)
+	       (ELSE
+		<SETG SITTING? T>
+		<TELL "You ">
+		<COND (<IN? ,PLAYER ,PRSO>
+		       <TELL "sit down">)
+		      (ELSE
+		       <MOVE ,PLAYER ,PRSO>
+		       <TELL "are now sitting">)>
+		<TELL " on " THE ,PRSO ". ">)>>
+
+<ROUTINE RANDOM-CARPET-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<COND (<OR <VERB? FLY>
+			   <AND <VERB? WALK>
+				<OR <EQUAL? ,P-WALK-DIR ,P?UP>
+				    <G? ,UD-COUNT 0>>>>
+		       <TELL ,NOTHING-HAPPENS>)
+		      (<VERB? WALK>
+		       <GET-OFF-FIRST>)
+		      (<VERB? TAKE MOVE>
+		       <TAKE-ON-CARPET ,RANDOM-CARPET>)
+		      (<AND <VERB? DISEMBARK>
+			    <EQUAL? ,PRSO ,RANDOM-CARPET>>
+		       <STEP-OFF-CARPET>
+		       <CRLF>)>)
+	       (<NOT .RARG>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"This is a cheaply made and ugly carpet. It is a garish red and looks ready
+to fall apart.">
+		       <CLEVER-CONTENTS ,RANDOM-CARPET
+					" On the carpet">
+		       <CRLF>)
+		      (<VERB? CASKLY>
+		       <TELL
+"It's perfectly awful already." CR>)
+		      (<AND <VERB? OFFER>
+			    <EQUAL? ,PRSI ,RANDOM-CARPET>
+			    <IN? ,MERCHANT ,HERE>>
+		       <SETG ASKED-FOR ,PRSI>
+		       <PERFORM ,V?GIVE ,PRSO ,MERCHANT>
+		       <RTRUE>)
+		      (<VERB? TAKE>
+		       <TAKE-CARPET>)
+		      (<VERB? BOARD CLIMB-ON STAND-ON>
+		       <BOARD-CARPET>)
+		      (<AND <VERB? SIT>
+			    <NOT <IN? ,WINNER ,RANDOM-CARPET>>>
+		       <COND (<CANT-GET-ON?>
+			      <RTRUE>)
+			     (ELSE
+			      <COND (<NOW-SITTING>
+				     <TELL
+"Some of the nap comes off on you." CR>)>
+			      <RTRUE>)>)
+		      (<AND <VERB? CUT>
+			    <EQUAL? ,PRSI ,SHEARS ,KNIFE>>
+		       <CARPET-CRUMBLES>)>)>>
+
+<GLOBAL SITTING? <>>
+
+<ROUTINE CANT-GET-ON? ()
+	 <COND (<FSET? ,HERE ,RAIRBIT>
+		<TELL
+"A good thought, but a little too late to save you, I'm afraid." CR>)
+	       (<FSET? ,HERE ,RWATERBIT>
+		<TELL
+"Impossible under the circumstances." CR>)
+	       (<HELD? ,PRSO>
+		<TELL
+,YOU-HAVE-TO " put it down first." CR>)>>
+
+<ROUTINE BOARD-CARPET ()
+	 <COND (<IN? ,PLAYER ,PRSO>
+		<TELL ,YOU-ARE ,PERIOD>)
+	       (<CANT-GET-ON?> <RTRUE>)
+	       (ELSE
+		<MOVE ,PLAYER ,PRSO>
+		<SETG SITTING? <>>
+		<TELL
+,YOU-ARE-NOW "standing on the carpet. Nothing expected is happening." CR>)>>
+
+<ROUTINE STEP-OFF-CARPET ()
+	 <SETG SITTING? <>>
+	 <MOVE ,PLAYER <LOC ,PRSO>>
+	 <TELL "You step off the carpet.">>
+
+<OBJECT MAGIC-CARPET
+	(DESC "beautiful blue carpet")
+	(SYNONYM CARPET RUG)
+	(ADJECTIVE MAGIC BEAUTIFUL BLUE STRANGE DESIGN)
+	(FLAGS TAKEBIT VEHBIT MAGICBIT CONTBIT OPENBIT SURFACEBIT SEARCHBIT)
+	(CAPACITY 200)
+	(GENERIC GENERIC-CARPET-F)
+	(ACTION MAGIC-CARPET-F)>
+
+<ROUTINE MAGIC-CARPET-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? TAKE MOVE>
+		       <TAKE-ON-CARPET ,MAGIC-CARPET>)
+		      (<AND <VERB? DROP> <G? ,UD-COUNT 0>>
+		       <DROP-IN-AIR>)
+		      (<OR <VERB? FLY>
+			   <AND <VERB? WALK>
+				<OR <EQUAL? ,P-WALK-DIR ,P?UP>
+				    <G? ,UD-COUNT 0>>>>
+		       <COND (<AND <VERB? FLY>
+				   <NOT ,PRSO>>
+			      <SETG P-WALK-DIR ,P?UP>)>
+		       <COND (<OR <NOT <IN? ,CARPET-LABEL ,MAGIC-CARPET>>
+				  <FSET? ,CARPET-LABEL ,RMUNGBIT>>
+			      <TELL ,NOTHING-HAPPENS>)
+			     (<NOT ,SITTING?>
+			      <TELL ,RIPPLES ,PERIOD>)
+			     (<EQUAL? ,HERE ,MIDAIR>
+			      <COND (<EQUAL? ,P-WALK-DIR ,P?NORTH>
+				     <SETG NS-COUNT <+ ,NS-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?SOUTH>
+				     <SETG NS-COUNT <- ,NS-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?EAST>
+				     <SETG EW-COUNT <+ ,EW-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?WEST>
+				     <SETG EW-COUNT <- ,EW-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?UP>
+				     <SETG UD-COUNT <+ ,UD-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?DOWN>
+				     <SETG UD-COUNT <- ,UD-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?NE>
+				     <SETG NS-COUNT <+ ,NS-COUNT 1>>
+				     <SETG EW-COUNT <+ ,EW-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?NW>
+				     <SETG NS-COUNT <+ ,NS-COUNT 1>>
+				     <SETG EW-COUNT <- ,EW-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?SE>
+				     <SETG NS-COUNT <- ,NS-COUNT 1>>
+				     <SETG EW-COUNT <+ ,EW-COUNT 1>>)
+				    (<EQUAL? ,P-WALK-DIR ,P?SW>
+				     <SETG NS-COUNT <- ,NS-COUNT 1>>
+				     <SETG EW-COUNT <- ,EW-COUNT 1>>)
+				    (ELSE
+				     <TELL
+"The carpet doesn't move." CR>
+				     <RTRUE>)>
+			      <COND (<EQUAL? ,UD-COUNT 0>
+				     <COND (<AND <EQUAL? ,NS-COUNT 0>
+						 <EQUAL? ,EW-COUNT 0>>
+					    <GOTO ,ROC-NEST>)
+					   (<AND <EQUAL? ,NS-COUNT 0>
+						 <EQUAL? ,EW-COUNT 4>
+						 ,SEEN-TOWER?>
+					    <GOTO ,GUARD-TOWER>)
+					   (ELSE
+					    <GOTO ,LOST-ON-LAND>)>
+				     <RTRUE>)
+				    (ELSE
+				     <DESCRIBE-CARPET-LOC>)>)
+			     (<EQUAL? ,HERE ,LOST-IN-CLOUDS>
+			      <SETG SMASH-PROB <+ ,SMASH-PROB 5>>
+			      <COND (<PROB ,SMASH-PROB>
+				     <FCLEAR ,MIDAIR ,TOUCHBIT>
+				     <GOTO ,MIDAIR>)
+				    (ELSE
+				     <TELL
+"You are still lost in thick, fluffy clouds. It is impossible to tell
+directions in here." CR>)>)
+			     (<EQUAL? ,P-WALK-DIR ,P?UP>
+			      <COND (<EQUAL? ,HERE ,GUARD-TOWER ,ROC-NEST>
+				     <TELL
+"The carpet takes to the air, rising swiftly.">
+				     <COND (<AND <IN? ,ROC ,HERE>
+						 <EQUAL? ,HERE ,GUARD-TOWER>>
+					    <REMOVE ,ROC>
+					    <TELL
+" The huge bird stops, almost stalls, and flees goggle-eyed with
+surprise.">)>
+				     <CRLF>
+				     <CRLF>
+				     <FCLEAR ,MIDAIR ,TOUCHBIT>
+				     <GOTO ,MIDAIR>)
+				    (<EQUAL? ,HERE ,VOLCANO-ROOM ,VOLCANO-BASE
+					     ,OUTCROPPING-ROOM>
+				     <TELL
+"You begin to rise, but you notice that the ">
+				     <COND (<EQUAL? ,MAGIC-CARPET ,ICED-OBJECT>
+					    <SETG ICED-OBJECT <>>
+					    <TELL
+"carpet is steaming as the ice melts. You prudently return to earth." CR>
+					    <RTRUE>)
+					   (ELSE
+					    <REMOVE ,CARPET-LABEL>
+					    <JIGS-UP
+"fringe of the carpet is starting
+to singe and turn brown from the heat. Just as you are about to turn back,
+the label catches fire and burns to a crisp. You plummet into the lava and
+are seen no more.">)>)
+				    (<FSET? ,HERE ,OUTSIDE>
+				     <FCLEAR ,LOST-IN-CLOUDS ,TOUCHBIT>
+				     <GOTO ,LOST-IN-CLOUDS>)
+				    (ELSE
+				     <TELL
+"It ripples a little." CR>)>)
+			     (ELSE
+			      <TELL ,RIPPLES ,PERIOD>)>)
+		      (<VERB? WALK>
+		       <GET-OFF-FIRST>)
+		      (<AND <VERB? DISEMBARK>
+			    <EQUAL? ,PRSO ,MAGIC-CARPET>>
+		       <STEP-OFF-CARPET>
+		       <COND (<FSET? ,HERE ,RAIRBIT>
+			      <START-FALLING>
+			      <TELL
+" As you are in midair, you begin to fall. The
+carpet loses its impetus the moment you cease to touch it and accordians
+like a rug that's been slipped on. It too begins to fall.">)>
+		       <CRLF>)
+		      (<AND <VERB? LEAP> <G? ,UD-COUNT 0>>
+		       <TELL
+"This is not the most prudent method of disembarking." CR>)>)
+	       (<NOT .RARG>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"This is a carpet of unusual design. It is blue, beautifully woven and has
+a pattern that looks different each time you look at it.
+Sometimes, for example, it's an array of cubes pointing upward, and other
+times it's the same array pointing downward. There is a jaunty fringe
+around the outer edge.">
+		       <CLEVER-CONTENTS ,MAGIC-CARPET
+					" On the carpet"
+					,CARPET-LABEL>
+		       <CRLF>)
+		      (<AND <VERB? OFFER>
+			    <EQUAL? ,PRSI ,MAGIC-CARPET>
+			    <IN? ,MERCHANT ,HERE>>
+		       <SETG ASKED-FOR ,PRSI>
+		       <PERFORM ,V?GIVE ,PRSO ,MERCHANT>
+		       <RTRUE>)
+		      (<VERB? TAKE>
+		       <TAKE-CARPET>)
+		      (<AND <VERB? CUT>
+			    <EQUAL? ,PRSI ,SHEARS ,KNIFE>>
+		       <START-FALLING>
+		       <CARPET-CRUMBLES>)
+		      (<VERB? LOOK-INSIDE>
+		       <COND (<CLEVER-CONTENTS ,PRSO
+					"On the carpet"
+					,CARPET-LABEL>
+			      <CRLF>)
+			     (ELSE <ITS-EMPTY>)>)
+		      (<VERB? LOOK-UNDER TURN-OVER MOVE>
+		       <TELL "You turn the carpet over and discover ">
+		       <COND (<AND <IN? ,PLAYER ,MAGIC-CARPET>
+				   <EQUAL? ,HERE ,MIDAIR ,LOST-IN-CLOUDS>>
+			      <JIGS-UP
+"that you have sent the carpet into a fatal stall!">
+			      <RFATAL>) 
+			     (<AND <IN? ,CARPET-LABEL ,MAGIC-CARPET>
+				   <NOT <FSET? ,CARPET-LABEL ,RMUNGBIT>>>
+			      <FCLEAR ,CARPET-LABEL ,INVISIBLE>
+			      <TELL "a label">)
+			     (ELSE
+			      <TELL "nothing">)>
+		       <TELL ,PERIOD>)
+		      (<VERB? BOARD CLIMB-ON STAND-ON>
+		       <BOARD-CARPET>)
+		      (<VERB? SIT>
+		       <COND (<CANT-GET-ON?> <RTRUE>)
+			     (<NOW-SITTING>
+			      <COND (<AND <IN? ,CARPET-LABEL
+					       ,MAGIC-CARPET>
+					  <NOT <FSET? ,CARPET-LABEL
+						      ,RMUNGBIT>>>
+				     <TELL
+"At first nothing happens. Then the
+fringe of the carpet starts to ruffle expectantly." CR>)
+				    (ELSE
+				     <TELL
+"Nothing interesting happens, although the carpet is comfortable." CR>)>)>
+		       <RTRUE>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<SETG SMASH-PROB 0>)>>
+
+<ROUTINE TAKE-CARPET ("AUX" (IGNORE? <>))
+	 <COND (<EQUAL? <ITAKE> T>
+		<TELL "Taken">
+		<SET IGNORE?
+		     <COND (<NOT <FSET? ,CARPET-LABEL ,RMUNGBIT>>
+			    ,CARPET-LABEL)>>
+		<COND (<ROB ,PRSO ,HERE .IGNORE?>
+		       <TELL ", but something fell off">)>
+		<TELL ,PERIOD>)>
+	 <RTRUE>>
+
+<GLOBAL RIPPLES "The carpet ripples excitedly">
+
+<ROUTINE GET-OFF-FIRST ()
+	 <TELL
+,YOU-HAVE-TO " get off the carpet first." CR>>
+
+<ROUTINE CARPET-CRUMBLES ()
+	 <REMOVE ,PRSO>
+	 <TELL
+"As the first thread is cut, the " 'PRSO " crumbles to dust." CR>>
+
+<ROUTINE DESCRIBE-CARPET-LOC ()
+	 <TELL "You are ">
+	 <COND (<IN? ,PLAYER ,MAGIC-CARPET> <TELL "flying ">)>
+	 <COND (<G? ,UD-COUNT 3>
+		<TELL "dizzyingly high ">)
+	       (<G? ,UD-COUNT 2>
+		<TELL "very high ">)
+	       (<G? ,UD-COUNT 1>
+		<TELL "high ">)>
+	 <TELL "above ">
+	 <COND (<AND <EQUAL? ,NS-COUNT 0>
+		     <EQUAL? ,EW-COUNT 0>>
+		<TELL "a giant bird's nest">)
+	       (<AND <EQUAL? ,NS-COUNT 0>
+		     <EQUAL? ,EW-COUNT 4>
+		     ,SEEN-TOWER?>
+		<TELL "an abandoned guard tower">)
+	       (<EQUAL? ,EW-COUNT 0>
+		<TELL "jagged mountains">)
+	       (ELSE
+		<TELL "a trackless wilderness to the ">
+		<COND (<G? ,EW-COUNT 0>
+		       <TELL "east">)
+		      (ELSE
+		       <TELL "west">)>
+		<TELL " of a range of jagged mountains">)>
+	 <TELL ,PERIOD>>
+
+<OBJECT CARPET-LABEL
+	(IN MAGIC-CARPET)
+	(DESC "label")
+	(SYNONYM LABEL)
+	(FLAGS INVISIBLE TAKEBIT READBIT)
+	(ACTION CARPET-LABEL-F)>
+
+<ROUTINE CARPET-LABEL-F ()
+	 <COND (<VERB? READ EXAMINE>
+		<TELL
+"The label reads:|
+|
+\"Frobozz Magic Magic Carpet Co.|
+|
+This carpet is made of all-unnatural fibers.
+Occupancy by more than one person is prohibited. Keep to posted speeds.
+Do not remove this label under penalty of law.|
+|
+Abdul el-Flathead|
+|
+(Printed by the Frobozz Magic Label Co.)\"" CR>)
+	       (<AND <VERB? CASKLY>
+		     <NOT <IN? ,CARPET-LABEL ,MAGIC-CARPET>>>
+		<TELL ,NOTHING-HAPPENS>)
+	       (<VERB? TAKE MUNG>
+		<FSET ,PRSO ,RMUNGBIT>
+		<COND (<AND <IN? ,PLAYER ,MAGIC-CARPET>
+			    <FSET? ,HERE ,RAIRBIT>>
+		       <START-FALLING>
+		       <MOVE ,PLAYER ,HERE>
+		       <TELL
+"As soon as the label is removed, the carpet hits an air pocket and rolls
+up. There is no room for you on a rolled-up carpet. You begin to fall."
+CR>)>)>>
+
+<ROUTINE START-FALLING ()
+	 <SETG FALLING? T>
+	 <SETG SMASH-PROB 0>
+	 <QUEUE I-FALLING -1>>
+
+<ROOM MIDAIR
+      (IN ROOMS)
+      (DESC "Midair")
+      (ACTION MIDAIR-F)
+      (FLAGS RAIRBIT OUTSIDE ONBIT)
+      (THINGS
+       <PSEUDO (FLATHEAD MOUNTAIN MOUNTAIN-PSEUDO)
+	       (TRACKLESS WILDERNESS RANDOM-PSEUDO)
+	       (<> CLOUDS CLOUD-PSEUDO)
+	       (GUARD TOWER RANDOM-PSEUDO)
+	       (ROC NEST NEST-PSEUDO)>)>
+
+<ROUTINE MIDAIR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL "You are in midair.">
+		<COND (<IN? ,PLAYER ,ROC>
+		       <TELL
+" Fortunately a very large bird is carrying you, otherwise you would fall.">)
+		      (<IN? ,PLAYER ,MAGIC-CARPET>
+		       <TELL
+" Fortunately you are sitting on a magic carpet and thus are fairly safe.">)
+		      (,FALLING?
+		       <TELL " You are falling.">)>
+		<COND (<EQUAL? ,HERE ,MIDAIR>
+		       <TELL " ">
+		       <DESCRIBE-CARPET-LOC>)
+		      (ELSE <CRLF>)>
+		<RTRUE>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT <IN? ,PLAYER ,MAGIC-CARPET>>
+		       <SETG ROC-PROB
+			     <COND (<FSET? ,HERE ,TOUCHBIT> 0)
+				   (ELSE 25)>>
+		       <QUEUE I-ROC -1>)>
+		<SETG EW-COUNT
+		      <COND (<EQUAL? ,OHERE ,LOST-IN-CLOUDS>
+			     <- <RANDOM 5> 1>)
+			    (<EQUAL? ,OHERE ,GUARD-TOWER
+				     ,AIR-ROOM ,EARTH-ROOM>
+			     4)
+			    (ELSE
+			     0)>>
+		<SETG NS-COUNT
+		      <COND (<EQUAL? ,OHERE ,LOST-IN-CLOUDS>
+			     <- <RANDOM 5> 3>)
+			    (ELSE
+			     0)>>
+		<SETG UD-COUNT
+		      <COND (<EQUAL? ,OHERE ,LOST-IN-CLOUDS>
+			     <RANDOM 4>)
+			    (<EQUAL? ,OHERE ,AIR-ROOM ,EARTH-ROOM>
+			     4)
+			    (ELSE
+			     1)>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<COND (<IN? ,MAGIC-CARPET ,HERE>
+		       <MOVE ,MAGIC-CARPET ,LOST-ON-LAND>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? WALK> ,FALLING?>
+		       <COND (<EQUAL? ,P-WALK-DIR ,P?DOWN>
+			      <TELL "You have little choice." CR>)
+			     (ELSE
+			      <TELL "Down seems more likely." CR>)>)
+		      (<AND <VERB? LESOCH> <NOT ,PRSO>>
+		       <LESOCH-CLOUDS>)
+		      (<VERB? DROP>
+		       <DROP-IN-AIR>)>)
+	       (<EQUAL? .RARG ,M-END>
+		<COND (<AND <NOT <EQUAL? <LOC ,PLAYER> ,ROC ,MAGIC-CARPET>>
+			    <NOT ,FALLING?>>
+		       <SETG ROC-PROB 0>
+		       <START-FALLING>
+		       <TELL "You have begun to fall." CR>)>)>>
+
+<ROUTINE DROP-IN-AIR ()
+	 <COND (<EQUAL? ,PRSO <LOC ,WINNER>>
+		<RFALSE>)
+	       (<IDROP>
+		<COND (<EQUAL? ,PRSO ,MAGIC-BOX>
+		       <MOVE ,PRSO ,LOST-ON-LAND>)
+		      (ELSE
+		       <REMOVE ,PRSO>)>
+		<TELL
+CTHE ,PRSO " falls, dwindling below you, never to be seen again." CR>)
+	       (ELSE <RTRUE>)>>
+
+<GLOBAL NS-COUNT 0>
+<GLOBAL EW-COUNT 0>
+<GLOBAL UD-COUNT 0>
+
+<ROOM LOST-IN-CLOUDS
+      (IN ROOMS)
+      (DESC "In Thick Clouds")
+      (ACTION MIDAIR-F)
+      (FLAGS ONBIT RAIRBIT)
+      (THINGS <PSEUDO (<> CLOUDS CLOUD-PSEUDO)
+		      (<> CLOUD CLOUD-PSEUDO)>)>
+
+<ROOM LOST-ON-LAND
+      (IN ROOMS)
+      (DESC "Wilderness")
+      (ACTION WILDERNESS-F)
+      (FLAGS ONBIT RLANDBIT)>
+
+<ROUTINE WILDERNESS-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<TELL
+"Wilderness|
+You are lost in a trackless wilderness. Wild creatures and wild men
+rule here. As soon as ">
+		<COND (<IN? ,PLAYER ,MAGIC-CARPET>
+		       <TELL "your carpet touches ground">)
+		      (ELSE
+		       <TELL "you arrive">)>
+		<TELL ", you are set upon by
+one or the other (they are difficult to tell apart) and devoured.">
+			<JIGS-UP>)>>
+
+"FIRE"
+
+<OBJECT FIRE-CUBE
+	(IN PILLAR-ROOM)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE DQ ;C4 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "salamanders")
+	(FLAGS TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE FIRE-ROOM)>
+
+<ROOM FIRE-ROOM
+      (IN ROOMS)
+      (DESC "Fire Room")
+      (CUBE FIRE-CUBE)
+      (SOUTH TO CLIFF-TOP)
+      (NORTH TO VOLCANO-ROOM)
+      (EAST PER MAGIC-BOX-EXIT)
+      (ACTION FIRE-ROOM-F)
+      (FLAGS RLANDBIT ONBIT)>
+
+<ROUTINE FIRE-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"In this room, the walls are brick and glow a deep red. The floor itself
+radiates heat, and in fact the entire room is hot, oppressive and smokey.
+Searing heat radiates from openings in the north, east and south walls." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM VOLCANO-ROOM
+      (IN ROOMS)
+      (DESC "Volcano")
+      (ACTION VOLCANO-ROOM-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (GLOBAL OUTCROPPING GLOBAL-ROCKS)
+      (THINGS
+       <PSEUDO (<> VOLCANO VOLCANO-PSEUDO)
+	       (MOLTEN LAVA LAVA-PSEUDO)>)>
+
+<ROUTINE VOLCANO-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are at the edge of a lava vent in an active volcano. The
+lava glows red and yellow, and there is a stench of sulphur in the air.
+A lake of lava bubbles and steams before you, molten rock roiling from
+unseen disturbances. To the west, in the middle of the tumult, is a
+small outcropping of something with a higher melting point than rock. It
+is undisturbed by the heat." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <TELL ,SMELL-LAVA>)>)>>
+
+<ROUTINE VOLCANO-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<PERFORM ,V?LOOK>
+		<RTRUE>)
+	       (<VERB? SMELL>
+		<TELL ,SMELL-LAVA>)
+	       (<VERB? TINSOT>
+		<LAVA-COOLS>)>>
+
+<ROUTINE LAVA-COOLS ()
+	 <TELL
+"A small patch of lava cools, but it is swept away." CR>>
+
+<GLOBAL SMELL-LAVA "It smells like boiling brimstone.|">
+
+<ROUTINE LAVA-PSEUDO ()
+	 <COND (<VERB? EXAMINE TAKE SWIM THROUGH>
+		<TAKE-LAVA>)
+	       (<VERB? SMELL>
+		<TELL ,SMELL-LAVA>)
+	       (<AND <VERB? THROW PUT>
+		     <HELD? ,PRSO>
+		     <EQUAL? ,PRSI ,PSEUDO-OBJECT>>
+		<INTO-LAVA>)
+	       (<VERB? TAKE RUB>
+		<TAKE-LAVA>)
+	       (<VERB? TINSOT>
+		<LAVA-COOLS>)>>
+
+<ROUTINE INTO-LAVA ()
+	 <REMOVE ,PRSO>
+	 <TELL
+"It disappears into the lava." CR>>
+
+<ROOM VOLCANO-BASE
+      (IN ROOMS)
+      (DESC "Volcano Base")
+      (ACTION VOLCANO-BASE-F)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL GLOBAL-ROCKS)
+      (THINGS
+       <PSEUDO (<> VOLCANO VOLCANO-PSEUDO)
+	       (MOLTEN LAVA LAVA-PSEUDO)>)>
+
+<ROUTINE VOLCANO-BASE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are partway up the base of an active volcano. All around you is a
+stream of glowing, molten lava, bubbling and spitting. Clumps of red-hot
+lava fly through the air, narrowly missing you. Your
+vantage point is a small point of rock that hasn't been remelted by
+the flow." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? WALK>
+		       <TELL
+"The heat of the lava would cook you for sure!" CR>)
+		      (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <TELL ,SMELL-LAVA>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT ,ROCK-ARRIVED?>
+		       <SETG ROCK-ARRIVED? T>
+		       <QUEUE I-ROCK-ARRIVES 2>)>)>>
+
+<GLOBAL ROCK-ARRIVED? <>>
+
+<OBJECT LAVA-ROCK
+	(DESC "lava fragment")
+	(SYNONYM FRAGMENT)
+	(ADJECTIVE LAVA)
+	(FLAGS TAKEBIT TRYTAKEBIT RMUNGBIT)
+	(ACTION LAVA-ROCK-F)>
+
+<ROUTINE LAVA-ROCK-F ()
+	 <COND (<OR <VERB? TINSOT>
+		    <AND <VERB? POUR>
+			 <EQUAL? ,PRSO ,LOCAL-WATER>>>
+		<COND (<VERB? POUR>
+		       <REMOVE ,LOCAL-WATER>)>
+		<FSET ,LAVA-ROCK ,TOUCHBIT>
+		<FCLEAR ,LAVA-ROCK ,RMUNGBIT>
+		<THIS-IS-IT ,LAVA-ROCK>
+		<TELL
+"The fragment is cool enough to touch." CR>)
+	       (<AND <VERB? EXAMINE>
+		     <FSET? ,PRSO ,RMUNGBIT>>
+		<TELL
+"It's cooling slowly but is still too hot to touch safely." CR>)
+	       (<VERB? SMELL>
+		<TELL ,SMELL-LAVA>)
+	       (<AND <VERB? TAKE RUB>
+		     <FSET? ,PRSO ,RMUNGBIT>>
+		<TAKE-LAVA>)>>
+
+<ROUTINE TAKE-LAVA ()
+	 <COND (,PRSI
+		<COND (<OR <EQUAL? ,PRSI ,WEED ,SPELL-BOOK>
+			   <EQUAL? ,PRSI ,DEAD-BOOK ,BREAD ,FISH>
+			   <EQUAL? ,PRSI ,MAGIC-CARPET ,RANDOM-CARPET>
+			   <FSET? ,PRSI ,SCROLLBIT>>
+		       <REMOVE ,PRSI>
+		       <TELL
+CTHE ,PRSI " catches fire and burns to a crisp." CR>)
+		      (ELSE
+		       <TELL
+CTHE ,PRSI " hisses and sizzles when you touch the lava with it." CR>)>)
+	       (ELSE
+		<TELL
+"It's too hot to touch. You burn yourself slightly just getting near it."
+		 CR>)>>
+
+<ROOM OUTCROPPING-ROOM
+      (IN ROOMS)
+      (DESC "Outcropping")
+      (ACTION OUTCROPPING-ROOM-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (GLOBAL OUTCROPPING GLOBAL-ROCKS)
+      (THINGS
+       <PSEUDO (SOLID GROUND SOLID-GROUND-PSEUDO)
+	       (<> VOLCANO VOLCANO-PSEUDO)
+	       (MOLTEN LAVA LAVA-PSEUDO)
+	       (<> MOUNTAIN VOLCANO-PSEUDO)>)>
+
+<GLOBAL GOT-MAGIC-CUBE? <>>
+
+<ROUTINE OUTCROPPING-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are on a very small outcropping of some material that is
+impervious to heat. All around you lava bubbles and steams, flowing down
+the side of the mountain in a relentless stream. There is solid ground out
+of reach to the east." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? TAKE>
+			    <EQUAL? ,PRSO ,MAGIC-CUBE>
+			    <NOT ,GOT-MAGIC-CUBE?>>
+		       <SETG GOT-MAGIC-CUBE? T>
+		       <SCORE-OBJECT>
+		       <MOVE ,MAGIC-CUBE ,WINNER>
+		       <TELL
+"As you take the cube, you are nearly blinded by a blast of power. It
+rolls out from the cube, up your arm and all over your body. Every hair
+stands on end, every muscle is tense. You feel more powerful, as though
+a weight had been lifted from your body and a veil drawn from before you.
+The very stuff of magic crackles from your fingertips." CR>)
+		      (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <TELL ,SMELL-LAVA>)>)>>
+
+<ROUTINE SOLID-GROUND-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"There is solid ground about twenty feet to the east, past a stream of
+molten lava.">
+		<CLEVER-CONTENTS ,VOLCANO-ROOM " On the ground">
+		<CRLF>)
+	       (<AND <VERB? THROW>
+		     <HELD? ,PRSO>
+		     <EQUAL? ,PRSI ,PSEUDO-OBJECT>>
+		<MOVE ,PRSO ,VOLCANO-ROOM>
+		<TELL
+CTHE ,PRSO " sails smoothly through the broiling air and lands on the
+ground to your east." CR>)
+	       (<VERB? CLIMB-ON BOARD>
+		<TELL ,TOO-FAR>)>>
+
+<OBJECT OUTCROPPING
+	(IN LOCAL-GLOBALS)
+	(DESC "outcropping")
+	(SYNONYM OUTCROPPING)
+	(ADJECTIVE HARD SOLID)
+	(FLAGS NDESCBIT AN SURFACEBIT OPENBIT CONTBIT)
+	(ACTION OUTCROPPING-F)>
+
+<ROUTINE OUTCROPPING-F ()
+	 <COND (<EQUAL? ,HERE ,VOLCANO-ROOM>
+		<COND (<VERB? EXAMINE LOOK-INSIDE>
+		       <TELL
+"The outcropping is made of some hard, heat-resistant substance. It sticks
+up about three feet out of the lava about twenty feet from you. It has a
+flat top about four feet across which is roughly square.">
+		       <COND (<IN? ,MAGIC-CUBE ,OUTCROPPING-ROOM>
+			      <TELL
+" Sitting in the very center of the outcropping is something small, white,
+and cubical.">)>
+		       <CLEVER-CONTENTS ,OUTCROPPING-ROOM
+					" On the top of the outcropping"
+					 ,MAGIC-CUBE>
+		       <CRLF>)
+		      (<AND <VERB? PUT PUT-ON>
+			    <EQUAL? ,PRSI ,OUTCROPPING>>
+		       <TELL ,TOO-FAR>)
+		      (<THROW-ONTO ,OUTCROPPING ,OUTCROPPING-ROOM>
+		       <RTRUE>)
+		      (<AND <VERB? THROW-OFF>
+			    <HELD? ,PRSO>
+			    <EQUAL? ,PRSI ,OUTCROPPING>>
+		       <INTO-LAVA>)
+		      (<VERB? THROUGH WALK-TO CLIMB-ON BOARD>
+		       <TELL ,TOO-FAR>)>)
+	       (ELSE
+		<COND (<VERB? EXAMINE LOOK-INSIDE>
+		       <TELL
+"Now that you are on it, you can see that the outcropping is made
+of some kind of volcanic glass that somehow was expelled from the volcano
+and lodged here in the middle of the lava stream. It is an iceberg only
+partly above the flow, stuck solidly in the channel through which the
+lava flows." CR>)>)>>
+
+<ROUTINE THROW-ONTO (OBJ RM)
+	 <COND (<AND <VERB? THROW>
+		     <HELD? ,PRSO>
+		     <EQUAL? ,PRSI .OBJ>>
+		<COND (<EQUAL? ,PRSO ,WATER ,LOCAL-WATER>
+		       <INTO-LAVA>)
+		      (ELSE
+		       <MOVE ,PRSO .RM>
+		       <TELL
+CTHE ,PRSO " sails smoothly through the air, bounces on " THE ,PRSI
+" and ends up perched on the very edge of the far side." CR>)>)>>
+
+"DARK"
+
+<OBJECT DARK-CUBE
+	(IN OTHER-ROCK)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE EQ ;C5 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "grues")
+	(FLAGS NDESCBIT TRYTAKEBIT TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE DARK-ROOM)>
+
+<ROOM DARK-ROOM
+      (IN ROOMS)
+      (DESC "Dark Room")
+      (DOWN TO DARK-CAVE)
+      (UP PER MAGIC-BOX-EXIT)
+      (CUBE DARK-CUBE)
+      (ACTION DARK-ROOM-F)
+      (FLAGS RLANDBIT)>
+
+<ROUTINE DARK-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This room is totally black, so black that you see nothing when you look
+around it. All light is absorbed by the substance of
+the place. You can tell it is physical, because you can feel your feet
+touching the floor, but your eyes tell you nothing." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM DARK-CAVE
+      (IN ROOMS)
+      (DESC "Dark Cave")
+      (DOWN TO GRUE-CAVE)
+      (ACTION DARK-CAVE-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GLOBAL-CAVE)>
+
+<ROUTINE DARK-CAVE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <TELL
+"This is a jumbled, rough cave with many small passages leading in and
+out, and one large one leading down." CR>)
+		      (ELSE
+		       <TELL
+"This is a large cave with a rough floor. You can tell little about the
+surroundings, because your " 'FROTZ-SPELL " doesn't seem to be
+working normally here and produces only a wan and sickly glow. The
+light coming from ">
+		       <TELL-LIGHT-SOURCE>
+		       <TELL " has been reduced
+to a thin, barely glowing stream of tiny blobs that drips, spurts
+and sputters uselessly to the ground. There it collects into a small pile
+which is slowly disappearing, perhaps by evaporation." CR>)>)>>
+
+<ROUTINE TELL-LIGHT-SOURCE ()
+	 <COND (<EQUAL? ,LIT ,WINNER>
+		<TELL "you">)
+	       (<EQUAL? ,LIT ,HERE>
+		<TELL "here">)
+	       (ELSE
+		<TELL THE ,LIT>)>>
+
+<ROOM GRUE-CAVE
+      (IN ROOMS)
+      (DESC "Grue Cave")
+      (UP TO DARK-CAVE)
+      (IN TO LIGHT-POOL)
+      (DOWN TO LIGHT-POOL)
+      (ACTION GRUE-CAVE-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GRUE GLOBAL-CAVE PILLAR)
+      (THINGS <PSEUDO (LIGHT POOL POOL-PSEUDO)>)>
+
+<ROUTINE POOL-PSEUDO ()
+	 <COND (<VERB? THROUGH> <DO-WALK ,P?DOWN>)
+	       (<VERB? EXAMINE> <PERFORM ,V?LOOK> <RTRUE>)
+	       (<AND <VERB? THROW DROP>
+		     <EQUAL? ,PRSI ,PSEUDO-OBJECT>>
+		<COND (<IDROP>
+		       <MOVE ,PRSO ,LIGHT-POOL>
+		       <COND (<VERB? THROW> <TELL "Thrown">)
+			     (ELSE <TELL "Dropped">)>
+		       <TELL ,PERIOD>)
+		      (ELSE <RTRUE>)>)>>
+
+<ROUTINE GRUE-CAVE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <TELL
+"A natural amphitheater carved out of the underground rock opens from
+several small passages. The cave is crowded with grues of all shapes and
+sizes. At the lowest point of the cave a small pool of light has gathered,
+glowing very dimly (from a human point of view).
+The grues avoid it, and in fact it hurts your eyes to look at it for very
+long. In the middle of the pool is a short, squat pillar">
+		       <COND (<FIRST? ,PILLAR-ROOM>
+			      <THIS-IS-IT ,FIRE-CUBE>
+			      <TELL " with something
+on top of it. This is the object of all the attention. The grues
+seem to regard the pillar or its contents with awe">)>
+		       <TELL ,PERIOD>)
+		      (ELSE
+		       <TELL
+"This is a large underground chamber filled with nightmarish, barely
+visible shapes. There is very dim light issuing from somewhere near the
+center of the room." CR>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <NOT <EQUAL? ,CHANGED? ,GRUE>>
+			    <VERB? WALK TELL HELLO BOARD>>
+		       <DEQUEUE I-GRUES-NOTICE>
+		       <I-GRUES-NOTICE T>
+		       <RTRUE>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT <EQUAL? ,CHANGED? ,GRUE>>
+		       <COND (<NOT <EQUAL? ,OHERE ,DARK-CAVE>>
+			      <QUEUE I-GRUES-NOTICE 1>
+			      <RFALSE>)>
+		       <QUEUE I-GRUES-NOTICE 2>
+		       <COND (<NOT ,LIT>
+			      <TELL
+"You stumble blindly down a short passage which opens into what feels like
+a larger area." CR CR>)
+			     (<NOT <EQUAL? ,LIT ,GRUE>>
+			      <TELL
+"You make your way carefully in the almost non-existent light down to an
+area filled with dim shapes. They move about purposefully, making horrible
+gurgling noises. The floor is rough and jumbled near the walls, so you
+haven't been noticed yet." CR CR>)>)>)>>
+
+<ROOM LIGHT-POOL
+      (IN ROOMS)
+      (DESC "Light Pool")
+      (OUT TO GRUE-CAVE)
+      (UP TO GRUE-CAVE)
+      (ACTION LIGHT-POOL-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL PILLAR GRUE GLOBAL-CAVE)
+      (THINGS <PSEUDO (LIGHT POOL POOL-PSEUDO)>)>
+
+<ROUTINE LIGHT-POOL-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a small pool or pond of light, very dim by human standards, but
+painful for a grue to even look at. In the center of the pool is a pillar
+which sticks up out of the light." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? DISEMBARK>
+			    <EQUAL? ,PRSO <> ,ROOMS ,PSEUDO-OBJECT>>
+		       <DO-WALK ,P?OUT>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<QUEUE I-FRIED-GRUE 2>
+		<TELL
+"You enter the pool, which is composed of the accumulated dribbles of light
+that have made their way to this uttermost bottom of a dark dimension. The
+light tickles">
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <TELL " at first, but then it begins to burn and your eyes are
+hurting severely">)>
+		<TELL ,PERIOD CR>)>>
+
+<ROOM PILLAR-ROOM
+      (IN ROOMS)
+      (DESC "On Pillar")
+      (DOWN TO LIGHT-POOL)
+      (ACTION PILLAR-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL PILLAR GRUE GLOBAL-CAVE)
+      (THINGS <PSEUDO (LIGHT POOL POOL-PSEUDO)>)>
+
+<ROUTINE PILLAR-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are on top of a short marble pillar surrounded by a pool of ">
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <TELL
+"light. Squinting through the intolerable glare, you can see
+that the other grues are staring at you with a mixture of amazement and
+fear." CR>)
+		      (ELSE
+		       <TELL
+"almost imperceptible light. You can barely see dim shapes capering in
+the dark." CR>)>)>>
+
+<OBJECT PILLAR
+	(IN LOCAL-GLOBALS)
+	(DESC "pillar")
+	(SYNONYM PILLAR GLYPHS)
+	(ADJECTIVE MARBLE SHORT ERODED)
+	(FLAGS NDESCBIT SURFACEBIT READBIT)
+	(ACTION PILLAR-F)
+	(TEXT "The only readable ones say \"D.L. 1985.\"")>
+
+<ROUTINE PILLAR-F ("AUX" (IGNORE? <>))
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL
+"This is a short, squat marble pillar covered with eroded glyphs. It
+barely projects out of the pool of light. The grues seem awed by it.">
+		<COND (<AND <IN? ,FIRE-CUBE ,PILLAR-ROOM>
+			    <NOT <EQUAL? ,HERE ,PILLAR-ROOM>>>
+		       <SET IGNORE? ,FIRE-CUBE>
+		       <TELL
+" There is something small and white on the pillar.">)>
+		<CLEVER-CONTENTS ,PILLAR-ROOM
+				 " On top of the pillar"
+				 .IGNORE?>
+		<CRLF>)
+	       (<THROW-ONTO ,PILLAR ,PILLAR-ROOM>
+		<RTRUE>)
+	       (<VERB? CLIMB-ON CLIMB-FOO BOARD>
+		<COND (<EQUAL? ,HERE ,GRUE-CAVE>
+		       <TELL
+"It's in the pool, out of reach from here." CR>)
+		      (<EQUAL? ,HERE ,LIGHT-POOL>
+		       <GOTO ,PILLAR-ROOM>)
+		      (<EQUAL? ,HERE ,PILLAR-ROOM>
+		       <TELL
+"It doesn't go any higher, and you're on it already." CR>)>)
+	       (<VERB? DISEMBARK CLIMB-DOWN>
+		<COND (<EQUAL? ,HERE ,LIGHT-POOL ,GRUE-CAVE>
+		       <TELL
+,YOU-ARENT "on it yet." CR>)
+		      (<EQUAL? ,HERE ,PILLAR-ROOM>
+		       <GOTO ,LIGHT-POOL>)>)>>
+
+"MIND"
+
+<OBJECT MIND-CUBE
+	(IN MAZE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE FQ ;C6 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "owls")
+	(FLAGS TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE MIND-ROOM)>
+
+<ROOM MIND-ROOM
+      (IN ROOMS)
+      (DESC "No Place")
+      (EAST PER SCALES-ROOM-EXIT)
+      (SOUTH PER PLAIN-ROOM-EXIT)
+      (WEST PER MIND-BOX-EXIT)
+      (CUBE MIND-CUBE)
+      (ACTION MIND-ROOM-F)
+      (FLAGS RLANDBIT)>
+
+<ROUTINE SCALES-ROOM-EXIT ()
+	 <TELL
+"You slowly drift \"eastward,\" and the nothing attenuates. Something
+begins to break through the nothing." CR CR>
+	 ,INNER-VAULT>
+
+<ROUTINE PLAIN-ROOM-EXIT ()
+	 <TELL
+"Your mind starts to wander \"southward,\" and slowly something impinges
+itself on your mind." CR CR>
+	 ,PLAIN-ROOM>
+
+<ROUTINE MIND-BOX-EXIT ()
+	 <COND (<AND <IN? <LOC ,MAGIC-BOX> ,ROOMS>
+		     <EQUAL? <GETP ,HERE ,P?CUBE> ,MAGIC-BOX-CUBE>>
+		<TELL
+"Your mind drifts \"westward,\" and slowly something surrounds your mind."
+CR CR>
+		<LOC ,MAGIC-BOX>)
+	       (ELSE
+		<TELL
+"Oddly, although your mind is drawn in that direction, no act of will
+helps in going that way." CR>
+		<RFALSE>)>>
+
+<ROUTINE MIND-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+,THERE-IS-NOTHING "here. You are here, but there is no here where you are.
+You see nothing. Your senses are vainly trying to find something, anything
+to work on. You can know your body is there, but you can't truly sense it
+to confirm the suspicion. Your mind is alternately drawn in three
+\"directions\"
+(or at least what seem like directions): east, west and south. There is something
+slightly different about the nothing in those directions." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM INNER-VAULT
+      (IN ROOMS)
+      (DESC "Inner Vault")
+      (OUT TO SCALES-ROOM IF VAULT-DOOR IS OPEN)
+      (NORTH TO SCALES-ROOM IF VAULT-DOOR IS OPEN)
+      (FLAGS RLANDBIT)
+      (ACTION INNER-VAULT-F)
+      (GLOBAL VAULT-DOOR)
+      (THINGS <PSEUDO (<> COINS FAKE-PSEUDO)
+		      (RARE PAINTINGS FAKE-PSEUDO)
+		      (STACKS PAINTINGS FAKE-PSEUDO)
+		      (ORNAMENTED GLASSWARE FAKE-PSEUDO)>)>
+
+<ROUTINE FAKE-PSEUDO ()
+	 <REDIRECT ,PSEUDO-OBJECT ,TREASURE>>
+
+<ROUTINE INNER-VAULT-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a bare concrete chamber that looks like the inside of a vault.">
+		<COND (<IN? ,TREASURE ,HERE>
+		       <TELL
+" The room is filled with unimaginable treasure. Gold and jewels are
+strewn everywhere. Coffers burst with coins, and stacks of rare
+paintings lean against the walls. Beautifully ornamented vases and
+glassware are carelessly stacked in corners.">)>
+		<TELL " There is a door on the
+north side of the room whose lock mechanism is visible. ">
+		<DESCRIBE-VAULT-DOOR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<MAKE-JUNK>)>>
+
+<OBJECT VAULT-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "vault door")
+	(SYNONYM DOOR MECHANISM)
+	(ADJECTIVE STEEL VAULT)
+	(FLAGS DOORBIT)
+	(ACTION VAULT-DOOR-F)>
+
+<ROUTINE VAULT-DOOR-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a steel door. It is thick and heavy, like the door
+to a bank vault. ">
+		<COND (<EQUAL? ,HERE ,INNER-VAULT>
+		       <TELL
+"It is covered with complicated mechanisms which
+look like they are part of a timing or locking device. ">)>
+		<DESCRIBE-VAULT-DOOR>)
+	       (<AND <VERB? OPEN UNLOCK>
+		     <NOT <FSET? ,PRSO ,OPENBIT>>>
+		<TELL "You can see no way to open "> <THE-PRSO>)
+	       (<VERB? THROUGH>
+		<DO-WALK <COND (<EQUAL? ,HERE ,SCALES-ROOM> ,P?SOUTH)
+			       (ELSE ,P?NORTH)>>)
+	       (<VERB? REZROV>
+		<COND (<FSET? ,VAULT-DOOR ,OPENBIT>
+		       <TELL-OPEN-CLOSED ,VAULT-DOOR>)
+		      (<HELD? ,MAGIC-CUBE>
+		       <FCLEAR ,VAULT-DOOR ,LOCKED>
+		       <FSET ,VAULT-DOOR ,OPENBIT>
+		       <COND (<EQUAL? ,HERE ,INNER-VAULT>
+			      <TELL
+"The mechanisms whirr madly">)
+			     (ELSE
+			      <TELL
+"You hear strange noises">)>
+		       <TELL " for a few moments, and then the door swings
+ponderously open." CR>)
+		      (ELSE
+		       <REZROV-TOUGH-DOOR>)>)>>
+
+<ROUTINE REZROV-TOUGH-DOOR ()
+	 <COND (<EQUAL? ,HERE ,INNER-VAULT>
+		<TELL
+"The mechanisms try vainly to turn,">)
+	       (ELSE
+		<TELL
+"The door strains and creaks,">)>
+	 <TELL " but your spell is just not powerful enough." CR>>
+
+<ROUTINE DESCRIBE-VAULT-DOOR ()
+	 <TELL "The door is ">
+	 <COND (<FSET? ,VAULT-DOOR ,OPENBIT>
+		<TELL
+"open, and beyond you can see ">
+		<COND (<EQUAL? ,HERE ,SCALES-ROOM>
+		       <TELL "a treasure chamber">)
+		      (ELSE
+		       <TELL "the outer vault">)>)
+	       (ELSE
+		<TELL
+"closed and locked">)>
+	 <TELL ,PERIOD>>
+
+<ROOM SCALES-ROOM
+      (IN ROOMS)
+      (DESC "Outer Vault")
+      (OUT PER IRON-DOOR-EXIT)
+      (NORTH PER IRON-DOOR-EXIT)
+      (SOUTH TO INNER-VAULT IF VAULT-DOOR IS OPEN)
+      (FLAGS RLANDBIT)
+      (ACTION SCALES-ROOM-F)
+      (GLOBAL IRON-DOOR VAULT-DOOR)
+      (THINGS <PSEUDO (BURLY GUARDS CASTLE-GUARDS-PSEUDO)>)>
+
+<ROUTINE CASTLE-GUARDS-PSEUDO ()
+	 <COND (<OR <AND <EQUAL? ,HERE ,SCALES-ROOM ,INNER-VAULT>
+			 <ZERO? ,GUARDS-FLAG>>
+		    <AND <EQUAL? ,HERE ,PAST-CELL-EAST>
+			 <NOT <FSET? ,CELL-DOOR ,OPENBIT>>>>
+		<TELL "What guards?" CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The guards are no doubt burly, thuggish and nasty." CR>)
+	       (<SPELL-VERB?>
+		<TELL
+"\"A wise guy, eh?\" The guards burst in and dispatch you before you
+can finish the spell." CR CR>
+		<TIME-SICK-CELL-EAST>)>>
+
+<ROUTINE IRON-DOOR-EXIT ()
+	 <COND (<FSET? ,IRON-DOOR ,OPENBIT>
+		<TELL
+"You poke your head out the door. ">
+		<COND (<EQUAL? ,GUARDS-FLAG 1>
+		       <TELL
+"You see, directly in front of you, five burly guards who look like they
+want to discuss something with you." CR>)
+		      (ELSE
+		       <TELL
+"You see a long, gloomy corridor down which
+five burly guards are coming." CR>)>)
+	       (ELSE
+		<THIS-IS-IT ,IRON-DOOR>
+		<TELL-OPEN-CLOSED ,IRON-DOOR>)>
+	 <RFALSE>>
+
+<OBJECT IRON-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "iron door")
+	(SYNONYM DOOR)
+	(ADJECTIVE IRON NORTH N)
+	(FLAGS DOORBIT LOCKED)
+	(ACTION IRON-DOOR-F)>
+
+<ROUTINE IRON-DOOR-F ()
+	 <COND (<AND <VERB? UNLOCK OPEN>
+		     <NOT <FSET? ,IRON-DOOR ,OPENBIT>>>
+		<TELL
+"The lock is beyond your ability to unlock or pick." CR>)
+	       (<VERB? THROUGH>
+		<DO-WALK ,P?NORTH>)>>
+
+<GLOBAL SPELLS-USED 0>
+
+<ROUTINE SCALES-ROOM-F (RARG "AUX" P1 P2)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are in a large, bare concrete room.">
+		<COND (<AND <FIRST? ,PILE-1> <FIRST? ,PILE-2>>
+		       <TELL
+" There are two piles on the floor. The first contains ">
+		       <PILE-LOOP ,PILE-1>
+		       <TELL ". The second contains ">
+		       <PILE-LOOP ,PILE-2>
+		       <TELL ".">)
+		      (<FIRST? ,PILE-1>
+		       <TELL-PILE ,PILE-1 ,PILE-2>)
+		      (<FIRST? ,PILE-2>
+		       <TELL-PILE ,PILE-2 ,PILE-1>)>
+		<TELL
+" An exit is to the north. It is ">
+		<COND (<FSET? ,IRON-DOOR ,OPENBIT>
+		       <TELL "an open">)
+		      (ELSE
+		       <TELL "a closed">)>
+		<TELL " iron door. To the south is the inner vault. Its
+steel door is ">
+		<COND (<FSET? ,IRON-DOOR ,OPENBIT>
+		       <TELL "open">)
+		      (ELSE
+		       <TELL "closed">)>
+		<COND (<IN? ,ALARM-FAIRY ,HERE>
+		       <TELL
+". An agitated alarm fairy flits about near the ceiling">)>
+		<TELL ,PERIOD>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? SAVE>
+		       <TELL "That spell doesn't work here." CR>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<EQUAL? ,OHERE ,INNER-VAULT>
+		       <COND (<HELD? ,TREASURE>
+			      <USE-SPELL>)>
+		       <FCLEAR ,VAULT-DOOR ,OPENBIT>
+		       <TELL
+"As you enter the outer vault, the vault door swings inexorably shut." CR CR>)>
+		<COND (,TREASURY-GUARDED?
+		       <JIGS-UP
+"A group of burly guards has been stationed permanently in the treasury
+now. They are surprised but happy to see you, dedicated professionals
+that they are.">)
+		      (ELSE
+		       <JUGGLE-CUBES>
+		       <SETG USED-JINDAK? <>>
+		       <COND (<PROB 50>
+			      <SETG REAL-VALUE 3>
+			      <SETG FAKE-VALUE 2>)
+			     (ELSE
+			      <SETG REAL-VALUE 2>
+			      <SETG FAKE-VALUE 3>)>)>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<CUBES-TO-PILES>
+		<COND (,TIME-CUBE-SCORE?
+		       <SETG TREASURY-GUARDED? T>)>
+		<MAKE-JUNK>)>>
+
+<GLOBAL FAKE-CUBE-LIST
+	<LTABLE 0
+		CUBE-1 CUBE-2 CUBE-3 CUBE-4 CUBE-5 CUBE-6
+		CUBE-7 CUBE-8 CUBE-9 CUBE-10 CUBE-11 TIME-CUBE>>
+
+<ROUTINE INITIALIZE-CUBES ("AUX" (CNT 1) L BUF)
+	 <SET L ,FAKE-CUBE-LIST>
+	 <SET BUF ,P-QBUF>
+	 <REPEAT ()
+		 <COND (<IGRTR? CNT 13> <RETURN>)>
+		 <PUTP <GET .L .CNT> ,P?NAME .BUF>
+		 <SET BUF <REST .BUF 10>>>
+	 <PUT .BUF 0 0>
+	 <SETG P-QNEXT .BUF>>
+
+<ROUTINE CUBES-TO-PILES ("AUX" (CNT 1) L)
+	 <SET L ,FAKE-CUBE-LIST>
+	 <REPEAT ()
+		 <COND (<IGRTR? CNT 13> <RETURN>)>
+		 <MOVE <GET .L .CNT> ,PILE-1>>
+	 <COND (<EQUAL? ,TIME-CUBE ,BLORPLE-OBJECT>
+		<REMOVE ,TIME-CUBE>
+		<COND (<NOT ,TIME-CUBE-SCORE?>
+		       <SETG TIME-CUBE-SCORE? T>
+		       <FCLEAR ,TIME-CUBE ,TOUCHBIT>
+		       <SCORE-OBJECT ,TIME-CUBE>)>)>
+	 <COND (<AND ,BLORPLE-OBJECT
+		     <LOC ,BLORPLE-OBJECT>>
+		<SETG BLORPLE-OBJECT <>>)>>
+
+<GLOBAL TIME-CUBE-SCORE? <>>
+
+<ROUTINE JUGGLE-CUBES ("AUX" (CNT 1) BUF (P1 0) (P2 0) Q)
+	 <ROB ,PILE-1 ,SCALES-ROOM>
+	 <ROB ,PILE-2 ,SCALES-ROOM>
+	 <REPEAT ()
+		 <COND (<IGRTR? CNT 13> <RETURN>)>
+		 <SET Q <PICK-ONE ,FAKE-CUBE-LIST>>
+		 <FSET .Q ,NDESCBIT>
+		 <COND (<OR <EQUAL? .P2 6>
+			    <AND <L? .P1 6> <PROB 50>>>
+			<SET P1 <+ .P1 1>>
+			<MOVE .Q ,PILE-1>)
+		       (ELSE
+			<MOVE .Q ,PILE-2>
+			<SET P2 <+ .P2 1>>)>>
+	 <SET BUF ,P-QBUF>
+	 <SET Q <FIRST? ,PILE-1>>
+	 <REPEAT ()
+		 <COND (<NOT .Q> <RETURN>)>
+		 <PUTP .Q ,P?NAME .BUF>
+		 <PUT .BUF 0 <CUBE-ADJ .Q>>
+		 <SET BUF <REST .BUF 10>>
+		 <SET Q <NEXT? .Q>>>
+	 <SET Q <FIRST? ,PILE-2>>
+	 <REPEAT ()
+		 <COND (<NOT .Q> <RETURN>)>
+		 <PUTP .Q ,P?NAME .BUF>
+		 <PUT .BUF 0 <CUBE-ADJ .Q>>
+		 <SET BUF <REST .BUF 10>>
+		 <SET Q <NEXT? .Q>>>>
+
+<ROUTINE TELL-PILE (PILE OTHER)
+	 <TELL
+" There is a pile of things on the floor, containing ">
+	 <PILE-LOOP .PILE>
+	 <TELL
+". There is an empty spot where " THE .OTHER " was.">>
+
+<OBJECT TREASURE
+	(IN INNER-VAULT)
+	(SYNONYM TREASURE GOLD JEWELS VASES)
+	(ADJECTIVE RICH ORNAMENTED)
+	(DESC "treasure")
+	(FLAGS TAKEBIT TRYTAKEBIT NDESCBIT)
+	(ACTION TREASURE-F)>
+
+<ROUTINE TREASURE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"On closer examination, the treasure is even richer than you thought." CR>)
+	       (<VERB? DROP>
+		<COND (<EQUAL? ,HERE ,INNER-VAULT>
+		       <FSET ,TREASURE ,NDESCBIT>)>
+		<RFALSE>)>>
+
+<ROUTINE MAKE-JUNK ()
+	 <COND (<VERB? BLORPLE>
+		<FCLEAR ,VAULT-DOOR ,OPENBIT>
+		<COND (<HELD? ,TREASURE>
+		       <MOVE ,JUNK <LOC ,TREASURE>>
+		       <FSET ,TREASURE ,NDESCBIT>
+		       <MOVE ,TREASURE ,INNER-VAULT>)>)>>
+
+<OBJECT JUNK
+	(SYNONYM JUNK PASTE GILT LEAD)
+	(ADJECTIVE PILE)
+	(DESC "pile of junk")
+	(FLAGS TAKEBIT TRYTAKEBIT)
+	(ACTION JUNK-F)>
+
+<ROUTINE JUNK-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The treasure consists of paste jewels, badly crafted gilt vessels and
+lead coins." CR>)
+	       (<AND <VERB? DROP>
+		     <EQUAL? ,HERE ,INNER-VAULT>>
+		<COND (<IDROP>
+		       <REMOVE ,JUNK>
+		       <MOVE ,TREASURE ,HERE>
+		       <TELL "The junk looks valuable again." CR>)
+		      (ELSE <RTRUE>)>)>>
+
+<GLOBAL IS-GLOWING " is glowing with a faint blue glow.">
+
+<ROUTINE MEASURE (OBJ "AUX" (F <FIRST? .OBJ>) (CNT 0))
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN .CNT>)
+		       (<GETP .F ,P?CUBE> ;"REAL CUBE"
+			<SET CNT <+ .CNT ,REAL-VALUE>>)
+		       (<GETPT .F ,P?NAME> ;"FAKE CUBE"
+			<SET CNT <+ .CNT ,FAKE-VALUE>>)
+		       (<OR <FSET? .F ,MAGICBIT>
+			    <FSET? .F ,SCROLLBIT>>
+			<SET CNT <+ .CNT 1>>)>
+		 <SET F <NEXT? .F>>>>
+
+<GLOBAL REAL-VALUE 3>
+<GLOBAL FAKE-VALUE 2>
+
+<OBJECT ALARM-FAIRY
+	(DESC "alarm fairy")
+	(SYNONYM FAIRY)
+	(ADJECTIVE ALARM)
+	(FLAGS THE PERSON NDESCBIT AN)
+	(ACTION ALARM-FAIRY-F)>
+
+<ROUTINE ALARM-FAIRY-F ()
+	 <COND (<EQUAL? ,WINNER ,ALARM-FAIRY>
+		<TELL
+"\"Go away, thief! Just wait 'til the guards come! You'll be sorry!\"" CR>)
+	       (<VERB? EXAMINE KISS>
+		<TELL
+"The alarm fairy is small, winged and very obnoxious. It flies near the
+ceiling, out of reach, and jeers at you." CR>)
+	       (<VERB? ESPNIS>
+		<TELL
+"It thumbs its nose at you. \"I never sleep!\" it jeers." CR>)
+	       (<VERB? YOMIN>
+		<TELL
+"You sense a mixture of spitefulness and pleasurable anticipation." CR>)
+	       (<VERB? SNAVIG>
+		<TELL
+"It's too small." CR>)
+	       (<HOSTILE-VERB?>
+		<TELL
+"\"Missed me! Missed me! Now you have to kiss me!\" It plants a smooch
+on your cheek." CR>)>>
+
+<GLOBAL GUARDS-FLAG 0>
+<GLOBAL TREASURY-GUARDED? <>>
+
+<OBJECT PILE-1
+	(IN SCALES-ROOM)
+	(DESC "first pile")
+	(SYNONYM PILE PILES)
+	(ADJECTIVE FIRST)
+	(FLAGS NDESCBIT OPENBIT TRANSBIT CONTBIT SEARCHBIT)
+	(CAPACITY 200)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION PILE-F)>
+
+<OBJECT PILE-2
+	(IN SCALES-ROOM)
+	(DESC "second pile")
+	(SYNONYM PILE PILES)
+	(ADJECTIVE SECOND)
+	(FLAGS NDESCBIT OPENBIT TRANSBIT CONTBIT SEARCHBIT)
+	(CAPACITY 200)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION PILE-F)>
+
+<GLOBAL WHITE-CUBE "featureless white cube">
+
+<ROUTINE PILE-LOOP (OBJ "AUX" (F <FIRST? .OBJ>) (1ST? T) (CNT 0) N CUBE?)
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<COND (<G? .CNT 0>
+			       <COND (<NOT .1ST?>
+				      <TELL " and ">)>
+			       <TELL N .CNT " " ,WHITE-CUBE>
+			       <COND (<G? .CNT 1> <TELL "s">)>)>
+			<RETURN>)>
+		 <SET N <NEXT? .F>>
+		 <SET CUBE? <GETPT .F ,P?NAME>>
+		 <COND (<OR <NOT .CUBE?> ;"not a cube?"
+			    <NOT <ZERO? <GETP .F ,P?NAME>>>>
+			<COND (<NOT .1ST?>
+			       <COND (<AND <NOT .N> <ZERO? .CNT>>
+				      <TELL " and ">)
+				     (ELSE <TELL ", ">)>)
+			      (T <SET 1ST? <>>)>
+			<COND (<NOT <GETPT .F ,P?NAME>>
+			       <TELL A .F>)
+			      (ELSE
+			       <TELL THE .F>)>)
+		       (ELSE <SET CNT <+ .CNT 1>>)>
+		 <SET F .N>>>
+
+<ROUTINE PILE-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<FIRST? ,PRSO>
+		       <TELL
+"The pile contains ">
+		       <PILE-LOOP ,PRSO>)
+		      (ELSE
+		       <TELL "Its spot is empty">)>
+		<TELL ,PERIOD>)
+	       (<AND <VERB? COUNT>
+		     <NOT <ZERO? <GETPT ,PRSO ,P?NAME>>>
+		     <EQUAL? ,PRSI ,PILE-1 ,PILE-2>>
+		<TELL CTHE ,PRSI " holds ">
+		<TELL-CUBE-COUNT ,PRSI>)
+	       (<VERB? CUT>
+		<TELL
+,MORE-SPECIFIC " about individual items to take, drop,
+etc." CR>)
+	       (<VERB? PUT>
+		<COND (<EQUAL? ,PRSI ,PILE-1 ,PILE-2>
+		       <COND (<AND <NOT <HELD? ,PRSO>>
+				   <EQUAL? <ITAKE> ,M-FATAL <>>>
+			      <RTRUE>)
+			     (ELSE
+			      <MOVE ,PRSO ,PRSI>
+			      <FSET ,PRSO ,TOUCHBIT>
+			      <FSET ,PRSO ,NDESCBIT>
+			      <TELL "Done." CR>)>)>)
+	       (<VERB? PUT-ON>
+		<PERFORM ,V?PUT ,PRSO ,PRSI>
+		<RTRUE>)>>
+
+<OBJECT CUBE-1
+	(IN PILE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE AZ ;F1 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-2
+	(IN PILE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE BZ ;F2 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-3
+	(IN PILE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE CZ ;F3 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-4
+	(IN PILE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE DZ ;F4 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-5
+	(IN PILE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE EZ ;F5 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-6
+	(IN PILE-1)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE FZ ;F6 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-7
+	(IN PILE-2)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE GZ ;F7 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-8
+	(IN PILE-2)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE HZ ;F8 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-9
+	(IN PILE-2)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE IZ ;F9 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-10
+	(IN PILE-2)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE JZ ;F10 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<OBJECT CUBE-11
+	(IN PILE-2)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE KZ ;F11 SMALL WHITE)
+	(NAME 0)
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(ACTION CUBE-F)>
+
+<ROUTINE CUBE-DESC (RARG OBJ)
+	 <TELL
+"A white cube">
+	 <COND (<NOT <ZERO? <GETP .OBJ ,P?NAME>>>
+		<TELL " labelled ">
+		<CUBE-NAME .OBJ>)>
+	 <TELL " is here." CR>>
+
+<ROUTINE CUBE-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<NOT <ZERO? <GETP ,PRSO ,P?NAME>>>
+		       <TELL
+"This is a white cube with the word "> <CUBE-NAME ,PRSO> <TELL " written
+on it." CR>)
+		      (ELSE
+		       <TELL
+"This is a " ,WHITE-CUBE ,PERIOD>)>)
+	       (<AND <VERB? COMPARE>
+		     <NOT <EQUAL? ,PRSO ,PRSI>>
+		     <GETPT ,PRSO ,P?NAME>
+		     <GETPT ,PRSI ,P?NAME>>
+		<TELL
+"Structurally, they are identical.">
+		<COND (<GETP ,PRSO ,P?NAME>
+		       <TELL " One has ">
+		       <CUBE-NAME ,PRSO>
+		       <TELL " written on it.">)>
+		<COND (<GETP ,PRSI ,P?NAME>
+		       <TELL " One has ">
+		       <CUBE-NAME ,PRSI>
+		       <TELL " written on it.">)>
+		<CRLF>)
+	       (<VERB? WRITE>
+		<COND (<EQUAL? ,PRSO ,QWORD>
+		       <COND (<AND ,PRSI <NOT <HELD? ,PRSI>>>
+			      <TELL
+"You must have " THE ,PRSI " to write on it." CR>)
+			     (<KNOWN-NAME? ,P-QWORD>
+			      <TELL
+"Strangely, your efforts leave " THE ,PRSI " unchanged." CR>)
+			     (<NOT <ZERO? <GETP ,PRSI ,P?NAME>>>
+			      <TELL "You replace the word ">
+			      <CUBE-NAME ,PRSI>
+			      <TELL " with the word ">
+			      <WRITE-ON-CUBE ,PRSI>
+			      <CUBE-NAME ,PRSI>
+			      <TELL ,PERIOD>)
+			     (<WRITE-ON-CUBE ,PRSI>
+			      <TELL "The word ">
+			      <CUBE-NAME ,PRSI>
+			      <TELL " is now written on the cube." CR>)
+			     (ELSE
+			      <YOU-CANT-X-THAT "write on">)>)
+		      (<AND ,PRSI <GETPT ,PRSI ,P?NAME>>
+		       <COND (<FSET? ,PRSO ,READBIT>
+			      <TELL
+"Strangely, you cannot duplicate the pattern." CR>)
+			     (ELSE
+			      <YOU-CANT-X-PRSI "write that on">)>)>)
+	       (<VERB? TAKE>
+		<COND (<EQUAL? ,PRSI ,PILE-1 ,PILE-2>
+		       <FCLEAR ,PRSO ,NDESCBIT>)>
+		<RFALSE>)
+	       (<VERB? COUNT>
+		<TELL "You have ">
+		<TELL-CUBE-COUNT ,WINNER>)>>
+
+<ROUTINE TELL-CUBE-COUNT (OBJ "AUX" CNT)
+	 <SET CNT <CUBE-COUNT .OBJ>>
+	 <COND (<ZERO? .CNT>
+		<TELL "no">)
+	       (ELSE <TELL N .CNT>)>
+	 <TELL " cube">
+	 <COND (<NOT <EQUAL? .CNT 1>>
+		<TELL "s">)>
+	 <TELL "." CR>>
+
+<ROUTINE CUBE-COUNT (OBJ "AUX" (CNT 0) (CONT <FIRST? .OBJ>))
+	 <REPEAT ()
+		 <COND (<NOT .CONT> <RETURN>)
+		       (<NOT <ZERO? <GETPT .CONT ,P?NAME>>>
+			<SET CNT <+ .CNT 1>>)
+		       (<FIRST? .CONT>
+			<SET CNT <+ .CNT <CUBE-COUNT .CONT>>>)>
+		 <SET CONT <NEXT? .CONT>>>
+	 .CNT>
diff --git a/c4.zil b/c4.zil
new file mode 100644
index 0000000..b75b3b0
--- /dev/null
+++ b/c4.zil
@@ -0,0 +1,1839 @@
+"C4 for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+"ROCK CHASING"
+
+<ROOM PLAIN-ROOM
+      (IN ROOMS)
+      (DESC "Plain")
+      (ACTION PLAIN-ROOM-F)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL LINES)
+      (THINGS
+       <PSEUDO (FEATURELESS PLAIN PLAIN-PSEUDO)
+	       (DISTANT MOUNTAIN MOUNTAIN-PSEUDO)>)>
+
+<ROUTINE MOUNTAIN-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The mountains are tall and volcanic." CR>)
+	       (<VERB? CLIMB-FOO CLIMB-UP>
+		<DO-WALK ,P?UP>)
+	       (<VERB? CLIMB-DOWN>
+		<DO-WALK ,P?DOWN>)>>
+
+<ROUTINE PLAIN-PSEUDO ()
+	 <REDIRECT ,PSEUDO-OBJECT ,GROUND>>
+
+<ROUTINE PLAIN-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a flat plain punctuated by boulders. The boulders
+are all identical and slide to and fro on the eerie surface,
+propelled by an unknown mechanism. The ground is scratched by many
+intersecting lines which seem to have a regular pattern. ">
+		<DESCRIBE-PLAIN>
+		<TELL " Far in the
+distance are mountains which quiver itchily as they belch forth purple
+fire." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<SETG ROCK-MOVED? <>>
+		<COND (<AND <EQUAL? ,WINNER ,PLAYER> <VERB? WALK>>
+		       <COND (<IN? ,PLAYER ,HERE>
+			      <TELL
+"You find that the surface is too smooth. Your feet
+slip out from under you, and you crash to the ground." CR>)
+			     (<EQUAL? ,P-WALK-DIR ,P?DOWN>
+			      <PERFORM ,V?DISEMBARK>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+,YOU-HAVE-TO " get down off the rock if you want to walk." CR>)>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<SETG ROCK-LOC 5>
+		<SETG YOU-LOC 5>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<SETG ROCK-BRIBED? <>>
+		<DEQUEUE I-OTHER-ROCK>)>>
+
+<ROUTINE PLAIN-SPELL-FAIL ()
+	 <COND (<VERB? BLORPLE> <RFALSE>)>
+	 <TELL
+"A bright purple ball of light issues from your fingers and collapses
+like a deflated balloon on the ground.">
+	 <COND (<NOT <IN? ,PLAYER ,OTHER-ROCK>>
+		<SETG ROCK-TALKED? T>
+		<TELL
+" \"Great effect!\" says the " 'ROCK ". \"That's better than most of you soft
+ones can do here.\"">)>
+	 <CRLF>>
+
+<GLOBAL ROCK-MOVED? <>>
+
+<GLOBAL YOU-LOC 5>
+<GLOBAL ROCK-LOC 5>
+<GLOBAL OTHER-ROCK-LOC 7>
+
+<ROUTINE DESCRIBE-PLAIN ("OPTIONAL" (ROCKS? T))
+	 <COND (<HELD? ,PLAYER ,ROCK>
+		<TELL "You are on a large, green eyed rock. ">)>
+	 <TELL
+"From where you are " <COND (<OR <HELD? ,PLAYER ,ROCK>
+				 <HELD? ,PLAYER ,OTHER-ROCK>>
+			     "perched")
+			    (T "standing")>
+" you can see lines radiating ">
+	 <TELL-WALLS <GETB ,PLAIN-WALLS ,YOU-LOC>>
+	 <TELL ".">
+	 <COND (<NOT .ROCKS?> <RTRUE>)>
+	 <COND (<OR <NOT <EQUAL? ,YOU-LOC ,ROCK-LOC>>
+		    <NOT <IN? ,PLAYER ,ROCK>>>
+		<TELL " There is a large green eyed rock">
+		<COND (<NOT <IN? ,PLAYER ,ROCK>>
+		       <TELL " here">)
+		      (ELSE 
+		       <ROCK-DIRECTION ,ROCK-LOC>)>
+		<TELL ".">)>
+	 <COND (<NOT <IN? ,PLAYER ,OTHER-ROCK>>
+		<TELL " Also, there is a large brown eyed rock ">
+		<COND (<IN? ,DARK-CUBE ,OTHER-ROCK>
+		       <TELL "with a " ,WHITE-CUBE " on its back ">)>
+		<COND (<EQUAL? ,YOU-LOC ,OTHER-ROCK-LOC>
+		       <TELL "here">)
+		      (ELSE
+		       <ROCK-DIRECTION ,OTHER-ROCK-LOC>)>
+		<TELL ".">)>>
+
+<GLOBAL PLAIN-WALLS
+	<TABLE #BYTE 0
+	       #BYTE %<+ 2 8 128>	;"1 -- E, S, SW"
+	       #BYTE %<+ 2 4 8>		;"2 -- E, W, S"
+	       #BYTE %<+ 4 8>		;"3 -- W, S"
+	       #BYTE %<+ 2 8 16>	;"4 -- E, S, NE"
+	       #BYTE %<+ 1 2 4 8>	;"5 -- N, E, W, S"
+	       #BYTE %<+ 1 2 4 8>	;"6 -- N, E, W, S"
+	       #BYTE %<+ 1 4 8>		;"7 -- N, W, S"
+	       #BYTE %<+ 1 2 8>		;"8 -- N, E, S"
+	       #BYTE %<+ 1 2 4 8>	;"9 -- N, E, W, S"
+	       #BYTE %<+ 1 2 4 8>	;"10 --N, E, W, S"
+	       #BYTE %<+ 1 4 8>		;"11 -- N, W, S"
+	       #BYTE %<+ 1 2>		;"12 -- N, E"
+	       #BYTE %<+ 1 2 4>		;"13 -- N, W, E"
+	       #BYTE %<+ 1 2 4>		;"14 -- N, W, E"
+	       #BYTE %<+ 1 4>		;"15 -- N, W">>
+
+<ROUTINE ROCK-DIRECTION (R "AUX" ROW COL RROW RCOL (DROW 0) (DCOL 0))
+	 <SET ROW </ ,YOU-LOC 4>>
+	 <SET COL <BAND ,YOU-LOC 3>>
+	 <SET RROW </ .R 4>>
+	 <SET RCOL <BAND .R 3>>
+	 <SET DROW
+	      <COND (<G? .RROW .ROW> <- .RROW .ROW>)
+		    (ELSE <- .ROW .RROW>)>>
+	 <SET DCOL
+	      <COND (<G? .RCOL .COL> <- .RCOL .COL>)
+		    (ELSE <- .COL .RCOL>)>>
+	 <COND (<AND <L? .DROW 2> <L? .DCOL 2>>
+		<TELL "nearby and off">)
+	       (<AND <L? .DROW 3> <L? .DCOL 3>>
+		<TELL "some distance">)
+	       (ELSE <TELL "quite a ways off">)>
+	 <TELL " to the ">
+	 <COND (<G? .RROW .ROW>
+		<COND (<G? .RCOL .COL> <TELL "southeast">)
+		      (<L? .RCOL .COL> <TELL "southwest">)
+		      (<EQUAL? .RCOL .COL> <TELL "south">)>)
+	       (<L? .RROW .ROW>
+		<COND (<G? .RCOL .COL> <TELL "northeast">)
+		      (<L? .RCOL .COL> <TELL "northwest">)
+		      (<EQUAL? .RCOL .COL> <TELL "north">)>)
+	       (ELSE
+		<COND (<G? .RCOL .COL> <TELL "east">)
+		      (ELSE <TELL "west">)>)>>
+
+<OBJECT LINES
+	(IN LOCAL-GLOBALS)
+	(DESC "lines")
+	(SYNONYM LINES SCRATCH LINE)
+	(ADJECTIVE REGULAR INTERSECTING)
+	(FLAGS NDESCBIT NOABIT)
+	(ACTION LINES-F)>
+
+<ROUTINE LINES-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"These lines appear to be discolorations in the surface, perhaps a different
+mineral permeating the rock. They form a usually rectangular grid.
+The boulders, as far as you can tell, always follow the lines. ">
+		<DESCRIBE-PLAIN <>>
+		<CRLF>)
+	       (<VERB? RUB>
+		<TELL
+"The lines aren't raised or lowered with respect to the plain. They are
+most likely just discolorations in the surface." CR>)>>
+
+<OBJECT ROCK
+	(IN PLAIN-ROOM)
+	(DESC "green eyed rock")
+	(SYNONYM ROCK BOULDER)
+	(ADJECTIVE GREEN EYED LARGE ;GREEN-EYED FLAT)
+	(FLAGS NDESCBIT THE PERSON VEHBIT CONTBIT OPENBIT TAKEBIT SURFACEBIT)
+	(GENERIC GENERIC-ROCK-F)
+	(SIZE 400)
+	(CAPACITY 200)
+	(CONTFCN ROCK-F)
+	(ACTION ROCK-F)>
+
+<ROUTINE ROCK-SPEECHES ()
+	 <COND (,ROCK-TALKED?
+		<COND (,ROCK-BRIBED?
+		       <TELL
+"\"That was pretty good food. A little light on the phosphorus for my taste,
+but some have been known to disagree.\" It snorts good-naturedly." CR>)
+		      (ELSE
+		       <TELL
+"\"You know, I could do with a little food. The paths are sort of bare this
+time of year; everyone's scraped them pretty thin. Yes, a little food would
+be nice. Something crunchy. Then you could watch me eat. I'm really at my
+best then.\"" CR>)>)
+	       (ELSE
+		<SETG ROCK-TALKED? T>
+		<TELL
+"The rock seems somewhat surprised to see you, and looks you over
+carefully before answering. ">
+		<COND (<NOT <VERB? HELLO>>
+		       <TELL "It doesn't pay much attention to you. ">)>
+		<TELL "\"Hello. You're certainly an odd-looking
+one, though not as odd as the last. It was
+as unprepossessing as you. Of course, I am the most handsome.\"" CR>)>>
+
+<GLOBAL ROCK-TALKED? <>>
+<GLOBAL ROCK-BRIBED? <>>
+<GLOBAL TRIED-BOARDING? <>>
+
+<ROUTINE ROCK-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? ,WINNER ,ROCK>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>) 	
+		      (<VERB? WALK WALK-TO>
+		       <COND (<AND <VERB? WALK> <HELD? ,PLAYER ,ROCK>>
+			      <ROCK-WALK ,P-WALK-DIR>)
+			     (,ROCK-BRIBED?
+			      <TELL
+"\"Do you want to ride along? ">
+			      <COND (,TRIED-BOARDING?
+				     <TELL
+"That's what you seemed to want. ">)>
+			      <TELL
+"Do you have any more food?\"" CR>)
+			     (ELSE
+			      <WHATS-IN-IT-FOR-ME?>)>)
+		      (<VERB? TELL-ME-ABOUT>
+		       <COND (<EQUAL? ,PRSO ,BREAD ,FISH>
+			      <TELL
+"\"Yummy food? Food is crunchy and nice. I like it with lots of
+phosphorus!\"" CR>)
+			     (<EQUAL? ,PRSO ,OTHER-ROCK>
+			      <TELL
+"\"It's not as pretty as me.\"" CR>)
+			     (ELSE
+			      <TELL
+"\"I don't know much about that.\"" CR>)>)
+		      (<VERB? EAT>
+		       <TELL "\"You have food?\"" CR>)
+		      (ELSE
+		       <ROCK-SPEECHES>)>
+		<SETG ROCK-TALKED? T>)
+	       (<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<NOT <HELD? ,PLAYER ,ROCK>>
+		       <CANT-REACH-THAT>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? DISEMBARK CLIMB-DOWN LEAP>
+			    <EQUAL? ,PRSO <> ,ROOMS ,ROCK>>
+		       <MOVE ,PLAYER ,HERE>
+		       <SETG ROCK-BRIBED? <>>
+		       <TELL
+"\"That was fun! I'm kind of tired from carrying you, though. Do you have
+any more food?\"" CR>)>)
+	       (<NOT .RARG>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"This is a rather large boulder with a flat bottom. Something
+prevents it from touching the ground, as it moves about quite nimbly,
+watching you with lovely green eyes.">
+		       <CLEVER-CONTENTS ,ROCK " On the rock">
+		       <CRLF>)
+		      (<VERB? ADMIRE>
+		       <SETG ROCK-TALKED? T>
+		       <TELL
+"\"You're very perceptive.\" The rock has no false modesty." CR>)
+		      (<VERB? MOVE PUSH>
+		       <SETG ROCK-TALKED? T>
+		       <TELL ,IT-TICKLES>)
+		      (<VERB? RUB>
+		       <SETG ROCK-TALKED? T>
+		       <TELL "\"Aren't I smooth?\" says the rock." CR>)
+		      (<AND <VERB? GIVE SHOW>
+			    <EQUAL? ,PRSI ,ROCK>>
+		       <SETG ROCK-TALKED? T>
+		       <COND (<EQUAL? ,PRSO ,BREAD ,FISH>
+			      <TELL
+"\"What's that? Dead animal or vegetable matter! You won't fool me!
+Horrible! It would ruin my complexion!\"" CR>)
+			     (<EQUAL? ,PRSO ,LAVA-ROCK>
+			      <COND (<VERB? GIVE>
+				     <REMOVE ,LAVA-ROCK>
+				     <SETG ROCK-BRIBED? T>
+				     <TELL
+"\"Mmm. That looks good. Just the right size, too.\" It slides happily over the
+piece of lava and settles comfortably to the ground. You hear a sound like
+a rasp for a while. The rock blinks contentedly and rises into the air
+again." CR>)
+				    (ELSE
+				     <TELL
+"\"Oh, yum! Give it to me, please!\"" CR>)>)
+			     (ELSE
+			      <TELL
+"\"That doesn't look very appetizing.\"" CR>)>)
+		      (<VERB? BOARD SIT CLIMB-ON CLIMB-FOO CLIMB-UP>
+		       <SETG ROCK-TALKED? T>
+		       <SETG TRIED-BOARDING? T>
+		       <COND (<IN? ,PLAYER ,ROCK>
+			      <TELL ,IT-TICKLES>)
+			     (,ROCK-BRIBED?
+			      <MOVE ,PLAYER ,ROCK>
+			      <TELL
+"You climb the rock and perch precariously on top. From here you can see that
+the long scratches in the ground form a rectangular grid that fills a
+rather small valley. \"My back is the most hemispheric of all my friends',\"
+remarks the rock." CR>)
+			     (ELSE
+			      <TELL
+"The rock spins in place, preventing you from getting on. ">
+			      <WHATS-IN-IT-FOR-ME?>)>)
+		      (<VERB? LOOK-UNDER>
+		       <SETG ROCK-TALKED? T>
+		       <TELL
+"The rock's underside is perfectly smooth. When you look under it, the
+rock says, \"Hey! What is this? What about my privacy?\"">
+		       <COND (,ROCK-BRIBED?
+			      <TELL
+" There is no sign of the lava.">)>
+		       <CRLF>)>)>>
+
+<ROUTINE WHATS-IN-IT-FOR-ME? ()
+	 <TELL
+"\"What's in it for me? For example, if you had some food, that might be
+nice. Then you could ride on top and admire me from that angle. It's a
+rare privilege.\"" CR>>
+
+<GLOBAL IT-TICKLES "The rock bobs in place. \"That tickles!\"|">
+
+<ROUTINE ROCK-WALK (DIR "AUX" ROW COL)
+	 <QUEUE I-OTHER-ROCK -1>
+	 <COND (<AND <EQUAL? ,ROCK-LOC 4> <EQUAL? .DIR ,P?NE>>
+		<SETG ROCK-LOC 1>)
+	       (<AND <EQUAL? ,ROCK-LOC 1> <EQUAL? .DIR ,P?SW>>
+		<SETG ROCK-LOC 4>)
+	       (ELSE
+		<SET ROW </ ,ROCK-LOC 4>>
+		<SET COL <BAND ,ROCK-LOC 3>>
+		<COND (<AND <EQUAL? .DIR ,P?NORTH>
+			    <OR <G? .ROW 1>
+				<AND <G? .ROW 0>
+				     <G? .COL 0>>>>
+		       <SET ROW <- .ROW 1>>)
+		      (<AND <EQUAL? .DIR ,P?SOUTH> <L? .ROW 3>>
+		       <SET ROW <+ .ROW 1>>)
+		      (<AND <EQUAL? .DIR ,P?EAST> <L? .COL 3>>
+		       <SET COL <+ .COL 1>>)
+		      (<AND <EQUAL? .DIR ,P?WEST>
+			    <OR <G? .COL 1>
+				<AND <G? .COL 0>
+				     <G? .ROW 0>>>>
+		       <SET COL <- .COL 1>>)
+		      (ELSE
+		       <TELL
+"The rock says, \"There isn't a line there. Do you want me to starve
+to death? Besides, what would my friends think if I was out of line?\"" CR>
+		       <RTRUE>)>
+		<SETG ROCK-LOC <+ <* .ROW 4> .COL>>)>
+	 <COND (<HELD? ,PLAYER ,ROCK>
+		<SETG YOU-LOC ,ROCK-LOC>)>
+	 <SETG ROCK-MOVED? T>
+	 <TELL
+"The rock glides smoothly, carefully following the line on the plain.
+\"Yum!\" it remarks, parenthetically. ">
+	 <DESCRIBE-PLAIN>
+	 <REMOVE ,OTHER-ROCK>
+	 <COND (<ROB ,HERE <> ,ROCK>
+		<TELL
+" Something you left behind on the ground has been crushed by the rock.">)>
+	 <MOVE ,OTHER-ROCK ,HERE>
+	 <CRLF>
+	 %<DEBUG-CODE <COND (,ZDEBUG
+<TELL "[Green: " N ,ROCK-LOC "]" CR>)>>
+	 <RTRUE>>
+
+<OBJECT OTHER-ROCK
+	(IN PLAIN-ROOM)
+	(DESC "brown eyed rock")
+	(SYNONYM ROCK BOULDER)
+	(ADJECTIVE BROWN EYED LARGE FLAT)
+	(FLAGS NDESCBIT THE PERSON VEHBIT CONTBIT OPENBIT TAKEBIT SURFACEBIT)
+	(GENERIC GENERIC-ROCK-F)
+	(SIZE 400)
+	(CAPACITY 200)
+	(CONTFCN OTHER-ROCK-F)
+	(ACTION OTHER-ROCK-F)>
+
+<ROUTINE OTHER-ROCK-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? ,WINNER ,OTHER-ROCK>
+		<COND (<NOT <EQUAL? ,OTHER-ROCK-LOC ,YOU-LOC>>
+		       <TELL ,TOO-FAR>)
+		      (ELSE
+		       <TELL
+CTHE ,OTHER-ROCK " doesn't respond. It acts sulky and peevish." CR>)>
+		<END-QUOTE>)
+	       (<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<NOT <HELD? ,PLAYER ,OTHER-ROCK>>
+		       <CANT-REACH-THAT>)>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? DISEMBARK CLIMB-DOWN LEAP>
+			    <EQUAL? ,PRSO <> ,ROOMS ,OTHER-ROCK>>
+		       <MOVE ,PLAYER ,HERE>
+		       <SETG OTHER-ROCK-LOC
+			     <COND (<NOT <EQUAL? ,OTHER-ROCK-LOC 3>>
+				    3)
+				   (ELSE 12)>>
+		       <TELL
+"You jump down, and the " 'OTHER-ROCK " zooms away in a huff." CR>)>)
+	       (<NOT .RARG>
+		<COND (<VERB? EXAMINE LOOK-INSIDE>
+		       <TELL
+"This rock looks just like the other, except that it has brown eyes.">
+		       <CLEVER-CONTENTS ,OTHER-ROCK " On the rock">
+		       <CRLF>)
+		      (<VERB? BOARD SIT CLIMB-ON CLIMB-FOO CLIMB-UP LEAP>
+		       <COND (<NOT <EQUAL? ,OTHER-ROCK-LOC ,YOU-LOC>>
+			      <TELL ,TOO-FAR>
+			      <RTRUE>)>
+		       <COND (<IN? ,PLAYER ,ROCK>
+			      <SETG ROCK-MOVED? <>>
+			      <SETG ROCK-BRIBED? <>>
+			      <MOVE ,PLAYER ,OTHER-ROCK>
+			      <TELL
+"You leap gracefully to the " 'OTHER-ROCK ", almost slide off, and finally
+settle yourself carefully on top. ">
+			      <COND (<IN? ,DARK-CUBE ,OTHER-ROCK>
+				     <FCLEAR ,DARK-CUBE ,NDESCBIT>
+				     <TELL
+"Right in front of you is a " ,WHITE-CUBE ". ">)>)>
+		       <TELL ,ROCK-IRRITATION>)
+		      (<VERB? TELL ASK-ABOUT TELL-ME-ABOUT>
+		       <RFALSE>)
+		      (<NOT <EQUAL? ,OTHER-ROCK-LOC ,YOU-LOC>>
+		       <TELL ,TOO-FAR>)>)>>
+
+<GLOBAL ROCK-IRRITATION 
+"The rock grumbles in irritation. \"Go away,\" it says.|">
+
+<GLOBAL TOO-FAR "It's too far away.|">
+
+"LIGHT"
+
+<OBJECT LIGHT-CUBE
+	(IN GROUPER-NEST)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE GQ ;C7 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "fireflies")
+	(FLAGS TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE LIGHT-ROOM)>
+
+<ROOM LIGHT-ROOM
+      (IN ROOMS)
+      (DESC "Light Room")
+      (SOUTH PER MAGIC-BOX-EXIT)
+      (WEST TO VOLCANO-BASE)
+      (CUBE LIGHT-CUBE)
+      (ACTION LIGHT-ROOM-F)
+      (FLAGS ONBIT RLANDBIT)>
+
+<ROUTINE LIGHT-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This place is bright and glaring. The very materials of which it is made
+blaze with light so bright that their forms are obscured. There are glowing
+archways to the west and south." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+"LIFE"
+
+<OBJECT LIFE-CUBE
+	(IN HUT-ROOM)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE HQ ;C8 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "rabbits")
+	(FLAGS NDESCBIT TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE LIFE-ROOM)>
+
+<ROOM LIFE-ROOM
+      (IN ROOMS)
+      (DESC "Soft Room")
+      (EAST PER MAGIC-BOX-EXIT)
+      (SOUTH TO MEADOW-ROOM)
+      (CUBE LIFE-CUBE)
+      (ACTION LIFE-ROOM-F)
+      (FLAGS RLANDBIT)>
+
+<ROUTINE LIFE-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This place is soft, warm and slightly spongy. It glistens in
+the light. There are passages leading east and south." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM MEADOW-ROOM
+      (IN ROOMS)
+      (DESC "Meadow")
+      (ACTION MEADOW-ROOM-F)
+      (FLAGS RLANDBIT OUTSIDE ONBIT)
+      (THINGS
+       <PSEUDO (<> RABBIT RABBIT-PSEUDO)
+	       (<> GRASS GRASS-PSEUDO)
+	       (<> FLOWERS FLOWERS-PSEUDO)
+	       (<> WILDFLOWERS FLOWERS-PSEUDO)
+	       (PUFFY CLOUD CLOUD-PSEUDO)
+	       (PUFFY CLOUDS CLOUD-PSEUDO)
+	       (<> BIRD RANDOM-PSEUDO)
+	       (<> BIRDS PLURAL-PSEUDO)
+	       (<> INSECT PLURAL-PSEUDO)>)>
+
+<ROUTINE FLOWERS-PSEUDO ()
+	 <COND (<VERB? SMELL>
+		<TELL "Taking time to stop and smell the flowers?" CR>)
+	       (ELSE
+		<PLANTS-PSEUDO>)>>
+
+<ROUTINE GRASS-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "It's well maintained." CR>)
+	       (ELSE
+		<PLANTS-PSEUDO>)>>
+
+<ROUTINE PLANTS-PSEUDO ()
+	 <COND (<AND <VERB? CUT>
+		     <EQUAL? ,PRSI ,KNIFE ,SHEARS>>
+		<TELL "Doing a little gardening?" CR>)
+	       (<VERB? PICK>
+		<TELL "You shouldn't pick that." CR>)
+	       (ELSE
+		<RANDOM-PSEUDO>)>>
+
+<ROUTINE CLOUD-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The clouds are puffy and white, perfect for a lazy summer's day." CR>)
+	       (<VERB? LESOCH> <LESOCH-CLOUDS>)>>
+
+<ROUTINE LESOCH-CLOUDS ()
+	 <TELL "The clouds clear away.">
+	 <COND (<EQUAL? ,HERE ,LOST-IN-CLOUDS>
+		<CRLF>
+		<CRLF>
+		<GOTO ,MIDAIR>)
+	       (ELSE <CRLF>)>>
+
+<ROUTINE RABBIT-PSEUDO ()
+	 <COND (<OR <VERB? EXAMINE FOLLOW FIND>
+		    <SPELL-VERB?>>
+		<TELL
+"What rabbit? I guess he was late for something." CR>)>>
+
+<ROUTINE MEADOW-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a warm, sunny meadow nestled among low hills. Wildflowers abound,
+and insects buzz lazily through the air. The grass is soft and thick.
+Birds drift serenely through the sky, where puffy white clouds decorate
+the bright blue background." CR>)
+	       (<EQUAL? .RARG ,M-END>
+		<COND (<AND <NOT ,RABBIT-FLAG> <PROB 20>>
+		       <SETG RABBIT-FLAG T>
+		       <TELL CR
+"A rabbit hops across the meadow, twitches its nose at you, and
+then scampers away." CR>)>)>>
+
+<GLOBAL RABBIT-FLAG <>>
+
+<OBJECT SHEARS
+	(IN MEADOW-ROOM)
+	(DESC "pair of pruning shears")
+	(SYNONYM SHEARS)
+	(ADJECTIVE PRUNING PAIR)
+	(FLAGS TAKEBIT TOOLBIT WEAPONBIT)
+	(ACTION SHEARS-F)>
+
+<ROUTINE SHEARS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a very nice pair of pruning shears, such as a gardener
+would own." CR>)
+	       (<AND <VERB? CUT>
+		     <NOT <HELD? ,SHEARS>>>
+		<NOT-HOLDING ,SHEARS>)>>
+
+<OBJECT WEED
+	(IN MEADOW-ROOM)
+	(DESC "weed")
+	(SYNONYM WEED TREE PLANT RAGWEED)
+	(ADJECTIVE UGLY YELLOW SMALL CUTTING)
+	(DESCFCN WEED-DESC)
+	(SIZE 2)
+	(FLAGS TAKEBIT)
+	(ACTION WEED-F)>
+
+<ROUTINE WEED-DESC (RARG OBJ)
+	 <WEED-DETAILS .RARG>>
+
+<ROUTINE WEED-DETAILS (RARG)
+	 <COND (.RARG <TELL "There is a weed ">)
+	       (ELSE <TELL "This is a ragweed ">)>
+	 <COND (<FSET? ,WEED ,RWATERBIT>
+		<TELL "cutting">)
+	       (ELSE
+		<TELL "plant">)>
+	 <COND (.RARG <TELL " here">)>
+	 <TELL ". It's tall">
+	 <COND (<AND <FSET? ,WEED ,RMUNGBIT>
+		     <NOT <EQUAL? ,SHRINK-FLAG ,WEED>>>
+		<TELL " as a tree">)>
+	 <TELL ", with yellow blossoms dripping pollen.">
+	 <COND (<AND <NOT .RARG>
+		     <EQUAL? ,HERE ,MEADOW-ROOM>>
+		<TELL " This is the only weed you can see anywhere
+in the meadow. It's like a well-kept garden.">)>
+	 <CRLF>>
+
+<GLOBAL WEED-PLANTED? 2>
+
+<ROUTINE WEED-F ()
+	 <COND (<VERB? EXAMINE>
+		<WEED-DETAILS <>>)
+	       (<VERB? TAKE PICK MOVE>
+		<COND (<AND <FSET? ,WEED ,RMUNGBIT>
+			    <NOT <EQUAL? ,SHRINK-FLAG ,WEED>>>
+		       <TELL
+"I suppose you have the logging equipment to do this? If so, I don't see
+it anywhere." CR>)
+		      (<NOT <HELD? ,PRSO>>
+		       <COND (<EQUAL? ,WEED-PLANTED? 2>
+			      <COND (<EQUAL? <ITAKE> T>
+				     <MOVE ,WEED ,HERE>
+				     <SETG WEED-PLANTED? 1>
+				     <TELL
+"The weed pulls partly out of the ground." CR>)>
+			      <RTRUE>)
+			     (<EQUAL? ,WEED-PLANTED? 1>
+			      <COND (<EQUAL? <ITAKE> T>
+				     <SETG WEED-PLANTED? <>>
+				     <TELL
+"The weed pulls out of the ground, taking a good-sized ball of
+earth with it." CR>)>
+			      <RTRUE>)>)>)
+	       (<AND <VERB? CUT>
+		     <EQUAL? ,PRSI ,KNIFE ,SHEARS>>
+		<COND (<AND <FSET? ,WEED ,RMUNGBIT>
+			    <NOT <EQUAL? ,SHRINK-FLAG ,WEED>>>
+		       <TELL
+"You would need an axe." CR>)
+		      (ELSE
+		       <MOVE ,WEED ,WINNER>
+		       <FSET ,WEED ,RWATERBIT>
+		       <TELL
+"You now have a weed cutting." CR>)>)
+	       (<AND <VERB? PLANT>
+		     <EQUAL? ,PRSI <> ,GROUND>>
+		<COND (<AND <FSET? ,HERE ,RLANDBIT>
+			    <NOT <GETP ,HERE ,P?CUBE>>
+			    <IN? ,WINNER ,HERE>>
+		       <COND (<FSET? ,WEED ,RWATERBIT> ;"MEANS YOU CUT IT"
+			      <TELL
+,YOU-CANT "expect it to grow from such a cutting." CR>)
+			     (ELSE
+			      <SETG WEED-PLANTED? 2>
+			      <MOVE ,WEED ,HERE>
+			      <TELL
+"You plant the weed. " ,IT-LOOKS-LIKE "it might even thrive if
+it gets some attention." CR>)>)
+		      (ELSE
+		       <TELL
+,I-DONT-THINK-THAT "even a weed can grow here." CR>)>)
+	       (<VERB? THROCK>
+		<COND (<FSET? ,WEED ,RWATERBIT> ;"CUT?"
+		       <TELL
+"The weed shivers, tries very hard to grow in its mutilated
+state and then gives up." CR>)
+		      (<NOT ,WEED-PLANTED?>
+		       <TELL
+"The spell envelops the weed, quests around its roots looking for
+something, fails to find it and fades." CR>)
+		      (<FSET? ,WEED ,RMUNGBIT>
+		       <TELL
+"The weed grows a few more inches and then stops." CR>)
+		      (ELSE
+		       <PUTP ,WEED ,P?SIZE 200>
+		       <FSET ,WEED ,RMUNGBIT>
+		       <TELL
+"With a spurt of explosive growth, the weed expands to spectacular size.
+It is now as large as a small tree!">
+		       <COND (<EQUAL? ,HERE ,CAVE-ENTRANCE>
+			      <OGRE-SNEEZING>
+			      <TELL
+" After a few seconds, you hear a muffled exclamation from within the cave,
+and then a volley of sneezes.">)
+			     (<EQUAL? ,HERE ,OGRE-CAVE>
+			      <OGRE-SNEEZING>
+			      <TELL
+" As the weed grows, the ogre watches in horror. \"Ragweed!\" he screams,
+and then his further comments are cut off by a volley of sneezes like the
+reports of a small cannon. The ogre begins to rub his
+eyes, which are
+watering horrifically, and his sneezes are monumental. He is totally
+oblivious to your presence.">)>
+		       <CRLF>)>)
+	       (<VERB? CASKLY>
+		<TELL ,NOTHING-HAPPENS>)
+	       (<VERB? LISKON>
+		<COND (<PRE-LISKON> <RTRUE>)
+		      (<FSET? ,WEED ,RMUNGBIT>
+		       <SETG SHRINK-FLAG ,WEED>
+		       <PUTP ,WEED ,P?SIZE 3>
+		       <QUEUE I-LISKON 15>
+		       <TELL
+"The weed shrinks back to almost exactly its former size." CR>)>)
+	       (<AND <VERB? SHAKE>
+		     <EQUAL? ,HERE ,OGRE-CAVE>>
+		<PERFORM ,V?WAVE-AT ,PRSO ,OGRE>
+		<RTRUE>)>>
+
+<ROUTINE OGRE-SNEEZING ()
+	 <QUEUE I-STOP-SNEEZING 10>
+	 <SETG SNEEZY? T>>
+
+"DEATH"
+
+<OBJECT DEATH-CUBE
+	(IN PRISON)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE IQ ;C9 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "worms")
+	(FLAGS TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE DEATH-ROOM)>
+
+<ROOM DEATH-ROOM
+      (IN ROOMS)
+      (DESC "Boneyard")
+      (CUBE DEATH-CUBE)
+      (OUT TO BELWIT-SQUARE)
+      (NORTH TO BELWIT-SQUARE)
+      (WEST PER MAGIC-BOX-EXIT)
+      (ACTION DEATH-ROOM-F)
+      (FLAGS ONBIT RLANDBIT)
+      (THINGS <PSEUDO (<> BONES PLURAL-PSEUDO)>)>
+
+<ROUTINE DEATH-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a room of bones. Shoulder blades make up the floor, skulls the
+walls and leg bones the door frames. The west exit leads into darkness,
+but the doorway to the north opens onto a seemingly normal street
+scene." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+"CHANGE"
+
+<OBJECT CHANGE-CUBE
+	(IN CHUNK)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE JQ ;C10 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "butterflies")
+	(FLAGS TAKEBIT NDESCBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE CHANGE-ROOM)>
+
+<ROOM CHANGE-ROOM
+      (IN ROOMS)
+      (DESC "Changing Room")
+      (NORTH TO BARE-ROOM)
+      (WEST TO MAZE-ANTEROOM)
+      (EAST PER MAGIC-BOX-EXIT)
+      (CUBE CHANGE-CUBE)
+      (ACTION CHANGE-ROOM-F)
+      (FLAGS RLANDBIT)>
+
+<ROOM BARE-ROOM
+      (IN ROOMS)
+      (DESC "Bare Room")
+      (LDESC
+"This is a room of smooth bare marble. It has no exits.")
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BARE MARBLE MARBLE-PSEUDO)>)>
+
+<ROUTINE MARBLE-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL ,IT-LOOKS-LIKE "bare, smooth marble." CR>)>>
+
+<ROUTINE CHANGE-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"The scene here shifts and changes constantly. For example, the exit to
+the west is always an exit, but one moment it is an oak door, and the next
+a flimsy curtain of beads. The details are impossible to pin down for
+longer than a second or two. The eastern and northern exits are equally
+fluid." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM MAZE-ANTEROOM
+      (IN ROOMS)
+      (DESC "Carving Room")
+      (NORTH TO MAZE-9 IF MAZE-EXIT-FLAG)
+      (ACTION MAZE-ANTEROOM-F)
+      (EXITS 0)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<GLOBAL MAZE-EXIT-FLAG <>>
+
+<ROUTINE MAZE-ANTEROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This room is a perfectly carved, smoothed and shaped cube of black marble. ">
+		<COND (,MAZE-EXIT-FLAG
+		       <TELL
+"There is a smallish " ,OCT-HOLE " in the north wall.">)
+		      (ELSE
+		       <TELL
+"There are no exits, but inset in the north wall is a carving of a compass
+rose.">)>
+		<CRLF>)
+	       (<AND <EQUAL? .RARG ,M-LEAVE>
+		     <NOT <VERB? BLORPLE>>>
+		<SETG MAZE-EXIT-FLAG <>>
+		<PUT ,MAZE-ANTEROOM ,P?EXITS 0>
+		<OCT-HOLE-DISAPPEARS>)>>
+
+<ROUTINE OCT-HOLE-DISAPPEARS ()
+	 <TELL
+"You slide through the " ,OCT-HOLE ", which constricts and disappears as
+soon as you are through it." CR CR>>
+
+<OBJECT COMPASS-CARVING
+	(IN MAZE-ANTEROOM)
+	(DESC "carving")
+	(SYNONYM CARVING ENGRAVE INSET)
+	(FLAGS NDESCBIT CONTBIT OPENBIT SEARCHBIT)
+	(CAPACITY 10)
+	(ACTION COMPASS-CARVING-F)>
+
+<ROUTINE COMPASS-CARVING-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<IN? ,COMPASS-ROSE ,COMPASS-CARVING>
+		       <TELL
+"The carving is hidden by the real compass rose, which resembles it in
+every particular." CR>)
+		      (ELSE
+		       <TELL
+"This carving of a compass rose was made by a master craftsman. All the
+delicate filigree one might expect on a real but ornamental counterpart is
+here. As though that challenge was not enough, the artist set the carving deep
+in the stone of the wall." CR>)>)
+	       (<VERB? OPEN>
+		<YOU-CANT-X-PRSO "open">)
+	       (<VERB? CLOSE>
+		<YOU-CANT-X-PRSO "close">)
+	       (<AND <VERB? PUT>
+		     <EQUAL? ,COMPASS-CARVING ,PRSO ,PRSI>>
+		<COND (<EQUAL? ,COMPASS-ROSE ,PRSO ,PRSI>
+		       <MOVE ,COMPASS-ROSE ,COMPASS-CARVING>
+		       <COND (,MAZE-EXIT-FLAG
+			      <TELL ,NOTHING-HAPPENS>)
+			     (ELSE
+			      <SETG MAZE-EXIT-FLAG T>
+			      <PUTP ,MAZE-ANTEROOM ,P?EXITS ,C-NORTH>
+			      <TELL
+"The silver rose fits the carving perfectly. As it slides in, an " ,OCT-HOLE 
+" appears below the carving. It is small, but large enough to squeeze
+through. You notice that the arm pointing north is now dull pot-metal.">
+			      <COND (<G? ,COMPASS-ROSE-ARMS 1>
+				     <TELL
+" Further, all the other arms are silver again!">)>
+			      <MOVE ,OCTAGONAL-HOLE ,HERE>
+			      <SETG COMPASS-ROSE-ARMS 1>
+			      <SETG COMPASS-ROSE-STATE ,C-NORTH>
+			      <CRLF>)>)
+		      (ELSE
+		       <TELL "It won't fit." CR>)>)>>
+
+<OBJECT COMPASS-ROSE
+	(IN BARE-ROOM)
+	(DESC "compass rose")
+	(SYNONYM ROSE ARM ARMS KNOB)
+	(ADJECTIVE COMPASS SILVER LEAD)
+	(FLAGS TAKEBIT MAGICBIT)
+	(DESCFCN COMPASS-ROSE-DESC)
+	(ACTION COMPASS-ROSE-F)>
+
+<ROUTINE COMPASS-ROSE-DESC (RARG OBJ)
+	 <COND (<NOT <FSET? .OBJ ,TOUCHBIT>>
+		<TELL "A " 'COMPASS-ROSE " lies discarded in a corner">)
+	       (T
+		<TELL "There is a " 'COMPASS-ROSE " here">)>
+	 <TELL ,PERIOD>>
+
+<GLOBAL COMPASS-ROSE-STATE 0>
+<GLOBAL COMPASS-ROSE-ARMS 0>
+
+<ROUTINE ARM-DIRECTION (N "AUX" (CNT 1) (L <GET ,DIR-TABLE 0>))
+	 <REPEAT ()
+		 <COND (<G? .CNT .L>
+			<RETURN>)
+		       (<EQUAL? <GET ,DIR-TABLE .CNT> .N>
+			<RETURN <GET ,DIR-TABLE <+ .CNT 2>>>)
+		       (ELSE
+			<SET CNT <+ .CNT 3>>)>>>
+
+<ROUTINE COMPASS-ROSE-F ("AUX" (N 1) (1ST? T))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"Ornate arms indicating the directions grace this lovely silver compass
+rose. The central knob tells which arm goes with which
+direction. The arms are decorated with mythological scenes">
+		<COND (<L? ,COMPASS-ROSE-ARMS 8>
+		       <COND (<ZERO? ,COMPASS-ROSE-ARMS>
+			      <TELL " in">)
+			     (ELSE
+			      <TELL ". Oddly, some of the arms are">)>
+		       <TELL " finely
+wrought silver chased with gold">)>
+		<COND (<G? ,COMPASS-ROSE-ARMS 0>
+		       <COND (<G? ,COMPASS-ROSE-ARMS 1>
+			      <COND (<L? ,COMPASS-ROSE-ARMS 8>
+				     <TELL ", while some of the arms (">
+				     <REPEAT ()
+				      <COND (<EQUAL? .N 256> <RETURN>)
+					    (<NOT <EQUAL?
+						   <BAND ,COMPASS-ROSE-STATE
+							 .N>
+						   0>>
+					     <COND (.1ST?
+						    <SET 1ST? <>>)
+						   (ELSE
+						    <TELL ", ">)>
+					     <TELL <ARM-DIRECTION .N>>)>
+				      <SET N <* .N 2>>>
+				     <TELL ")">)
+				    (ELSE
+				     <TELL ". Oddly, all of the arms">)>
+			      <TELL " are">)
+			     (ELSE
+			      <TELL ", while the "
+				    <ARM-DIRECTION ,COMPASS-ROSE-STATE>
+				    " arm is">)>
+		       <TELL " made of ornate lead or
+pot-metal chased with brass">)>
+		<TELL ".">
+		<COND (<AND <EQUAL? ,HERE ,MAZE-ANTEROOM>
+			    <NOT <IN? ,COMPASS-ROSE ,COMPASS-CARVING>>>
+		       <TELL
+" The compass rose exactly fits the carving of a compass rose on
+the north wall of the room.">)>
+		<CRLF>)
+	       (<AND <VERB? COMPARE>
+		     <EQUAL? ,COMPASS-ROSE ,PRSO ,PRSI>
+		     <EQUAL? ,COMPASS-CARVING ,PRSO ,PRSI>>
+		<TELL
+"The " 'COMPASS-CARVING " is a carving of the " 'COMPASS-ROSE ,PERIOD>)
+	       (<VERB? TURN MOVE RUB SPIN>
+		<TELL ,NOTHING-HAPPENS>)>>
+
+<OBJECT NORTH-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "north rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE NORTH N SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-NORTH)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT EAST-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "east rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE EAST E SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-EAST)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT WEST-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "west rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE WEST W SILVER LEAD GOLD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-WEST)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT SOUTH-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "south rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE SOUTH S SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-SOUTH)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT NE-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "northeast rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE NORTHEAST NE SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-NE)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT NW-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "northwest rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE NORTHWEST NW SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-NW)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT SE-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "southeast rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE SOUTHEAST SE SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-SE)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<OBJECT SW-RUNE
+	(IN LOCAL-GLOBALS)
+	(DESC "southwest rune")
+	(SYNONYM RUNE RUNES)
+	(ADJECTIVE SOUTHWEST SW SILVER LEAD)
+	(FLAGS NDESCBIT READBIT)
+	(EXITS %,C-SW)
+	(GENERIC GENERIC-RANDOM-F)
+	(ACTION RUNE-F)>
+
+<ROUTINE RUNE-F ("AUX" DIR)
+	 <COND (<VERB? EXAMINE READ>
+		<SET DIR <GETP ,PRSO ,P?EXITS>>
+		<TELL
+"This is the rune for \"" <ARM-DIRECTION .DIR> ",\" made
+of inlaid ">
+		<COND (<ZERO? <BAND <GETP ,HERE ,P?WALLS> .DIR>>
+		       <COND (<AND <EQUAL? ,HERE ,MAZE-2>
+				   <EQUAL? .DIR ,C-WEST>>
+			      <TELL "gold">)
+			     (ELSE
+			      <TELL "silver">)>)
+		      (ELSE <TELL "lead">)>
+		<TELL ,PERIOD>)>>
+
+<ROOM MAZE-1
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (SOUTH TO MAZE-4)
+      (SE TO MAZE-5)
+      (EAST TO MAZE-2)
+      (EXITS 0)
+      (WALLS -1)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<OBJECT OCTAGONAL-HOLE
+	(IN MAZE-2)
+	(SYNONYM HOLE DOOR)
+	(ADJECTIVE OCTAGONAL)
+	(DESC "octagonal hole")
+	(FLAGS DOORBIT NDESCBIT AN CONTBIT OPENBIT)
+	(GENERIC GENERIC-HOLE-F)
+	(ACTION OCTAGONAL-HOLE-F)>
+
+<ROUTINE OCTAGONAL-HOLE-F ("AUX" E)
+	 <COND (<AND <EQUAL? ,HERE ,MAZE-2>
+		     <NOT <IN? ,MAZE-2-DOOR ,HERE>>>
+		<MAZE-2-DOOR-F>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL ,NOW-BLACK CR>)
+	       (<VERB? EXAMINE>
+		<TELL "It looks like an " ,OCT-HOLE ,PERIOD>)
+	       (<VERB? THROUGH>
+		<SET E <GETP ,HERE ,P?EXITS>>
+		<COND (<L? .E 256>
+		       <DO-WALK <DIR-BASE .E ,DIR-BIT ,DIR-DIR>>)>)>>
+
+<OBJECT MAZE-2-DOOR
+	(IN MAZE-2)
+	(SYNONYM PLUG)
+	(ADJECTIVE ALABASTER)
+	(DESC "alabaster plug")
+	(FLAGS AN NDESCBIT TAKEBIT TRYTAKEBIT)
+	(ACTION MAZE-2-DOOR-F)>
+
+<GLOBAL OCT-HOLE "octagonal hole">
+
+<ROUTINE DESCRIBE-PLUG ()
+	 <TELL
+"On the west wall just under the rune is an " ,OCT-HOLE>
+	 <COND (<IN? ,MAZE-2-DOOR ,HERE>
+		<TELL
+" plugged with a perfectly fitting piece of alabaster">)>
+	 <TELL ".">>
+
+<ROUTINE MAZE-2-DOOR-F ("AUX" (OPEN? <NOT <IN? ,MAZE-2-DOOR ,HERE>>))
+	 <COND (<VERB? EXAMINE>
+		<DESCRIBE-PLUG>
+		<CRLF>)
+	       (<VERB? TAKE MOVE>
+		<COND (<NOT <FSET? ,PRSO ,OPENBIT>>
+		       <TELL
+"You can't budge it." CR>)>)
+	       (<VERB? PUSH>
+		<COND (.OPEN?
+		       <TELL
+,THERE-IS-NOTHING "there to push on anymore." CR>)
+		      (ELSE
+		       <TELL ,NOTHING-HAPPENS>)>)
+	       (<VERB? OPEN>
+		<TELL
+"There is no apparent lock or handle." CR>)
+	       (<VERB? CLOSE>
+		<COND (.OPEN?
+		       <NO-DOOR>)
+		      (ELSE
+		       <TELL ,IT-IS-ALREADY "closed" ,PERIOD>)>)
+	       (<VERB? THROUGH>
+		<COND (.OPEN?
+		       <DO-WALK ,P?WEST>)
+		      (ELSE
+		       <NO-DOOR>)>)
+	       (<VERB? REZROV>
+		<PUTP ,HERE ,P?EXITS 4 ;"WEST">
+		<FSET ,OCTAGONAL-HOLE ,OPENBIT>
+		<REMOVE ,MAZE-2-DOOR>
+		<TELL
+"The alabaster melts away, leaving an " ,OCT-HOLE " leading west." CR>)>>
+
+<ROUTINE NO-DOOR ()
+	 <TELL "There's no door there." CR>>
+
+<ROOM MAZE-2
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (WEST TO MAZE-1 IF OCTAGONAL-HOLE IS OPEN)
+      (SW TO MAZE-4)
+      (SOUTH TO MAZE-5)
+      (SE TO MAZE-6)
+      (EAST TO MAZE-3)
+      (EXITS 0)
+      (WALLS %<+ ,C-NW ,C-NORTH ,C-NE>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-3
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (WEST TO MAZE-2)
+      (SW TO MAZE-5)
+      (SOUTH TO MAZE-6)
+      (EXITS 0)
+      (WALLS %<+ ,C-NW ,C-NORTH ,C-NE ,C-EAST ,C-SE>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-4
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (NORTH TO MAZE-1)
+      (NE TO MAZE-2)
+      (EAST TO MAZE-5)
+      (SE TO MAZE-8)
+      (SOUTH TO MAZE-7)
+      (EXITS 0)
+      (WALLS %<+ ,C-NW ,C-WEST ,C-SW>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-5
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (NORTH TO MAZE-2)
+      (EAST TO MAZE-6)
+      (SOUTH TO MAZE-8)
+      (WEST TO MAZE-4)
+      (EXITS 0)
+      (WALLS %<+ ,C-NE ,C-NW ,C-SE ,C-SW>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-6
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (EXITS 0)
+      (NORTH TO MAZE-3)
+      (SOUTH TO MAZE-9)
+      (SW TO MAZE-8)
+      (WEST TO MAZE-5)
+      (NW TO MAZE-2)
+      (WALLS %<+ ,C-NE ,C-EAST ,C-SE>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-7
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (EXITS 0)
+      (NORTH TO MAZE-4)
+      (NE TO MAZE-5)
+      (EAST TO MAZE-8)
+      (WALLS %<+ ,C-NW ,C-WEST ,C-SW ,C-SOUTH ,C-SE>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-8
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (EXITS 0)
+      (WEST TO MAZE-7)
+      (NW TO MAZE-4)
+      (NORTH TO MAZE-5)
+      (NE TO MAZE-6)
+      (EAST TO MAZE-9)
+      (WALLS %<+ ,C-SOUTH ,C-SW ,C-SE>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROOM MAZE-9
+      (IN ROOMS)
+      (DESC "Octagonal Room")
+      (ACTION MAZE-F)
+      (WEST TO MAZE-8)
+      (NW TO MAZE-5)
+      (NORTH TO MAZE-6)
+      (SOUTH TO MAZE-ANTEROOM)
+      (EXITS 0)
+      (WALLS %<+ ,C-SE ,C-EAST ,C-NE ,C-SW>)
+      (GLOBAL NORTH-RUNE NE-RUNE EAST-RUNE SE-RUNE
+              SOUTH-RUNE SW-RUNE WEST-RUNE NW-RUNE)
+      (FLAGS RLANDBIT)
+      (THINGS <PSEUDO (BLACK MARBLE MARBLE-PSEUDO)>)>
+
+<ROUTINE DESCRIBE-MAZE-WALLS ("AUX" (EXITS <GETP ,HERE ,P?EXITS>)
+			      (CNT 1) (E 1))
+	 <REPEAT ()
+		 <COND (<==? .E 256> <RETURN>)
+		       (<NOT <EQUAL? <BAND .EXITS .E> 0>>
+			<TELL
+" The " <ARM-DIRECTION .E> <COND (<G? .E 8> " corner") (ELSE " wall")>
+" has a perfect " ,OCT-HOLE " in it, just under the ">
+			<COND (<EQUAL? ,HERE ,MAZE-ANTEROOM>
+			       <TELL "carving">)
+			      (ELSE <TELL "rune">)>
+			<TELL ".">)>
+		 <SET CNT <+ .CNT 1>>
+		 <SET E <* .E 2>>>>
+
+<ROUTINE MAZE-F (RARG "AUX" DIR OEXITS)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This room is in the shape of an octagonal solid carved from marble. The
+floor and ceiling are the octagons and each wall is a rectangle. On each
+wall is inlaid a rune indicating a direction: the north wall has \"north\"
+carved on it, and so on. The ">
+		<COND (<EQUAL? ,HERE ,MAZE-1>
+		       <TELL "runes are all of lead.">)
+		      (ELSE
+		       <COND (<EQUAL? ,HERE ,MAZE-2>
+			      <TELL "west rune is gold, the ">)>
+		       <TELL-WALLS>
+		       <TELL " runes are lead, the rest are of silver.">)>
+		<COND (<NOT <ZERO? <GETP ,HERE ,P?EXITS>>>
+		       <DESCRIBE-MAZE-WALLS>)>
+		<COND (<AND <EQUAL? ,HERE ,MAZE-2>
+			    <IN? ,MAZE-2-DOOR ,HERE>>
+		       <TELL " ">
+		       <DESCRIBE-PLUG>)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<EQUAL? ,HERE ,MAZE-2>
+		       <MOVE ,OCTAGONAL-HOLE ,HERE>
+		       <FCLEAR ,OCTAGONAL-HOLE ,OPENBIT>)>
+		<FCLEAR ,HERE ,TOUCHBIT>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<COND (<EQUAL? ,HERE ,MAZE-2>
+		       <MOVE ,MAZE-2-DOOR ,MAZE-2>
+		       <FCLEAR ,OCTAGONAL-HOLE ,OPENBIT>)>
+		<PUTP ,HERE ,P?EXITS 0>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? WALK>
+		       <SET DIR <DIR-BASE ,P-WALK-DIR ,DIR-DIR ,DIR-BIT>>
+		       <COND (<NOT <EQUAL? <BAND <GETP ,HERE ,P?EXITS> .DIR>
+					   0>>
+			      <OCT-HOLE-DISAPPEARS>
+			      <V-WALK>)
+			     (ELSE
+			      <TELL "There is no exit ">
+			      <COND (<EQUAL? ,P-WALK-DIR ,P?UP ,P?DOWN>
+				     <TELL "there">)
+				    (ELSE
+				     <TELL "on that wall">)>
+			      <TELL ,PERIOD>)>)
+		      (<AND <VERB? PUT PUT-ON>
+			    <EQUAL? ,PRSO ,COMPASS-ROSE>>
+		       <COND (<GLOBAL-IN? ,PRSI ,HERE>
+			      <PERFORM ,V?RUB ,PRSI ,PRSO>
+			      <RTRUE>)
+			     (<AND <IN? ,PRSI ,GLOBAL-OBJECTS>
+				   <GETP ,PRSI ,P?EXITS>>
+			      <TELL ,THERE-IS-NOTHING "to hang it on." CR>)>)
+		      (<AND <VERB? RUB>
+			    <EQUAL? ,PRSI ,COMPASS-ROSE>>
+		       <SET DIR <GETP ,PRSO ,P?EXITS>>
+		       <COND (<AND <EQUAL? ,HERE ,MAZE-2>
+				   <EQUAL? .DIR 4>>
+			      <TELL ,NOTHING-HAPPENS>)
+			     (<AND .DIR
+				   <EQUAL? <BAND <GETP ,HERE ,P?WALLS> .DIR>
+					   0>
+				   <EQUAL? <BAND <GETP ,HERE ,P?EXITS> .DIR>
+					   0>
+				   <EQUAL? <BAND ,COMPASS-ROSE-STATE .DIR>
+					   0>>
+			      <SETG COMPASS-ROSE-ARMS
+				    <+ ,COMPASS-ROSE-ARMS 1>>
+			      <SETG COMPASS-ROSE-STATE
+				    <BOR ,COMPASS-ROSE-STATE .DIR>>
+			      <SET OEXITS <GETP ,HERE ,P?EXITS>>
+			      <PUTP ,HERE ,P?EXITS .DIR>
+			      <MOVE ,OCTAGONAL-HOLE ,HERE>
+			      <TELL
+"As the compass rose touches the " 'PRSO ", the arm of the
+rose labelled \"" <ARM-DIRECTION .DIR> "\" turns dull and leaden,
+and an " ,OCT-HOLE " large enough for you to squeeze through
+appears in the wall below the rune.">
+			      <COND (<NOT <ZERO? .OEXITS>>
+				     <TELL " The other hole disappears.">)>
+			      <CRLF>)
+			     (ELSE
+			      <TELL ,NOTHING-HAPPENS>)>)>)>>
+
+<ROUTINE TELL-WALLS ("OPTIONAL" (N <>) "AUX" (CNT 1)
+		     (L <GET ,DIR-TABLE 0>) (1ST? T) (OLD <>))
+	 <COND (<NOT .N> <SET N <GETP ,HERE ,P?WALLS>>)>
+	 <REPEAT ()
+		 <COND (<G? .CNT .L>
+			<TELL " and " .OLD>
+			<RETURN>)
+		       (<NOT <ZERO? <BAND <GET ,DIR-TABLE .CNT> .N>>>
+			<COND (.OLD
+			       <COND (.1ST? <SET 1ST? <>>)
+				     (ELSE <TELL ", ">)>
+			       <TELL .OLD>)>
+			<SET OLD <GET ,DIR-TABLE <+ .CNT 2>>>)>
+		 <SET CNT <+ .CNT 3>>>>
+
+"MAGIC"
+
+<OBJECT MAGIC-CUBE
+	(IN OUTCROPPING-ROOM)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE MQ ;C13 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "unicorns")
+	(FLAGS TAKEBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE MAGIC-ROOM)>
+
+<ROOM MAGIC-ROOM
+      (IN ROOMS)
+      (DESC "Magic Room")
+      (CUBE MAGIC-CUBE)
+      (NORTH TO MEADOW-ROOM)
+      (EAST PER MAGIC-DOOR-EXIT)
+      (SOUTH PER MAGIC-BOX-EXIT)
+      (ACTION MAGIC-ROOM-F)
+      (FLAGS RLANDBIT)
+      (THINGS
+       <PSEUDO (<> MIRROR MIRROR-PSEUDO)
+	       (BIRD NESTS PLURAL-PSEUDO)
+	       (BIRD NEST RANDOM-PSEUDO)
+	       (<> WEED PLANTS-PSEUDO)
+	       (<> WEEDS PLANTS-PSEUDO)
+	       (<> GRASS PLANTS-PSEUDO)
+	       (BIRD DROPPINGS PLURAL-PSEUDO)>)>
+
+<ROUTINE MIRROR-PSEUDO ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<PERFORM ,V?EXAMINE ,ME>
+		<RTRUE>)
+	       (<VERB? RUB>
+		<TELL "Nothing happens here." CR>)>>
+
+<ROUTINE MAGIC-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This place is odd indeed. Nothing that you look at is what it seems. If
+you look at something carefully enough it turns out to be something
+entirely different. The room is cluttered with objects and obviously
+hasn't been cleaned in a long time. The floor is overgrown with grass
+and weeds, and rabbits have chewed them. There are bird nests around the
+ceiling and droppings here and there. A very untidy and unsettling
+place. Much of the walls, ceiling and floor is covered in mirrors.
+There are empty, mirrorless square areas at north and south and a round
+black emptiness to the east." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROUTINE GOT? (CUBE)
+	 <OR <EQUAL? .CUBE ,BLORPLE-OBJECT>
+	     <HELD? .CUBE>
+	     <IN? .CUBE ,CASTLE>>>
+
+<ROUTINE HAS-ALL-CUBES? ()
+	 <COND (<EQUAL? <COUNT-CUBES> 13> <RTRUE>)
+	       (ELSE <RFALSE>)>>
+
+<ROUTINE COUNT-CUBES ("AUX" (CNT 0) (N 0))
+	 <REPEAT ()
+		 <COND (<GOT? <GET ,CUBE-LIST <* .CNT 2>>>
+			<SET N <+ .N 1>>)>
+		 <COND (<IGRTR? CNT 12> <RETURN .N>)>>>
+
+<ROUTINE MAGIC-DOOR-EXIT ()
+	 <COND (<HAS-ALL-CUBES?>
+		,CASTLE)
+	       (ELSE
+		<TELL ,YOU-CANT "push your way through." CR>
+		<RFALSE>)>>
+
+"TIME CUBE"
+
+<OBJECT TIME-CUBE
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE KQ ;C11 SMALL WHITE)
+	(NAME 0)
+	(TEXT "turtles")
+	(FLAGS TAKEBIT NDESCBIT THE)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE TIME-ROOM)>
+
+<ROOM TIME-ROOM
+      (IN ROOMS)
+      (DESC "Sand Room")
+      (UP TO PAST-RUINS-ROOM)
+      (DOWN TO PAST-CELL-EAST)
+      (CUBE TIME-CUBE)
+      (ACTION TIME-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL GLOBAL-HOLE)
+      (THINGS <PSEUDO (<> SAND SAND-PSEUDO)>)>
+
+<ROUTINE SAND-PSEUDO ()
+	 <REDIRECT ,PSEUDO-OBJECT ,GROUND>>
+
+<ROUTINE TIME-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"A thin trickle of sand flows down from an exit in the ceiling of this
+circular room to a pile of sand on the floor. The walls of the room are
+glass, but you can see nothing through them. In the sand is a hole through
+which, oddly enough, no sand is pouring out." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROOM PAST-RUINS-ROOM
+      (IN ROOMS)
+      (DESC "Ruins Room")
+      (NORTH "The water is too deep and cold.")
+      (SOUTH "The water is too deep and cold.")
+      (ACTION PAST-RUINS-ROOM-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL WATER)
+      (THINGS
+       <PSEUDO (<> CHANNEL CHANNEL-PSEUDO)
+	       (MOULDERING RUIN RUINS-PSEUDO)
+	       (BROKEN PILLAR RUINS-PSEUDO)
+	       (FALLEN PILLAR RUINS-PSEUDO)
+	       (COLLAPSED PORTICO RUINS-PSEUDO)>)>
+
+<ROUTINE CHANNEL-PSEUDO ()
+	 <COND (<VERB? EXAMINE THROUGH>
+		<TELL "The channel is buried under rubble." CR>)>>
+
+<ROUTINE PAST-RUINS-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the south end of a vast chamber filled with partially ruined
+structures. Here the portico of a building is collapsing. The pillars
+holding it up are starting to crumble. One has recently fallen and
+smashed the pavement. The fall exposed and the rubble blocked a small
+channel filled with swiftly rushing water which is rapidly inundating
+the area. " <GET ,WATER-TABLE ,PAST-WATER-FLAG> CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? PUT>
+			    <EQUAL? ,PRSI ,WATER>>
+		       <REMOVE ,PRSO>
+		       <TELL CTHE ,PRSO " is borne away by the flood." CR>)
+		      (<AND <VERB? THROUGH>
+			    <OR <EQUAL? ,PRSO ,WATER>
+				<EQUAL? ,P-PNAM ,W?CHANNEL>>>
+		       <COND (<G? ,PAST-WATER-FLAG 2>
+			      <TELL ,YOU-ARE ,PERIOD>)
+			     (ELSE
+			      <TELL "It's cold and icy." CR>)>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<G? ,PAST-WATER-FLAG 0>
+		       <SETG DEATHS 3>
+		       <JIGS-UP
+"You emerge underwater, amidst a dim and blurry vision of drowned columns.
+You drown as well.">)
+		      (ELSE
+		       <MOVE ,GIRGOL-SCROLL ,SACK>
+		       <FSET ,GIRGOL-SCROLL ,TOUCHBIT>
+		       <QUEUE I-WATER-RISING 3>)>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<REMOVE ,PLAYER>
+		<COND (<AND <NOT ,DEAD?>
+			    <ONLY? ,ZIPPER ,HERE>
+			    <ONLY? ,GIRGOL-SCROLL ,ZIPPER>
+			    <NOT <FSET? ,ZIPPER ,OPENBIT>>>
+		       <MOVE ,PLAYER ,HERE>
+		       <SETG SCORE <+ ,SCORE ,RUINS-SCORE>>
+		       <SETG RUINS-SCORE 0>)
+		      (ELSE
+		       <MOVE ,PLAYER ,HERE>
+		       <MOVE ,GIRGOL-SCROLL ,SACK>
+		       <MOVE ,SACK ,HERE>
+		       <TELL
+,TIME-SICK "You feel that you are being pummelled by huge
+rocks and boulders">
+		       <SETG DEATHS 3>
+		       <JIGS-UP
+", again and again. Finally, you succumb.">)>)>>
+
+<GLOBAL RUINS-SCORE 25>
+
+<GLOBAL TIME-SICK
+"As you leave, your consciousness is wrenched as though your memories
+were being torn apart. ">
+
+<ROUTINE ONLY? (OBJ CON)
+	 <COND (<NOT <IN? .OBJ .CON>> <RFALSE>)
+	       (<NOT <SET CON <FIRST? .CON>>> <RFALSE>)
+	       (<NOT <EQUAL? .OBJ .CON>> <RFALSE>)
+	       (<NEXT? .CON> <RFALSE>)
+	       (ELSE <RTRUE>)>>
+
+<OBJECT SACK
+	(IN PAST-RUINS-ROOM)
+	(DESC "sack")
+	(SYNONYM SACK BAG)
+	(ADJECTIVE BURLAP)
+	(ACTION SACK-F)
+	(FLAGS TAKEBIT CONTBIT SEARCHBIT)
+	(CAPACITY 200)>
+
+<ROUTINE SACK-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a burlap sack of medium size. ">
+		<TELL-OPEN-CLOSED ,SACK>)
+	       (<AND <VERB? OPEN>
+		     <NOT <FSET? ,SACK ,OPENBIT>>>
+		<FSET ,SACK ,OPENBIT>
+		<TELL
+"Opening the " 'SACK " reveals ">
+		<WHAT-CONTENTS>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL CTHE ,SACK " is ">
+		<COND (<FSET? ,SACK ,OPENBIT>
+		       <TELL "dim inside, but you can see ">
+		       <COND (<NOT <PRINT-CONTENTS ,SACK>>
+			      <TELL "that it's empty">)>
+		       <TELL ".">)
+		      (ELSE
+		       <TELL "closed.">)>
+		<CRLF>)>>
+
+<GLOBAL WATER-TABLE
+	<PTABLE
+"You are in a small area not yet flooded."
+"The water has left only a tiny area dry."
+"The water has covered the entire floor. Your feet are wet."
+"The water is up to your waist."
+"You are in water over your head.">>
+
+<ROOM PAST-CELL-EAST
+      (IN ROOMS)
+      (DESC "Dungeon Cell")
+      (SOUTH PER PAST-CELL-EAST-EXIT)
+      (ACTION PAST-CELL-EAST-F)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL CELL-DOOR)
+      (THINGS
+       <PSEUDO (<> CELL CELL-PSEUDO)
+	       (BURLY GUARDS CASTLE-GUARDS-PSEUDO)
+	       (RICH HANGINGS PLURAL-PSEUDO)
+	       (ORNAMENTED FURNITURE RANDOM-PSEUDO)>)>
+
+<ROUTINE PAST-CELL-EAST-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a luxurious cell, obviously for the imprisonment of a
+highborn or powerful person. Its rich hangings and heavily ornamented
+furniture speak of a prisoner whose comfort is important even during
+imprisonment. A massive oak cabinet dominates one wall. ">
+		<TELL-OPEN-CLOSED ,PAST-CABINET>
+		<TELL-OPEN-CLOSED ,CELL-DOOR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<REMOVE ,PLAYER>
+		<COND (<AND <NOT ,DEAD?>
+			    <NOT <FSET? ,PAST-CABINET ,RMUNGBIT>>
+			    <FSET? ,PAST-CABINET ,LOCKED>
+			    <FSET? ,CELL-DOOR ,OPENBIT>
+			    <ONLY? ,SPELL-BOOK ,PAST-CABINET>
+			    <ONLY? ,PAST-CABINET ,HERE>>
+		       <SETG SCORE <+ ,SCORE 25>>
+		       <MOVE ,PLAYER ,HERE>)
+		      (ELSE
+		       <MOVE ,PLAYER ,HERE>
+		       <MOVE ,BLANK-SCROLL ,PAST-CABINET>
+		       <COND (<NOT ,DEAD?>
+			      <TIME-SICK-CELL-EAST>)>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<IN? ,SPELL-BOOK ,PAST-CABINET>
+		       <JIGS-UP ,PAST-CELL-GUARDS-KILL-YOU>)>)>>
+
+<ROUTINE TIME-SICK-CELL-EAST ()
+	 <TELL
+,TIME-SICK "You feel that you are being devoured by monsters
+and pulled screaming beneath the water simultaneously">
+	 <SETG DEATHS 3>
+	 <JIGS-UP
+", again and again. Finally, you succumb.">>
+
+<OBJECT CELL-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "cell door")
+	(SYNONYM DOOR)
+	(ADJECTIVE CELL)
+	(ACTION CELL-DOOR-F)
+	(FLAGS LOCKED DOORBIT)>
+
+<ROUTINE CELL-DOOR-F ()
+	 <COND (<VERB? OPEN>
+		<TELL "The door is locked." CR>)
+	       (<VERB? THROUGH>
+		<DO-WALK <COND (<EQUAL? ,HERE ,PAST-CELL-EAST ,CELL-EAST>
+				,P?SOUTH)
+			       (ELSE ,P?NORTH)>>)
+	       (<VERB? REZROV>
+		<COND (<HELD? ,MAGIC-CUBE>
+		       <FCLEAR ,CELL-DOOR ,LOCKED>
+		       <FSET ,CELL-DOOR ,OPENBIT>
+		       <QUEUE I-PRISON-GUARDS 2>
+		       <TELL
+"The door bursts outward in an explosion of power! Immediately, you hear
+the shouts of guards and the rattle of weapons." CR>)
+		      (ELSE
+		       <REZROV-TOUGH-DOOR>)>)>>
+
+<ROUTINE PAST-CELL-EAST-EXIT ()
+	 <COND (<FSET? ,CELL-DOOR ,OPENBIT>
+		<JIGS-UP ,PAST-CELL-GUARDS-KILL-YOU>
+		<RFALSE>)
+	       (ELSE
+		<TELL ,DOOR-LOCKED>
+		<TELL ,PERIOD>
+		<RFALSE>)>>
+
+<GLOBAL PAST-CELL-GUARDS-KILL-YOU
+"You exit into a tangle of guards, who promptly dispatch you for escaping
+and resisting arrest.">
+
+<GLOBAL DOOR-LOCKED "The door is closed and locked">
+
+"CONNECTIVITY CUBE"
+
+<OBJECT CONNECTIVITY-CUBE
+	(IN ROC-NEST)
+	(DESC "cube")
+	(SYNONYM CUBE CUBES)
+	(ADJECTIVE LQ ;C12 SMALL FEATURELESS WHITE)
+	(NAME 0)
+	(TEXT "spiders")
+	(FLAGS TAKEBIT TRYTAKEBIT NDESCBIT)
+	(ACTION CUBE-F)
+	(DESCFCN CUBE-DESC)
+        (GENERIC GENERIC-CUBE-F)
+	(CUBE CONNECTIVITY-ROOM)>
+
+<ROOM CONNECTIVITY-ROOM
+      (IN ROOMS)
+      (DESC "String Room")
+      (EAST PER MAGIC-BOX-EXIT)
+      (SOUTH TO RETREAT)
+      (CUBE CONNECTIVITY-CUBE)
+      (ACTION CONNECTIVITY-ROOM-F)
+      (FLAGS RLANDBIT)>
+
+<ROUTINE CONNECTIVITY-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the nexus of a web of multicolored strings and threads of
+light. They come in from the far distance in graceful curves or tangled,
+jagged paths. In the center of the room they tie together into a ball
+that looks like gossamer yarn or glowing cotton candy. One bright set of
+threads points south to a gap in the weave and another points east to
+a similar gap." CR>)
+	       (<EQUAL? .RARG ,M-LEAVE>
+		<RECOVER-CUBE>)>>
+
+<ROUTINE CUBE-NAME (CUBE "AUX" WRD CNT CHR)
+	 <SET WRD <GETP .CUBE ,P?NAME>>
+	 <COND (<NOT <ZERO? .WRD>>
+		<SET CNT <GET .WRD 1>>
+		<SET WRD <REST .WRD 4>>
+		<TELL "\"">
+		<REPEAT ()
+			<COND (<ZERO? <SET CHR <GETB .WRD 0>>>
+			       <RETURN>)>
+			<PRINTC .CHR>
+			<SET WRD <REST .WRD>>
+			<SET CNT <- .CNT 1>>
+			<COND (<EQUAL? .CNT 0>
+			       <RETURN>)>>
+		<TELL "\"">)
+	       (ELSE <TELL "no word">)>>
+
+<OBJECT QWORD
+	(IN GLOBAL-OBJECTS)
+	(DESC "handwritten word")
+	(SYNONYM QWORD)
+	(FLAGS NDESCBIT)>
+
+<GLOBAL CUBE-LIST
+	<PTABLE EARTH-CUBE <VOC "AQ" ADJECTIVE>
+		WATER-CUBE <VOC "BQ" ADJECTIVE>
+		AIR-CUBE <VOC "CQ" ADJECTIVE>
+		FIRE-CUBE <VOC "DQ" ADJECTIVE>
+		DARK-CUBE <VOC "EQ" ADJECTIVE>
+		MIND-CUBE <VOC "FQ" ADJECTIVE>
+		LIGHT-CUBE <VOC "GQ" ADJECTIVE>
+		LIFE-CUBE <VOC "HQ" ADJECTIVE>
+		DEATH-CUBE <VOC "IQ" ADJECTIVE>
+		CHANGE-CUBE <VOC "JQ" ADJECTIVE>
+		TIME-CUBE <VOC "KQ" ADJECTIVE>
+		CONNECTIVITY-CUBE <VOC "LQ" ADJECTIVE>
+		MAGIC-CUBE <VOC "MQ" ADJECTIVE>
+		CUBE-1 <VOC "AZ" ADJECTIVE>
+		CUBE-2 <VOC "BZ" ADJECTIVE>
+		CUBE-3 <VOC "CZ" ADJECTIVE>
+		CUBE-4 <VOC "DZ" ADJECTIVE>
+		CUBE-5 <VOC "EZ" ADJECTIVE>
+		CUBE-6 <VOC "FZ" ADJECTIVE>
+		CUBE-7 <VOC "GZ" ADJECTIVE>
+		CUBE-8 <VOC "HZ" ADJECTIVE>
+		CUBE-9 <VOC "IZ" ADJECTIVE>
+		CUBE-10 <VOC "JZ" ADJECTIVE>
+		CUBE-11 <VOC "KZ" ADJECTIVE>>>
+
+<ROUTINE CUBE-ADJ (OBJ "AUX" TBL)
+	 <COND (<SET TBL <ZMEMQ .OBJ ,CUBE-LIST 47>>
+		<GET .TBL 1>)>>
+
+<ROUTINE WRITE-ON-CUBE (OBJ "AUX" ADJ PTR F)
+	 <COND (<SET ADJ <CUBE-ADJ .OBJ>>
+		<COND (<ZERO? <SET PTR <GETP .OBJ ,P?NAME>>>
+		       <SET F <GETPT .OBJ ,P?ADJECTIVE>>
+		       <PUTB .F 1 <GETB .F 2>> ;"REMOVE 'FEATURELESS' AS ADJ."
+		       <SET PTR ,P-QNEXT>
+		       <SETG P-QNEXT <REST ,P-QNEXT 10>>
+		       <PUT ,P-QNEXT 0 <>>)>
+		<PUTP .OBJ
+		      ,P?NAME
+		      %<COND (<GASSIGNED? ZILCH> '.PTR)
+			     (ELSE '<CHTYPE .PTR TABLE>)>>
+		<FSET .OBJ ,THE>
+		<QCOPY .ADJ ,P-QWORD .PTR>
+		.ADJ)>>
+
+
diff --git a/debug.zil b/debug.zil
new file mode 100644
index 0000000..dbc91b0
--- /dev/null
+++ b/debug.zil
@@ -0,0 +1,40 @@
+%<DEBUG-CODE <GLOBAL ZDEBUG <>>>
+
+%<DEBUG-CODE <SYNTAX $DEBUG = V-$DEBUG>>
+
+%<DEBUG-CODE
+  <ROUTINE V-$DEBUG ()
+	 <COND (<SETG ZDEBUG <NOT ,ZDEBUG>>
+		<TELL-ON>)
+	       (T <TELL-OFF>)>>>
+
+%<DEBUG-CODE <ROUTINE TELL-ON () <TELL "On." CR>>>
+%<DEBUG-CODE <ROUTINE TELL-OFF () <TELL "Off." CR>>>
+
+%<DEBUG-CODE <SYNTAX $BLORPLE OBJECT = V-$BLORPLE>>
+
+%<DEBUG-CODE
+  <ROUTINE V-$BLORPLE ("AUX" CUBE)
+	 <MOVE ,PRSO ,WINNER>
+	 <V-BLORPLE>>>
+
+%<DEBUG-CODE <SYNTAX $CHEAT = V-$CHEAT>>
+
+%<DEBUG-CODE
+  <ROUTINE V-$CHEAT ("AUX" CUBE)
+	 <TELL "[Solution: " D ,TIME-CUBE "]" CR>>>
+
+%<DEBUG-CODE
+  <SYNTAX $TAKE OBJECT = V-$TAKE>>
+
+%<DEBUG-CODE
+  <ROUTINE V-$TAKE ("AUX" CUBE)
+	 <MOVE ,PRSO ,WINNER>
+	 <FCLEAR ,PRSO ,NDESCBIT>
+	 <FCLEAR ,PRSO ,INVISIBLE>
+	 <TELL ,TAKEN>>>
+
+%<DEBUG-CODE
+  <ROUTINE TELL-C-INTS ()
+	   <TELL "[MaxInts: " N </ <- ,C-TABLELEN ,C-MAXINTS> ,C-INTLEN>
+		 "]" CR>>>
\ No newline at end of file
diff --git a/globals.zil b/globals.zil
new file mode 100644
index 0000000..72ef08b
--- /dev/null
+++ b/globals.zil
@@ -0,0 +1,1087 @@
+"GLOBALS for
+			      MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+<DIRECTIONS ;"Do not change the order of the first 8 without consulting MARC!"
+ 	    NORTH NE EAST SE SOUTH SW WEST NW UP DOWN IN OUT>
+
+<GLOBAL HERE <>>
+
+<GLOBAL LIT <>>
+
+<GLOBAL MOVES 0>
+
+<GLOBAL SCORE 0>
+
+<GLOBAL INDENTS
+	<PTABLE ""
+	        "  "
+	        "    "
+	        "      "
+	        "        "
+	        "          ">>
+
+<GLOBAL DIR-TABLE
+	<PLTABLE 1 P?NORTH "north"
+		 2 P?EAST "east"
+		 4 P?WEST "west"
+		 8 P?SOUTH "south"
+		 16 P?NE "northeast"
+		 32 P?NW "northwest"
+		 64 P?SE "southeast"
+		 128 P?SW "southwest">>
+
+<CONSTANT DIR-BIT 1>
+<CONSTANT DIR-DIR 2>
+<CONSTANT DIR-NAME 3>
+
+<ROUTINE DIR-BASE (DIR I O "AUX" (CNT 0) (L <GET ,DIR-TABLE 0>))
+	 <REPEAT ()
+		 <COND (<G? .CNT .L> <RFALSE>)
+		       (<EQUAL? <GET ,DIR-TABLE <+ .CNT .I>> .DIR>
+			<RETURN <GET ,DIR-TABLE <+ .CNT .O>>>)
+		       (ELSE
+			<SET CNT <+ .CNT 3>>)>>>
+
+"global objects and associated routines"
+
+<OBJECT GLOBAL-OBJECTS
+	(FLAGS AN
+	       BRIEFBIT
+	       CONTBIT
+	       DOORBIT
+	       INVISIBLE
+	       LOCKED
+	       NDESCBIT
+	       NOABIT
+	       NOTHEBIT
+	       ONBIT
+	       OPENBIT
+	       PERSON
+	       RAIRBIT
+	       READBIT
+	       RLANDBIT
+	       RMUNGBIT
+	       RWATERBIT
+	       SCROLLBIT
+	       SEARCHBIT
+	       SPELLBIT
+	       SURFACEBIT
+	       TAKEBIT
+	       THE
+	       TOOLBIT
+	       TOUCHBIT
+	       TRANSBIT
+	       TRYTAKEBIT
+	       VEHBIT
+	       WEAPONBIT)>
+
+<OBJECT LOCAL-GLOBALS
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM ZZMGCK) ;"Yes, this needs to exist."
+	;(DESCFCN 0)
+        ;(GLOBAL GLOBAL-OBJECTS)
+	;(FDESC "F")
+	;(LDESC "F")
+	;(PSEUDO "FOOBAR" V-WALK)
+	;(SIZE 0)
+	;(TEXT "")
+	;(EXITS 0)
+	;(CAPACITY 0)>
+
+<OBJECT ROOMS
+	(IN TO ROOMS)>
+
+<OBJECT INTNUM
+	(IN GLOBAL-OBJECTS)
+	(DESC "number")
+	(SYNONYM INTNUM)
+	(ADJECTIVE NUMBER)>
+
+<OBJECT PSEUDO-OBJECT
+	(IN GLOBAL-OBJECTS)
+	(DESC "pseudo")
+	(ACTION ME-F)>
+
+<OBJECT IT
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM IT THEM OBJECT HIM)
+	(ADJECTIVE HER)
+	(DESC "it")
+	(FLAGS AN NOABIT NOTHEBIT NDESCBIT TOUCHBIT)>
+
+<OBJECT NOT-HERE-OBJECT
+	(DESC "it")
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION NOT-HERE-OBJECT-F)>
+
+<ROUTINE NOT-HERE-OBJECT-F ("AUX" TBL (PRSO? T) OBJ (X <>))
+	 <COND (<AND <PRSO? ,NOT-HERE-OBJECT>
+		     <PRSI? ,NOT-HERE-OBJECT>>
+		<TELL "Those things aren't here!" CR>
+		<RTRUE>)
+	       (<PRSO? ,NOT-HERE-OBJECT>
+		<SET TBL ,P-PRSO>
+		<COND (<OR <VERB? FOLLOW LEARN WHAT>
+			   <VERB? WHERE WHO WAIT-FOR>
+			   <VERB? CAST WALK-TO FIND>>
+		       <SET X T>)>
+		%<DEBUG-CODE
+		  <COND (<VERB? $BLORPLE $TAKE>
+			 <SET X T>)>>)
+	       (T
+		<SET TBL ,P-PRSI>
+		<COND (<VERB? ASK-ABOUT ASK-FOR TELL-ABOUT>
+		       <SET X T>)>
+		<SET PRSO? <>>)>
+	 <COND (.X
+		<COND (<SET OBJ <FIND-NOT-HERE .TBL .PRSO?>>
+		       <COND (<NOT <EQUAL? .OBJ ,NOT-HERE-OBJECT>>
+			      <RTRUE>)>)
+		      (T
+		       <RFALSE>)>
+		<COND (<AND <NOT <VERB? FIND FOLLOW WHERE>>
+			    <NOT <VERB? LEARN CAST>>>
+		       <TELL ,MORE-SPECIFIC ", I'm afraid." CR>
+		       <RTRUE>)>)>
+	 ;"Here is the default 'cant see any' printer"
+	 <COND (<EQUAL? ,WINNER ,PLAYER>
+		<TELL "You">)
+	       (ELSE
+		<TELL CTHE ,WINNER>)>
+	 <TELL " can't see">
+	 <COND (<NOT <NAME? ,P-XNAM>> <TELL " any">)>
+	 <NOT-HERE-PRINT .PRSO?>
+	 <TELL " here." CR>
+	 <END-QUOTE>>
+
+<ROUTINE FIND-NOT-HERE (TBL PRSO? "AUX" M-F OBJ)
+;"Special-case code goes here. <MOBY-FIND .TBL> returns # of matches. If 1,
+then P-MOBY-FOUND is it. You can treat the 0 and >1 cases alike or differently.
+Always return RFALSE (not handled) if you have resolved the problem."
+	<SET M-F <MOBY-FIND .TBL>>
+	%<DEBUG-CODE
+	  <COND (,ZDEBUG
+		 <TELL "[Found " N .M-F " obj]" CR>)>>
+	<COND (<EQUAL? 1 .M-F>
+	       %<DEBUG-CODE
+		 <COND (,ZDEBUG
+			<TELL "[Namely: " D ,P-MOBY-FOUND "]" CR>)>>
+	       <COND (.PRSO?
+		      <SETG PRSO ,P-MOBY-FOUND>)
+		     (T
+		      <SETG PRSI ,P-MOBY-FOUND>)>
+	       <RFALSE>)
+	      (T
+	       ,NOT-HERE-OBJECT)>>
+
+<ROUTINE NOT-HERE-PRINT (PRSO?)
+	 <TELL " ">
+	 <COND (,P-OFLAG
+	        <COND (,P-XADJ
+		       <PRINTB ,P-XADJN>)>
+	        <COND (,P-XNAM
+		       <PRINTB ,P-XNAM>)>)
+               (ELSE
+	        <THING-PRINT .PRSO?>)>>
+
+<OBJECT LIGHT
+	(IN GLOBAL-OBJECTS)
+	(DESC "light")
+	(SYNONYM LIGHT LIGHTS PILE)
+	(ADJECTIVE PILE)
+        (ACTION LIGHT-F)>
+
+<ROUTINE LIGHT-F ()
+	 <COND (<VERB? LAMP-ON>
+		<COND (<FSET? ,HERE ,ONBIT>
+		       <TELL ,IT-IS-ALREADY "light" ,PERIOD>)
+		      (T
+		       <TELL
+"Perhaps you should \"frotz\" something?" CR>)>)
+	       (<VERB? LAMP-OFF>
+		<TELL ,WASTE-OF-TIME>)
+	       (<VERB? THROUGH>
+		<COND (<EQUAL? ,HERE ,GRUE-CAVE ,PILLAR-ROOM>
+		       <GOTO ,LIGHT-POOL>)>)
+	       (<VERB? EXAMINE>
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <COND (<EQUAL? ,HERE ,LIGHT-POOL>
+			      <TELL
+"The light is so bright and painful you can barely stand it." CR>)
+			     (ELSE
+			      <TELL
+"It hurts to look at light so dim you could hardly discern it
+normally." CR>)>)
+		      (<EQUAL? ,HERE ,DARK-CAVE ,GRUE-CAVE>
+		       <TELL
+"The light is in a small, dimly glowing pile." CR>)>)>>
+
+<OBJECT GLOBAL-HOLE
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "hole")
+	(SYNONYM HOLE)
+	(ADJECTIVE MUDDY)
+	(GENERIC GENERIC-HOLE-F)
+	(ACTION GLOBAL-HOLE-F)>
+
+<ROUTINE GLOBAL-HOLE-F ()
+	 <COND (<VERB? THROUGH LEAP CLIMB-DOWN>
+		<DO-WALK ,P?DOWN>)
+	       (<AND <VERB? PUT>
+		     <HELD? ,PRSO>
+		     <EQUAL? ,PRSI ,GLOBAL-HOLE>>
+		<MOVE ,PRSO ,LOST-ON-LAND>
+		<TELL
+"You drop " THE ,PRSO " through the hole, and it disappears." CR>)
+	       (<VERB? LOOK-INSIDE LOOK-DOWN>
+		<TELL "You see clouds!" CR>)
+	       (<VERB? REACH-IN>
+		<TELL "You find nothing of interest." CR>)>>
+
+<OBJECT CEILING
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "ceiling")
+	(SYNONYM CEILIN ROOF)
+	(ACTION CEILING-F)>
+
+<ROUTINE CEILING-F ()
+	 <COND (<VERB? LOOK-UNDER>
+		<PERFORM ,V?LOOK>
+		<RTRUE>)>>
+
+<OBJECT ICE
+	(IN GLOBAL-OBJECTS)
+	(DESC "ice")
+	(SYNONYM ICE)
+	(FLAGS NOABIT)
+	(ACTION ICE-F)>
+
+<GLOBAL ICED-OBJECT <>>
+
+<ROUTINE ICE-F ()
+	 <COND (<IN? ,ICEBERG ,HERE>
+		<REDIRECT ,ICE ,ICEBERG>)
+	       (<AND ,ICED-OBJECT <ACCESSIBLE? ,ICED-OBJECT>>
+		<COND (<VERB? EXAMINE>
+		       <TELL ,IT-LOOKS-LIKE "an icy " D ,ICED-OBJECT ,PERIOD>)
+		      (<VERB? RUB>
+		       <TELL "It's cold." CR>)>)
+	       (<NOT <EQUAL? ,HERE ,GLACIER-ROOM>>
+		<TELL "There is no ice here." CR>)>>
+
+<OBJECT AIR
+	(IN GLOBAL-OBJECTS)
+	(DESC "air")
+	(SYNONYM AIR)
+	(FLAGS AN NOABIT)>
+
+<OBJECT HANDS
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM HANDS)
+	(ADJECTIVE BARE)
+	(DESC "your hand")
+	(FLAGS NDESCBIT TOOLBIT TOUCHBIT NOABIT NOTHEBIT)>
+
+<OBJECT HEAD
+	(IN GLOBAL-OBJECTS)
+	(DESC "your head")
+	(SYNONYM HEAD FACE)
+	(ADJECTIVE YOUR MY)
+	(FLAGS NOABIT NOTHEBIT)>
+
+<OBJECT EYES
+	(IN GLOBAL-OBJECTS)
+	(DESC "your eyes")
+	(SYNONYM EYE EYES)
+	(ADJECTIVE YOUR MY)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION EYES-F)>
+
+<ROUTINE EYES-F ()
+	 <COND (<VERB? OPEN>
+		<TELL "They are." CR>)
+	       (<VERB? CLOSE>
+		<TELL "That won't help." CR>)
+	       (<NOT ,LIT>
+		<TELL ,TOO-DARK>)
+	       (<EQUAL? ,HERE ,NORTH-SNAKE-ROOM ,SOUTH-SNAKE-ROOM>
+		<COND (<VERB? EXAMINE>
+		       <TELL "The eye stares balefully at you." CR>)
+		      (ELSE
+		       <REDIRECT ,EYES ,SNAKE>)>)>>
+
+<OBJECT PLAYER
+	(IN COUNCIL-CHAMBER)
+	(SYNONYM PROTAG)
+	(DESC "it")
+	(FLAGS NDESCBIT INVISIBLE)
+	(ACTION PLAYER-F)>
+
+<ROUTINE PLAYER-F ()
+	 <COND (<NOT ,CHANGED?> <RFALSE>)
+	       (<EQUAL? ,CHANGED? ,GROUPER>
+		<COND (<VERB? WRITE OPEN CLOSE TAKE DROP PUT>
+		       <TELL
+"Your finny fins aren't capable of that." CR>)>)
+	       (<EQUAL? ,CHANGED? ,GRUE>
+		<COND (<VERB? SLAVER>
+		       <TELL
+"You do that very well for such an inexperienced grue." CR>)
+		      (<AND <VERB? EAT> <HELD? ,PRSO>>
+		       <REMOVE ,PRSO>
+		       <TELL
+"That tasted surprisingly good." CR>)>)
+	       (<EQUAL? ,CHANGED? ,OGRE>
+		<COND (<VERB? SMELL>
+		       <TELL
+"You are completely congested and can't smell a thing. This may explain
+why, in spite of their appalling sanitary habits, ogres are not
+extinct." CR>)>)>>
+
+<OBJECT ME
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM ME MYSELF I SELF)
+	(DESC "yourself")
+	(FLAGS PERSON TOUCHBIT NOABIT NOTHEBIT)
+	(ACTION ME-F)>
+
+<ROUTINE ME-F ("AUX" OLIT)
+	 <COND (<AND <VERB? EXAMINE>
+		     <EQUAL? ,PRSO ,ME>>
+		<V-DIAGNOSE>)
+	       (<VERB? TELL>
+		<TELL
+"Talking to yourself is a sign of impending mental collapse." CR>
+		<END-QUOTE>)
+	       (<VERB? LISTEN>
+		<TELL "Yes?" CR>)
+	       (<VERB? ALARM>
+		<TELL ,YOU-ARE>
+		<TELL ,PERIOD>)
+	       (<VERB? GIVE>
+		<COND (<EQUAL? ,PRSO ,ME>
+		       <V-SQUEEZE>)
+		      (<EQUAL? ,PRSI ,ME>
+		       <COND (<IN? ,PRSO ,PLAYER>
+			      <PRE-TAKE>)
+			     (T
+			      <PERFORM ,V?TAKE ,PRSO>
+			      <RTRUE>)>)>)
+	       (<VERB? MOVE>
+		<V-WALK-AROUND>)
+	       (<VERB? SEARCH>
+		<V-INVENTORY>
+		<RTRUE>)
+	       (<VERB? KILL MUNG PLANT>
+		<JIGS-UP "Done.">
+		<RTRUE>)
+	       (<VERB? WHO>
+		<V-WHAT>)
+	       (<VERB? FOLLOW>
+		<TELL
+"You're getting ahead of yourself." CR>)
+	       (<VERB? WRITE WRITE-ON>
+		<TELL
+,YOU-ARENT "a tattoo artist!" CR>)
+	       (<VERB? TINSOT>
+		<TELL
+"You are covered with a thin film of ice, which shatters as soon as you
+move." CR>)
+	       (<VERB? CASKLY>
+		<V-SQUEEZE>)
+	       (<VERB? YOMIN>
+		<TELL
+"You would know better than I." CR>)>>
+
+<OBJECT GLOBAL-ROOM
+	(IN GLOBAL-OBJECTS)
+	(DESC "room")
+	(SYNONYM ROOM CHAMBER PLACE)
+	(ADJECTIVE AREA)
+	(ACTION GLOBAL-ROOM-F)>
+
+<ROUTINE GLOBAL-ROOM-F ()
+	 <COND (<VERB? LOOK EXAMINE LOOK-INSIDE>
+		<V-LOOK>
+		<RTRUE>)
+	       (<VERB? THROUGH WALK-TO>
+		<V-WALK-AROUND>)
+	       (<VERB? DROP LEAVE EXIT>
+		<DO-WALK ,P?OUT>)
+	       (<VERB? WALK-AROUND>
+		<TELL
+"Walking around the room reveals nothing new. To move elsewhere, just type
+the desired direction." CR>)
+	       (<VERB? LAMP-ON>
+		<PERFORM ,V?LAMP-ON ,LIGHT>
+		<RTRUE>)>>
+
+<OBJECT NORTH-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "north wall")
+	(SYNONYM WALL)
+	(ADJECTIVE NORTH N)
+	(ACTION WALL-F)
+	(EXITS %,C-NORTH)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT EAST-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "east wall")
+	(SYNONYM WALL)
+	(ADJECTIVE EAST E BLANK)
+	(ACTION WALL-F)
+	(EXITS %,C-EAST)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT WEST-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "west wall")
+	(SYNONYM WALL)
+	(ADJECTIVE WEST W)
+	(ACTION WALL-F)
+	(EXITS %,C-WEST)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT SOUTH-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "south wall")
+	(SYNONYM WALL)
+	(ADJECTIVE SOUTH S)
+	(ACTION WALL-F)
+	(EXITS %,C-SOUTH)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT NE-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "northeast wall")
+	(SYNONYM WALL)
+	(ADJECTIVE NORTHEAST NE)
+	(ACTION WALL-F)
+	(EXITS %,C-NE)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT NW-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "northwest wall")
+	(SYNONYM WALL)
+	(ADJECTIVE NORTHWEST NW)
+	(ACTION WALL-F)
+	(EXITS %,C-NW)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT SE-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "southeast wall")
+	(SYNONYM WALL)
+	(ADJECTIVE SOUTHEAST SE)
+	(ACTION WALL-F)
+	(EXITS %,C-SE)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<OBJECT SW-WALL
+	(IN GLOBAL-OBJECTS)
+	(DESC "southwest wall")
+	(SYNONYM WALL)
+	(ADJECTIVE SOUTHWEST SW)
+	(ACTION WALL-F)
+	(EXITS %,C-SW)
+	(GENERIC GENERIC-RANDOM-F)>
+
+<ROUTINE WALL-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<AND <EQUAL? ,HERE ,MAZE-ANTEROOM>
+			    <EQUAL? ,PRSO ,NORTH-WALL>
+			    ,MAZE-EXIT-FLAG>
+		       <TELL "There is a hole there." CR>)
+		      (<NOT <ZERO? <GETPT ,HERE ,P?EXITS>>>
+		       <TELL
+"The wall is marble.">
+		       <DESCRIBE-MAZE-WALLS>
+		       <CRLF>)
+		      (ELSE
+		       <TELL ,IT-LOOKS-LIKE "a wall." CR>)>)>>
+
+<OBJECT DIRT
+	(IN GLOBAL-OBJECTS)
+	(DESC "dirt")
+	(SYNONYM RUBBLE DEBRIS DUST DIRT)
+	(FLAGS NOABIT)>
+
+<OBJECT GROUND
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM FLOOR GROUND FIELD)
+	(ADJECTIVE STONE SANDY TINY LEVEL)
+	(DESC "ground")
+	(FLAGS NOABIT)
+	(ACTION GROUND-F)>
+
+<ROUTINE GROUND-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (,FALLING?
+		       <TELL
+"You can see the ground rushing towards you from below, or vice versa." CR>)
+		      (<FSET? ,HERE ,RAIRBIT>
+		       <TELL
+"It's a long way down." CR>)
+		      (ELSE
+		       <TELL
+"It's still there." CR>)>)
+	       (<AND <VERB? PUT> <EQUAL? ,GROUND ,PRSI>>
+		<PERFORM ,V?PLANT ,PRSO>
+		<RTRUE>)
+	       (<VERB? CLIMB-UP CLIMB-ON CLIMB-FOO BOARD>
+		<TELL ,WASTE-OF-TIME>)
+	       (<VERB? LOOK-UNDER>
+		<TELL "You've never mastered an X-ray vision spell." CR>)>>
+
+<OBJECT CORRIDOR
+	(IN GLOBAL-OBJECTS)
+	(DESC "passage")
+	(SYNONYM PASSAGE CORRIDOR EXIT)
+	(ADJECTIVE LONG DARK)
+	(ACTION CORRIDOR-F)>
+
+<ROUTINE CORRIDOR-F ()
+	 <COND (<VERB? THROUGH WALK-TO>
+		<V-WALK-AROUND>)>>
+
+<OBJECT WALLS
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "wall")
+	(SYNONYM WALL WALLS)>
+
+<OBJECT GLOBAL-GRUE
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM GRUE)
+	(ADJECTIVE LURKIN SINIST SILENT)
+	(DESC "lurking grue")
+	(ACTION GLOBAL-GRUE-F)
+	(FLAGS NDESCBIT THE PERSON)>
+
+<GLOBAL LURKING " lurking in the darkness nearby.">
+
+<ROUTINE GLOBAL-GRUE-F ()
+	 <COND (<EQUAL? ,WINNER ,GLOBAL-GRUE>
+		<TELL
+"There is no answer.">
+		<END-QUOTE>)
+	       (<VERB? WHAT>
+		<TELL
+"Grues are darkness-loving, enchanterivorous monsters." CR>)
+	       (<OR <HOSTILE-VERB?>
+		    <VERB? EXAMINE RAISE LOWER SMELL TAKE LOOK-UNDER>>
+		<CANT-SEE-GRUE>)
+	       (<VERB? WHERE>
+		<TELL
+"There is no grue here, but I'm sure there is at least one" ,LURKING " I'd
+stay near a light source if I were you!" CR>)
+	       (<VERB? LISTEN>
+		<TELL
+"It makes no sound but is always" ,LURKING CR>)
+	       (<VERB? FROTZ>
+		<COND (,LIT
+		       <TELL "There aren't any grues here -- it's light!" CR>)
+		      (T
+		       <TELL
+"There's a flash of light nearby, and you glimpse a horrible, multifanged
+creature, a look of sheer terror on its face. It charges away, gurgling in
+agony, tearing at its glowing fur." CR>)>)
+	       (<VERB? SNAVIG>
+		<CANT-SEE-GRUE>)
+	       (<SPELL-VERB?>
+		<TELL
+"Nothing happens. Either there are no grues nearby, or they were able to
+dodge in time." CR>)>>
+
+<ROUTINE CANT-SEE-GRUE ()
+	 <TELL ,YOU-CANT-SEE "any grue here (thankfully)." CR>>
+
+<OBJECT GRUE
+	(IN LOCAL-GLOBALS)
+	(SYNONYM GRUE GRUES TROOP SHAPES)
+	(ADJECTIVE LURKIN SINIST SILENT)
+	(DESC "grue")
+	(FLAGS NDESCBIT THE PERSON)
+	(ACTION GRUE-F)>
+
+<ROUTINE GRUE-F ("AUX" OLIT)
+	 <COND (<AND <NOT <EQUAL? ,CHANGED? ,GRUE>>
+		     <NOT <EQUAL? ,HERE ,GRUE-CAVE ,PILLAR-ROOM ,LIGHT-POOL>>>
+		<REDIRECT ,GRUE ,GLOBAL-GRUE>)
+	       (<EQUAL? ,WINNER ,GRUE>
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <JIGS-UP
+"Your inability to speak grue, not to mention your use of a human
+tongue, arouses the grues and seals your fate.">)
+		      (ELSE
+		       <CALLED-ATTENTION>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE LOOK-UNDER>
+		<COND (,LIT
+		       <TELL
+"The grues look exactly as you would expect, only worse." CR>)
+		      (ELSE
+		       <GLOBAL-GRUE-F>)>)
+	       (<AND <VERB? GIVE>
+		     <EQUAL? ,PRSI ,GRUE>>
+		<COND (<FSET? ,PRSO ,ONBIT>
+		       <GRUES-NOTICE-LIGHT>)
+		      (ELSE
+		       <REMOVE ,PRSO>
+		       <COND (<EQUAL? ,PRSO ,BREAD ,FISH>
+			      <TELL
+"The grue snarls at you, but takes it anyway">)
+			     (ELSE
+			      <TELL
+"It looks quizzically at the " 'PRSO ", then snatches it">)>
+		       <TELL " and noisily wolfs it down, teeth
+tearing it into tiny gobbets." CR>)>)
+	       (<OR <HOSTILE-VERB?> <VERB? RAISE LOWER TAKE>>
+		<COND (<EQUAL? ,CHANGED? ,GRUE>
+		       <JIGS-UP
+"The grue is the most evil-tempered of all creatures. When dealing
+with grues, discretion and good intentions often count for
+nothing. To say that grues are touchy, even with their own kind, is an
+understatement. \"Sour as a grue\" is a common expression, even among the
+creatures themselves. You have made a fatal mistake.">)
+		      (ELSE <CALLED-ATTENTION>)>)
+	       (<VERB? WHERE>
+		<TELL
+"There are grues all around." CR>)
+	       (<VERB? LISTEN>
+		<TELL
+"The grues gurgle unsettlingly, intent upon their business." CR>)
+	       (<VERB? SNAVIG>
+		<COND (<EQUAL? ,HERE ,GRUE-CAVE ,LIGHT-POOL ,PILLAR-ROOM>
+		       <TELL
+"You feel yourself changing in a very unpleasant way. Your claws feel odd,
+and you have an uncontrollable tendency to slaver. You gurgle vilely
+to yourself, worrying about the presence of light.">
+		       <COND (<FSET? ,WINNER ,ONBIT>
+			      <JIGS-UP
+" A justified worry, as the glow from your own body fries you to a crisp!">)
+			     (ELSE
+			      <COND (<EQUAL? ,HERE ,GRUE-CAVE>
+				     <TELL
+" Directly in front of you, a horrific creature recoils with a look of
+shocked surprise. It scuttles off, perplexed.">)>
+			      <COND (<SET OLIT <LIT? ,HERE>>
+				     <TELL
+" The light from " THE .OLIT " hurts your eyes.">)>
+			      <SETG CHANGED? ,GRUE>
+			      <QUEUE I-SNAVIG 12>
+			      <SETG LIT <LIT? ,HERE>>
+			      <TELL CR CR>
+			      <PERFORM ,V?LOOK>
+			      <RTRUE>)>)
+		      (ELSE
+		       <TELL
+"You see no grues here." CR>)>)
+	       (<VERB? YOMIN>
+		<TELL
+"You sense ravening hunger and a nasty, mean, and brutish
+disposition." CR>)
+	       (<SPELL-VERB?>
+		<COND (<AND <NOT <EQUAL? ,CHANGED? ,GRUE>>
+			    ,LIT>
+		       <GLOBAL-GRUE-F>)
+		      (ELSE
+		       <TELL ,NOTHING-HAPPENS>)>)>>
+
+<ROUTINE CALLED-ATTENTION ()
+	 <JIGS-UP
+"You've called attention to yourself. The grues invite you to dinner.">>
+
+<OBJECT LOCAL-WATER
+	(SYNONYM WATER)
+	(ADJECTIVE FRESH SALT SEA)
+	(DESC "water")
+	(FLAGS NOABIT)
+	(ACTION WATER-F)>
+
+<OBJECT WATER
+	(IN LOCAL-GLOBALS)
+	(SYNONYM WATER)
+	(DESC "water")
+	(FLAGS NDESCBIT NOABIT)
+	(ACTION WATER-F)>
+
+<ROUTINE WATER-F ()
+	 <COND (<AND <VERB? POUR THROW>
+		     <EQUAL? ,PRSO ,LOCAL-WATER>>
+		<COND (<AND <LOC ,PRSO>
+			    <IN? <LOC ,PRSO> ,WINNER>>
+		       <PERFORM ,V?POUR <LOC ,PRSO>>
+		       <RTRUE>)
+		      (ELSE
+		       <DONT-HAVE-THAT>)>)
+	       (<VERB? EAT DRINK DRINK-FROM>
+	        <COND (<EQUAL? ,PRSO ,LOCAL-WATER>
+		       <COND (<IN? <LOC ,PRSO> ,WINNER>
+			      <COND (<FSET? <LOC ,PRSO> ,OPENBIT>
+				     <REMOVE ,PRSO>)
+				    (ELSE
+				     <TELL-OPEN-CLOSED ,BOTTLE>
+				     <RTRUE>)>)
+			     (<NOT <GLOBAL-IN? ,WATER ,HERE>>
+			      <TELL ,YOU-DONT-HAVE THE <LOC ,PRSO> ,PERIOD>
+			      <RTRUE>)>)>
+		<COND (<OR <AND <EQUAL? ,PRSO ,LOCAL-WATER>
+				<FSET? ,PRSO ,RMUNGBIT>>
+			   <AND <EQUAL? ,PRSO ,WATER>
+				<EQUAL? ,HERE
+					,OCEAN-ROOM
+					,LOST-IN-OCEAN
+					,OCEAN-FLOOR>>>
+		       <TELL
+"It's bitter and you spit it out immediately.">)
+		      (ELSE
+		       <TELL
+"That was refreshing, but you shouldn't drink untested water.">)>
+		<CRLF>)
+	       (<VERB? REACH-IN RUB>
+		<TELL
+"It's wet." CR>)
+	       (<VERB? LOOK-INSIDE LOOK-UNDER>
+		<MAKE-OUT>)
+	       (<VERB? THROUGH LEAP>
+		<COND (<FSET? ,HERE ,RWATERBIT>
+		       <TELL ,YOU-ARE ,PERIOD>)>)>>
+
+<ROOM RETREAT
+      (IN ROOMS)
+      (DESC "Enchanters' Retreat")
+      (ACTION RETREAT-F)
+      (FLAGS RLANDBIT ONBIT OUTSIDE)
+      (THINGS
+       <PSEUDO (FLATHEAD MOUNTAIN MOUNTAIN-PSEUDO)
+	       (ENCHANTER RETREAT RANDOM-PSEUDO)
+	       (<> BARSAP ANSWER-PSEUDO)
+	       (<> BARBEL ANSWER-PSEUDO)
+	       (BARBEL GURTH ANSWER-PSEUDO)
+	       (<> GUSTAR ANSWER-PSEUDO)
+	       (GUSTAR WOOMAX ANSWER-PSEUDO)
+	       (<> DIMITHIO ANSWER-PSEUDO)
+	       (DIMITHIO BORPHEE ANSWER-PSEUDO)
+	       (<> FORBURN ANSWER-PSEUDO)
+	       (FORBURN WILY ANSWER-PSEUDO)
+	       (<> BERKNIP ANSWER-PSEUDO)>)>
+
+<ROUTINE RETREAT-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"The Enchanters' Retreat is an old stone structure perched high in the
+mountains. For generations, retired (or even burnt-out) enchanters have
+come here to breathe the clean mountain air, watch the stars, and rest
+from their exertions. The appointments are simple, the fare is unsophisticated,
+but those here have a look of quiet contentment that is easy for you to envy."
+CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? WALK>
+		       <TELL
+"Belboz stops you. \"You should not even be here. You will disturb
+our rest.\"" CR>)
+		      (<VERB? ANSWER YES NO>
+		       <PERFORM ,V?REPLY ,BELBOZ>
+		       <RTRUE>)
+		      (<AND <VERB? SAY>
+			    ,BELBOZ-ASKS
+			    <NOT ,BELBOZ-CONVINCED?>>
+		       <QUOTED-PHRASE <- ,P-CONT ,P-LEXELEN> ,ACT?ANSWER>
+		       <ORPHAN-VERB ,W?ANSWER ,ACT?ANSWER>)>)>>
+
+<OBJECT BELBOZ
+	(IN RETREAT)
+	(DESC "Belboz")
+	(LDESC
+"Belboz is meditating here.")
+	(SYNONYM BELBOZ NECROMANCER)
+	(FLAGS PERSON NOABIT NOTHEBIT OPENBIT CONTBIT)
+	(ACTION BELBOZ-F)
+	(CONTFCN BELBOZ-F)>
+
+<ROUTINE BELBOZ-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? ,WINNER ,BELBOZ>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (<VERB? HELLO>
+		       <TELL
+"\"Hello.\" Belboz doesn't seem pleased to see you." CR>)
+		      (<NOT ,BELBOZ-CONVINCED?>
+		       <TELL "Belboz looks at you suspiciously. ">
+		       <COND (,BELBOZ-ASKS
+			      <TELL
+"\"Please answer my question, or I shall be forced to conclude you are
+an imposter.\"" CR>)
+			     (ELSE
+			      <TELL
+"\"You were here a few days ago, or
+rather someone who resembled you strongly enough to be your twin was
+here. This being betrayed its true nature, however, as it did not know
+facts which would be trifles to even the rawest apprentice. It fled
+before I could capture it. Prove to me that you are truly yourself, and
+answer me a question. ">
+			      <SETG BELBOZ-ASKS
+				    <RANDOM <GET ,QUESTIONS 0>>>
+			      <ORPHAN-VERB ,W?ANSWER ,ACT?ANSWER>
+			      <TELL <GET ,QUESTIONS ,BELBOZ-ASKS> "?\"" CR>)>)
+		      (<VERB? GIVE>
+		       <TELL
+"\"All in good time.\"" CR>)
+		      (<AND <VERB? HELP>
+			    <EQUAL? ,PRSO <> ,ME>>
+		       <TELL
+"The great mage looks tired. \"That is beyond my power,\" he says. \"I have
+given up worldly affairs. My time is past, I am old, and the world is now
+in the care of my successors. I am convinced you will not fail.\"" CR>)
+		      (<VERB? TELL-ME-ABOUT>
+		       <COND (<EQUAL? ,PRSO ,MAGIC>
+			      <TELL
+"\"I can tell you nothing which you do not already know. We live in
+perilous times.\"" CR>)
+			     (<EQUAL? ,PRSO ,SHADOW>
+			      <TELL
+"\"I have encountered such creatures, but this one is unfamiliar to me.
+They are sometimes spirits of the dead, or demons, or even illusory
+sendings.\"" CR>)
+			     (<EQUAL? ,PRSO ,SNAKE>
+			      <TELL
+"\"This serpent brings to mind the great Ouroboros, said to encircle the
+world.\"" CR>)
+			     (<EQUAL? ,PRSO ,KEY>
+			      <TELL
+"\"It was left nearby.\"" CR>)
+			     (<GETP ,PRSO ,P?CUBE>
+			      <COND (<HELD? ,PRSO>
+				     <TELL
+"Belboz looks at the cube for a while, turning it over and over in his
+hands.">)
+				    (ELSE
+				     <TELL
+"Belboz thinks for a while.">)>
+			      <TELL
+" \"There is a legend about cubes. When the foundations of the
+world were laid down, it is said that the elemental powers and forces
+were symbolized during the making by small cubes. The cubes and the
+forces were merged in a way that our knowledge no longer comprehends.
+When the making was done, the cubes were hidden
+away where their powers could not be tampered with. If someone has
+gained access to them, or rediscovered the knowledge of their making, we
+are in terrible danger. One who had power over these cubes could change
+the very structure of our universe. Such a one would have powers I do
+not care to contemplate.\"">
+			      <COND (<HELD? ,PRSO>
+				     <TELL
+" Belboz gives back the cube.">)>
+			      <CRLF>)
+			     (<EQUAL? ,PRSO ,PSEUDO-OBJECT>
+			      <TELL
+"\"I know little you do not know yourself.\"" CR>)
+			     (ELSE
+			      <TELL
+"\"I know nothing of interest about that.\"" CR>)>)
+		      (ELSE
+		       <TELL
+"Belboz looks at you, but says nothing." CR>)>)
+	       (<EQUAL? .RARG ,M-CONTAINER>
+		<COND (<VERB? TAKE>
+		       <FORLORN-ENCYSTMENT>)>)
+	       (<NOT .RARG>
+		<COND (<AND <VERB? TELL>
+			    ,BELBOZ-ASKS
+			    <NOT ,BELBOZ-CONVINCED?>>
+		       <ORPHAN-VERB ,W?ANSWER ,ACT?ANSWER>
+		       <RFALSE>)
+		      (<VERB? EXAMINE>
+		       <TELL
+"Belboz looks the same as always, ageless at an age when most have already
+departed the world. Outwardly, he seems relaxed and carefree." CR>)
+		      (<VERB? SHOW>
+		       <SETG WINNER ,BELBOZ>
+		       <PERFORM ,V?TELL-ME-ABOUT ,PRSO>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)
+		      (<VERB? ASK-FOR>
+		       <SETG WINNER ,BELBOZ>
+		       <PERFORM ,V?GIVE ,ME ,PRSO>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)
+		      (<VERB? WHO>
+		       <TELL
+"Belboz the Necromancer was head of the Accardi-by-the-sea chapter of
+the Guild of Enchanters until his recent retirement. You owe your position
+(and your life) to him, and it is partly because he was your mentor that
+you have achieved your present position. When he retired, he expressed an
+interest in rest, meditation and learning to arrange flowers." CR>)
+		      (<AND <NOT ,BELBOZ-CONVINCED?>
+			    <AND <VERB? REPLY>
+				 <EQUAL? ,PRSO ,BELBOZ>
+				 <NOT ,PRSI>>>
+		       <ORPHAN-VERB ,W?ANSWER ,ACT?ANSWER>
+		       <TELL "\"Yes? What is the answer?\"" CR>)
+		      (<VERB? REPLY>
+		       <ANSWER-BELBOZ>)
+		      (<VERB? YOMIN>
+		       <TELL
+"You sense peacefulness">
+		       <COND (<NOT ,BELBOZ-CONVINCED?>
+			      <TELL " overlaid upon a foundation of worry">)>
+		       <TELL ,PERIOD>)
+		      (<OR <HOSTILE-VERB?>
+			   <VERB? ESPNIS LISKON SNAVIG>
+			   <VERB? TINSOT>>
+		       <TELL
+"Belboz stops you with a word of power." CR>
+		       <FORLORN-ENCYSTMENT>)
+		      (<VERB? WHERE FIND>
+		       <COND (<AND <NOT <IN? ,BELBOZ ,HERE>>
+				   <NOT <FSET? ,RETREAT ,TOUCHBIT>>>
+			      <TELL
+"You last saw Belboz months ago, when he left for the
+Enchanters' Retreat in the mountains." CR>)
+			     (ELSE
+			      <TELL
+"I would assume he is still at the Retreat." CR>)>)>)>>
+
+<GLOBAL FAKE-KEY <>>
+
+<ROUTINE ANSWER-BELBOZ ()
+	 <COND (<AND ,BELBOZ-ASKS
+		     <NOT ,BELBOZ-CONVINCED?>>
+		<COND (<AND <EQUAL? ,PRSO ,PSEUDO-OBJECT ,BELBOZ>
+			    <EQUAL? ,PRSI <> ,PSEUDO-OBJECT>>
+		       <COND (<NOT <CORRECT? <GET ,ANSWERS ,BELBOZ-ASKS>>>
+			      <SETG FAKE-KEY T>)>
+		       <SETG SCORE <+ ,SCORE 25>>
+		       <SETG BELBOZ-CONVINCED? T>
+		       %<DEBUG-CODE <COND (,FAKE-KEY <TELL "[Wrong]" CR>)
+					  (ELSE <TELL "[Right]" CR>)>>
+		       <TELL
+"\"Good! I knew it was you all along. What may I do for you?\"">
+		       <COND (<IN? ,KEY ,BELBOZ>
+			      <FCLEAR ,KEY ,NDESCBIT>
+			      <MOVE ,KEY ,WINNER>
+			      <TELL " He fumbles
+in his pouch for a moment. \"First, let me give you this.\" He hands you a "
+'KEY ". \"It may prove useful.\"">)>
+		       <CRLF>)
+		      (ELSE
+		       <FORLORN-ENCYSTMENT>)>)
+	       (ELSE
+		<TELL
+"\"I asked no question,\" says Belboz." CR>)>>
+
+<ROUTINE FORLORN-ENCYSTMENT ()
+	 <SETG DEATHS 3>
+	 <JIGS-UP
+"\"Ah! Now I have you, charlatan! Fool me twice? Never!\" He rises to his
+feet, makes a threatening gesture, and you find yourself transported to a
+tiny cell deep beneath the earth, all belongings stripped from you. In
+time, though it takes years and you are mad long since, you starve.">>
+
+<ROUTINE CORRECT? (WRD)
+	 <COND (<EQUAL? .WRD ,P-PNAM>
+		<RTRUE>)
+	       (<AND <EQUAL? .WRD ,W?BARBEL>
+		     <EQUAL? ,P-PADJN ,W?BARBEL <>>
+		     <EQUAL? ,P-PNAM ,W?GURTH>>
+		<RTRUE>)
+	       (<AND <EQUAL? .WRD ,W?GUSTAR>
+		     <EQUAL? ,P-PADJN ,W?GUSTAR <>>
+		     <EQUAL? ,P-PNAM ,W?WOOMAX>>
+		<RTRUE>)
+	       (<AND <EQUAL? .WRD ,W?DIMITHIO>
+		     <EQUAL? ,P-PADJN ,W?DIMITHIO <>>
+		     <EQUAL? ,P-PNAM ,W?BORPHEE>>
+		<RTRUE>)
+	       (<AND <EQUAL? .WRD ,W?FORBURN>
+		     <EQUAL? ,P-PADJN ,W?FORBURN <>>
+		     <EQUAL? ,P-PNAM ,W?WILY>>
+		<RTRUE>)
+	       (ELSE <RFALSE>)>>
+
+<ROUTINE ANSWER-PSEUDO ()
+	 <COND (<VERB? WHO>
+		<TELL
+"You studied his career while still an apprentice." CR>)
+	       (<AND <VERB? REPLY>
+		     <EQUAL? ,PRSO ,PSEUDO-OBJECT>
+		     <EQUAL? ,HERE ,RETREAT>>
+		<PERFORM ,V?REPLY ,BELBOZ ,PRSO>
+		<RTRUE>)>>
+
+<GLOBAL BELBOZ-CONVINCED? <>>
+
+<GLOBAL BELBOZ-ASKS <>>
+
+<GLOBAL QUESTIONS
+	<PLTABLE
+"Which mage had the motto, 'The hardest trick is making it look easy.'"
+"Who invented the golmac spell"
+"Who wrote of the Coconut of Quendor"
+"In Borphee, who was famed for his skill with fireworks displays"
+"Which of our esteemed colleagues was fabled for his skill at Double Fanucci"
+"Of the necromancers, who other than (harumph) myself is best-known">>
+
+<GLOBAL ANSWERS
+	<PLTABLE <VOC "BARSAP">
+		 <VOC "BARBEL">
+		 <VOC "GUSTAR">
+		 <VOC "DIMITHIO">
+		 <VOC "FORBURN">
+		 <VOC "BERKNIP">>>
+
+<ROUTINE PLURAL-PSEUDO ()
+	 <RANDOM-PSEUDO T>>
+
+<ROUTINE RANDOM-PSEUDO ("OPTIONAL" (PLURAL? <>))
+	 <COND (<VERB? EXAMINE>
+		<COND (.PLURAL? <TELL "They look">)
+		      (ELSE <TELL "It looks">)>
+		<TELL " exactly as you would expect." CR>)
+	       (<VERB? TAKE>
+		<TELL
+"You're an enchanter, not a garbage collector." CR>)>>
+
+<ROUTINE REDIRECT (FROM TO)
+	 <PERFORM ,PRSA
+		  <COND (<EQUAL? ,PRSO .FROM> .TO)
+			(ELSE ,PRSO)>
+		  <COND (<EQUAL? ,PRSI .FROM> .TO)
+			(ELSE ,PRSI)>>
+	 <RTRUE>>
+
+"sleep, hunger, etc."
+
+<GLOBAL LAST-SLEPT 40> ;"move when you last woke-up, for purposed of V-TIME"
+
+<OBJECT GLOBAL-SLEEP
+	(IN GLOBAL-OBJECTS)
+	(DESC "sleep")
+	(SYNONYM SLEEP NAP)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION GLOBAL-SLEEP-F)>
+
+<ROUTINE GLOBAL-SLEEP-F ()
+	 <COND (<VERB? WALK-TO TAKE>
+                <PERFORM ,V?SLEEP>
+		<RTRUE>)
+	       (<VERB? FIND>
+		<TELL "Sleep anywhere." CR>)>>
+
+<OBJECT MAGIC
+	(IN GLOBAL-OBJECTS)
+	(DESC "magic")
+	(SYNONYM MAGIC)
+        (ACTION MAGIC-F)>
+
+<ROUTINE MAGIC-F ()
+	 <COND (<VERB? WHAT>
+		<TELL
+"The Guild will be surprised to hear you don't know." CR>)>>
diff --git a/guild.zil b/guild.zil
new file mode 100644
index 0000000..f0c87a7
--- /dev/null
+++ b/guild.zil
@@ -0,0 +1,688 @@
+"GUILD for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+<OBJECT KNIFE
+	(IN PLAYER)
+	(DESC "knife")
+	(SYNONYM KNIFE DAGGER)
+	(FLAGS TAKEBIT WEAPONBIT)
+	(ACTION KNIFE-F)>
+
+<ROUTINE KNIFE-F ()
+	 <COND (<AND <VERB? CUT>
+		     <EQUAL? ,PRSO ,BREAD ,FISH>>
+		<TELL
+"You slice off a little piece and eat it. It tastes pretty good, but
+you really weren't feeling very hungry." CR>)>>
+
+<ROOM GUILD-HALL
+      (IN ROOMS)
+      (DESC "Guild Hall")
+      (NORTH TO COUNCIL-CHAMBER)
+      (SOUTH TO BELWIT-SQUARE)
+      (OUT TO BELWIT-SQUARE)
+      (ACTION GUILD-HALL-F)
+      (FLAGS ONBIT RLANDBIT)>
+
+<ROUTINE GUILD-HALL-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the entrance to the Guild Hall in Borphee. To the north is
+the Council Chamber, and to the south is an exit leading outside.">
+		<COND (<OR <NOT <FSET? ,BREAD ,TOUCHBIT>>
+			   <NOT <FSET? ,FISH ,TOUCHBIT>>>
+		       <TELL
+" Little is left of the sumptuous buffet lunch. Only ">
+		       <COND (<NOT <FSET? ,BREAD ,TOUCHBIT>>
+			      <TELL "a loaf of bread">
+			      <COND (<NOT <FSET? ,FISH ,TOUCHBIT>>
+				     <TELL " and ">)>)>
+		       <COND (<NOT <FSET? ,FISH ,TOUCHBIT>>
+			      <TELL "some smoked fish">)>
+		       <TELL " remains.">)>
+		<CRLF>)>>
+
+<OBJECT BREAD
+	(IN GUILD-HALL)
+	(DESC "chunk of rye bread")
+	(SYNONYM BREAD FOOD LOAF CHUNK)
+	(ADJECTIVE FRESH RYE LOAF CHUNK)
+	(FLAGS NDESCBIT BRIEFBIT TAKEBIT)>
+
+<OBJECT FISH
+	(IN GUILD-HALL)
+	(DESC "smoked fish")
+	(SYNONYM FISH SARDINE HERRING FOOD)
+	(ADJECTIVE SMOKED)
+	(FLAGS NDESCBIT BRIEFBIT TAKEBIT)
+	(GENERIC GENERIC-FISH-F)>
+
+<ROOM COUNCIL-CHAMBER
+      (IN ROOMS)
+      (DESC "Council Chamber")
+      (ACTION COUNCIL-CHAMBER-F)
+      (SOUTH TO GUILD-HALL)
+      (OUT TO GUILD-HALL)
+      (FLAGS ONBIT RLANDBIT)
+      (THINGS
+       <PSEUDO (LEOPARD FROG FROG-PSEUDO)
+	       (<> FROGS AMPHIBIAN-PSEUDO)
+	       (TREE TOAD TOAD-PSEUDO)
+	       (<> TOADS AMPHIBIAN-PSEUDO)
+	       (<> SALAMANDER SALAMANDER-PSEUDO)
+	       (<> NEWT NEWT-PSEUDO)
+	       (<> NEWTS AMPHIBIAN-PSEUDO)
+	       (<> HELLBENDER HELLBENDER-PSEUDO)
+	       (<> EFT AMPHIBIAN-PSEUDO)
+	       (<> EFTS AMPHIBIAN-PSEUDO)>)>
+
+<ROUTINE FROG-PSEUDO ()
+	 <COND (,CLEESHED? <REDIRECT ,PSEUDO-OBJECT ,GZORNENPLATZ>)
+	       (ELSE <AMPHIBIAN-PSEUDO>)>>
+
+<ROUTINE TOAD-PSEUDO ()
+	 <COND (,CLEESHED? <REDIRECT ,PSEUDO-OBJECT ,SNEFFLE>)
+	       (ELSE <AMPHIBIAN-PSEUDO>)>>
+
+<ROUTINE SALAMANDER-PSEUDO ()
+	 <COND (,CLEESHED? <REDIRECT ,PSEUDO-OBJECT ,HOOBLY>)
+	       (ELSE <AMPHIBIAN-PSEUDO>)>>
+
+<ROUTINE NEWT-PSEUDO ()
+	 <COND (,CLEESHED? <REDIRECT ,PSEUDO-OBJECT ,ARDIS>)
+	       (ELSE <AMPHIBIAN-PSEUDO>)>>
+
+<ROUTINE HELLBENDER-PSEUDO ()
+	 <COND (,CLEESHED? <REDIRECT ,PSEUDO-OBJECT ,ORKAN>)
+	       (ELSE <AMPHIBIAN-PSEUDO>)>>
+
+<ROUTINE AMPHIBIAN-PSEUDO ()
+	 <COND (,CLEESHED?
+		<TELL
+"They are hopping around so wildly it's hard to do anything with them." CR>)
+	       (ELSE
+		<TELL
+"I think you had too much punch at lunch. There's no such thing here." CR>)>>
+
+<GLOBAL ORATOR <>>
+<GLOBAL CLEESHED? <>>
+
+<OBJECT SORCERER
+	(IN COUNCIL-CHAMBER)
+	(DESC "sorcerer")
+	(SYNONYM SORCERER ENCHANTER MAGE MAGES)
+	(ADJECTIVE GROUP PARTY)
+	(ACTION SORCERER-F)
+	(FLAGS NDESCBIT PERSON THE)>
+
+<ROUTINE SORCERER-F ()
+	 <COND (<VERB? TELL>
+		<TELL
+,MORE-SPECIFIC ". There are about ten of them around, including
+yourself." CR>)
+	       (<VERB? EXAMINE>
+		<COND (,CLEESHED?
+		       <TELL
+"The former mages are scuttling hither and yon across the floor." CR>)
+		      (ELSE
+		       <TELL
+"The mages, grouped loosely near you, are listening to the speakers." CR>)>)
+	       (<VERB? COUNT>
+		<COND (,CLEESHED?
+		       <TELL
+"It's hard to tell. I assume there are still about ten." CR>)
+		      (ELSE
+		       <TELL
+"There are about ten, including you and " 'ORKAN ", the
+most eminent of the group, now that Belboz has retired." CR>)>)>>
+
+<OBJECT SPEAKER
+	(IN COUNCIL-CHAMBER)
+	(DESC "speaker")
+	(SYNONYM SPEAKER ORATOR GUILDMASTER)
+	(ACTION SPEAKER-F)
+	(FLAGS NDESCBIT)>
+
+<ROUTINE SPEAKER-F ()
+	 <REDIRECT ,SPEAKER ,ORATOR>>
+
+<ROUTINE COUNCIL-CHAMBER-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are in the Council Chamber of the ancient Guild Hall at Borphee. To
+the south is the entry of the Guild Hall. ">
+		<COND (,CLEESHED?
+		       <TELL
+"Scurrying wetly hither and yon around you are many brightly colored newts,
+efts, and salamanders. Toads and frogs hop excitedly about.">)
+		      (ELSE
+		       <TELL
+"There is a meeting of the Guildmasters going on. You are standing among
+a group of about ten sorcerers, each the master of an Enchanters Guild chapter
+somewhere in the land.">
+		       <COND (<G? ,OCOUNT 0>
+			      <TELL
+" " 'ORATOR " is addressing the meeting.">)>)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<NOT ,CLEESHED?>
+		       <COND (<VERB? WALK>
+			      <TELL
+"Annoyed guildmasters make way grudgingly. You hear muttering about
+\"arrogant enchanters\" as you try to leave the chamber. Finally, "
+'ORKAN ", one of your colleagues, says, \"Stay. Be quiet. Don't
+embarrass us.\"" CR>)
+			     (<AND <VERB? SAY> <NOT ,PRSO>>
+			      <TELL
+'ORKAN " quiets you. \"Interruptions will only annoy them.\"" CR>)
+			     (<AND <VERB? LISTEN>
+				   <NOT ,PRSO>>
+			      <TELL
+'ORATOR " is speaking." CR>)
+			     (<SPELL-VERB?>
+			      <TELL
+'ORKAN " stares at you in wonderment. \"Are you trying to get them
+even more mad at us?\" He makes a gesture of cancellation before you can
+finish the spell." CR>)
+			     (<AND <HOSTILE-VERB?>
+				   <FSET? ,PRSO ,PERSON>>
+			      <COND (<EQUAL? ,PRSO ,ORKAN>
+				     <TELL
+'ORKAN " easily subdues you without causing undue disruption." CR>)
+				    (ELSE
+				     <TELL
+'ORKAN " grabs you and prevents your antisocial deed." CR>)>)
+			     (<VERB? YAWN SLEEP>
+			      <TELL
+"Realizing how insulting you are being to the speaker, you try to stifle
+the yawn." CR>)>)>)>>
+
+<OBJECT ORKAN
+	(IN COUNCIL-CHAMBER)
+	(DESC "Orkan of Thriff")
+	(SYNONYM ORKAN)
+	(ADJECTIVE THRIFF)
+	(ACTION ORKAN-F)
+	(FLAGS PERSON NOABIT NOTHEBIT NDESCBIT)>
+
+<ROUTINE ORKAN-F ()
+	 <COND (<EQUAL? ,WINNER ,ORKAN>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (,CLEESHED?
+		       <TELL "Orkan doesn't reply." CR>)
+		      (ELSE
+		       <TELL
+"\"Please! You should at least pretend to pay attention to these fools,\"
+whispers Orkan." CR>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<COND (,CLEESHED?
+		       <TELL "Orkan is now a hellbender." CR>)
+		      (ELSE
+		       <TELL
+'ORKAN " is a large bear-like gentleman dressed in the traditional garb
+of a mage." CR>)>)
+	       (<VERB? LISTEN>
+		<COND (<NOT ,CLEESHED?>
+		       <TELL
+"Orkan is listening to the speaker and suggests you do the same." CR>)>)
+	       (<VERB? YOMIN>
+		<COND (,CLEESHED?
+		       <TELL
+"You get a vague impression of hunger and annoyance at being dry." CR>)>)>>
+
+<OBJECT SNEFFLE
+	(IN COUNCIL-CHAMBER)
+	(DESC "Sneffle")
+	(SYNONYM SNEFFLE BAKER)
+	(ACTION SNEFFLE-F)
+	(FLAGS PERSON NOABIT NOTHEBIT NDESCBIT)>
+
+<ROUTINE SNEFFLE-F ()
+	 <COND (<EQUAL? ,WINNER ,SNEFFLE>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (,CLEESHED?
+		       <TELL "\"Breep!\"" CR>)
+		      (ELSE
+		       <TELL
+"\"Interrupting, eh? This is precisely what I was talking about!\" snorts "
+'SNEFFLE>
+		       <TELL ,PERIOD>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<COND (,CLEESHED?
+		       <TELL "Sneffle is now a tree toad." CR>)
+		      (ELSE
+		       <TELL
+"Sneffle is a small doughy gentleman whose person is splotched here and
+there with flour." CR>)>)
+	       (<VERB? LISTEN>
+		<COND (<NOT ,CLEESHED?>
+		       <LISTEN-TO-GUILDMASTER>)>)
+	       (<VERB? YOMIN>
+		<COND (,CLEESHED?
+		       <TELL
+"Sneffle is searching intently for flies." CR>)>)>>
+
+<ROUTINE LISTEN-TO-GUILDMASTER ()
+	 <TELL 'PRSO " is ">
+	 <COND (<EQUAL? ,PRSO ,ORATOR>
+		<TELL "making a speech.">)
+	       (ELSE
+		<TELL "listening to the speaker.">)>
+	 <CRLF>>
+
+<OBJECT HOOBLY
+	(IN COUNCIL-CHAMBER)
+	(DESC "Hoobly")
+	(SYNONYM HOOBLY BREWER)
+	(ADJECTIVE CORPULENT FAT)
+	(ACTION HOOBLY-F)
+	(FLAGS PERSON NOABIT NOTHEBIT NDESCBIT)>
+
+<ROUTINE HOOBLY-F ()
+	 <COND (<EQUAL? ,WINNER ,HOOBLY>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (,CLEESHED?
+		       <TELL "\"Ssss!\"" CR>)
+		      (<EQUAL? ,ORATOR ,HOOBLY>
+		       <TELL
+'HOOBLY " pointedly ignores you." CR>)
+		      (ELSE
+		       <TELL
+"\"Your manners leave something to be desired! " 'ORATOR " is
+speaking!\" remarks " 'HOOBLY>
+		       <TELL ,PERIOD>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<COND (,CLEESHED?
+		       <TELL "Hoobly has become a salamander." CR>)
+		      (ELSE
+		       <TELL
+"Hoobly is a large, florid, and solid-looking fellow who gives the appearance
+of being one of his own better customers." CR>)>)
+	       (<VERB? YOMIN>
+		<COND (,CLEESHED?
+		       <TELL
+"You get a strong feeling of torpidity." CR>)>)>>
+
+<OBJECT GZORNENPLATZ
+	(IN COUNCIL-CHAMBER)
+	(DESC "Gzornenplatz")
+	(SYNONYM GZORNENPLATZ HUNTSMAN)
+	(ACTION GZORNENPLATZ-F)
+	(FLAGS PERSON NOABIT NOTHEBIT NDESCBIT)>
+
+<ROUTINE GZORNENPLATZ-F ()
+	 <COND (<EQUAL? ,WINNER ,GZORNENPLATZ>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (,CLEESHED?
+		       <TELL "\"Braaaak! Gleep?\"" CR>)
+		      (ELSE
+		       <TELL
+'GZORNENPLATZ " glares at you.">
+		       <COND (<NOT <EQUAL? ,ORATOR ,GZORNENPLATZ>>
+			      <TELL " \"No doubt you don't wish the speakers
+to be heard. This is what I expect from such as you!\"">)>
+		       <CRLF>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<COND (,CLEESHED?
+		       <TELL 'GZORNENPLATZ " has become a leopard frog." CR>)
+		      (ELSE
+		       <TELL
+'GZORNENPLATZ " is a tall, whipcord thin man with sandy blond hair. He
+is dressed in the traditional lincoln green of huntsmen." CR>)>)
+	       (<VERB? YOMIN>
+		<COND (,CLEESHED?
+		       <TELL
+"You feel a strong impression of intent, careful stalking of a beetle."
+CR>)>)>>
+
+<OBJECT ARDIS
+	(IN COUNCIL-CHAMBER)
+	(DESC "Ardis")
+	(SYNONYM ARDIS POET)
+	(ACTION ARDIS-F)
+	(FLAGS PERSON NOABIT NOTHEBIT NDESCBIT)>
+
+<ROUTINE ARDIS-F ()
+	 <COND (<EQUAL? ,WINNER ,ARDIS>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <EQUAL? ,PRSO ,ME>>
+		       <RFALSE>)
+		      (,CLEESHED?
+		       <UNINTERESTED ,ARDIS>)
+		      (ELSE
+		       <TELL
+"\"You must wait your turn!\" screams " 'ARDIS>
+		       <TELL ,PERIOD>)>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<COND (,CLEESHED?
+		       <TELL "Ardis has become a newt." CR>)
+		      (ELSE
+		       <TELL
+"Ardis is the muscular sort of poet (as opposed to the neurasthenic).
+He sports a full black beard, wild hair, and talks in a loud voice." CR>)>)
+	       (<VERB? YOMIN>
+		<COND (,CLEESHED?
+		       <TELL
+"You get a feeling of surprise and terror." CR>)>)>>
+
+<ROOM BELWIT-SQUARE
+      (IN ROOMS)
+      (DESC "Belwit Square")
+      (NORTH TO GUILD-HALL)
+      (EAST "You wander around for a while and end up back in the square.")
+      (WEST "You wander around for a while and end up back in the square.")
+      (SOUTH "A remarkably surly guard blocks your way.")
+      (ACTION BELWIT-SQUARE-F)
+      (FLAGS ONBIT RLANDBIT)
+      (THINGS
+       <PSEUDO (SURLY GUARD GUARD-PSEUDO)
+	       (STORIED MANSE MANSE-PSEUDO)
+	       (GUILD HALL GUILD-HALL-PSEUDO)
+	       (<> BUILDING RANDOM-PSEUDO)>)>
+
+<ROUTINE GUILD-HALL-PSEUDO ()
+	 <COND (<VERB? THROUGH>
+		<DO-WALK ,P?NORTH>)
+	       (ELSE <RANDOM-PSEUDO>)>>
+
+<ROUTINE MANSE-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "It is a large, imposing building of great age." CR>)
+	       (<VERB? THROUGH>
+		<TELL "The manse is closed to the public." CR>)>>
+
+<ROUTINE GUARD-PSEUDO ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "He looks very zealous." CR>)
+	       (<VERB? TELL ASK-ABOUT>
+		<TELL
+"The guard ignores you, intent on his duty." CR>
+		<COND (<VERB? TELL> <END-QUOTE>)
+		      (ELSE <RTRUE>)>)
+	       (<VERB? SHOW GIVE OFFER>
+		<TELL "Trying to bribe the guard, eh?" CR>)
+	       (<HOSTILE-VERB?>
+		<TELL "That would be incredibly dangerous." CR>)
+	       (<SPELL-VERB?>
+		<TELL
+"Nothing happens, as the mayoral guards are quite well-protected
+from spells." CR>)>>
+
+<ROUTINE BELWIT-SQUARE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is " 'HERE ". ">
+		<COND (<NOT <FSET? ,CLOUD ,INVISIBLE>>
+		       <TELL
+"Its many historic and picturesque buildings are obscured by
+a cloud of orange smoke.">)
+		      (ELSE
+		       <TELL
+"To the north is the ancient Guild Hall.
+A wide cobblestone street runs east and west. To the south is the storied
+Manse, home of the Mayors of Borphee for generations.">)>
+		<CRLF>)
+	       (<AND <EQUAL? .RARG ,M-BEG>
+		     <NOT <FSET? ,CLOUD ,INVISIBLE>>>
+		<COND (<VERB? WALK>
+		       <TELL
+,YOU-CANT-SEE "well enough to find your way out" ,PERIOD>)
+		      (<EQUAL? ,PRSO ,CLOUD> <RFALSE>)
+		      (<AND <VERB? FIND LOOK TAKE EXAMINE TELL ASK-ABOUT>
+			    <NOT <HELD? ,PRSO>>>
+		       <TELL
+,YOU-CANT-SEE "anything, what with the smokey orange cloud that blankets
+the square." CR>)
+		      (<VERB? DROP>
+		       <COND (<IDROP>
+			      <TELL
+"Dropped, but you lose it in the smoke." CR>)
+			     (ELSE <RTRUE>)>)
+		      (<AND <VERB? SMELL> <NOT ,PRSO>>
+		       <SMELL-CLOUD>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<AND <FSET? ,DEATH-CUBE ,TOUCHBIT>
+			    <NOT ,SAMARRA?>>
+		       <SETG SAMARRA? T>
+		       <QUEUE I-SAMARRA 1>)>)>>
+
+<OBJECT SHADOW
+	(IN COUNCIL-CHAMBER)
+	(DESC "shadowy figure")
+	(SYNONYM FIGURE SHADOW TWIN BEING)
+	(ADJECTIVE SHADOW CLOAKED)
+	(DESCFCN SHADOW-DESC)
+	(ACTION SHADOW-F)
+	(FLAGS PERSON NDESCBIT TAKEBIT TRYTAKEBIT THE MAGICBIT)>
+
+<ROUTINE SHADOW-DESC (RARG OBJ)
+	 <COND (,CLEESHED?
+		<TELL
+"A " 'SHADOW " in a dark cloak ">
+		<COND (<EQUAL? ,HERE ,GUILD-HALL ,COUNCIL-CHAMBER>
+		       <TELL "is running out the door">)
+		      (<EQUAL? ,HERE ,BELWIT-SQUARE>
+		       <TELL "flees across the square">)
+		      (ELSE
+		       <TELL "is here">)>
+		<TELL ,PERIOD>)>>
+
+<ROUTINE SHADOW-F ()
+	 <COND (<OR <NOT <EQUAL? ,HERE ,CASTLE>>
+		    <NOT <IN? ,SHADOW ,CASTLE>>>
+		<COND (<EQUAL? ,WINNER ,SHADOW>
+		       <END-QUOTE>
+		       <TELL "What shadow?" CR>)
+		      (<AND <NOT ,CLEESHED?>
+			    <VERB? FIND>
+			    <PROB 33>>
+		       <TELL
+"There is a figure wearing a dark cloak on the other side of the room,
+but almost the moment you catch sight of it, it disappears." CR>)
+		      (<VERB? EXAMINE>
+		       <TELL
+"I don't see any " 'SHADOW " anywhere." CR>)
+		      (<VERB? ASK-ABOUT TELL-ABOUT TELL-ME-ABOUT>
+		       <RFALSE>)
+		      (<AND <VERB? FOLLOW>
+			    <NOT <IN? ,SHADOW ,HERE>>>
+		       <COND (<EQUAL? ,HERE ,COUNCIL-CHAMBER ,GUILD-HALL>
+			      <DO-WALK ,P?SOUTH>)
+			     (ELSE
+			      <TELL
+"Where it went, I doubt you can follow." CR>)>)
+		      (ELSE
+		       <TELL
+"There is no sign of such a person." CR>)>)
+	       (<EQUAL? ,HERE ,CASTLE>
+		<COND (<EQUAL? ,WINNER ,SHADOW>
+		       <COND (<TIME-FROZEN?>
+			      <IMMOBILE>
+			      <END-QUOTE>)
+			     (ELSE
+			      <TELL
+"\"All will be revealed in due time.\"" CR>)>)
+		      (<AND <VERB? GIVE>
+			    <GETP ,PRSO ,P?CUBE>>
+		       <MOVE ,PRSO ,HERE>
+		       <FSET ,PRSO ,NDESCBIT>
+		       <TELL
+CTHE ,SHADOW " snatches it greedily." CR>)
+		      (<HOSTILE-VERB?>
+		       <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+			      <TELL
+"The frozen shadow is impervious to harm." CR>)
+			     (ELSE <FREEZES-YOU>)>)
+		      (<VERB? ESPNIS>
+		       <TELL
+"The shadow begins to nod off but with great effort resists and
+awakens. ">
+		       <FREEZES-YOU>)
+		      (<VERB? YOMIN>
+		       <TELL
+"You feel your own innermost desires, petty jealousies, and unworthy
+thoughts magnified a thousand times." CR>)
+		      (<VERB? EXAMINE>
+		       <TELL
+CTHE ,SHADOW " is hard to see, almost as though some spell is acting
+to obscure it. It's clad in a dark cloak with a hood, and it blends into
+the background in a disturbing way." CR>)
+		      (<AND <VERB? TELL> ,FROZEN?>
+		       <TELL "You cannot speak." CR>
+		       <END-QUOTE>)
+		      (<AND <NOT ,FROZEN?>
+			    <G? ,SHADOW-COUNT 4>
+			    <L? ,SHADOW-COUNT 8>>
+		       <COND (<VERB? TELL>
+			      <FREEZES-YOU>)
+			     (<OR <NO-CLOCK-VERB?>
+				  <VERB? EXAMINE LOOK WAIT LOOK-INSIDE>>
+			      <RFALSE>)
+			     (ELSE
+			      <FREEZES-YOU>)>)>)>>
+
+<OBJECT CLOUD
+	(IN BELWIT-SQUARE)
+	(DESC "cloud of orange smoke")
+	(SYNONYM CLOUD SMOKE)
+	(ADJECTIVE ORANGE)
+	(FLAGS NDESCBIT INVISIBLE)
+	(ACTION CLOUD-F)>
+
+<ROUTINE CLOUD-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a fairly standard " 'PRSO ", a side effect of a certain class
+of teleportation spells. These spells are favored by those of a less
+than honest nature, as the " 'PRSO " serves to conceal their usually
+hasty departures." CR>)
+	       (<VERB? THROUGH>
+		<TELL ,YOU-ARE " in the middle of it." CR>)
+	       (<VERB? SMELL>
+		<SMELL-CLOUD>)>>
+
+<ROUTINE SMELL-CLOUD ()
+	 <TELL
+"It smells vaguely of orange peels, but the predominant motif is less
+pleasant and more acrid." CR>>
+
+<ROOM CASTLE
+      (IN ROOMS)
+      (DESC "Castle")
+      (ACTION CASTLE-F)
+      (FLAGS RLANDBIT ONBIT)
+      (THINGS
+       <PSEUDO (<> THRONE RANDOM-PSEUDO)
+	       (<> WINDOW RANDOM-PSEUDO)
+	       (<> SKYLIGHT RANDOM-PSEUDO)
+	       (<> MIST RANDOM-PSEUDO)>)>
+
+<ROUTINE CASTLE-F (RARG "AUX" F)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the audience chamber. It is high and spacious, and every
+proportion and decoration is intended to highlight the throne that
+looms before you. The throne itself is bathed in light, but only
+featureless gray may be seen through the windows and skylights." CR>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<COND (<OR <VERB? EXAMINE WAIT LOOK>
+			   <NO-CLOCK-VERB?>>
+		       <RFALSE>)
+		      (,FROZEN?
+		       <COND (<EQUAL? ,FROZEN? 1>
+			      <COND (<NOT <EQUAL? ,TIME-STOPPED? ,HERE>>
+				     <TELL "You clumsily attempt to ">
+				     <COND (<SPELL-VERB?>
+					    <TELL "cast the spell.">)
+					   (ELSE
+					    <TELL "do it.">)>
+				     <COND (<OR <L? ,SHADOW-COUNT 8>
+						<SPELL-VERB?>
+						<HOSTILE-VERB?>
+						<EQUAL? ,PRSO ,SHADOW>>
+					    <TELL " ">
+					    <FREEZES-YOU>)>
+				     <RTRUE>)>)
+			     (ELSE
+			      <TELL "You are frozen." CR>)>)
+		      (<VERB? LEARN>
+		       <TELL
+"Something about this place prevents you. It's unsettling." CR>)
+		      (<VERB? TAKE>
+		       <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+			      <COND (<NOT <ZERO? ,P-MULT>>
+				     <TELL
+"As you try to decide what to take first, the spell wears off! ">
+				     <FREEZES-YOU>
+				     <RFATAL>)
+				    (<AND <EQUAL? ,PRSO ,MAGIC-CUBE>
+					  <EQUAL? ,SHADOW-COUNT 9>>
+				     <MOVE ,MAGIC-CUBE ,WINNER>
+				     <FCLEAR ,MAGIC-CUBE ,NDESCBIT>
+				     <TELL
+"You tug and pull at the cube, trying desperately to remove it from its
+place in the center of the tesseract. With your last reserve of strength
+you free it!" CR>)
+				    (<AND <GETP ,PRSO ,P?CUBE>
+					  <FSET? ,PRSO ,NDESCBIT>>
+				     <TELL
+"You can no longer see " THE ,PRSO " in the blaze of light." CR>)
+				    (<EQUAL? <ITAKE> T>
+				     <TELL ,TAKEN>)
+				    (ELSE <RTRUE>)>)
+			     (<IN? ,SHADOW ,HERE>
+			      <FREEZES-YOU>)>)
+		      (<AND <VERB? PUT>
+			    <EQUAL? ,PRSI ,HYPERCUBE>>
+		       <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+			      <COND (<SET F <FIRST? ,HYPERCUBE>>
+				     <TELL
+CTHE .F " is already there." CR>)
+				    (ELSE
+				     <MOVE ,PRSO ,HYPERCUBE>
+				     <FSET ,PRSO ,NDESCBIT>
+				     <TELL
+"You push " THE ,PRSO " into the hypercube, where it hangs unsupported." CR>)>)
+			     (<IN? ,SHADOW ,HERE>
+			      <FREEZES-YOU>)>)
+		      (<AND <VERB? BOARD>
+			    <IN? ,SHADOW ,HERE>
+			    <NOT <EQUAL? ,TIME-STOPPED? ,HERE>>>
+		       <FREEZES-YOU>)
+		      (<VERB? JINDAK>
+		       <TELL "Everything glows." CR>)>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT <IN? ,SHADOW ,HERE>>
+		       <QUEUE I-SHADOW-ARRIVES 2>)
+		      (ELSE <QUEUE I-SHADOW -1>)>
+		<TELL
+"Mocking laughter echoes around you." CR CR>)>>
+
+<OBJECT HYPERCUBE
+	(DESC "construction")
+	(SYNONYM CONSTRUCT HYPERCUBE TESSERACT SQUARE)
+	(ADJECTIVE GLOWING TUMBLING)
+	(FLAGS NDESCBIT CONTBIT OPENBIT)
+	(ACTION HYPERCUBE-F)>
+
+<ROUTINE HYPERCUBE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It floats in front of you, glowing and tumbling." CR>)
+	       (<VERB? LEAP>
+		<TELL
+"Though tempted, you cannot bring yourself to do it." CR>)>>
diff --git a/interrupts.zil b/interrupts.zil
new file mode 100644
index 0000000..9eff25a
--- /dev/null
+++ b/interrupts.zil
@@ -0,0 +1,1373 @@
+"INTERRUPTS for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+;"GENERICS"
+
+<ROUTINE GENERIC-CUBE-F (TBL LEN
+			 "AUX" F (CNT 1) (LAST? <>) (CONT <>) CUBE?)
+	 <COND (<VERB? ASK-ABOUT TELL-ME-ABOUT COUNT>
+		<GET .TBL .CNT>)
+	       (ELSE
+		<COND (<AND <VERB? TAKE>
+			    <EQUAL? <GET ,P-ITBL ,P-PREP2> ,PR?FROM>
+			    <EQUAL? <GET ,P-PRSI ,P-MATCHLEN> 1>>
+		       <SET CONT <GET ,P-PRSI 1>>)>
+		<REPEAT ()
+			<COND (<G? .CNT .LEN>
+			       <RFALSE>)>
+			<SET F <GET .TBL .CNT>>
+			<SET CUBE? <GETPT .F ,P?NAME>>
+			<COND (<AND .CUBE?
+				    <OR <VISIBLE? .F>
+					<VERB? ASK-ABOUT TELL-ABOUT>>>
+			       <COND (<ZERO? <GETP .F ,P?NAME>>
+				      <COND (<OR <NOT .CONT>
+						 <IN? .F .CONT>>
+					     <RETURN .F>)>)>)>
+			<SET CNT <+ .CNT 1>>>)>>
+
+<ROUTINE GENERIC-FISH-F (TBL LEN)
+	 <COND (<VERB? DROP EAT SHOW GIVE> ,FISH)>>
+
+<ROUTINE GENERIC-ROCK-F (TBL LEN)
+	 <COND (<IN? ,PLAYER ,ROCK>
+		,ROCK)
+	       (<IN? ,PLAYER ,OTHER-ROCK>
+		,OTHER-ROCK)
+	       (<AND <EQUAL? ,YOU-LOC ,ROCK-LOC>
+		     <EQUAL? ,YOU-LOC ,OTHER-ROCK-LOC>>
+		<RFALSE>)
+	       (<EQUAL? ,YOU-LOC ,ROCK-LOC>
+		,ROCK)
+	       (<EQUAL? ,YOU-LOC ,OTHER-ROCK-LOC>
+		,OTHER-ROCK)
+	       (ELSE
+		<RFALSE>)>>
+
+<ROUTINE GENERIC-CARPET-F (TBL LEN)
+	 <COND (<VERB? EXAMINE> <RFALSE>)
+	       (ELSE ,RANDOM-CARPET)>>
+
+<ROUTINE GENERIC-HOLE-F (TBL LEN)
+	 <COND (<EQUAL? ,HERE ,MAZE-2> ,OCTAGONAL-HOLE)
+	       (ELSE ,GLOBAL-HOLE)>>
+
+<ROUTINE GENERIC-RANDOM-F (TBL LEN)
+	 <RFALSE>>
+
+;"from GUILD.ZIL"
+
+<ROUTINE I-ORATION ()
+	 <SETG OCOUNT <+ ,OCOUNT 1>>
+	 <CRLF>
+	 <COND (<==? ,OCOUNT 1>
+		<SETG ORATOR ,SNEFFLE>
+		<TELL
+'SNEFFLE " of the Guild of Bakers is addressing the gathering. \"Do you know what this is doing
+to our business? Do you know how difficult it is to make those yummy butter
+pastries by hand? When a simple 'gloth' spell would fold the dough 83 times
+it was possible to make a profit, but now 'gloth' hardly works, and when it
+does, it usually folds the dough too often and the butter melts, or it
+doesn't come out the right size, or...\" He stops, apparently overwhelmed by
+the prospect of a world where the pastries have to be hand-made. \"Can't you do
+anything about this? You're supposed to know all about magic!\"">)
+		(<==? ,OCOUNT 2>
+		 <SETG ORATOR ,HOOBLY>
+		 <TELL
+'HOOBLY " of the Guild of Brewers stands, gesturing at the floury baker. \"You don't know what
+trouble is! Lately, what comes out of the vats, like as not, is cherry
+flavored or worse. The last vat, I swear it, tasted as if grues had been
+bathing in it. It takes magic to turn weird vegetables and water into
+good Borphee beer. Well, without magic, there isn't going to be any
+beer!\" This statement has a profound effect on portions of the
+crowd. You can hear rumblings from the back concerning Enchanters. The
+word \"traitors\" rises out of nowhere. Your fellow Enchanters are
+looking at one another nervously.">)
+		(<==? ,OCOUNT 3>
+		 <SETG ORATOR ,GZORNENPLATZ>
+		 <TELL
+"A tall, gruff fellow begins to speak. This is " 'GZORNENPLATZ " of the
+Guild of Huntsmen. \"I'm a simple man, and I don't know much about
+magic. But I do know that the wild beasts are kept out of the towns and
+villages not just by the huntsmen, but by spells as well. Just
+yesterday, one of my men was attacked and badly wounded by a troop of
+rat-ants. They'd slipped the bounds set down by a 'fripple' spell
+somehow. Are we going to let the sorcerers loose rat-ants on us, and
+worse?\" He sits, glaring significantly at the now-angry clump of mages
+around you.">)
+		(<==? ,OCOUNT 4>
+		 <SETG ORATOR ,ARDIS>
+		 <SETG CLEESHED? T>
+		 <MOVE ,BLORPLE-SPELL ,SPELL-BOOK>
+		 <TELL
+"As the huntsman's accusations are being absorbed and discussed, "
+'ARDIS " of the Guild of Poets takes the floor. He begins to talk about
+magic rhyming and spelling aids, and their lack.|
+|
+In the midst of his
+splendid peroration, just as he was sketching out an insulting
+mythological allusion in iambic hexameter, the poet turns even greener
+than usual. His chin elongates and his skin begins to look sort of
+slimy. In the blink of an eye there stands at the podium, not the
+orator, but rather a large orange newt. \"Breek! Co-ax! Co-ax!\" it
+protests.|
+|
+As you look around the room in shock, you discover that
+Ardis is not alone. Each and every guildmaster in the room has been
+turned into a frog, salamander, or other amphibian! All but one, that
+is: yourself!|
+|
+No! There is one other survivor. At the rear of the
+room, a " 'SHADOW " in a dark cloak slips quietly out the door.">
+		 <THIS-IS-IT ,SHADOW>
+		 <FCLEAR ,SHADOW ,NDESCBIT>
+		 <MOVE ,SHADOW ,GUILD-HALL>
+		 <QUEUE I-SHADOW-GOES 1>
+		 <DEQUEUE I-ORATION>)>
+	 <CRLF>>
+
+<GLOBAL OCOUNT 0>
+
+<GLOBAL SAMARRA? <>>
+
+<ROUTINE I-SAMARRA ()
+	 <COND (<EQUAL? ,HERE ,BELWIT-SQUARE ,GUILD-HALL>
+		<TELL CR
+"Out of the corner of your eye, you see the dark-cloaked figure. At
+first oblivious to you, it straightens up, startled and surprised,
+then vanishes." CR>)
+	       (ELSE
+		<SETG SAMARRA? <>>)>>
+
+<ROUTINE I-SHADOW-GOES ()
+	 <COND (<IN? ,SHADOW ,GUILD-HALL>
+		<QUEUE I-SHADOW-GOES 1>
+		<MOVE ,SHADOW ,BELWIT-SQUARE>
+		<COND (<EQUAL? ,HERE ,GUILD-HALL>
+		       <CRLF>
+		       <TELL
+CTHE ,SHADOW ", its cloak billowing, charges south into
+Belwit Square." CR>)>)
+	       (ELSE
+		<MOVE ,EARTH-CUBE ,BELWIT-SQUARE>
+		<MOVE ,SHADOW ,GLOBAL-OBJECTS>
+		<FCLEAR ,SHADOW ,TAKEBIT>
+		<FCLEAR ,SHADOW ,TRYTAKEBIT>
+		<FCLEAR ,CLOUD ,INVISIBLE>
+		<QUEUE I-CLOUD-GONE 20>
+		<COND (<EQUAL? ,HERE ,GUILD-HALL>
+		       <CRLF>
+		       <TELL
+"Out in the square, there is a crashing noise like
+an explosion, and then a wisp of orange smoke drifts in through the door." CR>)
+		      (<EQUAL? ,HERE ,BELWIT-SQUARE>
+		       <CRLF>
+		       <TELL
+"The sinister figure, its face hidden in the shadows of a dark cowl, turns to
+face you. It nonchalantly jumps into the air, where it is engulfed
+in a huge explosion. A thick and acrid
+cloud of orange smoke fills the square. There is no sign of the figure."
+CR>)>)>>
+
+<ROUTINE I-CLOUD-GONE ()
+	 <FSET ,CLOUD ,INVISIBLE>
+	 <COND (<IN? ,EARTH-CUBE ,BELWIT-SQUARE>
+		<FCLEAR ,EARTH-CUBE ,INVISIBLE>
+		<THIS-IS-IT ,EARTH-CUBE>)>
+	 <COND (<EQUAL? ,HERE ,BELWIT-SQUARE>
+		<CRLF>
+		<TELL
+"The orange smoke dissipates almost as suddenly as it arrived">
+		<COND (<IN? ,EARTH-CUBE ,BELWIT-SQUARE>
+		       <TELL
+". Left behind on the cobblestones is a small " ,WHITE-CUBE>)>
+		<CLEVER-CONTENTS ,HERE ". Also revealed" ,EARTH-CUBE>
+		<TELL ,PERIOD>)>>
+
+<ROUTINE I-SHADOW-ARRIVES ()
+	 <COND (<EQUAL? ,HERE ,CASTLE>
+		<COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+		       <QUEUE I-SHADOW-ARRIVES 1>
+		       <RFALSE>)>
+		<QUEUE I-SHADOW -1>
+		<MOVE ,SHADOW ,CASTLE>
+		<FCLEAR ,SHADOW ,TAKEBIT>
+		<FCLEAR ,SHADOW ,TRYTAKEBIT>
+		<CRLF>
+		<TELL
+"Around the throne a dark mist begins to coalesce. It thickens
+into the outline of a human figure sitting
+nonchalantly on the throne. You can see the ghost of a cloak and
+hood as well." CR>)>>
+
+<GLOBAL SHADOW-COUNT 0>
+
+<ROUTINE I-SHADOW ("AUX" (WON? <>) X)
+	 <COND (<NOT <EQUAL? ,HERE ,CASTLE>>
+		<DEQUEUE I-SHADOW>
+		<RFALSE>)>
+	 <COND (,SAMARRA?
+		<SETG SAMARRA? <>>
+		<TELL CR
+"\"So glad to see you. I was surprised to find you in Borphee when I knew
+we had an appointment here.\"" CR>
+		<RTRUE>)>
+	 <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+		<RFALSE>)>
+	 <SETG SHADOW-COUNT <+ ,SHADOW-COUNT 1>>
+	 <CRLF>
+	 <COND (<EQUAL? ,SHADOW-COUNT 1>
+		<TELL
+"The figure speaks. \"It's been such a pleasure to follow your progress. ">
+		<COND (<G? ,DEATHS 0>
+		       <TELL
+"I'm so glad I could be of assistance when you had trouble. It made me
+feel useful. ">)>
+		<TELL "Thank you for collecting the cubes.\"" CR>)
+	       (<EQUAL? ,SHADOW-COUNT 2>
+		<MOVE ,HYPERCUBE ,HERE>
+		<TELL
+"The figure waves its arms in the air. Before you, rolling and tumbling
+in a bath of light, are four cubes.
+\"When I gathered these and " THE ,EARTH-CUBE ", after searching old tomes and
+questioning the wise about their whereabouts, I conceived my plan.
+I could not gather the remainder of the cubes, but to achieve my
+desire, they had to be brought together. Who better than you to act in
+my stead?\"" CR>)
+	       (<EQUAL? ,SHADOW-COUNT 3>
+		<TELL
+"\"It was a simple matter to perturb the cubes I had to make your
+simple magics flicker or fail. I knew this would set you on a quest.
+For I know you well!\"
+The four cubes disappear. The figure sits straight on its throne and
+removes its hood. You are looking at a shadowy, dark and transparent
+version of yourself!" CR CR 
+"\"Magic is a powerful force, the most powerful in the universe, but
+its exercise has its price. Each time a great mage performs a spell, some
+part of the power in that spell is lost in shadow. A great
+mage ultimately creates a shadow-self that is dimly aware.\" The figure
+grins. \"You have become the most powerful wizard of all, for I, your
+shadow, have become very nearly as powerful as you!\"" CR>)
+	       (<EQUAL? ,SHADOW-COUNT 4>
+		<TELL
+"\"But why, you ask, am I collecting the elemental cubes? It's easy to
+answer. I am not powerful enough. My existence is still but a shadow of
+your own. My desires are unfulfilled. I wish power over all creation!
+I wish to remold the universe in my own image, and rule it. In such a
+universe, my merest whim would smash a star or slay a butterfly. You
+have brought me the tools of the remaking!\"" CR CR>
+		<COND (<NOT ,FROZEN?>
+		       <FREEZES-YOU T>
+		       <CRLF>)>
+		<SHADOW-ACQUIRES ,EARTH-CUBE>
+		<TELL " sets it in the air between
+you, where it hangs motionless." CR>)
+	       (<EQUAL? ,SHADOW-COUNT 5>
+		<SHADOW-ACQUIRES ,AIR-CUBE>
+		<TELL
+" places it next to " THE ,EARTH-CUBE ". They disappear into a glowing
+line which appears between them. ">
+		<SHADOW-ACQUIRES <>>
+		<TELL
+" places " THE ,FIRE-CUBE " and " THE ,WATER-CUBE " in the air,
+creating a square of glowing light." CR>)
+	       (<EQUAL? ,SHADOW-COUNT 6>
+		<TELL
+"Four more cubes are placed above the square: " THE ,LIFE-CUBE ", "
+THE ,DEATH-CUBE ", " THE ,LIGHT-CUBE " and " THE ,DARK-CUBE ". A
+cube of light shimmers before you. The shadow is growing
+more excited, hopping around the structure to place the cubes." CR>)
+	       (<EQUAL? ,SHADOW-COUNT 7>
+		<TELL
+"All the remaining cubes save one, " THE ,MAGIC-CUBE ", build another
+square, then the shadow adds its own four cubes to make a second cube
+of light, which hangs next to the first." CR>)
+	       (<EQUAL? ,SHADOW-COUNT 8>
+		<TELL
+"The shadow grabs the first cube of light, and twisting, chanting, squeezing,
+the cube is compressed and thrust inside the second cube. The points of
+the inner and outer cube connect, and it begins to tumble, seeming to
+twist and distort as one face, then another, presents itself to you. The
+figure capers madly in front of its construction, laughing and
+giggling. It ignores you." CR>)
+	       (<EQUAL? ,SHADOW-COUNT 9>
+		<COND (<ROB ,HYPERCUBE ,HERE ,MAGIC-CUBE>
+		       <TELL
+CTHE ,SHADOW " removes some detritus from " THE ,HYPERCUBE ". ">)>
+		<COND (<IN? ,MAGIC-CUBE ,HYPERCUBE>
+		       <TELL
+CTHE ,SHADOW " grins evilly at " THE ,MAGIC-CUBE " floating in">)
+		      (ELSE
+		       <SHADOW-ACQUIRES ,MAGIC-CUBE>
+		       <MOVE ,MAGIC-CUBE ,HYPERCUBE>
+		       <TELL
+" raising it high, thrusts it into">)>
+		<TELL " the
+center of the tesseract! Cascades of light pour forth, blindingly
+bright, but you can still see " THE ,MAGIC-CUBE " at the center. The
+shadow is growing more solid, no longer transparent and dark! Chortling
+gleefully, it prepares to jump into the hypercube!" CR>)
+	       (<EQUAL? ,SHADOW-COUNT 10>
+		<TELL
+"The shadow, now as solid as a real person, performs a back flip into
+the tesseract">
+		<COND (<IN? ,MAGIC-CUBE ,HYPERCUBE>
+		       <SET WON? <>>
+		       <TELL ", laughing triumphantly.">)
+		      (<SET X <FIRST? ,HYPERCUBE>>
+		       <COND (<NOT <MAGIC? .X>> <SET WON? 3>)
+			     (ELSE <SET WON? 2>)>)
+		      (ELSE
+		       <SET WON? 1>)>
+		<COND (<EQUAL? .WON? 2>
+		       <TELL
+". \"Fool! Everything will be as it was!\"">)
+		      (.WON?
+		       <TELL
+". \"No!\" It screams. \"Stop! Fool, you've destroyed me! You've destroyed ">
+		       <COND (<EQUAL? .WON? 1>
+			      <TELL "everything">)
+			     (<EQUAL? .WON? 3>
+			      <TELL "magic itself">)>
+		       <TELL "! All my lovely plans!\"">)>
+		<TELL " Now glowing as brightly as the
+construction it made, the figure approaches the center. ">
+		<COND (<EQUAL? .WON? 3>
+		       <TELL
+"It grows smaller and smaller, and just before it disappears, the hypercube
+vanishes with a pop, and " THE ,MAGIC-CUBE " melts in your hand like an
+ice cube." CR CR
+"You find yourself back in Belwit Square, all the Guildmasters and even
+Belboz crowding around you. \"A new age begins today,\" says Belboz after
+hearing your story. \"The age of magic is ended, as it must, for as magic
+can confer absolute power, so it can also produce absolute evil. We may
+defeat this evil when it appears, but if wizardry builds it anew, we can
+never ultimately win. The new world will be strange, but in time it will
+serve us better.\"" CR>
+		       <SETG SCORE 600>
+		       <FINISH>)
+		      (ELSE
+		       <END-OF-WORLD .WON?>
+		       <CRLF>
+		       <SETG SCORE -99>
+		       <FINISH>)>)>>
+
+<ROUTINE END-OF-WORLD (WON?)
+	 <COND (<EQUAL? .WON? 2>
+		<TELL
+"It returns in fury, retrieves the " 'MAGIC-CUBE ", and resumes
+its quest. ">
+		<END-OF-WORLD <>>
+		<RTRUE>)>
+	 <TELL
+"It dwindles in size and grows in brightness at the same time, until">
+	 <COND (<EQUAL? .WON? 1>
+		<TELL " it reaches the empty center.
+Then you, it and all the world blink out like a spent match.">)
+	       (ELSE
+		<TELL " you
+are almost blinded by a light so bright it fills the world. A
+voice like honey and ashes speaks in your mind. \"I am the All, I am
+the Will, I am the Power. The universe is Mine! Begone, insect!\" You
+and all you hold dear are abolished in an instant, and the reign of the
+shadow begins.">)>>
+
+<GLOBAL FROZEN? <>>
+
+<ROUTINE FREEZES-YOU ("OPTIONAL" (PREC? <>))
+	 <COND (<OR <NOT .PREC?> <NOT ,FROZEN?>>
+		<SETG FROZEN? 5>
+		<COND (<HELD? ,MAGIC-CUBE>
+		       <QUEUE I-UNFREEZE 2>)>
+		<COND (.PREC?
+		       <TELL
+"\"Now for a small precaution.\"">)
+		      (ELSE
+		       <TELL
+"The shadow notices you. \"You force me to take precautions.\"">)>
+		<TELL
+" The shadow gestures, and you are frozen in
+place, unable to move even your littlest finger." CR>)>>
+
+"steal all but magic cube"
+<ROUTINE STEAL-CUBES ("AUX" (CNT 0) (N 0) CUBE)
+	 <REPEAT ()
+		 <SET CUBE <GET ,CUBE-LIST <* .CNT 2>>>
+		 <MOVE .CUBE ,HERE>
+		 <FSET .CUBE ,NDESCBIT>
+		 <COND (<IGRTR? CNT 11> <RETURN .N>)>>>
+
+<ROUTINE SHADOW-ACQUIRES (OBJ)
+	 <TELL CTHE ,SHADOW>
+	 <COND (<NOT .OBJ> <STEAL-CUBES> ;"all but magic")
+	       (ELSE
+		<COND (<HELD? .OBJ ,WINNER>
+		       <TELL
+" deftly takes " THE .OBJ " from ">
+		       <COND (<IN? .OBJ ,WINNER>
+			      <TELL "you">)
+			     (ELSE
+			      <TELL THE <LOC .OBJ>>)>)
+		      (ELSE
+		       <TELL " takes " THE .OBJ>)>
+		<TELL " and">
+		<FSET .OBJ ,NDESCBIT>
+		<MOVE .OBJ ,HERE>)>>
+
+<ROUTINE I-UNFREEZE ()
+	 <SETG FROZEN? <- ,FROZEN? 1>>
+	 <QUEUE I-UNFREEZE 1>
+	 <CRLF>
+	 <COND (<EQUAL? ,FROZEN? 4>
+		<TELL
+"Your little finger is full of pins and needles. You could move it if you
+wanted." CR>)
+	       (<EQUAL? ,FROZEN? 3>
+		<TELL
+"Your feet and hands feel as if they've been asleep, but you can move
+them." CR>)
+	       (<EQUAL? ,FROZEN? 2>
+		<TELL
+"Your arms and legs are free, but you still cannot speak or move your
+head." CR>)
+	       (<EQUAL? ,FROZEN? 1>
+		<TELL
+"You feel almost thawed, but your mouth feels full of cotton." CR>)
+	       (<ZERO? ,FROZEN?>
+		<DEQUEUE I-UNFREEZE>
+		<SETG FROZEN? <>>
+		<TELL
+"The freeze has worn entirely off! Your contact with " THE ,MAGIC-CUBE
+" must have weakened it." CR>)>>
+
+;"from HUNGER"
+
+<GLOBAL LOAD-MAX 150>
+<GLOBAL LOAD-ALLOWED 150>
+
+<GLOBAL AWAKE -1>
+
+<ROUTINE I-TIRED ("AUX" (FORG <>))
+	 <COND (<G? ,LOAD-ALLOWED 10>
+		<SETG LOAD-ALLOWED <- ,LOAD-ALLOWED 10>>)>
+	 <COND (<G? ,FUMBLE-NUMBER 1>
+		<SETG FUMBLE-NUMBER <- ,FUMBLE-NUMBER 1>>)>
+	 <COND (<G? ,SPELL-MAX 1>
+		<SETG SPELL-MAX <- ,SPELL-MAX 1>>
+		<COND (<G? ,SPELL-ROOM 0>
+		       <SETG SPELL-ROOM <- ,SPELL-ROOM 1>>)>
+		<COND (<EQUAL? ,SPELL-ROOM 0>
+		       <SET FORG T>)>)>
+	 <QUEUE I-TIRED 8>
+	 <COND (<HELD? ,MAGIC-CUBE> <RTRUE>)>
+	 <SETG AWAKE <+ ,AWAKE 1>>
+	 <COND (<G? ,AWAKE 8>
+		<TELL
+"You are so exhausted you can't stay awake any longer." CR>
+		<CRLF>
+		<V-SLEEP T>
+		<RFATAL>)
+	       (T
+		<TELL "You are " <GET ,TIRED-TELL ,AWAKE>>
+		<COND (.FORG
+		       <TELL
+", and the spells you've memorized are becoming confused">)>
+		<TELL ,PERIOD>)>>
+
+;"from MAGIC"
+
+<ROUTINE I-SNAVIG ("AUX" OCHANGE)
+	 <COND (<NOT ,CHANGED?> <RFALSE>)>
+	 <SET OCHANGE ,CHANGED?>
+	 <SETG CHANGED? <>>
+	 <TELL CR
+"You have become yourself again.">
+	 <COND (<EQUAL? .OCHANGE ,GRUE>
+		<SETG LIT <LIT? ,HERE>>
+		<COND (<EQUAL? ,HERE ,GRUE-CAVE>
+		       <TELL
+" You are immediately noticed by the startled grues. The one drawback of this
+essentially light-free environment is that it is also adventurer-free. The
+grues are overjoyed to find this deficiency remedied. You are probably less
+so.">
+		       <JIGS-UP>
+		       <RFATAL>)>)
+	       (<EQUAL? .OCHANGE ,ROC>
+		<COND (<FSET? ,HERE ,RAIRBIT>
+		       <START-FALLING>
+		       <TELL
+" You begin to fall.">)>)
+	       (<EQUAL? .OCHANGE ,GROUPER>
+		<COND (<EQUAL? ,HERE ,OCEAN-FLOOR>
+		       <QUEUE I-DROWN 3>
+		       <TELL
+" Fortunately your gills have stored some oxygen, but you are in danger
+of drowning.">)>
+		<COND (,ATE-AS-GROUPER?
+		       <TELL
+" You have a horrible stomachache. It must have been something you ate.">)>)>
+	 <CRLF>>
+
+<ROUTINE I-DROWN ()
+	 <COND (<AND <EQUAL? ,HERE ,OCEAN-FLOOR>
+		     <NOT <EQUAL? ,CHANGED? ,GROUPER>>>
+		<CRLF>
+		<JIGS-UP
+"Your air has run out. You are still far underwater. You have drowned.">)>>
+
+<ROUTINE I-GIRGOL ("AUX" TF?)
+	 <COND (<NOT ,TIME-STOPPED?> <RFALSE>)
+	       (<SET TF? <TIME-FROZEN?>>
+		<TELL CR "Time resumes its forward flight." CR>)>
+	 <SETG TIME-STOPPED? <>>
+	 <COND (,ROCK-FLAG
+		<SETG ROCK-FLAG <>>
+		<COND (<EQUAL? ,HERE ,HUT-ROOM ,MOUNTAIN-TOP ,CAVE-ENTRANCE>
+		       <TELL CR
+"You hear a gigantic rush of sound as an avalanche tumbles down the
+mountain." CR>)
+		      (<EQUAL? ,HERE ,BOULDER-1 ,BOULDER-2 ,BOULDER-3>
+		       <CRLF>
+		       <JIGS-UP
+"Tons of rock and dirt continue towards their rendezvous with the valley
+floor. Unfortunately, you are ground to nothingness when they arrive for
+their appointment.">)
+		      (<EQUAL? .TF?
+			       ,CLIFF-TOP ,CLIFF-MIDDLE ,CLIFF-BOTTOM>
+		       <QUEUE I-AVALANCHE -1>
+		       <TELL CR
+"Tons of rock and dirt continue their downward plunge." CR>)>)>
+	 <COND (<EQUAL? .TF? ,OGRE-BEDROOM ,OGRE-CAVE>
+		<I-OGRE-KILLS-YOU T>)>
+	 <COND (<EQUAL? .TF? ,PAST-RUINS-ROOM>
+		<QUEUE I-WATER-RISING 3>
+		<TELL CR
+"The water begins to rise again." CR>)>
+	 <COND (<EQUAL? .TF? ,CASTLE>
+		<COND (<EQUAL? ,SHADOW-COUNT 8>
+		       <TELL CR
+"\"Fool!\" chortles the shadow." CR>)>
+		<RTRUE>)>>
+
+<ROUTINE I-OGRE-KILLS-YOU ("OPTIONAL" (GIRGOL? <>))
+	 <COND (<OR <TIME-FROZEN?>
+		    ,SNEEZY?
+		    <EQUAL? ,ESPNIS? ,OGRE>>
+		<QUEUE I-OGRE-KILLS-YOU 2>
+		<RFALSE>)>
+	 <COND (<EQUAL? ,HERE ,OGRE-CAVE ,OGRE-BEDROOM>
+		<COND (<NOT .GIRGOL?> <CRLF>)>
+		<TELL
+"The ogre, impatient with your presence and your impudent intrusion, ">
+		<COND (<EQUAL? ,HERE ,OGRE-BEDROOM>
+		       <TELL "charges in and ">)>
+		<TELL "tramples you to a pulp.">
+		<JIGS-UP>)>>
+
+<ROUTINE I-ESPNIS ()
+	 <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+		<QUEUE I-ESPNIS 2>)
+	       (<NOT ,ESPNIS?> <RFALSE>)>
+	 <COND (<IN? ,ESPNIS? ,HERE>
+		<TELL CR
+CTHE ,ESPNIS? " awakes, looking sheepish.">
+		<COND (<AND <EQUAL? ,ESPNIS? ,OGRE>
+			    <NOT ,SNEEZY?>>
+		       <OGRE-MAD>)
+		      (ELSE <CRLF>)>)>
+	 <SETG ESPNIS? <>>>
+
+<ROUTINE I-LISKON ("OPTIONAL" (NOCR? <>) "AUX" SF)
+	 <COND (<NOT ,SHRINK-FLAG> <RFALSE>)>
+	 <SET SF ,SHRINK-FLAG>
+	 <SETG SHRINK-FLAG <>>
+	 <COND (<NOT <EQUAL? .SF ,PLAYER>>
+		<COND (<AND <FSET? ,WEED ,RMUNGBIT>
+			    <EQUAL? .SF ,WEED>>
+		       <PUTP ,WEED ,P?SIZE 200>)>
+		<COND (<VISIBLE? .SF>
+		       <COND (<NOT .NOCR?> <CRLF>)>
+		       <COND (<EQUAL? .SF ,SNAKE>
+			      <TELL
+"The serpent slowly and jerkily returns to its former size, swallowing its
+tail again in the process." CR>)
+			     (ELSE
+			      <TELL
+"With a rather unsettling lack of uniformity, " THE .SF " returns
+to its former size.">
+			      <COND (<AND <IN? .SF ,WINNER>
+					  <EQUAL? .SF ,WEED>
+					  <FSET? ,WEED ,RMUNGBIT>>
+				     <MOVE .SF ,HERE>
+				     <TELL
+" It's too heavy to carry.">)>
+			      <CRLF>)>)>)
+	       (ELSE
+		<SETG SMALL-FLAG <>>
+		<COND (<NOT .NOCR?> <CRLF>)>
+		<TELL
+"You feel stretched, wrung out, and pulled in all directions. You
+are growing." CR>
+		<COND (<EQUAL? <LOC ,PLAYER> ,CABINET ,PAST-CABINET>
+		       <TOO-LARGE ,CABINET>)
+		      (<IN? ,PLAYER ,ZIPPER>
+		       <RFALSE>)
+		      (<EQUAL? ,HERE ,IN-PIPE ,IN-PIPE-2 ,IN-SEWER>
+		       <TOO-LARGE ,WATER-PIPE>
+		       <RFATAL>)
+		      (<EQUAL? ,HERE ,IN-CHANNEL>
+		       <CRLF>
+		       <GOTO ,OUBLIETTE>)
+		      (<EQUAL? ,HERE ,RUINED-PIPE>
+		       <CRLF>
+		       <GOTO ,RUINS-ROOM>)>)>>
+
+<ROUTINE TOO-LARGE (OBJ)
+	 <TELL
+"Unfortunately, you are rather too large for " THE .OBJ " you are in, and are
+crushed by its sides as you try to resume your full size." CR>
+	 <JIGS-UP>>
+
+;"from C1"
+
+<ROUTINE I-SNAKE ()
+	 <COND (<EQUAL? ,HERE ,NORTH-SNAKE-ROOM ,SOUTH-SNAKE-ROOM>
+		<TELL CR
+"The scaly wall begins to move, undulating back and forth in the
+confined space. A musty odor permeates the air, and you hear
+scales scraping on stone. Finally, an enormous head slides into view
+from the east and stops with one monstrous eye staring coldly at you.
+You notice something unusual about the huge serpent: the tail, which
+trails out of the western hole, disappears into the gaping maw of the
+creature. You realize that the monster must be huge enough to make a
+complete loop!" CR>)>>
+
+<ROUTINE I-UNMALYON-IDOL ()
+	 <DEQUEUE I-IDOL>
+	 <DEQUEUE I-FULL-YAWN>
+	 <DEQUEUE I-IDOL-ASLEEP>
+	 <FCLEAR ,IDOL ,PERSON>
+	 <COND (<EQUAL? ,HERE ,TEMPLE-ROOM>
+		<CRLF>
+		<TELL
+"The idol turns back into basalt.">
+		<COND (,IDOL-ASLEEP?
+		       <TELL
+" It is curled up comfortably asleep.">)
+		      (,IDOL-YAWNING?
+		       <TELL
+" It has been caught in a cheek-stretching yawn.">)>
+		<CRLF>)>>
+
+<ROUTINE I-IDOL ()
+	 <QUEUE I-IDOL -1>
+	 <COND (<EQUAL? ,HERE ,TEMPLE-ROOM>
+		<TELL CR
+"The idol is ">
+		<COND (,IDOL-SLEEPED?
+		       <TELL
+"looking sleepy and tired.">)
+		      (ELSE
+		       <TELL-IDOL-ACTION>
+		       <TELL
+" around the room, searching for something. No doubt
+it's you! It looks a little stiff, but for former basalt, it's pretty
+supple.">)>
+		<CRLF>)>>
+
+<ROUTINE TELL-IDOL-ACTION ()
+	 <COND (<IN? ,OPAL ,IDOL> <TELL "looking">)
+	       (ELSE <TELL "groping">)>>
+
+<ROUTINE I-FULL-YAWN ()
+	 <DEQUEUE I-IDOL>
+	 <SETG IDOL-ASLEEP? <>>
+	 <FSET ,MOUTH ,OPENBIT>
+	 <SETG IDOL-YAWNING? T>
+	 <COND (<EQUAL? ,HERE ,TEMPLE-ROOM>
+		<TELL CR
+"The idol is yawning sleepily, its mouth gaping open." CR>)>>
+
+<ROUTINE I-IDOL-ASLEEP ()
+	 <SETG IDOL-YAWNING? <>>
+	 <FCLEAR ,MOUTH ,OPENBIT>
+	 <SETG IDOL-ASLEEP? T>
+	 <COND (<EQUAL? ,HERE ,TEMPLE-ROOM>
+		<TELL CR
+"The idol curls up comfortably and falls asleep on the floor." CR>)>>
+
+<ROUTINE I-OPAL-SMASHES ()
+	 <COND (<AND <IN? ,OPAL ,IDOL> ,OPAL-LOOSE?>
+		<REMOVE ,OPAL>
+		<SETG OPAL-LOOSE? <>>
+		<MOVE ,OPAL-SHARD ,HERE>
+		<COND (<EQUAL? ,HERE ,TEMPLE-ROOM>
+		       <TELL
+"The opal totters one last time and falls. You ">
+		       <COND (<IN? ,PLAYER ,IDOL>
+			      <TELL "grab for it frantically">)
+			     (ELSE
+			      <TELL "try to catch it">)>
+		       <TELL ", but it
+escapes your grip and smashes into a million pieces on the idol's
+foot." CR>)>)>>
+
+<GLOBAL SLIDE-PROB 10>
+
+<ROUTINE I-AVALANCHE? ()
+	 <COND (<NOT <EQUAL? ,HERE ,CLIFF-TOP>> <RFALSE>)
+	       (<EQUAL? ,TIME-STOPPED? ,HERE> <RFALSE>)
+	       (<PROB ,SLIDE-PROB>
+		<SETG ROCK-SLIDE-COUNT 0>
+		<DEQUEUE I-AVALANCHE?>
+		<QUEUE I-AVALANCHE -1>
+		<TELL CR
+"Something you've done has disturbed the rocks above! Dirt and small stones
+are trickling down. " ,IT-LOOKS-LIKE "the whole dike is about to give way!" CR>)
+	       (ELSE
+		<SETG SLIDE-PROB <+ ,SLIDE-PROB 10>>)>>
+
+<GLOBAL ROCK-SLIDE-COUNT 0>
+
+<ROUTINE HEAR-AVALANCHE ()
+	 <TELL
+"You hear the tremendous sliding, deep-voiced roar of thousands of tons of
+rock tumbling down the mountain">>
+
+<ROUTINE I-AVALANCHE ()
+	 <COND (,TIME-STOPPED? <RFALSE>)
+	       (<G? ,ROCK-SLIDE-COUNT 3>
+		<SETG ROCK-SLIDE-COUNT 0>
+		<DEQUEUE I-AVALANCHE>
+		<RFALSE>)>
+	 <SETG ROCK-SLIDE-COUNT <+ ,ROCK-SLIDE-COUNT 1>>
+	 <COND (<EQUAL? ,HERE ,CAVE-ENTRANCE ,MOUNTAIN-TOP>
+		<CRLF>
+		<HEAR-AVALANCHE>
+		<COND (<EQUAL? ,HERE ,CAVE-ENTRANCE>
+		       <TELL " to your east">)>
+		<TELL ,PERIOD>)
+	       (<EQUAL? ,HERE ,CLIFF-TOP ,CLIFF-MIDDLE ,CLIFF-BOTTOM>
+		<CRLF>
+		<COND (<EQUAL? ,ROCK-SLIDE-COUNT 1>
+		       <TELL
+"Huge rocks and boulders are tumbling down, making an almost continuous
+curtain above you. If you don't do something soon, you will die!" CR>)
+		      (<OR <AND <EQUAL? ,HERE ,CLIFF-TOP>
+				<G? ,ROCK-SLIDE-COUNT 1>>
+			   <AND <EQUAL? ,HERE ,CLIFF-MIDDLE>
+				<G? ,ROCK-SLIDE-COUNT 2>>
+			   <AND <EQUAL? ,HERE ,CLIFF-BOTTOM>
+				<G? ,ROCK-SLIDE-COUNT 3>>>
+		       <DEQUEUE I-AVALANCHE>
+		       <SETG ROCK-SLIDE-COUNT 0>
+		       <JIGS-UP
+"You are swept away down the cliff face by thousands of tons of rock.
+A huge cloud of dust blowing away down the valley is your only memorial.">)
+		      (<EQUAL? ,HERE ,CLIFF-TOP ,CLIFF-MIDDLE ,CLIFF-BOTTOM>
+		       <ROCKS-TUMBLING>)>)>>
+
+<ROUTINE ROCKS-TUMBLING ()
+	 <TELL
+"Thousands of tons of rock are tumbling down the mountainside!" CR>>
+
+<ROUTINE I-OGRE ()
+	 <COND (<EQUAL? ,TIME-STOPPED? ,OGRE-CAVE> <RFALSE>)
+	       (<EQUAL? ,HERE ,CAVE-ENTRANCE ,OGRE-BEDROOM>
+		<COND (<EQUAL? ,ESPNIS? ,OGRE>
+		       <CRLF>
+		       <OGRE-NOISES>)
+		      (,SNEEZY?
+		       <TELL CR
+"You hear explosive sneezing from the cave." CR>)
+		      (<PROB 50>
+		       <CRLF>
+		       <OGRE-NOISES>)>)
+	       (<EQUAL? ,HERE ,OGRE-CAVE>
+		<COND (<EQUAL? ,ESPNIS? ,OGRE>
+		       <TELL CR
+"The ogre snores loudly." CR>)
+		      (,SNEEZY?
+		       <TELL CR
+"The ogre doubles over in a spectacular paroxysm of sneezing." CR>)
+		      (<PROB 50>
+		       <TELL CR
+"The ogre sneezes." CR>)>)
+	       (ELSE
+		<DEQUEUE I-OGRE>
+		<RFALSE>)>>
+
+<ROUTINE OGRE-NOISES ()
+	 <COND (<NOT <TIME-FROZEN?>>
+		<TELL
+"You hear a noise from within the cave that sounds like ">
+		<COND (<EQUAL? ,ESPNIS? ,OGRE> <TELL "snoring">)
+		      (T <TELL "a sneeze">)>
+		<TELL ,PERIOD>)>>	
+
+;"from C2"
+
+<ROUTINE I-FLOTSAM ()
+	 <SINK-STUFF ,OCEAN-ROOM>
+	 <SINK-STUFF ,LOST-IN-OCEAN>>
+
+<ROUTINE SINK-STUFF (RM "AUX" (F <FIRST? .RM>) N)
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN>)>
+		 <SET N <NEXT? .F>>
+		 <COND (<EQUAL? .F ,WATER-CUBE ,PLAYER ,GROUPER> T)
+		       (<OR <NOT <FSET? .F ,CONTBIT>>
+			    <AND <FSET? .F ,OPENBIT>
+				 <PROB 75>>>
+			<MOVE .F ,OCEAN-FLOOR>
+			<FCLEAR .F ,NDESCBIT>
+			<COND (<EQUAL? ,HERE .RM>
+			       <TELL
+CTHE .F " sinks beneath the waves." CR>)>)
+		       (ELSE
+			<QUEUE I-FLOTSAM 2>)>
+		 <SET F .N>>>
+
+<ROUTINE I-GROUPER ("AUX" (SNACK <>))
+	 <COND (<IN? ,FISH ,OCEAN-ROOM>
+		<SET SNACK ,FISH>)
+	       (<IN? ,BREAD ,OCEAN-ROOM>
+		<SET SNACK ,BREAD>)
+	       (<IN? ,WATER-CUBE ,OCEAN-ROOM>
+		<SET SNACK ,WATER-CUBE>)
+	       (<IN? ,BOTTLE ,OCEAN-ROOM>
+		<SET SNACK ,BOTTLE>)>
+	 <COND (.SNACK
+		<MOVE .SNACK ,GROUPER>
+		<QUEUE I-GROUPER-IN-NEST 2>
+		<COND (<EQUAL? ,HERE ,OCEAN-ROOM>
+		       <TELL CR
+"The grouper, nosing around for something tasty, swallows " THE .SNACK
+" and starts to swim downward, temporarily sated." CR>)>)>>
+
+<ROUTINE I-CUBE-SINKS ()
+	 <COND (<IN? ,WATER-CUBE ,OCEAN-ROOM>
+		<MOVE ,WATER-CUBE ,OCEAN-FLOOR>
+		<FCLEAR ,WATER-CUBE ,NDESCBIT>
+		<COND (<EQUAL? ,HERE ,OCEAN-ROOM>
+		       <TELL CR
+CTHE ,WATER-CUBE " sinks out of sight." CR>)>)>>
+
+<ROUTINE I-GROUPER-IN-NEST ()
+	 <MOVE ,GROUPER ,OCEAN-FLOOR>
+	 <COND (<EQUAL? ,HERE ,OCEAN-ROOM>
+		<TELL
+"The grouper swims down out of sight." CR>)
+	       (<EQUAL? ,HERE ,OCEAN-FLOOR>
+		<TELL
+"The grouper approaches, its goggle eyes staring curiously." CR>)>>
+
+<ROUTINE I-TINSOT ()
+	 <SETG ICED-OBJECT <>>
+	 <COND (<NOT <QUEUED? I-OUBLIETTE-EMPTIES>>
+		<SETG FREEZE-FLAG 0>)>
+	 <RFALSE>>
+
+<ROUTINE I-OUBLIETTE-FILLS ("AUX" (H <>))
+	 <COND (<EQUAL? ,HERE ,OUBLIETTE> <SET H T>)>
+	 <COND (<L? ,WATER-FLAG 3>
+		<ROB ,OUBLIETTE <> ,ICEBERG>
+		<SETG WATER-FLAG <+ ,WATER-FLAG 1>>
+		<COND (.H
+		       <TELL CR
+"The water level rises. The oubliette is "
+<GET ,WATER-HEIGHTS ,WATER-FLAG> " full.">
+		       <COND (<NOT <IN? ,PLAYER ,ICEBERG>>
+			      <SOAK-PLAYER>)>
+		       <NOT-SITTING>
+		       <CRLF>)>)
+	       (ELSE
+		<SETG WATER-FLAG 4>
+		<DEQUEUE I-OUBLIETTE-FILLS>
+		<QUEUE I-OUBLIETTE-EMPTIES 5>
+		<COND (.H
+		       <TELL CR
+"The oubliette is full. There is about four feet of space between the
+water and the roof. The water must have reached its level, because it has
+ceased to rise. You are ">
+		       <COND (<IN? ,PLAYER ,ICEBERG>
+			      <TELL
+"floating serenely on a small ice floe.">)
+			     (ELSE
+			      <TELL
+"splashing a tantalizing distance from the roof and trap door.">)>
+		       <CRLF>)>)>>
+
+
+<ROUTINE I-OUBLIETTE-EMPTIES ("AUX" (H <>))
+	 <COND (<EQUAL? ,HERE ,OUBLIETTE> <SET H T>)>
+	 <COND (<AND <EQUAL? ,WATER-FLAG 4>
+		     <G? ,FREEZE-FLAG 0>>
+		<SETG FREEZE-FLAG 0>
+		<QUEUE I-OUBLIETTE-EMPTIES -1>
+		<COND (.H
+		       <TELL CR
+"The water level has begun to fall." CR>)>)
+	       (ELSE
+		<SETG WATER-FLAG <- ,WATER-FLAG 1>>
+		<COND (<G? ,WATER-FLAG 0>
+		       <COND (.H
+			      <TELL CR
+"The water level falls. The oubliette is "
+<GET ,WATER-HEIGHTS ,WATER-FLAG> " full." CR>)>)
+		      (ELSE
+		       <DEQUEUE I-OUBLIETTE-EMPTIES>
+		       <COND (<IN? ,PLAYER ,ICEBERG>
+			      <MOVE ,WINNER ,HERE>)>
+		       <ROB ,ICEBERG ,HERE>
+		       <REMOVE ,ICEBERG>
+		       <SETG ICED-OBJECT <>>
+		       <COND (.H
+			      <TELL CR
+"The oubliette is empty again. All the ice has melted, and the pipes
+are open again." CR>)>)>)>>
+
+<ROUTINE I-DOWNSTREAM ("AUX" (RM <>))
+	 <COND (<EQUAL? ,HERE ,IN-CHANNEL>
+		<SET RM ,IN-PIPE>)
+	       (<EQUAL? ,HERE ,IN-PIPE>
+		<SET RM ,IN-PIPE-2>)
+	       (<EQUAL? ,HERE ,IN-PIPE-2>
+		<SET RM ,RUINED-PIPE>)
+	       (<EQUAL? ,HERE ,RUINED-PIPE>
+		<SET RM ,IN-SEWER>)>
+	 <COND (.RM
+		<TELL CR
+"The rushing water is forcing you downstream." CR CR>
+		<GOTO .RM>)>>
+
+<GLOBAL ROC-COUNT 0>
+
+<GLOBAL ROC-DESCS
+	<PTABLE
+"tiny black dot silhouetted against the clouds."
+"large object silhouetted against the clouds."
+"large bird approaching."
+"large bird circling the tower and eyeing you suspiciously.">>
+
+<ROUTINE I-ROC ()
+	 <COND (<EQUAL? ,HERE ,GUARD-TOWER>
+		<SETG ROC-COUNT <+ ,ROC-COUNT 1>>
+		<COND (<G? ,ROC-COUNT 4>
+		       <DEQUEUE I-ROC>
+		       <ROC-GRABS-PLAYER>
+		       <CRLF>
+		       <GOTO ,MIDAIR>)
+		      (<G? ,ROC-COUNT 0>
+		       <THIS-IS-IT ,ROC>
+		       <TELL CR "There is a ">
+		       <DESCRIBE-ROC>)>)>>
+
+<GLOBAL ROC-FLY-COUNT 0>
+
+<ROUTINE I-ROC-FLY ()
+	 <SETG ROC-FLY-COUNT <+ ,ROC-FLY-COUNT 1>>
+	 <SETG EW-COUNT <- ,EW-COUNT 1>>
+	 <CRLF>
+	 <COND (<EQUAL? ,ROC-FLY-COUNT 1>
+		<SETG UD-COUNT 4>
+		<TELL
+"The roc gains height and heads west towards the distant Flathead
+Mountains." CR>)
+	       (<EQUAL? ,ROC-FLY-COUNT 2>
+		<TELL
+"The roc continues to fly west towards the mountains." CR>)
+	       (<EQUAL? ,ROC-FLY-COUNT 3>
+		<TELL
+"You are rapidly approaching a rocky eyrie containing an enormous
+nest." CR>)
+	       (<EQUAL? ,ROC-FLY-COUNT 4>
+		<SETG UD-COUNT 0>
+		<DEQUEUE I-ROC-FLY>
+		<MOVE ,PLAYER ,HERE>
+		<MOVE ,ROC ,ROC-NEST>
+		<TELL
+"The roc circles over its nest, settles to the ground, and releases you."
+CR CR>
+		<GOTO ,ROC-NEST>)>>
+
+<ROUTINE I-ROC-HATCHES ("OPTIONAL" (ARG <>))
+	 <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+		<QUEUE I-ROC-HATCHES 5>
+		<RFALSE>)
+	       (<IN? ,BABY-ROC ,HERE>
+		<RFALSE>)>
+	 <MOVE ,BABY-ROC ,ROC-NEST>
+	 <FSET ,EGG ,RMUNGBIT>
+	 <COND (<EQUAL? ,HERE ,ROC-NEST>
+		<QUEUE I-YUM-YUM -1>
+		<COND (<IN? ,PLAYER ,ZIPPER> <RFALSE>)
+		      (<NOT .ARG> <CRLF>)
+		      (ELSE
+		       <TELL
+"You batter the egg, intending to destroy it. ">)>
+		<TELL
+"Suddenly the egg begins to crack. You can see feathers,
+then a large, almost reptilian eye. The egg shatters, and a small
+(wagon-sized) roc chick rolls out. It eyes you hungrily">
+		<COND (<IN? ,CONNECTIVITY-CUBE ,ROC-NEST>
+		       <REMOVE ,CONNECTIVITY-CUBE>
+		       <TELL ", notices the cube at its feet, and gobbles
+it greedily. It still looks hungry">)>
+		<TELL ,PERIOD>)>>
+
+<ROUTINE I-YUM-YUM ()
+	 <COND (<EQUAL? ,HERE ,ROC-NEST>
+		<COND (<AND <NOT <IN? ,PLAYER ,ZIPPER>>
+			    <NOT <EQUAL? ,ESPNIS? ,BABY-ROC>>>
+		       <COND (<IN? ,CONNECTIVITY-CUBE ,PLAYER>
+			      <MOVE ,CONNECTIVITY-CUBE ,HERE>)>
+		       <DEQUEUE I-YUM-YUM>
+		       <JIGS-UP
+"The baby roc, still ravenously hungry, devours you with relish.">)>)
+	       (ELSE
+		<DEQUEUE I-YUM-YUM>
+		<RFALSE>)>>
+
+;"from C3"
+
+<ROUTINE I-MERCHANT ()
+	 <COND (<NOT <FSET? ,MERCHANT ,TOUCHBIT>>
+		<FSET ,MERCHANT ,TOUCHBIT>
+		<MOVE ,MAGIC-CARPET ,MERCHANT>
+		<MOVE ,RANDOM-CARPET ,MERCHANT>
+		<TELL CR
+"The merchant approaches you. \"May I help you? We have a fine selection
+of carpets of all sizes and uses.\" He indicates the pile of rugs and
+picks up two of them. \"These are particularly nice,\" he says. One is "
+A ,MAGIC-CARPET " with a strange design of cubes, and the other is "
+A ,RANDOM-CARPET " that's rather shabby and badly made."
+CR>)
+	       (,MERCHANT-FLAG
+		<SETG MERCHANT-FLAG <>>
+		<RFALSE>)
+	       (<OR <IN? ,MAGIC-CARPET ,PLAYER>
+		    <IN? ,RANDOM-CARPET ,PLAYER>>
+		<TELL
+"The merchant is patiently waiting for you to leave." CR>)
+	       (ELSE
+		<TELL CR
+"The merchant tries to look bored. He doesn't pull it off." CR>)>>
+
+;<ROUTINE I-URCHIN ()
+	 <COND (<NOT <FIRST? ,BAZAAR>>
+		<DEQUEUE I-URCHIN>
+		<RFALSE>)
+	       (ELSE
+		<QUEUE I-URCHIN -1>)>
+	 <COND (<ROB ,HERE <> ,PLAYER>
+		<COND (<EQUAL? ,HERE ,BAZAAR>
+		       <TELL CR
+"A ragged street urchin, excited by this opportunity,
+runs up, scoops up something and disappears into the crowd." CR>)>)>>
+
+<GLOBAL SMASH-PROB 0>
+<GLOBAL ROC-PROB 0>
+<GLOBAL FALLING? <>>
+
+<ROUTINE I-FALLING ()
+	 <COND (<EQUAL? ,TIME-STOPPED? ,HERE>
+		<RFALSE>)
+	       (<NOT <EQUAL? ,HERE ,MIDAIR ,LOST-IN-CLOUDS>>
+		<SETG FALLING? <>>
+		<SETG SMASH-PROB 0>
+		<DEQUEUE I-FALLING>
+		<RFALSE>)>
+	 <COND (<G? ,UD-COUNT 1>
+		<SETG UD-COUNT <- ,UD-COUNT 1>>
+		<SETG ROC-PROB <+ ,ROC-PROB 25>>
+		<COND (<AND <NOT <FSET? <LOC ,PLAYER> ,VEHBIT>>
+			    <EQUAL? ,OHERE ,EARTH-ROOM ,AIR-ROOM>
+			    <PROB ,ROC-PROB>>
+		       <SETG FALLING? <>>
+		       <ROC-GRABS-PLAYER T>
+		       <RTRUE>)>)
+	       (ELSE
+		<SETG SMASH-PROB <+ ,SMASH-PROB 20>>
+		<COND (<PROB ,SMASH-PROB>
+		       <SETG FALLING? <>>
+		       <TELL CR
+"You tumble helplessly into the earth, and the results are, of course,
+fatal.">
+		       <JIGS-UP>
+		       <RFATAL>)>)>
+	 <TELL CR
+"You are falling towards the ground, wind whipping around you." CR>>
+
+<ROUTINE I-ROCK-ARRIVES ()
+	 <MOVE ,LAVA-ROCK ,VOLCANO-BASE>
+	 <COND (<EQUAL? ,HERE ,VOLCANO-BASE>
+		<TELL CR
+"One fragment of molten lava explodes out of the flow and drops right
+at your feet! It sizzles and hisses." CR>)>>
+
+<ROUTINE I-GRUES-NOTICE ("OPTIONAL" (CR? <>))
+	 <COND (<EQUAL? ,HERE ,GRUE-CAVE>
+		<COND (<NOT ,LIT>
+		       <COND (<NOT .CR?> <CRLF>)>
+		       <JIGS-UP
+"Scrabbling and scratching claws are approaching in the dark. The last
+sound you hear is the gurgling of the pack of grues that devours you
+with unmentionable enjoyment.">)
+		      (<OR <NOT <EQUAL? ,CHANGED? ,GRUE>>
+			   <NOT <EQUAL? ,LIT ,GRUE>>>
+		       <GRUES-NOTICE-LIGHT>)>)
+	       (<EQUAL? ,HERE ,PILLAR-ROOM ,LIGHT-POOL>
+		<COND (<NOT ,LIT>
+		       <COND (<NOT .CR?> <CRLF>)>
+		       <TELL
+"Scrabbling and scratching claws are nearby.">)
+		      (<OR <NOT <EQUAL? ,CHANGED? ,GRUE>>
+			   <NOT <EQUAL? ,LIT ,GRUE>>>
+		       <TELL
+"The grues have noticed you, and are terrifically agitated." CR>)>)>>
+
+<ROUTINE GRUES-NOTICE-LIGHT ()
+	 <TELL
+"The shapes are coming closer. They have noticed ">
+	 <TELL-LIGHT-SOURCE>
+	 <TELL ,PERIOD>
+	 <TELL
+"They approach you warily, avoiding the tiny drips
+of light. They grab you, overwhelm you, and ">
+	 <COND (<EQUAL? ,CHANGED? ,GRUE>
+		<TELL "as in
+addition to their other nasty habits, grues are cannibalistic, they ">)>
+	 <TELL "devour you, grunting, gurgling,
+and snapping at each other as they fight over the best parts.">
+	 <JIGS-UP>>
+
+<ROUTINE I-FRIED-GRUE ()
+	 <COND (<AND <EQUAL? ,HERE ,LIGHT-POOL>
+		     <EQUAL? ,CHANGED? ,GRUE>>
+		<JIGS-UP
+"The burning sensation gets worse and worse. You struggle
+against it, but the light is just too much. You lose consciousness, sink
+to the bottom of the pool, and expire.">)
+	       (ELSE
+		<QUEUE I-FRIED-GRUE -1>
+		<RFALSE>)>>
+
+<ROUTINE I-ALARM ()
+	 <COND (<NOT <IN? ,ALARM-FAIRY ,SCALES-ROOM>>
+		<MOVE ,ALARM-FAIRY ,SCALES-ROOM>
+		<COND (<EQUAL? ,HERE ,SCALES-ROOM>
+		       <TELL CR
+"Suddenly an alarm fairy appears in the Treasury. It carries a big gong which
+it begins to pound incessantly, and it yells at the top of its lungs." CR>)>)>
+	 <COND (<EQUAL? ,HERE ,SCALES-ROOM>
+		<TELL CR
+"\"There's a thief here! Hey, guards! Thief! Nasty thieving thief's here!
+Come capture the thief!\" The din is tremendous." CR>)>>
+
+<ROUTINE I-GUARDS ()
+	 <SETG GUARDS-FLAG <+ ,GUARDS-FLAG 1>>
+	 <COND (<EQUAL? ,GUARDS-FLAG 1>
+		<QUEUE I-GUARDS 1>
+		<COND (<EQUAL? ,HERE ,SCALES-ROOM>
+		       <COND (<FSET? ,IRON-DOOR ,OPENBIT>
+			      <TELL CR
+"Five burly guards, unshaven and thuggish, stand
+outside the door. It is clear their intention is to come in.">)
+			     (ELSE
+			      <TELL CR
+"You can hear a key being inserted in the lock from outside. The alarm
+fairy thumbs its nose at you derisively.">)>
+		       <CRLF>)>)
+	       (ELSE
+		<SETG TREASURY-GUARDED? T>
+		<COND (<EQUAL? ,HERE ,SCALES-ROOM ,INNER-VAULT>
+		       <TELL CR "All at once ">
+		       <COND (<NOT <FSET? ,IRON-DOOR ,OPENBIT>>
+			      <TELL "the door bursts in and ">)>
+		       <FCLEAR ,IRON-DOOR ,OPENBIT>
+		       <TELL
+"five burly guards crowd into the
+Treasury. They look at you with extreme disapproval, tinged with a
+certain sadistic anticipation of what is to come. The alarm fairy
+twitters about near the ceiling, jeering at you. \"Told you so, nyaah,
+nyaah!\" it chants. In the interest of taste, we will gloss over what
+happens next, but at the end of it you are dead.">
+		       <JIGS-UP>)>)>>
+
+;"from C4"
+
+
+<ROUTINE I-OTHER-ROCK ("AUX" DIR RROW RCOL OROW OCOL (DROW 0) (DCOL 0))
+	 <COND (<EQUAL? ,ROCK-LOC ,OTHER-ROCK-LOC>
+		<SETG ROCK-MOVED? <>>
+		<DEQUEUE I-OTHER-ROCK>
+		<TELL
+CTHE ,OTHER-ROCK ", mesmerized by the looming presence of " THE ,ROCK
+", does not move." CR>)
+	       (,ROCK-MOVED?
+		<SETG ROCK-MOVED? <>>
+		<SET RROW </ ,ROCK-LOC 4>>
+		<SET RCOL <BAND ,ROCK-LOC 3>>
+		<SET OROW </ ,OTHER-ROCK-LOC 4>>
+		<SET OCOL <BAND ,OTHER-ROCK-LOC 3>>
+		<SET DROW
+		     <COND (<G? .RROW .OROW> <- .RROW .OROW>)
+			   (ELSE <- .OROW .RROW>)>>
+		<SET DCOL
+		     <COND (<G? .RCOL .OCOL> <- .RCOL .OCOL>)
+			   (ELSE <- .OCOL .RCOL>)>>
+		<CRLF>
+		<COND (<EQUAL? ,OTHER-ROCK-LOC 1>
+		       <COND (<AND <NOT <EQUAL? ,ROCK-LOC 4 5 8>>
+				   <ZERO? <BAND <+ .DROW .DCOL> 1>>>
+			      <SET DIR ,P?SW>)
+			     (<NOT <EQUAL? ,ROCK-LOC 5>>
+			      <SET DIR ,P?SOUTH>)
+			     (<NOT <EQUAL? ,ROCK-LOC 2>>
+			      <SET DIR ,P?EAST>)>)
+		      (<EQUAL? ,OTHER-ROCK-LOC 4>
+		       <COND (<AND <NOT <EQUAL? ,ROCK-LOC 1 2 5>>
+				   <ZERO? <BAND <+ .DROW .DCOL> 1>>>
+			      <SET DIR ,P?NE>)
+			     (<NOT <EQUAL? ,ROCK-LOC 5>>
+			      <SET DIR ,P?EAST>)
+			     (<NOT <EQUAL? ,ROCK-LOC 8>>
+			      <SET DIR ,P?SOUTH>)>)
+		      (<AND <EQUAL? ,OTHER-ROCK-LOC 5>
+			    <EQUAL? ,ROCK-LOC 1 4>>
+		       <SET DIR
+			    <COND (<EQUAL? ,ROCK-LOC 4> ,P?EAST)
+				  (ELSE ,P?SOUTH)>>)
+		      (<EQUAL? .RROW .OROW>
+		       <COND (<OR <EQUAL? .OROW 0>
+				  <AND <EQUAL? .OROW 1>
+				       <EQUAL? .OCOL 0>>>
+			      <SET DIR ,P?SOUTH>)
+			     (<OR <EQUAL? .OROW 3>
+				  <PROB 50>>
+			      <SET DIR ,P?NORTH>)
+			     (ELSE
+			      <SET DIR ,P?SOUTH>)>)
+		      (<EQUAL? .RCOL .OCOL>
+		       <COND (<OR <EQUAL? .OCOL 0>
+				  <AND <EQUAL? .OCOL 1>
+				       <EQUAL? .OROW 0>>>
+			      <SET DIR ,P?EAST>)
+			     (<OR <EQUAL? .OCOL 3>
+				  <PROB 50>>
+			      <SET DIR ,P?WEST>)
+			     (ELSE
+			      <SET DIR ,P?EAST>)>)
+		      (<AND <EQUAL? .OCOL 0> <EQUAL? .OROW 3>>
+		       <COND (<PROB 50> <SET DIR ,P?EAST>)
+			     (ELSE <SET DIR ,P?NORTH>)>)
+		      (<AND <EQUAL? .OCOL 3> <EQUAL? .OROW 3>>
+		       <COND (<PROB 50> <SET DIR ,P?WEST>)
+			     (ELSE <SET DIR ,P?NORTH>)>)
+		      (<AND <EQUAL? .OCOL 3> <EQUAL? .OROW 0>>
+		       <COND (<PROB 50> <SET DIR ,P?WEST>)
+			     (ELSE <SET DIR ,P?SOUTH>)>)
+		      (<AND <G? .RROW .OROW>
+			    <G? .OROW 0>
+			    <OR <G? .OROW 1> <G? .OCOL 0>>>
+		       <SET DIR ,P?NORTH>)
+		      (<AND <G? .RCOL .OCOL>
+			    <G? .OCOL 0>
+			    <OR <G? .OCOL 1> <G? .OROW 0>>>
+		       <SET DIR ,P?WEST>)
+		      (<AND <L? .RROW .OROW> <L? .OROW 3>>
+		       <SET DIR ,P?SOUTH>)
+		      (<AND <L? .RCOL .OCOL> <L? .OCOL 3>>
+		       <SET DIR ,P?EAST>)>
+		%<DEBUG-CODE
+		   <COND (<ZERO? .DIR>
+			  <TELL
+"[BUG: Brown-eyed rock zero direction?]" CR
+"[Blue: " N ,ROCK-LOC ", Brown: " N ,OTHER-ROCK-LOC "]" CR>)>>
+		<COND (<EQUAL? .DIR ,P?EAST>
+		       <SET OCOL <+ .OCOL 1>>)
+		      (<EQUAL? .DIR ,P?WEST>
+		       <SET OCOL <- .OCOL 1>>)
+		      (<EQUAL? .DIR ,P?SOUTH>
+		       <SET OROW <+ .OROW 1>>)
+		      (<EQUAL? .DIR ,P?NORTH>
+		       <SET OROW <- .OROW 1>>)
+		      (<EQUAL? .DIR ,P?NE>
+		       <SET OROW <- .OROW 1>>
+		       <SET OCOL <+ .OCOL 1>>)
+		      (ELSE
+		       <SET OROW <+ .OROW 1>>
+		       <SET OCOL <- .OCOL 1>>)>
+		<SETG OTHER-ROCK-LOC <+ <* 4 .OROW> .OCOL>>
+		<COND (<IN? ,PLAYER ,OTHER-ROCK>
+		       <SETG YOU-LOC ,OTHER-ROCK-LOC>)>
+		%<DEBUG-CODE <COND (,ZDEBUG
+<TELL "[Brown: " N ,OTHER-ROCK-LOC "]" CR>)>>
+		<TELL
+CTHE ,OTHER-ROCK " slides gracefully ">
+		<COND (<SET DIR <DIR-BASE .DIR ,DIR-DIR ,DIR-NAME>>
+		       <TELL .DIR>)>
+		<TELL ,PERIOD>
+		%<DEBUG-CODE
+		   <COND (<OR <L? .OROW 0>
+			      <L? .OCOL 0>
+			      <G? .OROW 3>
+			      <G? .OCOL 3>
+			      <AND <EQUAL? .OROW 0>
+				   <EQUAL? .OCOL 0>>>
+			  <TELL
+"[BUG: Brown eyed rock off plain?]" CR
+"[Blue: " N ,ROCK-LOC ", Brown: " N ,OTHER-ROCK-LOC "]" CR>)>>
+		<RTRUE>)>>
+
+<ROUTINE I-STOP-SNEEZING ()
+	 <SETG SNEEZY? <>>
+	 <COND (<AND <EQUAL? ,HERE ,OGRE-CAVE>
+		     <NOT <EQUAL? ,TIME-STOPPED? ,HERE>>
+		     <NOT <EQUAL? ,ESPNIS? ,OGRE>>>
+		<TELL CR
+"The pollen has settled out, and the ogre's sneezes abate.">
+		<OGRE-MAD>)
+	       (<EQUAL? ,HERE ,CAVE-ENTRANCE ,OGRE-BEDROOM>
+		<TELL CR
+"The sneezing noises have slowed in volume and frequency." CR>)>>
+
+<ROUTINE OGRE-MAD ()
+	 <TELL " He recovers his self-possession." CR>
+	 <I-OGRE-KILLS-YOU>>
+
+<ROUTINE I-WATER-RISING ()
+	 <COND (<EQUAL? ,HERE ,PAST-RUINS-ROOM>
+		<COND (<EQUAL? ,PAST-WATER-FLAG 4>
+		       <HYPOTHERMIA>
+		       <RFATAL>)>
+		<QUEUE I-WATER-RISING 4>
+		<COND (<L? ,PAST-WATER-FLAG 4>
+		       <SETG PAST-WATER-FLAG <+ ,PAST-WATER-FLAG 1>>)>
+		<COND (<IN? ,PLAYER ,ZIPPER> <RFALSE>)>
+		<TELL CR <GET ,WATER-TABLE ,PAST-WATER-FLAG>>
+		<COND (<EQUAL? ,PAST-WATER-FLAG 2>
+		       <COND (<SOAK-STUFF ,HERE <>>
+			      <TELL
+" Items on the floor are wet and ruined, of course.">)>
+		       <NOT-SITTING>)
+		      (<EQUAL? ,PAST-WATER-FLAG 4>
+		       <SOAK-PLAYER>)>
+		<CRLF>)>>
+
+<GLOBAL PAST-WATER-FLAG 0>
+
+<ROUTINE I-PRISON-GUARDS ()
+	 <COND (<TIME-FROZEN?>
+		<QUEUE I-PRISON-GUARDS 2>
+		<RFALSE>)
+	       (<EQUAL? ,HERE ,PAST-CELL-EAST>
+		<TELL
+"Many nasty guards arrive">
+		<COND (<IN? ,PLAYER ,CABINET>
+		       <TELL ", find you hiding in the cabinet,">)>
+		<TELL " and immediately (for their own protection, of
+course) run you through with their swords." CR CR>
+		<TIME-SICK-CELL-EAST>)>>
\ No newline at end of file
diff --git a/magic.zil b/magic.zil
new file mode 100644
index 0000000..e9e9ad9
--- /dev/null
+++ b/magic.zil
@@ -0,0 +1,1364 @@
+"MAGIC for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+"---Summary of magic spells---
+
+    -Spell-	-English-
+
+ s  AIMFIZ	transport yourself to someone's location
+e   BLORB	STRONG-BOX-SPELL
+  6 BLORPLE	explore mystic connections
+  6 CASKLY	perfect
+e   CLEESH	NEWT-SPELL
+  6 ESPNIS	SLEEP-SPELL
+e   EXEX	HASTE-SPELL
+e   FILFRE	CREDITS-SPELL
+es  FROTZ	LIGHT-SPELL
+ s  FWEEP	turn caster into a bat
+ s  GASPAR	resurrection
+  6 GIRGOL	stop time
+es  GNUSTO	WRITE-MAGIC-SPELL
+ s  GOLMAC	travel temporally
+e   GONDAR	QUENCH-SPELL
+e   GUNCHO	BANISH-SPELL
+es  IZYUK	FLY-SPELL
+  6 JINDAK	detect magic
+e   KREBF	REPAIR-SPELL
+e   KULCAD	DISPEL-SPELL
+  6 LESOCH	gust of wind
+  6 LISKON	shrink
+ s  MALYON	bring life to inanimate objects
+ s  MEEF	cause plants to wilt
+e   MELBOR	PROTECTION-SPELL
+e   NITFOL	TALK-TO-ANIMALS-SPELL
+e   OZMOO	CHEAT-DEATH-SPELL
+ s  PULVER	cause liquids to dry up
+es  REZROV	OPEN-SPELL
+  6 SNAVIG	transform into another
+ s  SWANZO	exorcise an inhabiting presence
+  6 THROCK	cause plants to grow
+  6 TINSOT	freeze
+ s  VARDIK	shield a mind from an evil spirit
+e   VAXUM	CHARM-SPELL
+ s  VEZZA	view the future
+ s  YOMIN	mind probe
+ s  YONK	augment the power of certain spells
+e   ZIFMIA	SUMMON-SPELL
+
+    -Potion-	-English-
+
+ s  BERZIO	obviate need for food and drink
+ s  BLORT	see in the dark
+ s  FLAXO	exquisite torture
+ s  FOOBLE	increase coordination
+ s  VILSTU	obviate need for breathing
+"
+
+<OBJECT SPELL-BOOK
+	(IN PLAYER)
+	(SYNONYM BOOK NOTES)
+	(ADJECTIVE MY SPELL MARGIN)
+	(DESC "spell book")
+	(ACTION SPELL-BOOK-F)
+	(FLAGS TOUCHBIT TAKEBIT READBIT CONTBIT OPENBIT MAGICBIT)>
+
+<GLOBAL SEEN-BLORPLE? <>>
+
+<ROUTINE SPELL-BOOK-F ("AUX" (F <FIRST? ,SPELL-BOOK>))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is your well-used old " 'SPELL-BOOK ", first given to you by Belboz
+years ago after your original book was lost. ">
+		<COND (<FSET? ,PRSO ,RMUNGBIT>
+		       <TELL
+"He would be appalled by its current ruined condition. It's
+water-soaked, and the ink has run. It's useless.">)
+		      (ELSE
+		       <TELL "There are some spells
+written in the book, those few still working of the many you once knew.
+The rest have faded away.">
+		       <COND (<AND ,CLEESHED? <NOT ,SEEN-BLORPLE?>>
+			      <SEE-BLORPLE>
+			      <TELL
+" As you look at it closely, though, you realize that the book has
+changed subtly from its previous appearance. There is a new
+entry: " 'BLORPLE-SPELL " ("
+<GETP ,BLORPLE-SPELL ,P?TEXT> ").">)>)>
+		<CRLF>)
+	       (<VERB? OPEN CLOSE>
+		<TELL
+"The " 'SPELL-BOOK " is always open to the right place, but it is also
+always closed. This eliminates tedious leafing and hunting for spells.
+Many lives have been saved by this magical innovation." CR>)
+	       (<VERB? READ LOOK-INSIDE>
+		<COND (<FSET? ,PRSO ,RMUNGBIT>
+		       <TELL
+CTHE ,SPELL-BOOK " is totally unreadable. The ink has run, and the pages
+are soaked. What a mess!" CR>
+		       <RTRUE>)
+		      (<NOT ,LIT>
+		       <TELL
+"The magic writing of the spells casts enough light
+that you can read them." CR>)>
+		<TELL "My Spell Book|
+|
+">
+		<REPEAT ()
+			<COND (<NOT .F> <RETURN>)>
+			<TELL CTHE .F " (" <GETP .F ,P?TEXT> ")." CR>
+			<SET F <NEXT? .F>>>
+		<COND (<AND ,CLEESHED? <NOT ,SEEN-BLORPLE?>>
+		       <SEE-BLORPLE>
+		       <TELL
+"|
+Oddly enough, you have never before seen or heard of the blorple spell
+which now graces (or defaces?) your book." CR>)>
+		<RTRUE>)
+	       (<VERB? WRITE>
+		<TELL
+"When you are done, the " 'SPELL-BOOK " remains unmarred." CR>)>>
+
+<OBJECT BLORPLE-SPELL 
+	(IN CASTLE) ;"so MOBY-FIND can find it"
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC BLORPLE)
+	(DESC "blorple spell")
+	(TEXT "explore an object's mystic connections")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT LESOCH-SPELL 
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC LESOCH)
+	(DESC "lesoch spell")
+	(TEXT "gust of wind")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT SNAVIG-SPELL 
+	(IN CASTLE) ;"so MOBY-FIND can find it"
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC SNAVIG)
+	(DESC "snavig spell")
+	(TEXT "shape change")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT GIRGOL-SCROLL 
+	(IN CASTLE) ;"so MOBY-FIND can find it"
+	(SYNONYM SCROLL)
+	(ADJECTIVE FLIMSY)
+	(DESC "flimsy scroll")
+	(ACTION SCROLL-F)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<OBJECT GIRGOL-SPELL 
+	(IN GIRGOL-SCROLL)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC GIRGOL)
+	(DESC "girgol spell")
+	(TEXT "stop time")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT JINDAK-SPELL 
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC JINDAK)
+	(DESC "jindak spell")
+	(TEXT "detect magic")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT ESPNIS-SCROLL 
+	(IN OGRE-BEDROOM)
+	(SYNONYM SCROLL)
+	(ADJECTIVE DUSTY)
+	(DESC "dusty scroll")
+	(ACTION SCROLL-F)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<OBJECT ESPNIS-SPELL
+	(IN ESPNIS-SCROLL)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC ESPNIS)
+	(DESC "espnis spell")
+	(TEXT "sleep")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT TINSOT-SCROLL 
+	(IN GLACIER-ROOM)
+	(SYNONYM SCROLL)
+	(ADJECTIVE WHITE)
+	(DESC "white scroll")
+	(ACTION SCROLL-F)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<OBJECT TINSOT-SPELL 
+	(IN TINSOT-SCROLL)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC TINSOT)
+	(DESC "tinsot spell")
+	(TEXT "freeze")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT THROCK-SCROLL 
+	(IN CLIFF-MIDDLE)
+	(SYNONYM SCROLL)
+	(ADJECTIVE DIRTY)
+	(DESC "dirty scroll")
+	(ACTION SCROLL-F)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<OBJECT THROCK-SPELL 
+	(IN THROCK-SCROLL)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC THROCK)
+	(DESC "throck spell")
+	(TEXT "cause plants to grow")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT CASKLY-SCROLL 
+	(IN ROC-NEST)
+	(SYNONYM SCROLL)
+	(ADJECTIVE STAINED)
+	(DESC "stained scroll")
+	(ACTION SCROLL-F)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<OBJECT CASKLY-SPELL 
+	(IN CASKLY-SCROLL)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC CASKLY)
+	(DESC "caskly spell")
+	(TEXT "cause perfection")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT LISKON-SCROLL 
+	(IN BOTTLE)
+	(SYNONYM SCROLL)
+	(ADJECTIVE DAMP)
+	(DESC "damp scroll")
+	(ACTION SCROLL-F)
+	(FLAGS NDESCBIT
+	       TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<OBJECT LISKON-SPELL
+	(IN LISKON-SCROLL)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC LISKON)
+	(DESC "liskon spell")
+	(TEXT "shrink a living thing")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+"OLD SPELLS"
+
+<OBJECT MALYON-SPELL 
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC MALYON)
+	(DESC "malyon spell")
+	(TEXT "animate")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT GNUSTO-SPELL 
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC GNUSTO)
+	(DESC "gnusto spell")
+	(TEXT "write a magic spell into a spell book")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT FROTZ-SPELL
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC FROTZ)
+	(DESC "frotz spell")
+	(TEXT "cause something to give off light")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>
+
+<OBJECT REZROV-SPELL
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC REZROV)
+	(DESC "rezrov spell")
+	(TEXT "open even locked or enchanted objects")
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)>	
+
+<OBJECT YOMIN-SPELL
+	(IN SPELL-BOOK)
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE AABBCC YOMIN)
+	(DESC "yomin spell")
+	(TEXT "mind probe")
+	(COUNT 0)
+	(SIZE 1)
+	(FLAGS NDESCBIT SPELLBIT)
+	(ACTION SPELL-F)>
+
+<ROUTINE SCROLL-F ("AUX" SPELL)
+	 <COND (<VERB? TAKE>
+		<SET SPELL <FIRST? ,PRSO>>
+		<FSET .SPELL ,TOUCHBIT>
+		<FCLEAR ,PRSO ,TRYTAKEBIT>
+		<RFALSE>)
+	       ;(<AND <NOT <FIRST? ,PRSO>>
+		     <NOT <FIRST? ,PRSI>>>
+		<TELL "Bug #72" CR>)
+	       (<VERB? GNUSTO COPY WRITE>
+		<COND (<AND <FSET? ,PRSO ,SCROLLBIT>
+			    <NOT <IN? ,PRSO ,WINNER>>>
+		       <MUST-HOLD-SCROLL>)
+		      (<SET SPELL <FIRST? ,PRSO>>
+		       <PERFORM ,PRSA .SPELL ,PRSI>
+		       <RTRUE>)>)
+	       (<VERB? EXAMINE READ>
+		<READ-SCROLL>)>>
+
+<ROUTINE SCROLL-WET ()
+	 <TELL
+"The scroll is wet, and the spell cannot be read." CR>>
+
+<ROUTINE READ-SCROLL ("OPTIONAL" (SPELL <>))
+	 <COND (<FSET? ,PRSO ,RMUNGBIT>
+		<SCROLL-WET>
+		<RTRUE>)>
+	 <COND (<NOT .SPELL> <SET SPELL <FIRST? ,PRSO>>)>
+	 <TELL "The scroll">
+	 <SPELL-READS .SPELL>>
+
+<ROUTINE MUST-HOLD-SCROLL ()
+	 <TELL
+"You must be holding the spell scroll you wish to copy!" CR>>
+
+<ROUTINE SPELL-F ("AUX" MEM? (FORGET <>))
+	 <COND (<AND <VERB? READ LEARN>
+		     <NOT <IN? ,PRSO ,SPELL-BOOK>>
+		     <FSET? <LOC ,PRSO> ,TOUCHBIT>
+		     <NOT <IN? <LOC ,PRSO> ,WINNER>>>
+		<TELL
+,YOU-CANT "do that without having the spell in your book." CR>
+		<RFATAL>)
+	       (<AND <VERB? READ LEARN>
+		     <FSET? ,SPELL-BOOK ,RMUNGBIT>>
+		<PERFORM ,V?READ ,SPELL-BOOK>
+		<THIS-IS-IT ,PRSO>
+		<RFATAL>)
+	       (<AND <LOC ,PRSO>
+		     <FSET? <LOC ,PRSO> ,RMUNGBIT>>
+		<SCROLL-WET>)
+	       (<VERB? READ>
+		<TELL "The spell">
+		<SPELL-READS ,PRSO>)
+	       (<VERB? LEARN>
+		<COND (<NOT <IN? ,PRSO ,SPELL-BOOK>>
+		       <COND (<HELD? ,PRSO>
+			      <TELL
+"You haven't written that spell into your book yet. Until you do, you
+can't memorize the spell." CR>)
+			     (T
+			      <V-LEARN>)>
+		       <RFATAL>)
+		      (<IN? ,PRSO ,DEAD-BOOK>
+		       <TELL
+"You can learn spells only from your own " 'SPELL-BOOK>
+		       <TELL ,PERIOD>
+		       <RFATAL>)		      
+		      (<EQUAL? ,PRSO
+			       ,GNUSTO-SPELL ,FROTZ-SPELL ,REZROV-SPELL>
+		       <TELL "You already know that spell by heart." CR>)
+		      (<NOT <IN? ,SPELL-BOOK ,WINNER>>
+		       <TELL
+,YOU-DONT-HAVE "your " 'SPELL-BOOK ". You can't memorize a spell
+without a " 'SPELL-BOOK ,PERIOD>
+		       <RFATAL>)
+		      (T
+		       <SET MEM? <GETP ,PRSO ,P?COUNT>>
+		       <COND (<NOT <HELD? ,MAGIC-CUBE>>
+			      <COND (<OR <EQUAL? ,SPELL-MAX 1>
+					 <G? ,AWAKE 6>
+					 <AND <G? ,AWAKE 0>
+					      <PROB <* 5 ,AWAKE>>>>
+				     <TELL
+,YOU-CANT "concentrate well enough to learn the spell." CR>
+				     <RTRUE>)
+				    (<EQUAL? .MEM? ,SPELL-MAX>
+				     <TELL
+"You try, but you just can't memorize those complex syllables again.
+They slip out of your memory as soon as you cram them in." CR>
+				     <RTRUE>)
+				    (<NOT <G? ,SPELL-ROOM 0>>
+				     <FORGET-SPELL ,PRSO>
+				     <SETG SPELL-ROOM 1>
+				     <SET FORGET T>)>)>
+		       <SETG SPELL-ROOM <- ,SPELL-ROOM 1>>
+		       <SET MEM? <+ .MEM? 1>>
+		       <PUTP ,PRSO ,P?COUNT .MEM?>
+		       <COND (<HELD? ,MAGIC-CUBE>
+			      <TELL "You easily">)
+			     (ELSE
+			      <TELL "Using your best study habits, you">)>
+		       <TELL " learn the " 'PRSO>
+		       <COND (<G? .MEM? 1>
+			      <TELL " yet another time">)>
+		       <TELL ,PERIOD>
+		       <COND (.FORGET
+			      <TELL
+"You have so much buzzing around in your head, though, that it's
+likely that something may have been forgotten in the shuffle." CR>)>
+		       <RTRUE>)>)
+	       (<AND <NOT <VISIBLE? ,PRSO>>
+		     <NOT <VERB? CAST>>>
+		<TELL ,YOU-CANT-SEE "that spell here!" CR>)
+	       (<VERB? TAKE DROP THROW>
+		<TELL-YUKS>)>>
+
+<ROUTINE SPELL-READS (SPELL)
+	 <TELL
+" reads \"" D .SPELL ": " <GETP .SPELL ,P?TEXT> ".\"">
+	 <COND (<OR <EQUAL? .SPELL ,GIRGOL-SPELL>
+		    <AND <EQUAL? .SPELL ,SPELL-COPY>
+			 <EQUAL? <GETP .SPELL ,P?WALLS> ,GIRGOL-SPELL>>>
+		<TELL
+" The spell is long and complicated.">)>
+	 <CRLF>>
+
+<ROUTINE FORGET-SPELL (SPL "AUX" F CNT TBL (NUM 0) (SP <>))
+	 <SET F <FIRST? ,SPELL-BOOK>>
+	 <SET TBL ,FORGET-TBL>
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN>)
+		       (<G? <SET CNT <GETP .F ,P?COUNT>> 0>
+			<REPEAT ()
+				<SET SP .F>
+				<PUT .TBL 1 .F>
+				<SET NUM <+ .NUM 1>>
+				<SET TBL <REST .TBL 2>>
+				<COND (<L? <SET CNT <- .CNT 1>> 1>
+				       <RETURN>)>>)>
+		 <SET F <NEXT? .F>>>
+	 <COND (<AND <G? .NUM 0>
+		     <EQUAL? <GETP .SP ,P?COUNT> .NUM>>
+		<PUTP .SP ,P?COUNT <- .NUM 1>>
+		<RTRUE>)>
+	 <PUT ,FORGET-TBL 0 .NUM>
+	 <COND (<ZERO? .NUM> <RTRUE>)>
+	 <SET SPL <RANDOM-ELEMENT ,FORGET-TBL>>
+	 <PUTP .SPL ,P?COUNT <- <GETP .SPL ,P?COUNT> 1>>>
+
+<GLOBAL FORGET-TBL <LTABLE 0 0 0 0 0 0 0 0 0 0>>
+
+<ROUTINE FORGET-ALL ("AUX" F)
+	 <SETG SPELL-ROOM ,SPELL-MAX>
+	 <SET F <FIRST? ,SPELL-BOOK>>
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN>)
+		       (ELSE
+			<PUTP .F ,P?COUNT 0>
+			<SET F <NEXT? .F>>)>>>
+
+<ROUTINE WEAR-OFF-SPELLS ("OPTIONAL" (SLEEP? T))
+	 <COND (,CHANGED?
+		<COND (.SLEEP? <I-SNAVIG>)
+		      (ELSE
+		       <SETG CHANGED? <>>
+		       <DEQUEUE I-SNAVIG>)>)> ;"not changed"
+	 <COND (,SHRINK-FLAG
+		<COND (.SLEEP? <I-LISKON>)
+		      (ELSE
+		       <COND (<AND <HELD? ,SHRINK-FLAG>
+				   <EQUAL? ,SHRINK-FLAG ,WEED>>
+			      <MOVE ,WEED ,HERE>)>
+		       <SETG SHRINK-FLAG <>>
+		       <SETG SMALL-FLAG <>>
+		       <DEQUEUE I-LISKON>)>)> ;"not shrunk"
+	 <COND (,TIME-STOPPED?
+		<COND (.SLEEP? <I-GIRGOL>)
+		      (ELSE
+		       <SETG TIME-STOPPED? <>>
+		       <SETG ROCK-FLAG <>>
+		       <DEQUEUE I-GIRGOL>)>)> ;"not time-stopped"
+	 <COND (,ESPNIS?
+		<COND (.SLEEP? <I-ESPNIS>)
+		      (ELSE
+		       <SETG ESPNIS? <>>
+		       <DEQUEUE I-ESPNIS>)>)> ;"not sleeped">
+
+<GLOBAL REAL-SPELL-MAX 4>
+<GLOBAL SPELL-MAX 4>  ;"max spells memorizable"
+<GLOBAL SPELL-ROOM 4> ;"number can memorize now"
+
+"subtitle magic-related verbs"
+
+<ROUTINE SPELL-VERB? ()
+	 <VERB? GNUSTO FROTZ REZROV TINSOT YOMIN
+		MALYON LESOCH BLORPLE SNAVIG GIRGOL
+		JINDAK ESPNIS CASKLY LISKON THROCK>> 
+
+<ROUTINE PRE-CAST ("AUX" SPELL SCROLL)
+	 <COND (,SPELL-CAST <RFALSE>)>
+	 <SET SPELL
+	      <COND (<VERB? GNUSTO> ,GNUSTO-SPELL)
+		    (<VERB? FROTZ> ,FROTZ-SPELL)
+		    (<VERB? REZROV> ,REZROV-SPELL)
+		    (<VERB? YOMIN> ,YOMIN-SPELL)
+		    (<VERB? LESOCH> ,LESOCH-SPELL)
+		    (<VERB? BLORPLE> ,BLORPLE-SPELL)
+		    (<VERB? SNAVIG> ,SNAVIG-SPELL)
+		    (<VERB? GIRGOL> ,GIRGOL-SPELL)
+		    (<VERB? JINDAK> ,JINDAK-SPELL)
+		    (<VERB? ESPNIS> ,ESPNIS-SPELL)
+		    (<VERB? MALYON> ,MALYON-SPELL)
+		    (<VERB? CASKLY> ,CASKLY-SPELL)
+		    (<VERB? LISKON> ,LISKON-SPELL)
+		    (<VERB? THROCK> ,THROCK-SPELL)
+		    (<VERB? TINSOT> ,TINSOT-SPELL)
+		    (<VERB? $XEROX> ,SPELL-COPY)>>
+	 <COND (<AND <IN? .SPELL ,BLANK-SCROLL>
+		     <IN? <LOC ,SPELL-COPY> ,WINNER>
+		     <NOT <IN? ,BLANK-SCROLL ,WINNER>>>
+		<SET SPELL ,SPELL-COPY>)>
+	 <COND (<EQUAL? ,CHANGED? ,GROUPER ,SNAKE ,GRUE>
+		<TELL
+"Your mouth cannot form the words of spells while you are changed into a "
+'CHANGED? ,PERIOD>
+		<RTRUE>)
+	       (<EQUAL? ,HERE ,OCEAN-FLOOR>
+		<TELL
+"You can't cast a spell while underwater!" CR>
+		<RTRUE>)>
+	 <SET SCROLL <LOC .SPELL>>
+	 <COND (<OR <EQUAL? .SPELL ,PRSO>
+		    <AND <EQUAL? .SCROLL ,PRSO>
+			 <NOT <EQUAL? .SCROLL ,SPELL-BOOK>>>>
+		<TELL
+"As you must remember from Thaumaturgy 101, you cannot cast a spell upon
+itself, or upon the scroll it is written on." CR>
+		<RTRUE>)
+	       (<AND .SCROLL
+		     <NOT <EQUAL? .SCROLL ,SPELL-BOOK>>
+		     <OR <FSET? .SCROLL ,SCROLLBIT>
+			 <EQUAL? .SCROLL ,DEAD-BOOK>>>
+		<COND (<FSET? .SCROLL ,RMUNGBIT>
+		       <TELL CTHE .SCROLL " is unreadable." CR>
+		       <RTRUE>)
+		      (<IN? .SCROLL ,WINNER>
+		       <REMOVE .SCROLL>
+		       <TELL
+"As you cast the spell, " THE .SCROLL " vanishes!" CR>
+		       <PUTP .SPELL ,P?COUNT 1>)
+		      (T
+		       <TELL
+CTHE .SPELL " is not memorized, and you aren't holding a scroll
+on which it is written." CR>
+		       <RTRUE>)>)>
+	 <COND (<EQUAL? .SPELL ,SPELL-COPY>
+		<SETG PRSA <GETP ,SPELL-COPY ,P?EXITS>>)>
+	 <COND (<AND <VERB? BLORPLE> <NOT <IN? ,PRSO ,WINNER>>>
+		<NOT-HOLDING ,PRSO>
+		<RTRUE>)>
+	 <COND (<OR <NOT <ZERO? <GETP .SPELL ,P?COUNT>>>
+		    <EQUAL? .SPELL ,GNUSTO-SPELL ,REZROV-SPELL ,FROTZ-SPELL>>
+		<SETG SPELL-CAST .SPELL>
+		<COND (<EQUAL? ,HERE ,SCALES-ROOM>
+		       <COND (<AND <VERB? REZROV MALYON>
+				   <EQUAL? ,PRSO ,IRON-DOOR ,VAULT-DOOR>>
+			      <SETG SPELLS-USED 2>)>
+		       <USE-SPELL>)>
+		<COND (<EQUAL? ,HERE ,PLAIN-ROOM>
+		       <PLAIN-SPELL-FAIL>)
+		      (<NOT <SPELL-PROB? .SPELL>>
+		       <TELL
+"The casting feels wrong, and sure enough, " <PICK-ONE ,FIZZLES> CR>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)
+	       (ELSE
+		<TELL
+,YOU-DONT-HAVE THE .SPELL " memorized!" CR>
+		<THIS-IS-IT .SPELL>
+		<RTRUE>)>>
+
+<GLOBAL USED-JINDAK? <>>
+
+<ROUTINE USE-SPELL ()
+	 <COND (<VERB? JINDAK> <SETG USED-JINDAK? T>)>
+	 <SETG SPELLS-USED <+ ,SPELLS-USED 1>>
+	 <COND (<AND <G? ,SPELLS-USED 2>
+		     <ZERO? ,GUARDS-FLAG>
+		     <NOT <QUEUED? I-ALARM>>>
+		<QUEUE I-ALARM -1>
+		<QUEUE I-GUARDS 2>)>
+	 <RFALSE>>
+
+<GLOBAL SPELL-CAST <>>
+
+<GLOBAL FIZZLES
+	<LTABLE 0
+"nothing happens."
+"a huge ball of green light appears, then dissipates."
+"your fingers grow numb."
+"you are momentarily blinded."
+"there is a distant rumble of thunder."
+"your whole body feels as if your funny bone has been struck.">>
+
+<ROUTINE SPELL-PROB? (SPELL? "AUX" (P 50) N1 N2)
+	 <COND (<AND <GOT? ,MAGIC-CUBE>
+		     <NOT <EQUAL? .SPELL? ,GIRGOL-SPELL>>>
+		<RTRUE>)
+	       (<AND <EQUAL? .SPELL? ,FROTZ-SPELL>
+		     <OR <EQUAL? ,HERE ,DARK-CAVE ,GRUE-CAVE ,LIGHT-POOL>
+			 <EQUAL? ,HERE ,PILLAR-ROOM>>>
+		<RFALSE>)
+	       (<AND <EQUAL? .SPELL? ,BLORPLE-SPELL>
+		     <EQUAL? ,HERE ,CASTLE>
+		     <G? ,SHADOW-COUNT 8>>
+		<RFALSE>)>
+	 <COND (<EQUAL? .SPELL? ,GNUSTO-SPELL>
+		<SET P 75>
+		<SET N1 ,CHANGE-CUBE> <SET N2 ,EARTH-CUBE>)
+	       (<EQUAL? .SPELL? ,FROTZ-SPELL>
+		<SET P 75>
+		<SET N1 ,CHANGE-CUBE> <SET N2 ,LIGHT-CUBE>)
+	       (<EQUAL? .SPELL? ,REZROV-SPELL>
+		<SET N1 ,CHANGE-CUBE> <SET N2 ,EARTH-CUBE>)
+	       (<EQUAL? .SPELL? ,YOMIN-SPELL>
+		<SET N1 ,MIND-CUBE> <SET N2 ,LIGHT-CUBE>)
+	       (<EQUAL? .SPELL? ,LESOCH-SPELL>
+		<SET N1 ,AIR-CUBE> <SET N2 ,FIRE-CUBE>)
+	       (<EQUAL? .SPELL? ,BLORPLE-SPELL>
+		<RTRUE>)
+	       (<EQUAL? .SPELL? ,SNAVIG-SPELL>
+		<SET N1 ,CHANGE-CUBE> <SET N2 ,DARK-CUBE>)
+	       (<EQUAL? .SPELL? ,GIRGOL-SPELL>
+		<COND (<IN? ,GIRGOL-SPELL ,GIRGOL-SCROLL>
+		       <COND (<AND <EQUAL? .SPELL? ,GIRGOL-SPELL>
+				   <EQUAL? ,HERE ,COUNCIL-CHAMBER>>
+			      <RFALSE>)
+			     (ELSE <RTRUE>)>)
+		      (<EQUAL? ,HERE ,CASTLE ,PAST-RUINS-ROOM ,PAST-CELL-EAST>
+		       <RTRUE>)
+		      (<EQUAL? ,HERE ,MAGIC-ROOM ,TIME-ROOM>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)
+	       (<EQUAL? .SPELL? ,JINDAK-SPELL>
+		<SET N1 ,LIGHT-CUBE> <SET N2 ,CONNECTIVITY-CUBE>)
+	       (<EQUAL? .SPELL? ,ESPNIS-SPELL>
+		<SET N1 ,MIND-CUBE> <SET N2 ,DEATH-CUBE>)
+	       (<EQUAL? .SPELL? ,MALYON-SPELL>
+		<SET N1 ,FIRE-CUBE> <SET N2 ,LIFE-CUBE>)
+	       (<EQUAL? .SPELL? ,CASKLY-SPELL>
+		<SET N1 ,CHANGE-CUBE> <SET N2 ,CONNECTIVITY-CUBE>)
+	       (<EQUAL? .SPELL? ,LISKON-SPELL>
+		<SET N1 ,CHANGE-CUBE> <SET N2 ,EARTH-CUBE>)
+	       (<EQUAL? .SPELL? ,THROCK-SPELL>
+		<SET N1 ,LIFE-CUBE> <SET N2 ,WATER-CUBE>)
+	       (<EQUAL? .SPELL? ,TINSOT-SPELL>
+		<SET N1 ,WATER-CUBE> <SET N2 ,FIRE-CUBE>)>
+	 <SET P <+ .P <* <COUNT-CUBES> 5>>>
+	 <COND (<GOT? .N1> <SET P <+ .P 20>>)>
+	 <COND (<GOT? .N2> <SET P <+ .P 20>>)>
+	 %<DEBUG-CODE
+	    <COND (,ZDEBUG
+		   <TELL "[Prob=" N .P "]" CR>)>>
+	 <COND (<OR <NOT <L? .P 100>> <PROB .P>>
+		<RTRUE>)
+	       (ELSE
+		<RFALSE>)>>
+
+<ROUTINE V-CAST ("AUX" VRB)
+	 <COND (<NOT <FSET? ,PRSO ,SPELLBIT>>
+		<TELL
+"You can't cast "> <A-PRSO>)
+	       (T
+		<SET VRB <SPELL-TO-VERB>>
+		<COND (<AND <NOT ,PRSI>
+			    <NOT <EQUAL? .VRB
+					 ,V?JINDAK ,V?GIRGOL ,V?LESOCH>>
+			    <NOT <EQUAL? .VRB ,V?$XEROX>>>
+		       <TELL
+"You must cast that on something." CR>)
+		      (T
+		       <PERFORM .VRB ,PRSI>)>
+		<RTRUE>)>>
+
+<ROUTINE V-$XEROX ("AUX" VRB)
+	 <COND (<SET VRB <GETP ,SPELL-COPY ,P?EXITS>>
+		<PERFORM .VRB ,PRSO>)>
+	 <RTRUE>>
+
+<ROUTINE SPELL-TO-VERB ()
+	 <COND (<EQUAL? ,PRSO ,GNUSTO-SPELL> ,V?GNUSTO)
+	       (<EQUAL? ,PRSO ,FROTZ-SPELL> ,V?FROTZ)
+	       (<EQUAL? ,PRSO ,REZROV-SPELL> ,V?REZROV)
+	       (<EQUAL? ,PRSO ,YOMIN-SPELL> ,V?YOMIN)
+	       (<EQUAL? ,PRSO ,LESOCH-SPELL> ,V?LESOCH)
+	       (<EQUAL? ,PRSO ,BLORPLE-SPELL> ,V?BLORPLE)
+	       (<EQUAL? ,PRSO ,SNAVIG-SPELL> ,V?SNAVIG)
+	       (<EQUAL? ,PRSO ,GIRGOL-SPELL> ,V?GIRGOL)
+	       (<EQUAL? ,PRSO ,JINDAK-SPELL> ,V?JINDAK)
+	       (<EQUAL? ,PRSO ,ESPNIS-SPELL> ,V?ESPNIS)
+	       (<EQUAL? ,PRSO ,MALYON-SPELL> ,V?MALYON)
+	       (<EQUAL? ,PRSO ,CASKLY-SPELL> ,V?CASKLY)
+	       (<EQUAL? ,PRSO ,LISKON-SPELL> ,V?LISKON)
+	       (<EQUAL? ,PRSO ,THROCK-SPELL> ,V?THROCK)
+	       (<EQUAL? ,PRSO ,TINSOT-SPELL> ,V?TINSOT)
+	       (<EQUAL? ,PRSO ,SPELL-COPY> ,V?$XEROX ;<GETP ,PRSO ,P?EXITS>)>>
+
+<GLOBAL ALL-SPELLS
+	<PLTABLE
+	  GNUSTO-SPELL
+	  FROTZ-SPELL
+	  REZROV-SPELL
+	  YOMIN-SPELL
+	  LESOCH-SPELL
+	  BLORPLE-SPELL
+	  SNAVIG-SPELL
+	  GIRGOL-SPELL
+	  JINDAK-SPELL
+	  MALYON-SPELL
+	  ESPNIS-SPELL
+	  CASKLY-SPELL
+	  LISKON-SPELL
+	  THROCK-SPELL
+	  TINSOT-SPELL>>
+
+;"These spells no longer exist"
+	  ;IZYUK-SPELL
+	  ;AIMFIZ-SPELL
+	  ;SWANZO-SPELL
+	  ;GOLMAC-SPELL
+	  ;VARDIK-SPELL
+	  ;PULVER-SPELL
+	  ;MEEF-SPELL
+	  ;VEZZA-SPELL
+	  ;GASPAR-SPELL
+	  ;YONK-SPELL
+
+<ROUTINE V-SPELLS ("AUX" (CNT <GET ,ALL-SPELLS 0>) S (ANY <>) (OS <>) TMP)
+	 <TELL
+"The gnusto, rezrov, and frotz spells are yours forever. Other than that,
+you have ">
+	 <REPEAT ()
+		 <COND (<EQUAL? .CNT 0>
+			<COND (.OS
+			       <SPELL-PRINT .OS .ANY T>
+			       <SET ANY T>)>
+			<COND (<NOT .ANY>
+			       <TELL "no spells memorized.">)
+			      (T
+			       <TELL " committed to memory.">)>
+			<CRLF>
+			<RTRUE>)>
+		 <COND (<SET TMP <SPELL-TIMES <GET ,ALL-SPELLS .CNT>>>
+			<COND (.OS
+			       <SPELL-PRINT .OS .ANY>
+			       <SET ANY T>)>
+			<SET OS .TMP>)>
+		 <SET CNT <- .CNT 1>>>>
+
+<ROUTINE SPELL-PRINT (S ANY "OPTIONAL" (PAND? <>) "AUX" X)
+	 <COND (.ANY
+		<COND (.PAND?
+		       <TELL " and ">)
+		      (T
+		       <TELL ", ">)>)>
+	 <TELL THE .S " ">
+	 <SET X <- <GETP .S ,P?COUNT> 1>>
+	 <COND (<G? .X 4>
+		<SET X 4>)> ;"prevents ,COUNTERS table overflow"
+	 <TELL <GET ,COUNTERS .X>>
+	 .S>
+
+<ROUTINE SPELL-TIMES (S)
+	 <COND (<AND <G? <GETP .S ,P?COUNT> 0>
+		     <IN? .S ,SPELL-BOOK>>
+		.S)>>
+
+<GLOBAL COUNTERS	;"should be as many entries as ,SPELL-MAX"
+	<PTABLE "once"
+	       "twice"
+	       "thrice"
+	       "four times"
+	       "many times">>
+
+<ROUTINE V-LEARN ()
+	 <TELL ,YOU-DONT-HAVE "that spell, if indeed that is a spell." CR>>
+
+<ROUTINE SEE-BLORPLE ()
+	 <COND (<NOT ,SEEN-BLORPLE?>
+		<SETG SEEN-BLORPLE? T>
+		<SETG SCORE <+ ,SCORE 15>>)>>
+
+<ROUTINE V-BLORPLE ("AUX" RM)
+	 <SEE-BLORPLE>
+	 <COND (<OR <GETP ,HERE ,P?CUBE> <EQUAL? ,HERE ,DULL-ROOM>>
+		<TELL ,NOTHING-HAPPENS>)
+	       (ELSE
+		<COND (<AND <EQUAL? ,PRSO ,TIME-CUBE>
+			    <NOT ,USED-JINDAK?>>
+		       <SETG BLORPLE-OBJECT <>>
+		       <SET RM <>>)
+		      (ELSE
+		       <SETG BLORPLE-OBJECT ,PRSO>
+		       <SET RM <GETP ,PRSO ,P?CUBE>>)>
+		<COND (<NOT .RM>
+		       <SETG DULL-ROOM-RETURN ,HERE>
+		       <SET RM ,DULL-ROOM>)>
+		<TELL
+"Abruptly, your surroundings shift.">
+		<COND (<FSET? <LOC ,PLAYER> ,VEHBIT>
+		       <TELL
+" The spell leaves " THE <LOC ,PLAYER> " behind.">)>
+		<MOVE ,PLAYER ,HERE>
+		<REMOVE ,PRSO>
+		<CRLF>
+		<CRLF>
+		<GOTO .RM>)>>
+
+<GLOBAL BLORPLE-OBJECT <>>
+
+<ROUTINE RECOVER-CUBE ()
+	 <COND (<AND ,BLORPLE-OBJECT
+		     <NOT <EQUAL? ,HERE ,OHERE>>>
+		<TELL
+"As you leave, " THE ,BLORPLE-OBJECT " reappears in your hand." CR CR>
+		<MOVE ,BLORPLE-OBJECT ,WINNER>
+		<FCLEAR ,BLORPLE-OBJECT ,NDESCBIT>
+		<SETG BLORPLE-OBJECT <>>
+		<RTRUE>)>>
+
+<ROUTINE V-LESOCH ()
+	 <COND (<AND <EQUAL? ,HERE ,BELWIT-SQUARE>
+		     <OR <EQUAL? ,PRSO ,CLOUD>
+			 <AND <NOT ,PRSO>
+			      <NOT <FSET? ,CLOUD ,INVISIBLE>>>>>
+		<FSET ,CLOUD ,INVISIBLE>
+		<DEQUEUE I-CLOUD-GONE>
+		<TELL
+"A small gust of wind begins to roil the cloud. The cloud is unimpressed.
+The wind builds, slowly but inexorably, to hurricane force. The cloud starts
+to unravel at the edges, and then gives up and dissipates">
+		<COND (<IN? ,EARTH-CUBE ,HERE>
+		       <THIS-IS-IT ,EARTH-CUBE>
+		       <FCLEAR ,EARTH-CUBE ,INVISIBLE>
+		       <TELL
+". Left behind on the ground is a small " ,WHITE-CUBE ".">)>
+		<CLEVER-CONTENTS ,HERE " Also revealed" ,EARTH-CUBE>
+		<CRLF>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"Slowly, teasingly, a small puff of wind begins to blow. It quickly builds
+to gale force, then hurricane force, and just as you feel you are about to
+be swept away, it subsides." CR>)>>
+
+<GLOBAL CHANGED? <>>
+
+<ROUTINE V-SNAVIG ()
+	 <COND (<NOT ,PRSO>
+		<TELL
+"You have to transform into something, and it has to be something nearby." CR>)
+	       (<EQUAL? ,CHANGED? ,PRSO>
+		<TELL ,NOTHING-HAPPENS>)
+	       (<AND <EQUAL? ,PRSO ,PSEUDO-OBJECT>
+		     <EQUAL? ,P-PNAM ,W?MOSS ,W?CORAL>>
+		<TELL "You're too large." CR>)
+	       (ELSE
+		<YOU-CANT-X-PRSO "change into">)>>
+
+<GLOBAL TIME-STOPPED? <>>
+
+<ROUTINE TOO-PRECISE (STR)
+	 <COND (<NOT <EQUAL? ,PRSO <> ,GLOBAL-ROOM>>
+		<TELL
+"This spell " .STR " in a large area, so directing it at ">
+		<COND (<HELD? ,PRSO>
+		       <TELL "an object
+you are holding won't work very well">)
+		      (ELSE
+		       <TELL "a specific
+object is unnecessarily precise">)>
+		<TELL ,PERIOD CR>)>>
+
+<ROUTINE V-GIRGOL ()
+	 <COND (,TIME-STOPPED?
+		<TELL ,NOTHING-HAPPENS>)
+	       (<EQUAL? ,HERE ,EMPORIUM>
+		<PERFORM ,V?ESPNIS ,MERCHANT>
+		<RTRUE>)
+	       (ELSE
+		<TOO-PRECISE "stops time">
+		<SETG TIME-STOPPED? ,HERE>
+		<QUEUE I-GIRGOL 12>
+		<COND (<AND <EQUAL? ,HERE ,CLIFF-TOP>
+			    <QUEUED? I-AVALANCHE>
+			    <G? ,ROCK-SLIDE-COUNT 0>>
+		       <STOP-AVALANCHE>)
+		      (<EQUAL? ,HERE ,OGRE-CAVE>
+		       <TELL
+"The ogre, who was gesticulating wildly, freezes in place. He looks like
+a particularly bad statue of himself. Even his lice aren't moving." CR>)
+		      (<EQUAL? ,HERE ,SOUTH-SNAKE-ROOM ,NORTH-SNAKE-ROOM>
+		       <TELL
+"The snake freezes in place, as though a particularly good statue of itself
+had been put in its place. However, it still completely blocks the passage." CR>)
+		      (<EQUAL? ,HERE ,PAST-RUINS-ROOM>
+		       <DEQUEUE I-WATER-RISING>
+		       <TELL "The water stops rising." CR>)
+		      (<AND <EQUAL? ,HERE ,CASTLE>
+			    <IN? ,SHADOW ,CASTLE>>
+		       <COND (<L? ,SHADOW-COUNT 8>
+			      <SETG TIME-STOPPED? <>>
+			      <DEQUEUE I-GIRGOL>
+			      <TELL
+"The shadow turns and silences you with a word of power, cancelling
+the spell." CR>)
+			     (<EQUAL? ,SHADOW-COUNT 8>
+			      <QUEUE I-GIRGOL 3>
+			      <TELL
+"All around you freezes in place! The shadow is caught in
+a particularly evil posture. You can tell the spell won't hold for
+long!" CR>)
+			     (<EQUAL? ,SHADOW-COUNT 9>
+			      <QUEUE I-GIRGOL 3>
+			      <TELL
+"The shadow freezes in mid-leap! You can tell the spell won't hold for
+long in this magically charged atmosphere!" CR>)>)
+		      (ELSE
+		       <TELL
+,AT-FIRST "subtle changes in your
+surroundings. Nothing is moving. You can see dust motes hanging
+in midair, and a tiny gnat, its wings motionless, unknowingly defying
+gravity." CR>)>)>>
+
+<GLOBAL AT-FIRST "At first, nothing happens. Then you notice ">
+
+<ROUTINE V-JINDAK ("AUX" F (1ST? T) P1 P2)
+	 <TOO-PRECISE "detects magic">
+	 <COND (<EQUAL? ,HERE ,SCALES-ROOM>
+		<SET P1 <MEASURE ,PILE-1>>
+		<SET P2 <MEASURE ,PILE-2>>
+		<COND (<AND <G? .P1 0> <G? .P2 0>>
+		       <TELL
+"Both piles of cubes glow with a faint blue glow. ">
+		       <COND (<EQUAL? .P1 .P2>
+			      <TELL "Both piles seem to glow
+with identical brightness.">)
+			     (ELSE
+			      <TELL
+"However, the ">
+			      <COND (<G? .P1 .P2> <TELL 'PILE-1>)
+				    (ELSE <TELL 'PILE-2>)>
+			      <TELL " is glowing more brightly.">)>)
+		      (<G? .P1 0>
+		       <TELL CTHE ,PILE-1 ,IS-GLOWING>)
+		      (<G? .P2 0>
+		       <TELL CTHE ,PILE-2 ,IS-GLOWING>)
+		      (<AND <FIRST? ,PILE-1> <FIRST? ,PILE-2>>
+		       <TELL "Neither pile is glowing at all.">)>
+		<CRLF>
+		<COND (<NOT <DETECT-MAGIC ,HERE>>
+		       <TELL "Nothing else is glowing." CR>)>)
+	       (<NOT <DETECT-MAGIC ,HERE>>
+		<TELL
+"Nothing in the vicinity glows. Apparently there is no magic
+nearby." CR>)>>
+
+<ROUTINE DETECT-MAGIC (OBJ "OPTIONAL" (1ST? T) "AUX" F)
+	 <SET F <FIRST? .OBJ>>
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN <NOT .1ST?>>)
+		       (<NOT <EQUAL? .F ,PLAYER ,PILE-1 ,PILE-2>>
+			<COND (<AND <VISIBLE? .F>
+				    <MAGIC? .F>>
+			       <SET 1ST? <>>
+			       <TELL
+				CTHE .F ,IS-GLOWING CR>)
+			      (<AND <SEE-INSIDE? .F>
+				    <FIRST? .F>>
+			       <COND (<DETECT-MAGIC .F .1ST?>
+				      <SET 1ST? <>>)>)>)>
+		 <SET F <NEXT? .F>>>>
+
+<ROUTINE MAGIC? (OBJ)
+	 <COND (<FSET? .OBJ ,MAGICBIT> <RTRUE>)
+	       (<FSET? .OBJ ,SCROLLBIT> <RTRUE>)
+	       (<GETPT .OBJ ,P?NAME> <RTRUE>)>>
+
+<GLOBAL ESPNIS? <>>
+
+<ROUTINE V-ESPNIS ()
+	 <COND (<EQUAL? ,PRSO ,ME ,WINNER>
+		<V-SLEEP T>)
+	       (<TIME-FROZEN?>
+		<TELL ,NOTHING-HAPPENS>)
+	       (<FSET? ,PRSO ,PERSON>
+		<QUEUE I-ESPNIS 20>
+		<COND (<EQUAL? ,ESPNIS? ,PRSO>
+		       <TELL
+CTHE ,PRSO " continues to sleep." CR>)
+		      (ELSE
+		       <COND (,ESPNIS? <I-ESPNIS>)>
+		       <SETG ESPNIS? ,PRSO>
+		       <TELL
+CTHE ,PRSO " falls asleep, yawning lazily." CR>)>)
+	       (ELSE
+		<TELL
+"I suppose you expect to hear " THE ,PRSO " snoring?" CR>)>>
+
+<ROUTINE V-CASKLY ()
+	 <TELL CTHE ,PRSO>
+	 <COND (<AND <FSET? ,PRSO ,RMUNGBIT>
+		     <FSET? ,PRSO ,TAKEBIT>>
+		<FCLEAR ,PRSO ,RMUNGBIT>
+		<TELL
+" is returned to its original perfection." CR>)
+	       (ELSE
+		<TELL
+" looks pretty perfect as is." CR>)>>
+
+<ROUTINE V-THROCK ()
+	 <TELL 
+"I guess you have a black thumb. " ,NOTHING-HAPPENS>>
+
+<ROUTINE V-TINSOT ()
+	 <SETG ICED-OBJECT ,PRSO>
+	 <COND (<AND <EQUAL? ,HERE ,OUBLIETTE>
+		     <OR <EQUAL? ,PRSO ,INFLOW ,OUTFLOW ,OUBLIETTE-CHANNEL>
+			 <EQUAL? ,PRSO ,WATER>>>
+		<COND (<AND <G? ,WATER-FLAG 0>
+			    <NOT <EQUAL? ,PRSO ,WATER>>>
+		       <TELL ,YOU-CANT-SEE "that anymore" ,PERIOD>)
+		      (<EQUAL? ,PRSO ,INFLOW>
+		       <PARTIAL-BLOCKAGE ,INFLOW>)
+		      (<EQUAL? ,WATER-FLAG 0>
+		       <QUEUE I-TINSOT 30>
+		       <SETG ICED-OBJECT ,OUTFLOW>
+		       <SETG FREEZE-FLAG <+ ,FREEZE-FLAG 1>>
+		       <COND (<EQUAL? ,FREEZE-FLAG 1>
+			      <PARTIAL-BLOCKAGE ,OUTFLOW>)
+			     (<EQUAL? ,FREEZE-FLAG 2>
+			      <QUEUE I-OUBLIETTE-FILLS -1>
+			      <TELL
+"In a dazzling purple flash, more water freezes, forming a large icy cap over
+the outflow pipe in the channel. Water continues to pour in the inflow, and
+it spills over the edge of the channel and begins to fill the room." CR>)>)
+		      (<NOT <IN? ,ICEBERG ,HERE>>
+		       <MOVE ,ICEBERG ,HERE>
+		       <SETG ICED-OBJECT ,ICEBERG>
+		       <TELL
+"The purple flash freezes a small ice floe in the frigid water. It has a nice
+flat top." CR>)
+		      (ELSE
+		       <TELL ,NOTHING-HAPPENS>)>)
+	       ;(<AND <EQUAL? ,HERE ,RUINS-ROOM>
+		     <EQUAL? ,PRSO ,WATER ,RUINS-OUTFLOW ,RUINS-CHANNEL>>
+		)
+	       (<EQUAL? ,PRSO ,AIR>
+		<V-SQUEEZE>)
+	       (<AND <EQUAL? ,PRSO ,BOTTLE ,WATER ,LOCAL-WATER>
+		     <IN? ,LOCAL-WATER ,BOTTLE>>
+		<REMOVE ,LOCAL-WATER>
+		<REMOVE ,BOTTLE>
+		<TELL
+"The water and bottle freeze and shatter into a million pieces!" CR>)
+	       (ELSE
+		<TELL
+CTHE ,PRSO " is covered with a thin film of ice.">
+		<COND (<FSET? ,PRSO ,PERSON>
+		       <TELL
+" " CTHE ,PRSO " shakes and shivers, and the ice cracks and peels away.">)>
+		<CRLF>)>>
+
+<ROUTINE PARTIAL-BLOCKAGE (OBJ)
+	 <TELL
+"There is a purple flash, and in a burst of snow and freezing spray, the
+water in the channel freezes. But the water flow is so hard that " THE .OBJ
+" is only partially blocked." CR>>
+
+<ROUTINE PRE-LISKON ()
+	 <COND (<OR <EQUAL? ,SHRINK-FLAG ,PRSO>
+		    <AND <EQUAL? ,SHRINK-FLAG ,PLAYER>
+			 <EQUAL? ,PRSO ,ME>>>
+		<TELL ,NOTHING-HAPPENS>
+		<RTRUE>)
+	       (,SHRINK-FLAG
+		<COND (<I-LISKON T>
+		       <CRLF>)>
+		<RFALSE>)>>
+
+<ROUTINE V-LISKON ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<COND (<PRE-LISKON> <RTRUE>)
+		      (ELSE
+		       <QUEUE I-LISKON 15>
+		       <COND (<AND ,PRSO <NOT <EQUAL? ,PRSO ,ME>>>
+			      <SETG SHRINK-FLAG ,PRSO>
+			      <TELL
+CTHE ,PRSO " shrinks to about a tenth of its former size.">
+			      <COND (<EQUAL? ,PRSO ,OGRE>
+				     <TELL " He still looks mean.">)>
+			      <CRLF>)
+			     (ELSE
+			      <SETG SHRINK-FLAG ,PLAYER>
+			      <SETG SMALL-FLAG T>
+			      <TELL
+"You feel very funny, sort of squashed and pushed and squeezed. Your
+surroundings are wavering, then growing, then wavering again. The feeling
+vanishes, but your surroundings are ten times their former size... or is
+it that you are one-tenth your former size?" CR>)>)>)
+	       (ELSE
+		<TELL
+"Nothing happens, which is unsurprising, as this spell works only on
+living things." CR>)>>
+
+<GLOBAL SHRINK-FLAG <>> ;"object shrunk"
+<GLOBAL SMALL-FLAG <>> ;"T if player shrunk"
+
+<ROUTINE V-GNUSTO ("AUX" SCROLL)
+	 <COND (<NOT <IN? ,SPELL-BOOK ,WINNER>>
+		<TELL
+"The spell quests around in your hands, looking for your " 'SPELL-BOOK ", and
+not finding it, fades reluctantly." CR>)
+	       (<NOT <FSET? ,PRSO ,SPELLBIT>>
+		<TELL
+,YOU-CANT "inscribe " A ,PRSO " in your " 'SPELL-BOOK "!" CR>)
+	       (<IN? ,PRSO ,SPELL-BOOK>
+		<TELL
+,YOU-HAVE "that spell inscribed in your " 'SPELL-BOOK "!" CR>)
+	       (<AND <LOC ,PRSO>
+		     <NOT <IN? <LOC ,PRSO> ,WINNER>>>
+		<MUST-HOLD-SCROLL>)
+	       (<FSET? ,PRSO ,RMUNGBIT>
+		<TELL "The spell is unreadable." CR>)
+	       (T
+		<SET SCROLL <LOC ,PRSO>>
+		<COND (<FSET? .SCROLL ,RMUNGBIT>
+		       <SCROLL-WET>)
+		      (<AND <FSET? .SCROLL ,SCROLLBIT>
+			    <HELD? .SCROLL>> 
+		       <TELL "Your " 'SPELL-BOOK " begins to glow softly. ">
+		       <COND (<EQUAL? ,PRSO ,GIRGOL-SPELL>
+			      <TELL "In a spectacular effort of magic,
+the powers of the gnusto spell attempt to copy the " 'PRSO " into your
+book, but the spell is too long, too complicated, and too powerful. The
+glow fades, but fortunately " THE .SCROLL " remains intact." CR>
+			      <RTRUE>)
+			     (T
+			      <REMOVE .SCROLL>
+			      <MOVE ,PRSO ,SPELL-BOOK>
+			      <PUTP ,PRSO ,P?COUNT 0>
+			      <TELL "Slowly, ornately, the words of the "
+'PRSO " are inscribed, glowing even more brightly than
+the book itself. The book's brightness fades, but the spell remains!">
+			      <COND (<EQUAL? .SCROLL ,DEAD-BOOK>
+				     <TELL
+" The old book in which it was written crumbles to dust">)
+				    (ELSE
+				     <TELL
+" However, the scroll on which it was written vanishes">)>
+			      <TELL " as the last word is copied." CR>)>
+		       T)
+		      (T
+		       <TELL
+"You must have the object from which you are copying in your hands before
+the gnusto spell will work on it." CR>)>)>>
+
+<ROUTINE V-FROTZ ("AUX" OLIT) ;"light"
+	 <SET OLIT ,LIT>
+	 <COND (<FSET? ,PRSO ,ONBIT>
+		<TELL
+"Have you forgotten that you already frotzed " THE ,PRSO "?" CR>)
+	       (<OR <FSET? ,PRSO ,TAKEBIT>
+		    <FSET? ,PRSO ,PERSON>>
+		<FSET ,PRSO ,ONBIT>
+		<FSET ,PRSO ,TOUCHBIT>
+		<TELL "There is an almost blinding flash of light as ">
+		<COND (<EQUAL? ,PRSO ,ME>
+		       <FSET ,WINNER ,ONBIT>
+		       <TELL "you begin">)
+		      (ELSE
+		       <TELL THE ,PRSO " begins">)>
+		<TELL
+" to glow! It slowly fades to a less painful level, but ">
+		<COND (<EQUAL? ,PRSO ,ME>
+		       <TELL "you are">)
+		      (ELSE <TELL THE ,PRSO " is">)>
+		<TELL
+" now a serviceable light source.">
+		<CRLF>
+		<SETG LIT <LIT? ,HERE>>
+		<COND (<AND <NOT .OLIT> ,LIT>
+		       <CRLF>
+		       <V-LOOK>)>
+		<RTRUE>)
+	       (T
+		<V-NO-OP>)>>
+
+<ROUTINE V-MALYON ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+"Wow! " ,IT-LOOKS-LIKE THE ,PRSO " is now alive! What a magician you are!" CR>)
+	       (<FSET? ,PRSO ,TAKEBIT>
+		<TELL
+"As you complete the spell, " THE ,PRSO " comes alive! It blinks, dances a
+little jig, and a moment later returns to normal." CR>)
+	       (T
+		<V-NO-OP>)>>
+
+<ROUTINE V-REZROV () ;"open"
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+"It might be a boon to surgeons if it worked, but it doesn't." CR>)
+	       (<AND <FSET? ,PRSO ,VEHBIT>
+		     <NOT <EQUAL? ,PRSO ,ZIPPER>>>
+		<TELL
+"It doesn't need opening." CR>)
+	       (<OR <FSET? ,PRSO ,CONTBIT>
+		    <FSET? ,PRSO ,DOORBIT>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <ALREADY-OPEN>)
+		      (<NOT <FSET? ,PRSO ,SCROLLBIT>>
+		       <TELL "Silently, ">
+		       <TELL THE ,PRSO " swings open">
+		       <COND (<FIRST? ,PRSO>
+			      <TELL ", revealing ">
+			      <PRINT-CONTENTS ,PRSO>)>
+		       <COND (<NOT <EQUAL? ,PRSO ,IRON-DOOR>>
+			      <TELL
+". Like swatting a fly with a sledge hammer, if you ask me">)>
+		       <TELL ,PERIOD>
+		       <FSET ,PRSO ,OPENBIT>)
+		      (T
+		       <V-NO-OP>)>)
+	       (T
+		<V-NO-OP>)>>
+
+<ROUTINE V-NO-OP () ;"exorcise"
+	 <TELL
+"Although you complete the spell, nothing has happened." CR>>
+
+<ROUTINE V-YOMIN ()
+	 <TELL "I'm afraid ">
+	 <TELL THE ,PRSO " doesn't have much of a mind for you to read." CR>>
+
+<OBJECT SPELL-COPY 
+	(SYNONYM SPELLS SPELL)
+	(ADJECTIVE DUPLICATE ;"PLACE HOLDER" ORIGINAL)
+	(DESC "original")
+	(TEXT 0)
+	(COUNT 0)
+	(ACTION SPELL-F)
+	(SIZE 1)
+	(EXITS 0) ;"will hold verb of spell this is a copy of"
+	(WALLS 0) ;"will hold spell this is a copy of"
+	(FLAGS NDESCBIT SPELLBIT AN)>
+
+<OBJECT BLANK-SCROLL 
+	(IN PAST-CABINET)
+	(SYNONYM SCROLL)
+	(ADJECTIVE NEW VELLUM BLANK)
+	(DESC "vellum scroll")
+	(ACTION BLANK-SCROLL-F)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT
+	       SCROLLBIT CONTBIT TRANSBIT)>
+
+<ROUTINE BLANK-SCROLL-F ("AUX" OT DT)
+	 <COND (<VERB? COPY>
+		<COND (<NOT <IN? ,BURIN ,WINNER>>
+		       <NO-BURIN>)
+		      (<NOT <EQUAL? ,PRSI ,BLANK-SCROLL>>
+		       <RFALSE>)
+		      (<FSET? ,PRSI ,RMUNGBIT>
+		       <TELL CTHE ,PRSI " is too wet." CR>)
+		      (<FIRST? ,PRSI>
+		       <ALREADY-USED>)
+		      (<NOT <FSET? ,PRSO ,SPELLBIT>>
+		       <RFALSE>)
+		      (<EQUAL? <LOC ,PRSO> ,SPELL-BOOK ,DEAD-BOOK>
+		       <TELL
+"Spell books are copy-protected to prevent spell thieves from making
+spell scrolls from another mage's spell book." CR>)
+		      (<AND <EQUAL? ,PRSO ,GIRGOL-SPELL>
+			    <NOT <HELD? ,MAGIC-CUBE>>>
+		       <TELL
+"You try hard to copy the obscure runes and ideographs of the spell, but
+your mind just can't comprehend them, and your fingers just can't
+follow the curves and strokes." CR>)
+		      (ELSE
+		       <SET DT <GETPT ,PRSO ,P?ADJECTIVE>>
+		       <SET OT <GETPT ,SPELL-COPY ,P?ADJECTIVE>>
+		       <PUTB .DT 0 <GETB .OT 0>>
+		       <PUTB .OT 0 <GETB .DT 1>>
+		       <PUTP ,SPELL-COPY
+			     ,P?TEXT
+			     <GETP ,PRSO ,P?TEXT>>
+		       <MOVE ,SPELL-COPY <LOC ,PRSO>>
+		       <FSET ,PRSO ,RWATERBIT>
+		       <MOVE ,PRSO ,PRSI>
+		       <PUTP ,SPELL-COPY ,P?WALLS ,PRSO>
+		       <PUTP ,SPELL-COPY ,P?EXITS <SPELL-TO-VERB>>
+		       <TELL
+			"Copied." CR>)>)
+	       (<NOT <FIRST? ,PRSO>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+,IT-LOOKS-LIKE "a blank piece of vellum scroll paper." CR>)
+		      (<VERB? READ>
+		       <TELL "This scroll is blank." CR>)
+		      (<AND <VERB? WRITE>
+			    <EQUAL? ,PRSO ,QWORD>>
+		       <TELL
+"You should write spells, not random words, on spell paper." CR>)
+		      (<AND <VERB? WRITE>
+			    <NOT <FSET? ,PRSO ,SPELLBIT>>>
+		       <TELL
+"That's not a spell! You'll waste good spell paper!" CR>)>)
+	       (ELSE <SCROLL-F>)>>
diff --git a/misc.zil b/misc.zil
new file mode 100644
index 0000000..7d91e88
--- /dev/null
+++ b/misc.zil
@@ -0,0 +1,957 @@
+"MISC for
+			      MAGE
+	     (c) 1985 by Infocom, Inc. All Rights Reserved."
+
+;"former MACROS.ZIL stuff"
+
+<SETG C-NORTH 1>
+<SETG C-EAST 2>
+<SETG C-WEST 4>
+<SETG C-SOUTH 8>
+<SETG C-NE 16>
+<SETG C-NW 32>
+<SETG C-SE 64>
+<SETG C-SW 128>
+
+<CONSTANT C-NORTH 1>
+<CONSTANT C-EAST 2>
+<CONSTANT C-WEST 4>
+<CONSTANT C-SOUTH 8>
+<CONSTANT C-NE 16>
+<CONSTANT C-NW 32>
+<CONSTANT C-SE 64>
+<CONSTANT C-SW 128>
+
+;"SUSPECT tell macro and friends"
+
+<COND (<GASSIGNED? ZILCH> ;"version for when compiling"
+       <DEFMAC TELL ("ARGS" A)
+	       <FORM PROG ()
+		     !<MAPF ,LIST
+			    <FUNCTION ("AUX" E P O)
+				 <COND (<EMPTY? .A> <MAPSTOP>)
+				       (<SET E <NTH .A 1>>
+					<SET A <REST .A>>)>
+				 <COND (<TYPE? .E ATOM>
+					<COND (<OR <=? <SET P <SPNAME .E>>
+						       "CRLF">
+						   <=? .P "CR">>
+					       <MAPRET '<CRLF>>)
+					      ;(<=? .P "V">
+						<MAPRET '<VPRINT>>)
+					      (<EMPTY? .A>
+					       <ERROR INDICATOR-AT-END? .E>)
+					      (ELSE
+					       <SET O <NTH .A 1>>
+					       <SET A <REST .A>>
+					       <COND (<OR <=? <SET P <SPNAME .E>>
+							      "DESC">
+							  <=? .P "D">
+							  <=? .P "OBJ">
+							  <=? .P "O">>
+						      <MAPRET
+						       <PFORM DPRINT .O>>)
+						     (<=? .P "CD">
+						      <MAPRET
+						       <PFORM CDPRINT .O>>)
+						     (<=? .P "THE">
+						      <MAPRET
+						       <PFORM THE-PRINT .O>>)
+						     (<=? .P "CTHE">
+						      <MAPRET
+						       <PFORM CTHE-PRINT .O>>)
+						     (<OR <=? .P "A">
+							  <=? .P "AN">>
+						      <MAPRET
+						       <PFORM PRINTA .O>>)
+						     (<OR <=? .P "NUM">
+							  <=? .P "N">>
+						      <MAPRET
+						       <FORM PRINTN .O>>)
+						     (<OR <=? .P "CHAR">
+							  <=? .P "CHR">
+							  <=? .P "C">>
+						      <MAPRET
+						       <FORM PRINTC
+							     <CHTYPE .O FIX>>>)
+						     (ELSE
+						      <MAPRET
+						       <FORM PRINT
+							     <FORM GETP .O .E>>>)>)>)
+				       (<TYPE? .E STRING ZSTRING>
+					<MAPRET
+					 <COND (<==? <LENGTH .E> 1>
+						<FORM PRINTC
+						      <CHTYPE <1 .E> FIX>>)
+					       (ELSE
+						<FORM PRINTI .E>)>>)
+				       (<AND <TYPE? .E FORM>
+					     <==? <NTH .E 1> QUOTE>>
+					<MAPRET
+					 <FORM PRINTD
+					       <MAKE-GVAL <NTH .E 2>>>>)
+				       (<TYPE? .E FORM LVAL GVAL>
+					<MAPRET <FORM PRINT .E>>)
+				       (ELSE <ERROR UNKNOWN-TYPE .E>)>>>>>)
+      (ELSE ;"version for when interpreting"
+       <DEFINE TELL ("TUPLE" A)
+	       <MAPR <>
+		     <FUNCTION ("AUX" E P O)
+			  <COND (<EMPTY? .A> <MAPLEAVE>)
+				(<SET E <NTH .A 1>>
+				 <SET A <REST .A>>)>
+			  <COND (<TYPE? .E ATOM>
+				 <COND (<OR <=? <SET P <SPNAME .E>>
+						"CRLF">
+					    <=? .P "CR">>
+					<CRLF>)
+				       ;(<=? .P "V"> <VPRINT>)
+				       (<AND <GASSIGNED? .E>
+					     <TYPE? ,.E OBJECT>>
+					<PRINTD ,.E>)
+				       (<EMPTY? .A>
+					<ERROR INDICATOR-AT-END? .E>)
+				       (ELSE
+					<SET O <NTH .A 1>>
+					<SET A <REST .A>>
+					<COND (<OR <=? <SET P <SPNAME .E>>
+						       "DESC">
+						   <=? .P "D">
+						   <=? .P "OBJ">
+						   <=? .P "O">>
+					       <DPRINT .O>)
+					      (<=? .P "CD">
+					       <DPRINT .O T>)
+					      ;(<=? .P "HE/SHE">
+						<HE/SHE-PRINT .O>)
+					      ;(<=? .P "HIM/HER">
+						<HIM/HER-PRINT .O>)
+					      ;(<=? .P "HIS/HER">
+						<HIM/HER-PRINT .O T>)
+					      (<=? .P "THE">
+					       <THE-PRINT .O>)
+					      (<=? .P "CTHE">
+					       <CTHE-PRINT .O>)
+					      (<OR <=? .P "A">
+						   <=? .P "AN">>
+					       <PRINTA .O>)
+					      (<OR <=? .P "NUM">
+						   <=? .P "N">>
+					       <PRINTN .O>)
+					      (<OR <=? .P "CHAR">
+						   <=? .P "CHR">
+						   <=? .P "C">>
+					       <PRINTC .O>)
+					      (ELSE
+					       <PRINT <GETP .O .E>>)>)>)
+				(<TYPE? .E STRING ZSTRING>
+				 <PRINTI .E>)
+				(<AND <TYPE? .E FORM>
+				      <==? <NTH .E 1> QUOTE>>
+				 <PRINTD <GVAL <NTH .E 2>>>)
+				(<TYPE? .E FORM LVAL GVAL>
+				 <PRINT .E>)
+				(ELSE <ERROR UNKNOWN-TYPE .E>)>>>>
+)>
+
+<DEFINE PFORM (APP OBJ "AUX" A)
+	<COND (<AND <TYPE? .OBJ LVAL GVAL>
+		    <MEMQ <SET A <CHTYPE .OBJ ATOM>> '[PRSO PRSI]>>
+	       <COND (<==? .APP DPRINT>
+		      <COND (<==? .A PRSO> <FORM DPRINT-PRSO>)
+			    (ELSE <FORM DPRINT-PRSI>)>)
+		     (<==? .APP CDPRINT>
+		      <COND (<==? .A PRSO> <FORM CDPRINT-PRSO>)
+			    (ELSE <FORM CDPRINT-PRSI>)>)
+		     (<==? .APP THE-PRINT>
+		      <COND (<==? .A PRSO> <FORM THE-PRINT-PRSO>)
+			    (ELSE <FORM THE-PRINT-PRSI>)>)
+		     (<==? .APP CTHE-PRINT>
+		      <COND (<==? .A PRSO> <FORM CTHE-PRINT-PRSO>)
+			    (ELSE <FORM CTHE-PRINT-PRSI>)>)
+		     (<==? .APP PRINTA>
+		      <COND (<==? .A PRSO> <FORM PRINTA-PRSO>)
+			    (ELSE <FORM PRINTA-PRSI>)>)
+		     (ELSE <ERROR .APP .OBJ>)>)
+	      (<ASSIGNED? EXT>
+	       <FORM .APP .OBJ .EXT>)
+	      (ELSE
+	       <FORM .APP .OBJ>)>>
+
+<DEFINE MAKE-GVAL (E)
+	<COND (<OR <GASSIGNED? MUDDLE>
+		   <NOT <TYPE? .E ATOM>>>
+	       <FORM GVAL .E>)
+	      (ELSE
+	       <CHTYPE .E GVAL>)>>
+
+<ROUTINE CTHE-PRINT-PRSO ()
+	 <THE-PRINT ,PRSO T>>
+
+<ROUTINE CTHE-PRINT-PRSI ()
+	 <THE-PRINT ,PRSI T>>
+
+<ROUTINE CTHE-PRINT (O)
+	 <THE-PRINT .O T>>
+
+<ROUTINE THE-PRINT-PRSO ()
+	 <THE-PRINT ,PRSO>>
+
+<ROUTINE THE-PRINT-PRSI ()
+	 <THE-PRINT ,PRSI>>
+
+<ROUTINE THE-PRINT (O "OPTIONAL" (CAP? <>))
+	 <DPRINT .O .CAP? <NOT <FSET? .O ,NOTHEBIT>>>>
+
+<ROUTINE PRINTA-PRSO ()
+	 <PRINTA ,PRSO>>
+
+<ROUTINE PRINTA-PRSI ()
+	 <PRINTA ,PRSI>>
+
+<ROUTINE PRINTA (O)
+	 <COND (<FSET? .O ,THE> <PRINTI "the ">)
+	       (<NOT <FSET? .O ,NOABIT>>
+		<COND (<FSET? .O ,AN> <PRINTI "an ">)
+		      (ELSE <PRINTI "a ">)>)>
+	 <IPRINT .O>>
+
+;<ROUTINE CDPRINT-PRSO ()
+	 <DPRINT ,PRSO T>>
+
+;<ROUTINE CDPRINT-PRSI ()
+	 <DPRINT ,PRSI T>>
+
+;<ROUTINE CDPRINT (O)
+	 <DPRINT .O T>>
+
+<ROUTINE DPRINT (O "OPTIONAL" (CAP? <>) (THE? <>) "AUX" S)
+	 <COND (<OR .THE? <FSET? .O ,THE>>
+		<COND (.CAP? <PRINTI "The ">)
+		      (T <PRINTI "the ">)>)>
+	 <IPRINT .O>>
+
+<ROUTINE IPRINT (O)
+	 <COND (<AND <EQUAL? .O ,PSEUDO-OBJECT>
+		     <NOT ,P-MERGED>
+		     <EQUAL? .O ,PRSO ,PRSI>>
+		<THING-PRINT ,PSEUDO-PRSO ;"<EQUAL? .O ,PRSO>">)
+	       (<AND <EQUAL? .O ,WEED>
+		     <FSET? .O ,RWATERBIT>>
+		<TELL "weed cutting">)
+	       (<EQUAL? .O ,SPELL-COPY>
+		<PRINTD .O>
+		<PRINTI " ">
+		<PRINTD <GETP .O ,P?WALLS>>)
+	       (ELSE
+		<COND (<NOT <ZERO? <GETP .O ,P?NAME>>>
+		       <CUBE-NAME .O>
+		       <PRINTI " ">)
+		      (<AND <FSET? .O ,RWATERBIT>
+			    <GETPT .O ,P?COUNT>>
+		       <PRINTI "duplicate ">)>
+		<PRINTD .O>)>>
+
+<COND (<GASSIGNED? ZILCH>
+<DEFMAC VERB? ("ARGS" ATMS)
+	<MULTIFROB PRSA .ATMS>>
+
+<DEFMAC PRSO? ("ARGS" ATMS)
+	<MULTIFROB PRSO .ATMS>>
+
+<DEFMAC PRSI? ("ARGS" ATMS)
+	<MULTIFROB PRSI .ATMS>>
+
+<DEFMAC ROOM? ("ARGS" ATMS)
+	<MULTIFROB HERE .ATMS>>
+
+<DEFINE MULTIFROB (X ATMS "AUX" (OO (OR)) (O .OO) (L ()) ATM) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- <COND (<LENGTH? .OO 1> <ERROR .X>)
+				       (<LENGTH? .OO 2> <NTH .OO 2>)
+				       (ELSE <CHTYPE .OO FORM>)>>)>
+		<REST
+		 <PUTREST
+		  .O
+		  <SET O (<REPEAT ((LL <FORM EQUAL? <MAKE-GVAL .X>>)
+				   (L <REST .LL>))
+				  <COND (<OR <EMPTY? .ATMS>
+					     <==? <LENGTH <REST .LL 2>> 3>>
+					 <RETURN!- .LL>)>
+				  <SET ATM <NTH .ATMS 1>>
+				  <PUTREST .L
+					   <SET L
+						(<COND
+						  (<TYPE? .ATM ATOM>
+						   <MAKE-GVAL
+						    <COND (<==? .X PRSA>
+							   <PARSE
+							    <STRING
+							     "V?"
+							     <SPNAME .ATM>>>)
+							  (ELSE .ATM)>>)
+						  (ELSE .ATM)>)>>
+				  <SET ATMS <REST .ATMS>>>)>>>>>)
+(ELSE
+ <DEFINE VERB? ("TUPLE" ATMS)
+	 <MAPF <>
+	       <FUNCTION (A "AUX" ATM)
+		    <COND (<NOT <TYPE? .A ATOM>> <ERROR MULTIFROB>)
+			  (<NOT <SET ATM
+				     <LOOKUP <STRING "V?" <SPNAME .A>>
+					     <MOBLIST INITIAL>>>>
+			   <ERROR NOT-A-VERB? .A>)
+			  (<EQUAL? ,PRSA ,.ATM>
+			   <MAPLEAVE T>)>>
+	       .ATMS>>
+ <DEFINE PRSO? ("TUPLE" ATMS)
+	 <MULTIFROB ,PRSO .ATMS>>
+ <DEFINE PRSI? ("TUPLE" ATMS)
+	 <MULTIFROB ,PRSI .ATMS>>
+ <DEFINE ROOM? ("TUPLE" ATMS)
+	 <MULTIFROB HERE .ATMS>>
+ <DEFINE MULTIFROB (X ATMS) 
+	 <MAPF <>
+	       <FUNCTION (A)
+		    <COND (<TYPE? .A ATOM> <SET A ,.A>)>
+		    <COND (<EQUAL? .X .A>
+			   <MAPLEAVE T>)>>
+	       .ATMS>>)>
+
+<COND (<GASSIGNED? ZILCH>
+<DEFMAC BSET ('OBJ "ARGS" BITS)
+	<MULTIBITS FSET .OBJ .BITS>>
+
+<DEFMAC BCLEAR ('OBJ "ARGS" BITS)
+	<MULTIBITS FCLEAR .OBJ .BITS>>
+
+<DEFMAC BSET? ('OBJ "ARGS" BITS)
+	<MULTIBITS FSET? .OBJ .BITS>>
+
+<DEFINE MULTIBITS (X OBJ ATMS
+		   "AUX" (OT <COND (<==? .X FSET?> <FORM OR>)
+				   (ELSE <FORM PROG ()>)>)
+		         (OO <COND (<LENGTH? .OT 1> .OT)
+				   (ELSE <REST .OT>)>)
+			 (O .OO)
+			 ATM) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- .OT>)>
+		<SET ATM <NTH .ATMS 1>>
+		<SET ATMS <REST .ATMS>>
+		<PUTREST .O
+			 <SET O
+			      (<FORM .X
+				     .OBJ
+				     <COND (<TYPE? .ATM FORM> .ATM)
+					   (ELSE <MAKE-GVAL .ATM>)>>)>>>>)
+(ELSE
+<DEFINE BSET (OBJ "TUPLE" BITS)
+	<MULTIBITS ,FSET .OBJ .BITS>>
+
+<DEFINE BCLEAR (OBJ "TUPLE" BITS)
+	<MULTIBITS ,FCLEAR .OBJ .BITS>>
+
+<DEFINE BSET? (OBJ "TUPLE" BITS)
+	<MAPF <>
+	      <FUNCTION (A)
+		   <COND (<FSET? .OBJ ,.A> <MAPLEAVE T>)>>
+	      .BITS>>
+
+<DEFINE MULTIBITS (X OBJ ATMS) 
+	<MAPF <>
+	      <FUNCTION (A)
+		   <APPLY!- .X .OBJ ,.A>>
+	      .ATMS>>)>
+
+<DEFMAC RFATAL ()
+	'<PROG () <PUSH 2> <RSTACK>>>
+
+<COND (<GASSIGNED? ZILCH>
+       <DEFMAC PROB ('BASE?)
+	       <FORM NOT <FORM L? .BASE? '<RANDOM 100>>>>)
+      (ELSE
+       <DEFINE PROB (BASE?)
+	       <NOT <L? .BASE? <RANDOM 100>>>>)>
+
+<ROUTINE PICK-ONE (FROB
+		   "AUX" (L <GET .FROB 0>) (CNT <GET .FROB 1>) RND MSG RFROB)
+	 <SET L <- .L 1>>
+	 <SET FROB <REST .FROB 2>>
+	 <SET RFROB <REST .FROB <* .CNT 2>>>
+	 <SET RND <RANDOM <- .L .CNT>>>
+	 <SET MSG <GET .RFROB .RND>>
+	 <PUT .RFROB .RND <GET .RFROB 1>>
+	 <PUT .RFROB 1 .MSG>
+	 <SET CNT <+ .CNT 1>>
+	 <COND (<==? .CNT .L> <SET CNT 0>)>
+	 <PUT .FROB 0 .CNT>
+	 .MSG>
+
+<ROUTINE RANDOM-ELEMENT (FROB)
+	 <GET .FROB <RANDOM <GET .FROB 0>>>>
+
+
+
+;"former MAIN.ZIL stuff"
+
+<GLOBAL P-WON <>>
+
+<CONSTANT M-FATAL 2>
+
+<CONSTANT M-BEG 1>
+<CONSTANT M-END 2>
+<CONSTANT M-ENTER 3>
+<CONSTANT M-LEAVE 4>
+<CONSTANT M-LOOK 5>
+<CONSTANT M-FLASH 6>
+<CONSTANT M-OBJDESC 7>
+<CONSTANT M-CONTAINER 8>
+
+<ROUTINE GO () 
+	 <INITIALIZE-CUBES>
+	 <PUTB ,P-LEXV 0 59>
+;"put interrupts on clock chain"
+	 <SETG CLOCK-HAND <REST ,C-TABLE ,C-TABLELEN>>
+	 <QUEUE I-TIRED 80>
+	 <QUEUE I-ORATION -1>
+;"set up and go"
+	 <SETG MAGIC-BOX-CUBE ,WATER-CUBE>
+	 <SETG WINNER ,PLAYER>
+	 <SETG HERE ,COUNCIL-CHAMBER>
+	 <SETG LIT <LIT? ,HERE>>
+	 <SETG ORATOR ,SNEFFLE>
+	 <V-VERSION>
+	 <CRLF>
+	 <V-LOOK>
+	 <MAIN-LOOP>
+	 <AGAIN>>    
+
+<ROUTINE MAIN-LOOP ("AUX" TRASH)
+	<REPEAT ()
+	     <SET TRASH <MAIN-LOOP-1>>>>
+
+<ROUTINE MAIN-LOOP-1 ("AUX" ICNT OCNT NUM CNT OBJ TBL (V <>) PTBL OBJ1 TMP)
+     <SET CNT 0>
+     <SET OBJ <>>
+     <SET PTBL T>
+     <COND (<SETG P-WON <PARSER>>
+	    <SET ICNT <GET ,P-PRSI ,P-MATCHLEN>>
+	    <SET OCNT <GET ,P-PRSO ,P-MATCHLEN>>
+	    <COND (<AND ,P-IT-OBJECT <ACCESSIBLE? ,P-IT-OBJECT>>
+		   <SET TMP <>>
+		   <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .ICNT>
+				  <RETURN>)
+				 (T
+				  <COND (<EQUAL? <GET ,P-PRSI .CNT> ,IT>
+					 <PUT ,P-PRSI .CNT ,P-IT-OBJECT>
+					 <SET TMP T>
+					 <RETURN>)>)>>
+		   <COND (<NOT .TMP>
+			  <SET CNT 0>
+			  <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .OCNT>
+				  <RETURN>)
+				 (T
+				  <COND (<EQUAL? <GET ,P-PRSO .CNT> ,IT>
+					 <PUT ,P-PRSO .CNT ,P-IT-OBJECT>
+					 <RETURN>)>)>>)>
+		   <SET CNT 0>)>
+	    <SET NUM
+		 <COND (<ZERO? .OCNT> .OCNT)
+		       (<G? .OCNT 1>
+			<SET TBL ,P-PRSO>
+			<COND (<ZERO? .ICNT> <SET OBJ <>>)
+			      (T <SET OBJ <GET ,P-PRSI 1>>)>
+			.OCNT)
+		       (<G? .ICNT 1>
+			<SET PTBL <>>
+			<SET TBL ,P-PRSI>
+			<SET OBJ <GET ,P-PRSO 1>>
+			.ICNT)
+		       (T 1)>>
+	    <COND (<AND <NOT .OBJ>
+			<1? .ICNT>>
+		   <SET OBJ <GET ,P-PRSI 1>>)>
+	    <COND (<EQUAL? ,PRSA ,V?WALK> <SET V <PERFORM ,PRSA ,PRSO>>)
+		  (<ZERO? .NUM>
+		   <COND (<ZERO? <BAND <GETB ,P-SYNTAX ,P-SBITS> ,P-SONUMS>>
+			  <SET V <PERFORM ,PRSA>>
+			  <SETG PRSO <>>)
+			 (<NOT ,LIT>
+			  <TELL ,TOO-DARK>
+			  <END-QUOTE>)
+			 (T
+			  <TELL "There isn't anything to ">
+			  <SET TMP <GET ,P-ITBL ,P-VERBN>>
+			  <COND (<VERB? TELL>
+				 <TELL "talk to">)
+				(<OR ,P-OFLAG ,P-MERGED>
+				 <PRINTB <GET .TMP 0>>)
+				(T
+				 <WORD-PRINT <GETB .TMP 2>
+					     <GETB .TMP 3>>)>
+			  <TELL "!" CR>
+			  <SET V <>>
+			  <END-QUOTE>)>)
+		  (T
+		   <SETG P-NOT-HERE 0>
+		   <SETG P-MULT <>>
+		   <COND (<G? .NUM 1> <SETG P-MULT 1>)>
+		   <SET TMP <>>
+		   <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .NUM>
+				  <COND (<G? ,P-NOT-HERE 0>
+					 <TELL "The ">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE .NUM>>
+						<TELL "other ">)>
+					 <TELL "object">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE 1>>
+						<TELL "s">)>
+					 <TELL " that you mentioned ">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE 1>>
+						<TELL "are">)
+					       (T <TELL "is">)>
+					 <TELL "n't here." CR>)
+					(<NOT .TMP>
+					 <TELL ,REFERRING CR>)>
+				  <RETURN>)
+
+(T ;"REFORMATTED AREA"
+ <COND (.PTBL <SET OBJ1 <GET ,P-PRSO .CNT>>)
+       (T <SET OBJ1 <GET ,P-PRSI .CNT>>)>
+ <SETG PRSO <COND (.PTBL .OBJ1) (T .OBJ)>>
+ <SETG PRSI <COND (.PTBL .OBJ) (T .OBJ1)>>
+ <COND (<OR <G? .NUM 1>
+	    <EQUAL? <GET <GET ,P-ITBL ,P-NC1> 0> ,W?ALL>>
+	<COND (<MULTIPLE-EXCEPTION? .OBJ1> <AGAIN>)
+	      (T
+	       <COND (<EQUAL? .OBJ1 ,IT>
+		      <TELL D ,P-IT-OBJECT>)
+		     (ELSE
+		      <TELL D .OBJ1>)>
+	       <TELL ": ">)>)>
+ <SET TMP T>
+ <SETG PSEUDO-PRSO <COND (<EQUAL? ,PRSO ,PSEUDO-OBJECT>)>>
+ <SET V <PERFORM ,PRSA ,PRSO ,PRSI>>
+ <COND (<EQUAL? .V ,M-FATAL> <RETURN>)>
+ <COND (,P-MULT <SETG P-MULT <+ ,P-MULT 1>>)>) ;"END REFORMATTING"
+
+				 >>)>
+	    <COND (<NOT <EQUAL? .V ,M-FATAL>>
+		   <COND (<VERB? TELL BRIEF SUPER-BRIEF VERBOSE
+				 SAVE VERSION RESTORE SCRIPT UNSCRIPT>
+			  T)
+			 (T
+			  <SET V
+			       %<DEBUG-CODE
+				 <D-APPLY "End"
+					  <GETP <LOC ,WINNER> ,P?ACTION>
+					  ,M-END>
+				 <APPLY <GETP <LOC ,WINNER> ,P?ACTION>
+					,M-END>>>)>)>
+	    <COND (<VERB? SAVE RESTORE SCRIPT UNSCRIPT
+			  VERBOSE BRIEF SUPER-BRIEF>
+		   T)
+		  (,P-OFLAG T)>
+	    <COND (<EQUAL? .V ,M-FATAL>
+		   <SETG P-CONT <>>)>)
+	   (T
+	    <SETG P-CONT <>>)>
+     <COND (,P-WON
+	    %<DEBUG-CODE
+	      <COND (<VERB? $DEBUG>
+		     <AGAIN>)>>
+	    <COND (<NO-CLOCK-VERB?> T)
+		  (T
+		   <SET V <CLOCKER>>)>
+	    <SETG PRSA <>>
+	    <SETG PRSO <>>
+	    <SETG PRSI <>>)>>
+
+<GLOBAL PSEUDO-PRSO <>> ;"T IF ORIGINAL PRSO WAS PSEUDO-OBJECT"
+
+<ROUTINE NO-CLOCK-VERB? ()
+	 <COND (<AND <VERB? TELL> ,P-CONT> <RTRUE>)
+	       (<VERB? BRIEF SUPER-BRIEF VERBOSE VERSION QUIT SCORE
+		       SAVE RESTORE SCRIPT UNSCRIPT HELP RESTART $VERIFY
+		       TIME $RANDOM $COMMAND $RECORD $UNRECORD>
+		<RTRUE>)>>
+
+"MULTIPLE-EXCEPTION? -- return true if an object found by all should not
+be include when the crunch comes."
+
+<ROUTINE MULTIPLE-EXCEPTION? (OBJ1 "AUX" (L <LOC .OBJ1>))
+	 <COND (<EQUAL? .OBJ1 ,NOT-HERE-OBJECT>
+		<SETG P-NOT-HERE <+ ,P-NOT-HERE 1>>
+		<RTRUE>)
+	       (<AND <VERB? TAKE>
+		     ,PRSI
+		     <NOT <IN? ,PRSO ,PRSI>>>
+		;"TAKE X FROM Y and x not in y"
+		<RTRUE>)
+	       (<NOT <ACCESSIBLE? .OBJ1>>
+		;"can't get at object"
+		<RTRUE>)
+	       (<EQUAL? ,P-GETFLAGS ,P-ALL>
+		;"cases for ALL"
+		<COND (<AND <VERB? TAKE>
+			    <OR <AND <NOT <EQUAL? .L ,WINNER ,HERE ,PRSI>>
+				     <NOT <EQUAL? .L <LOC ,WINNER>>>
+				     <NOT <FSET? .L ,SURFACEBIT>>
+				     <NOT <FSET? .L ,SEARCHBIT>>>
+				<AND <NOT <FSET? .OBJ1 ,TAKEBIT>>
+				     <NOT <FSET? .OBJ1 ,TRYTAKEBIT>>>>>
+		       ;"TAKE ALL and object not accessible or takeable"
+		       <RTRUE>)
+		      (<AND <VERB? TAKE>
+			    <NOT ,PRSI>
+			    <HELD? ,PRSO>>
+		       ;"TAKE ALL and one object has others in it"
+		       <RTRUE>)
+		      (<AND <VERB? DROP>
+			    <NOT <IN? .OBJ1 ,WINNER>>>
+		       ;"DROP ALL and object not held"
+		       <RTRUE>)
+		      (<AND ,PRSI
+			    <EQUAL? ,PRSO ,PRSI>>
+		       ;"VERB ALL and prso = prsi"
+		       <RTRUE>)
+		      (<AND <VERB? PUT>
+			    <NOT <IN? ,PRSO ,WINNER>>
+			    <HELD? ,PRSO ,PRSI>>
+		       ;"PUT ALL IN X and object already in x"
+		       <RTRUE>)
+		      (<AND <FSET? ,PRSO ,SPELLBIT>
+			    <NOT <VERB? LEARN GNUSTO CAST>>
+			    <NOT <VERB? READ>>>
+		       ;"normally ignore spells in ALL"
+		       <RTRUE>)>)>>
+
+;<ROUTINE SAVE-INPUT (TBL "AUX" (OFFS 0) CNT TMP)
+	 <SET CNT <+ <GETB ,P-LEXV <SET TMP <* 4 ,P-INPUT-WORDS>>>
+		     <GETB ,P-LEXV <+ .TMP 1>>>>
+	 <COND (<EQUAL? .CNT 0> ;"failed"
+		<RFALSE>)>
+	 <SET CNT <- .CNT 1>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .OFFS .CNT>
+			<PUTB .TBL .OFFS 0>
+			<RETURN>)
+		       (T
+			<PUTB .TBL .OFFS <GETB ,P-INBUF <+ .OFFS 1>>>)>
+		 <SET OFFS <+ .OFFS 1>>>
+	 <RTRUE>>
+
+;<ROUTINE RESTORE-INPUT (TBL "AUX" CHR)
+	 <REPEAT ()
+		 <COND (<EQUAL? <SET CHR <GETB .TBL 0>> 0>
+			<RETURN>)
+		       (T
+			<PRINTC .CHR>
+			<SET TBL <REST .TBL>>)>>>
+
+<GLOBAL P-MULT <>>
+
+<GLOBAL P-NOT-HERE 0>
+
+
+<ROUTINE FAKE-ORPHAN ("AUX" TMP)
+	 <ORPHAN ,P-SYNTAX <>>
+	 <TELL "What do you want to ">
+	 <SET TMP <GET ,P-OTBL ,P-VERBN>>
+	 <COND (<EQUAL? .TMP 0>
+		<TELL "tell">)
+	       (<ZERO? <GETB ,P-VTBL 2>>
+		<PRINTB <GET .TMP 0>>)
+	       (T
+		<WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
+		<PUTB ,P-VTBL 2 0>)>
+	 <SETG P-OFLAG T>
+	 <SETG P-WON <>>
+	 <PREP-PRINT
+	     <GETB ,P-SYNTAX ,P-SPREP1>>
+	 <TELL "?" CR>>
+
+<ROUTINE PERFORM (A "OPTIONAL" (O <>) (I <>) "AUX" V OA OO OI CNT)
+	%<DEBUG-CODE
+	  <COND (,ZDEBUG
+		 <TELL "[Perform: ">
+		 %<COND (<GASSIGNED? ZILCH> '<TELL N .A>)
+			(T '<PRINT <SPNAME <NTH ,ACTIONS <+ <* .A 2> 1>>>>)>
+		 <COND (.O
+			<COND (<AND <EQUAL? .A ,V?WALK>
+				    ,P-WALK-DIR>
+			       <TELL "/" N .O>)
+			      (ELSE
+			       <TELL "/" D .O>)>)>
+		 <COND (.I <TELL "/" D .I>)>
+		 <TELL "]" CR>)>>
+	<SET OA ,PRSA>
+	<SET OO ,PRSO>
+	<SET OI ,PRSI>
+	<SETG PRSA .A>
+	<COND (<EQUAL? ,IT .I .O>
+	       <COND (<NOT .I>
+		      <FAKE-ORPHAN>)
+		     (T
+		      <TELL ,REFERRING CR>)>
+	       <RFATAL>)
+	      (<AND .O
+		    <NOT <VERB? WALK>>
+		    <NOT <EQUAL? .O ,NOT-HERE-OBJECT>>>
+	       <THIS-IS-IT .O>)>
+	<SETG PRSO .O>
+	<SETG PRSI .I>
+	<COND (<AND <NOT <EQUAL? .A ,V?WALK>>
+		    <EQUAL? ,NOT-HERE-OBJECT ,PRSO ,PRSI>
+		    <SET V
+			 %<DEBUG-CODE
+			   <D-APPLY "Not Here" ,NOT-HERE-OBJECT-F>
+			   <APPLY ,NOT-HERE-OBJECT-F>>>>
+	       <SETG P-WON <>>
+	       .V)
+	      (T
+	       <SET O ,PRSO>
+	       <SET I ,PRSI>
+	       <COND (<SET V
+			   %<DEBUG-CODE
+			     <DD-APPLY "Actor" ,WINNER
+				       <GETP ,WINNER ,P?ACTION>>
+			     <APPLY <GETP ,WINNER ,P?ACTION>>>>
+		      .V)
+		     (<AND <NOT <EQUAL? <LOC ,WINNER> ,HERE>>
+			   <SET V
+				%<DEBUG-CODE
+				  <D-APPLY "Begin"
+					   <GETP <LOC ,WINNER> ,P?ACTION>
+					   ,M-BEG>
+				  <APPLY <GETP <LOC ,WINNER> ,P?ACTION>
+					 ,M-BEG>>>>
+		      .V)
+		     (<SET V
+			   %<DEBUG-CODE
+			     <D-APPLY "Begin"
+				      <GETP ,HERE ,P?ACTION>
+				      ,M-BEG>
+			     <APPLY <GETP ,HERE ,P?ACTION>
+				    ,M-BEG>>>
+		      .V)
+		     (<SET V
+			   %<DEBUG-CODE
+			     <D-APPLY "Preaction"
+				      <GET ,PREACTIONS .A>>
+			     <APPLY <GET ,PREACTIONS .A>>>>
+		      .V)
+		     (<AND .I
+			   <SET V
+				%<DEBUG-CODE
+				  <D-APPLY "PRSI" <GETP .I ,P?ACTION>>
+				  <APPLY <GETP .I ,P?ACTION>>>>>
+		      .V)
+		     (<AND .O
+			   <NOT <EQUAL? .A ,V?WALK>>
+			   <LOC .O>
+			   <GETP <LOC .O> ,P?CONTFCN>
+			   <SET V
+				%<DEBUG-CODE
+				  <D-APPLY "Container"
+					   <GETP <LOC .O> ,P?CONTFCN>
+					   ,M-CONTAINER>
+				  <APPLY <GETP <LOC .O> ,P?CONTFCN>
+					 ,M-CONTAINER>>>>
+		      .V) 
+		     (<AND .O
+			   <NOT <EQUAL? .A ,V?WALK>>
+			   <SET V
+				%<DEBUG-CODE
+				  <D-APPLY "PRSO"
+					   <GETP .O ,P?ACTION>>
+				  <APPLY <GETP .O ,P?ACTION>>>>>
+		      .V)
+		     (<SET V
+			   %<DEBUG-CODE
+			     <D-APPLY <>
+				      <GET ,ACTIONS .A>>
+			     <APPLY <GET ,ACTIONS .A>>>>
+		      .V)>)>
+	<COND (,SPELL-CAST
+	       <COND (<G? <SET CNT <GETP ,SPELL-CAST ,P?COUNT>> 0>
+		      <PUTP ,SPELL-CAST ,P?COUNT <- .CNT 1>>)>
+	       <COND (<L? ,SPELL-ROOM ,SPELL-MAX>
+		      <SETG SPELL-ROOM <+ ,SPELL-ROOM 1>>)>
+	       <SETG SPELL-CAST <>>)>
+	<SETG PRSA .OA>
+	<SETG PRSO .OO>
+	<SETG PRSI .OI>
+	.V>
+
+%<COND (,ZDEBUGGING?
+	<COND (<GASSIGNED? ZILCH>
+	       <ROUTINE II-APPLY (STR FCN)
+			<COND (,ZDEBUG
+			       <TELL "[I- " N <* .FCN 2> " ">)>
+			<D-APPLY .STR .FCN>>)
+	      (ELSE
+	       <ROUTINE II-APPLY (STR FCN)
+			<D-APPLY <COND (<TYPE? .FCN ATOM> <SPNAME .FCN>)
+				       (ELSE .STR)>
+				 .FCN>>)>)>
+
+%<DEBUG-CODE
+  <ROUTINE DD-APPLY (STR OBJ FCN)
+	   <COND (,ZDEBUG <TELL "[" D .OBJ "=]">)>
+	   <D-APPLY .STR .FCN>>>
+
+%<DEBUG-CODE
+  <ROUTINE D-APPLY (STR FCN "OPTIONAL" (FOO <>) "AUX" RES)
+	<COND (<NOT .FCN> <>)
+	      (T
+	       <COND (,ZDEBUG
+		      <COND (<NOT .STR>
+			     <TELL "[Action:]" CR>)
+			    (T <TELL "[" .STR ": ">)>)>
+	       <SET RES
+		    <COND (.FOO <APPLY .FCN .FOO>)
+			  (T <APPLY .FCN>)>>
+	       %<DEBUG-CODE
+		 <COND (<AND ,ZDEBUG .STR>
+			<COND (<EQUAL? .RES ,M-FATAL>
+			       <TELL "Fatal]" CR>)
+			      (<NOT .RES>
+			       <TELL "Not handled]" CR>)
+			      (T <TELL "Handled]" CR>)>)>>
+	       .RES)>>>
+
+;"former CLOCK.ZIL stuff"
+
+<GLOBAL CLOCK-WAIT <>>
+
+<GLOBAL C-TABLE %<COND (<GASSIGNED? ZILCH>
+			'<ITABLE NONE 26>)
+		       (T
+			'<ITABLE NONE 52>)>>
+
+<CONSTANT C-TABLELEN 52>
+<GLOBAL C-INTS 52>
+%<DEBUG-CODE <GLOBAL C-MAXINTS 52>>
+
+<CONSTANT C-INTLEN 4>	;"length of an interrupt entry"
+<CONSTANT C-RTN 0>	;"offset of routine name"
+<CONSTANT C-TICK 1>	;"offset of count"
+
+<ROUTINE DEQUEUE (RTN)
+	 <COND (<SET RTN <QUEUED? .RTN>>
+		<PUT .RTN ,C-RTN 0>)>>
+
+<ROUTINE QUEUED? (RTN "AUX" C E)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .C .E> <RFALSE>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<COND (<ZERO? <GET .C ,C-TICK>>
+			       <RFALSE>)
+			      (T <RETURN .C>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+"this version of QUEUE automatically enables as well"
+
+<ROUTINE QUEUE (RTN TICK "AUX" C E (INT <>))
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .C .E>
+			<COND (.INT
+			       <SET C .INT>)
+			      (ELSE
+			       %<DEBUG-CODE
+				 <COND (<L? ,C-INTS ,C-INTLEN>
+					<TELL
+					  "[**Too many interrupts!**]" CR>)>>
+			       <SETG C-INTS <- ,C-INTS ,C-INTLEN>>
+			       %<DEBUG-CODE
+				 <COND (<L? ,C-INTS ,C-MAXINTS>
+					<SETG C-MAXINTS ,C-INTS>)>>
+			       <SET INT <REST ,C-TABLE ,C-INTS>>)>
+			<PUT .INT ,C-RTN .RTN>
+			<RETURN>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<SET INT .C>
+			<RETURN>)
+		       (<ZERO? <GET .C ,C-RTN>>
+			<SET INT .C>)>
+		 <SET C <REST .C ,C-INTLEN>>>
+	 <COND (%<COND (<GASSIGNED? ZILCH>
+			'<G? .INT ,CLOCK-HAND>)
+		       (ELSE
+			'<L=? <LENGTH .INT> <LENGTH ,CLOCK-HAND>>)>
+		<SET TICK <- <+ .TICK 3>>>)>
+	 <PUT .INT ,C-TICK .TICK>
+	 .INT>
+
+<GLOBAL CLOCK-HAND <>>
+
+<ROUTINE CLOCKER ("AUX" E TICK RTN (FLG <>) (Q? <>) OWINNER)
+	 <COND (,CLOCK-WAIT <SETG CLOCK-WAIT <>> <RFALSE>)>
+	 <SETG CLOCK-HAND <REST ,C-TABLE ,C-INTS>>
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET OWINNER ,WINNER>
+	 <SETG WINNER ,PLAYER>
+	 <REPEAT ()
+		 <COND (<EQUAL? ,CLOCK-HAND .E>
+			<SETG CLOCK-HAND .E>
+			<SETG MOVES <+ ,MOVES 1>>
+			<SETG WINNER .OWINNER>
+			<RETURN .FLG>)
+		       (<NOT <ZERO? <GET ,CLOCK-HAND ,C-RTN>>>
+			<SET TICK <GET ,CLOCK-HAND ,C-TICK>>
+			<COND (<L? .TICK -1>
+			       <PUT ,CLOCK-HAND ,C-TICK <- <- .TICK> 3>>
+			       <SET Q? ,CLOCK-HAND>)
+			      (<NOT <ZERO? .TICK>>
+			       <COND (<G? .TICK 0>
+				      <SET TICK <- .TICK 1>>
+				      <PUT ,CLOCK-HAND ,C-TICK .TICK>)>
+			       <COND (<NOT <ZERO? .TICK>>
+				      <SET Q? ,CLOCK-HAND>)>
+			       <COND (<NOT <G? .TICK 0>>
+				      <SET RTN
+					   %<COND (<GASSIGNED? ZILCH>
+						   '<GET ,CLOCK-HAND ,C-RTN>)
+						  (ELSE
+						   '<NTH ,CLOCK-HAND
+							 <+ <* ,C-RTN 2>
+							    1>>)>>
+				      <COND (<ZERO? .TICK>
+					     <PUT ,CLOCK-HAND ,C-RTN 0>)>
+				      <COND (%<COND
+					       (,ZDEBUGGING?
+						'<II-APPLY "Int" .RTN>)
+					       (ELSE
+						'<APPLY .RTN>)>
+					     <SET FLG T>)>
+				      <COND (<AND <NOT .Q?>
+						  <NOT
+						   <ZERO?
+						    <GET ,CLOCK-HAND
+							 ,C-RTN>>>>
+					     <SET Q? T>)>)>)>)>
+		 <SETG CLOCK-HAND <REST ,CLOCK-HAND ,C-INTLEN>>
+		 <COND (<NOT .Q?>
+			<SETG C-INTS <+ ,C-INTS ,C-INTLEN>>)>>>
+
+<DEFINE PSEUDO ("TUPLE" V)
+	<MAPF ,PLTABLE
+	      <FUNCTION (OBJ)
+		   <COND (<N==? <LENGTH .OBJ> 3>
+			  <ERROR BAD-THING .OBJ>)>
+		   <MAPRET <COND (<NTH .OBJ 2>
+				  <VOC <SPNAME <NTH .OBJ 2>>>)>
+			   <COND (<NTH .OBJ 1>
+				  <VOC <SPNAME <NTH .OBJ 1>> ADJECTIVE>)>
+			   <3 .OBJ>>>
+	      .V>>
diff --git a/parser.zil b/parser.zil
new file mode 100644
index 0000000..93a110c
--- /dev/null
+++ b/parser.zil
@@ -0,0 +1,1763 @@
+"PARSER for
+				MAGE
+	 (c) Copyright 1985 Infocom, Inc. All Rights Reserved"
+
+;"Parser global variable convention: All parser globals will begin
+with 'P-'. Local variables are not restricted in any way."
+
+<SETG SIBREAKS ".,\"">
+
+<GLOBAL P-AND <>>
+
+<GLOBAL PRSA <>>
+
+<GLOBAL PRSI <>>
+
+<GLOBAL PRSO <>>
+
+<GLOBAL P-TABLE 0>
+
+<GLOBAL P-ONEOBJ 0>
+
+<GLOBAL P-SYNTAX 0>
+
+<GLOBAL P-CCTBL <TABLE 0 0 0 0>>
+
+;"pointers used by CLAUSE-COPY (source/destination beginning/end pointers)"
+<CONSTANT CC-SBPTR 0>
+<CONSTANT CC-SEPTR 1>
+<CONSTANT CC-DBPTR 2>
+<CONSTANT CC-DEPTR 3>
+
+<GLOBAL P-LEN 0>
+
+<GLOBAL WINNER 0>
+
+<GLOBAL P-LEXV <ITABLE BYTE 120>>
+<GLOBAL AGAIN-LEXV <ITABLE BYTE 120>>
+<GLOBAL RESERVE-LEXV <ITABLE BYTE 120>>
+<GLOBAL RESERVE-PTR <>>
+
+<GLOBAL P-INBUF <ITABLE BYTE 60>> ;"INBUF - Input buffer for READ"
+<GLOBAL OOPS-INBUF <ITABLE BYTE 60>>
+<GLOBAL OOPS-TABLE <TABLE <> <> <> <>>>
+<CONSTANT O-PTR 0>	"word pointer to unknown token in P-LEXV"
+<CONSTANT O-START 1>	"word pointer to sentence start in P-LEXV"
+<CONSTANT O-LENGTH 2>	"byte length of unparsed tokens in P-LEXV"
+<CONSTANT O-END 3>	"byte pointer to first free byte in OOPS-INBUF"
+
+<GLOBAL P-CONT <>> ;"Parse-cont variable"
+
+<GLOBAL P-IT-OBJECT <>>
+
+<GLOBAL LAST-PSEUDO-LOC <>>
+
+<GLOBAL P-OFLAG <>> ;"Orphan flag"
+
+<GLOBAL P-MERGED <>>
+
+<GLOBAL P-ACLAUSE <>>
+
+<GLOBAL P-ANAM <>>
+<GLOBAL P-AADJ <>>
+
+<GLOBAL P-PNAM <>>
+<GLOBAL P-PADJN <>>
+
+;"Parser variables and temporaries"
+
+<CONSTANT P-LEXWORDS 1> ;"Byte offset to # of entries in LEXV"
+<CONSTANT P-LEXSTART 1> ;"Word offset to start of LEXV entries"
+<CONSTANT P-LEXELEN 2> ;"Number of words per LEXV entry"
+<CONSTANT P-WORDLEN 4>
+<CONSTANT P-PSOFF 4> ;"Offset to parts of speech byte"
+<CONSTANT P-P1OFF 5> ;"Offset to first part of speech"
+<CONSTANT P-P1BITS 3> ;"First part of speech bit mask in PSOFF byte"
+<CONSTANT P-ITBLLEN 9>
+
+<GLOBAL P-ITBL
+	<TABLE 0 0 0 0 0 0 0 0 0 0>>
+
+<GLOBAL P-OTBL
+	<TABLE 0 0 0 0 0 0 0 0 0 0>>
+
+<GLOBAL P-VTBL
+	<TABLE 0 0 0 0>>
+
+<GLOBAL P-OVTBL
+	<TABLE 0 0 0 0>>
+
+<GLOBAL P-NCN 0>
+
+<CONSTANT P-VERB 0>
+
+<CONSTANT P-VERBN 1>
+
+<CONSTANT P-PREP1 2>
+
+<CONSTANT P-PREP1N 3>
+
+<CONSTANT P-PREP2 4>
+
+<CONSTANT P-PREP2N 5>
+
+<CONSTANT P-NC1 6>
+
+<CONSTANT P-NC1L 7>
+
+<CONSTANT P-NC2 8>
+
+<CONSTANT P-NC2L 9>
+
+<GLOBAL QUOTE-FLAG <>>
+
+;<GLOBAL P-INPUT-WORDS <>>
+
+<GLOBAL P-END-ON-PREP <>>
+
+" Grovel down the input finding the verb, prepositions, and noun clauses.
+   If the input is <direction> or <walk> <direction>, fall out immediately
+   setting PRSA to ,V?WALK and PRSO to <direction>. Otherwise, perform
+   all required orphaning, syntax checking, and noun clause lookup."
+
+<ROUTINE PARSER ("AUX" (PTR ,P-LEXSTART) WRD (VAL 0) (VERB <>) (OF-FLAG <>)
+		       OWINNER OMERGED LEN (DIR <>) (NW 0) (LW 0) (CNT -1))
+	<REPEAT ()
+		<COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN> <RETURN>)
+		      (T
+		       <COND (<NOT ,P-OFLAG>
+			      <PUT ,P-OTBL .CNT <GET ,P-ITBL .CNT>>)>
+		       <PUT ,P-ITBL .CNT 0>)>>
+	<SET OWINNER ,WINNER>
+	<SET OMERGED ,P-MERGED>
+	<SETG P-ADVERB <>>
+	<SETG P-MERGED <>>
+	<SETG P-END-ON-PREP <>>
+	<PUT ,P-PRSO ,P-MATCHLEN 0>
+	<PUT ,P-PRSI ,P-MATCHLEN 0>
+	<PUT ,P-BUTS ,P-MATCHLEN 0>
+	<COND (<AND <NOT ,QUOTE-FLAG> <N==? ,WINNER ,PLAYER>>
+	       <SETG WINNER ,PLAYER>
+	       <COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		      <SETG HERE <LOC ,WINNER>>)>
+	       <SETG LIT <LIT? ,HERE>>)>
+	<COND (,RESERVE-PTR
+	       <SET PTR ,RESERVE-PTR>
+	       <STUFF ,RESERVE-LEXV ,P-LEXV>
+	       <COND (<AND ,VERBOSITY <EQUAL? ,PLAYER ,WINNER>>
+		      <CRLF>)>
+	       <SETG RESERVE-PTR <>>
+	       <SETG P-CONT <>>)
+	      (,P-CONT
+	       <SET PTR ,P-CONT>
+	       <COND (<AND ,VERBOSITY <EQUAL? ,PLAYER ,WINNER>>
+		      <CRLF>)>
+	       <SETG P-CONT <>>)
+	      (T
+	       <SETG WINNER ,PLAYER>
+	       <SETG QUOTE-FLAG <>>
+	       <COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		      <SETG HERE <LOC ,WINNER>>)>
+	       <SETG LIT <LIT? ,HERE>>
+	       <COND (,VERBOSITY <CRLF>)>
+	       <TELL ">">
+	       <READ ,P-INBUF ,P-LEXV>)>
+	<SETG P-LEN <GETB ,P-LEXV ,P-LEXWORDS>>
+	<COND (<ZERO? ,P-LEN>
+	       <BEG-PARDON>
+	       <RFALSE>)>
+	<COND (<EQUAL? <SET WRD <GET ,P-LEXV .PTR>> ,W?OOPS>
+	       <COND (<EQUAL? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+			      ,W?PERIOD ,W?COMMA>
+		      <SET PTR <+ .PTR ,P-LEXELEN>>
+		      <SETG P-LEN <- ,P-LEN 1>>)>
+	       <COND (<NOT <G? ,P-LEN 1>>
+		      <TELL "I can't help your clumsiness." CR>
+		      <RFALSE>)
+		     (<GET ,OOPS-TABLE ,O-PTR>
+		      <COND (<AND <G? ,P-LEN 2>
+				  <EQUAL? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					  ,W?QUOTE>>
+			     <TELL
+"Sorry, you can't correct mistakes in quoted text." CR>
+			     <RFALSE>)
+			    (<G? ,P-LEN 2>
+			     <TELL
+"Warning: only the first word after OOPS is used." CR>)>
+		      <PUT ,AGAIN-LEXV <GET ,OOPS-TABLE ,O-PTR>
+			   <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>>
+		      <SETG WINNER .OWINNER> ;"maybe fix oops vs. chars.?"
+		      <INBUF-ADD <GETB ,P-LEXV <+ <* .PTR ,P-LEXELEN> 6>>
+				 <GETB ,P-LEXV <+ <* .PTR ,P-LEXELEN> 7>>
+				 <+ <* <GET ,OOPS-TABLE ,O-PTR> ,P-LEXELEN> 3>>
+		      <STUFF ,AGAIN-LEXV ,P-LEXV>
+		      <SETG P-LEN <GETB ,P-LEXV ,P-LEXWORDS>>
+		      <SET PTR <GET ,OOPS-TABLE ,O-START>>
+		      <INBUF-STUFF ,OOPS-INBUF ,P-INBUF>)
+		     (T
+		      <PUT ,OOPS-TABLE ,O-END <>>
+		      <TELL "There was no word to replace!" CR>
+		      <RFALSE>)>)
+	      (T
+	       <COND (<NOT <EQUAL? .WRD ,W?AGAIN ,W?G>>
+		      <SETG P-QWORD <>>
+		      <SETG P-NUMBER 0>)>
+	       <PUT ,OOPS-TABLE ,O-END <>>)>
+	<COND (<EQUAL? <GET ,P-LEXV .PTR> ,W?AGAIN ,W?G>
+	       <COND (<ZERO? <GETB ,OOPS-INBUF 1>>
+		      <BEG-PARDON>
+		      <RFALSE>)
+		     (,P-OFLAG
+		      <TELL "It's difficult to repeat fragments." CR>
+		      <RFALSE>)
+		     (<NOT ,P-WON>
+		      <TELL "That would just repeat a mistake." CR>
+		      <RFALSE>)
+		     (<G? ,P-LEN 1>
+		      <COND (<OR <EQUAL? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					,W?PERIOD ,W?COMMA ,W?THEN>
+				 <EQUAL? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					,W?AND>>
+			     <SET PTR <+ .PTR <* 2 ,P-LEXELEN>>>
+			     <PUTB ,P-LEXV ,P-LEXWORDS
+				   <- <GETB ,P-LEXV ,P-LEXWORDS> 2>>)
+			    (T
+			     <TELL "I couldn't understand that sentence." CR>
+			     <RFALSE>)>)
+		     (T
+		      <SET PTR <+ .PTR ,P-LEXELEN>>
+		      <PUTB ,P-LEXV ,P-LEXWORDS
+			    <- <GETB ,P-LEXV ,P-LEXWORDS> 1>>)>
+	       <COND (<G? <GETB ,P-LEXV ,P-LEXWORDS> 0>
+		      <STUFF ,P-LEXV ,RESERVE-LEXV>
+		      <SETG RESERVE-PTR .PTR>)
+		     (T
+		      <SETG RESERVE-PTR <>>)>
+	       ;<SETG P-LEN <GETB ,AGAIN-LEXV ,P-LEXWORDS>>
+	       <SETG WINNER .OWINNER>
+	       <SETG P-MERGED .OMERGED>
+	       <INBUF-STUFF ,OOPS-INBUF ,P-INBUF>
+	       <STUFF ,AGAIN-LEXV ,P-LEXV>
+	       <SET CNT -1>
+	       <SET DIR ,AGAIN-DIR>
+	       <REPEAT ()
+		<COND (<IGRTR? CNT ,P-ITBLLEN> <RETURN>)
+		      (T <PUT ,P-ITBL .CNT <GET ,P-OTBL .CNT>>)>>)
+	      (T
+	       <STUFF ,P-LEXV ,AGAIN-LEXV>
+	       <INBUF-STUFF ,P-INBUF ,OOPS-INBUF>
+	       <PUT ,OOPS-TABLE ,O-START .PTR>
+	       <PUT ,OOPS-TABLE ,O-LENGTH <* 4 ,P-LEN>>
+	       <SET LEN
+		    <* 2 <+ .PTR <* ,P-LEXELEN <GETB ,P-LEXV ,P-LEXWORDS>>>>>
+	       <PUT ,OOPS-TABLE ,O-END <+ <GETB ,P-LEXV <- .LEN 1>>
+					  <GETB ,P-LEXV <- .LEN 2>>>>
+	       <SETG RESERVE-PTR <>>
+	       <SET LEN ,P-LEN>
+	       ;<SETG P-DIR <>>
+	       <SETG P-NCN 0>
+	       <SETG P-GETFLAGS 0>
+	       <REPEAT ()
+		<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
+		       <SETG QUOTE-FLAG <>>
+		       <RETURN>)
+		      (<SET WRD <KNOWN-WORD? .PTR .VERB>>
+		       <COND (<AND <EQUAL? .WRD ,W?TO>
+				   <EQUAL? .VERB ,ACT?TELL ,ACT?ASK>
+				   ;"next clause added 8/20/84 by JW to
+				     enable TELL MY NAME TO BEAST"
+				   <NOT <ZERO?
+					 <WT? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					      ,PS?VERB ,P1?VERB>>>>
+			      <PUT ,P-ITBL ,P-VERB ,ACT?TELL>
+			      <SET WRD ,W?QUOTE>)
+			     (<AND <EQUAL? .WRD ,W?THEN>
+				   <G? ,P-LEN 0>
+				   <NOT .VERB>
+				   <NOT ,QUOTE-FLAG>>
+			      <COND (<EQUAL? .LW 0 ,W?PERIOD>
+				     <SET WRD ,W?THE>)
+				    (ELSE
+				     <PUT ,P-ITBL ,P-VERB ,ACT?TELL>
+				     <PUT ,P-ITBL ,P-VERBN 0>
+				     <SET WRD ,W?QUOTE>)>)>
+		       <COND (<EQUAL? .WRD ,W?THEN ,W?PERIOD ,W?QUOTE>
+			      <COND (<EQUAL? .WRD ,W?QUOTE>
+				     <COND ;"Following clause added for
+					     WRITE 'FOO' ON CUBE"
+				           (<AND <EQUAL? <GET ,P-LEXV .PTR>
+							 ,W?QUOTE>
+						 <OR <NOT <EQUAL?
+							    .VERB
+							    ,ACT?TELL
+							    ,ACT?SAY>>
+						     <NOT <EQUAL? ,WINNER
+								  ,PLAYER>>>>
+					    <COND (<QUOTED-PHRASE .PTR .VERB>
+						   <SET PTR
+							<+ .PTR ,P-LEXELEN>>
+						   <AGAIN>)
+						  (ELSE
+						   <RFALSE>)>)
+					   (,QUOTE-FLAG
+					    <SETG QUOTE-FLAG <>>)
+					   (T <SETG QUOTE-FLAG T>)>)>
+			      <OR <ZERO? ,P-LEN>
+				  <SETG P-CONT <+ .PTR ,P-LEXELEN>>>
+			      <PUTB ,P-LEXV ,P-LEXWORDS ,P-LEN>
+			      <RETURN>)
+			     (<AND <NOT <ZERO?
+					 <SET VAL
+					      <WT? .WRD
+						   ,PS?DIRECTION
+						   ,P1?DIRECTION>>>>
+				   <EQUAL? .VERB <> ,ACT?WALK ;,ACT?FLY>
+				   <OR <EQUAL? .LEN 1>
+				       <AND <EQUAL? .LEN 2>
+					    <EQUAL? .VERB ,ACT?WALK ;,ACT?FLY>>
+				       <AND <EQUAL? <SET NW
+						     <GET ,P-LEXV
+							  <+ .PTR ,P-LEXELEN>>>
+					            ,W?THEN
+					            ,W?PERIOD
+					            ,W?QUOTE>
+					    <NOT <L? .LEN 2>>>
+				       <AND ,QUOTE-FLAG
+					    <EQUAL? .LEN 2>
+					    <EQUAL? .NW ,W?QUOTE>>
+				       <AND <G? .LEN 2>
+					    <EQUAL? .NW ,W?COMMA ,W?AND>>>>
+			      <SET DIR .VAL>
+			      <COND (<EQUAL? .NW ,W?COMMA ,W?AND>
+				     <CHANGE-LEXV <+ .PTR ,P-LEXELEN>
+						  ,W?THEN>)>
+			      <COND (<NOT <G? .LEN 2>>
+				     <SETG QUOTE-FLAG <>>
+				     <RETURN>)>)
+			     (<AND <NOT <ZERO?
+					  <SET VAL <WT? .WRD
+							,PS?VERB ,P1?VERB>>>>
+				   <NOT .VERB>>
+			      <SET VERB .VAL>
+			      <PUT ,P-ITBL ,P-VERB .VAL>
+			      <PUT ,P-ITBL ,P-VERBN ,P-VTBL>
+			      <PUT ,P-VTBL 0 .WRD>
+			      <PUTB ,P-VTBL 2 <GETB ,P-LEXV
+						    <SET CNT
+							 <+ <* .PTR 2> 2>>>>
+			      <PUTB ,P-VTBL 3 <GETB ,P-LEXV <+ .CNT 1>>>)
+			     (<OR <NOT <ZERO?
+				  <SET VAL <WT? .WRD ,PS?PREPOSITION 0>>>>
+				  <AND <OR <EQUAL? .WRD ,W?ALL ,W?ONE ,W?BOTH>
+					   <NOT <ZERO? <WT? .WRD ,PS?ADJECTIVE>>>
+					   <NOT <ZERO? <WT? .WRD ,PS?OBJECT>>>>
+				       <SET VAL 0>>>
+			      <COND (<AND <G? ,P-LEN 1>
+					  <EQUAL? <GET ,P-LEXV
+						       <+ .PTR ,P-LEXELEN>>
+						  ,W?OF>
+					  <ZERO? .VAL>
+					  <NOT <EQUAL? .WRD
+						       ,W?ALL ,W?ONE ,W?A>>
+					  <NOT <EQUAL? .WRD
+						       ,W?BOTH>>>
+				     <SET OF-FLAG T>)
+				    (<AND <NOT <ZERO? .VAL>>
+				          <OR <ZERO? ,P-LEN>
+					      <EQUAL? <GET ,P-LEXV <+ .PTR 2>>
+						      ,W?THEN ,W?PERIOD>>>
+				     <SETG P-END-ON-PREP T>
+				     <COND (<L? ,P-NCN 2>
+					    <PUT ,P-ITBL ,P-PREP1 .VAL>
+					    <PUT ,P-ITBL ,P-PREP1N .WRD>)>)
+				    (<EQUAL? ,P-NCN 2>
+				     <TELL
+"There were too many nouns in that sentence." CR>
+				     <RFALSE>)
+				    (T
+				     <SETG P-NCN <+ ,P-NCN 1>>
+				     <SETG P-ACT .VERB>
+				     <OR <SET PTR <CLAUSE .PTR .VAL .WRD>>
+					 <RFALSE>>
+				     <COND (<L? .PTR 0>
+					    <SETG QUOTE-FLAG <>>
+					    <RETURN>)>)>)
+			     (<EQUAL? .WRD ,W?OF>
+			      <COND (<OR <NOT .OF-FLAG>
+					 <EQUAL?
+					  <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					  ,W?PERIOD ,W?THEN>>
+				     <CANT-USE .PTR>
+				     <RFALSE>)
+				    (T
+				     <SET OF-FLAG <>>)>)
+			     (<NOT <ZERO? <WT? .WRD ,PS?BUZZ-WORD>>>)
+			     (<AND <EQUAL? .VERB ,ACT?TELL>
+				   <NOT <ZERO? <WT? .WRD ,PS?VERB ,P1?VERB>>>
+				   ;"Next expr added to fix FORD, TELL ME WHY"
+				   ;"NOT taken out of said expr to fix fix"
+				   <EQUAL? ,WINNER ,PLAYER>>
+			      <TELL
+"Please consult your manual for the correct way to talk to characters." CR>
+			      <RFALSE>)
+			     (T
+			      <CANT-USE .PTR>
+			      <RFALSE>)>)
+		      (T
+		       <UNKNOWN-WORD .PTR>
+		       <RFALSE>)>
+		<SET LW .WRD>
+		<SET PTR <+ .PTR ,P-LEXELEN>>>)>
+	<PUT ,OOPS-TABLE ,O-PTR <>>
+	<COND (.DIR
+	       <SETG PRSA ,V?WALK>
+	       <SETG PRSO .DIR>
+	       <SETG P-OFLAG <>>
+	       <SETG P-WALK-DIR .DIR>
+	       <SETG AGAIN-DIR .DIR>)
+	      (ELSE
+	       <COND (,P-OFLAG <ORPHAN-MERGE>)>
+	       <SETG P-WALK-DIR <>>
+	       <SETG AGAIN-DIR <>>
+	       <COND (<AND <SYNTAX-CHECK>
+			   <SNARF-OBJECTS>
+			   <MANY-CHECK>
+			   <TAKE-CHECK>>
+		      T)>)>>
+
+<ROUTINE BEG-PARDON () <TELL "I beg your pardon?" CR>>
+
+<GLOBAL P-ACT <>>
+
+<ROUTINE KNOWN-WORD? (PTR "OPTIONAL" (VERB <>) "AUX" (WRD <>))
+	 <OR <SET WRD <GET ,P-LEXV .PTR>>
+	     <SET WRD <QUOTED-WORD? .PTR .VERB>>
+	     <SET WRD <NUMBER? .PTR>>>
+	 .WRD>
+
+<ROUTINE CHANGE-LEXV (PTR WRD)
+	 <PUT ,P-LEXV .PTR .WRD>
+	 <PUT ,AGAIN-LEXV .PTR .WRD>>
+
+<GLOBAL P-WALK-DIR <>>
+<GLOBAL AGAIN-DIR <>>
+
+;"For AGAIN purposes, put contents of one LEXV table into another."
+<ROUTINE STUFF (SRC DEST "OPTIONAL" (MAX 29) "AUX" (PTR ,P-LEXSTART) (CTR 1)
+						   BPTR)
+	 <PUTB .DEST 0 <GETB .SRC 0>>
+	 <PUTB .DEST 1 <GETB .SRC 1>>
+	 <REPEAT ()
+	  <PUT .DEST .PTR <GET .SRC .PTR>>
+	  <SET BPTR <+ <* .PTR 2> 2>>
+	  <PUTB .DEST .BPTR <GETB .SRC .BPTR>>
+	  <SET BPTR <+ <* .PTR 2> 3>>
+	  <PUTB .DEST .BPTR <GETB .SRC .BPTR>>
+	  <SET PTR <+ .PTR ,P-LEXELEN>>
+	  <COND (<IGRTR? CTR .MAX>
+		 <RETURN>)>>>
+
+;"Put contents of one INBUF into another"
+<ROUTINE INBUF-STUFF (SRC DEST "AUX" CNT)
+	 <SET CNT <- <GETB .SRC 0> 1>>
+	 <REPEAT ()
+		 <PUTB .DEST .CNT <GETB .SRC .CNT>>
+		 <COND (<DLESS? CNT 0> <RETURN>)>>>
+
+;"Put the word in the positions specified from P-INBUF to the end of
+OOPS-INBUF, leaving the appropriate pointers in AGAIN-LEXV"
+<ROUTINE INBUF-ADD (LEN BEG SLOT "AUX" DBEG (CTR 0) TMP)
+	 <COND (<SET TMP <GET ,OOPS-TABLE ,O-END>>
+		<SET DBEG .TMP>)
+	       (T
+		<SET DBEG <+ <GETB ,AGAIN-LEXV
+				   <SET TMP <GET ,OOPS-TABLE ,O-LENGTH>>>
+			     <GETB ,AGAIN-LEXV <+ .TMP 1>>>>)>
+	 <PUT ,OOPS-TABLE ,O-END <+ .DBEG .LEN>>
+	 <REPEAT ()
+	  <PUTB ,OOPS-INBUF <+ .DBEG .CTR> <GETB ,P-INBUF <+ .BEG .CTR>>>
+	  <SET CTR <+ .CTR 1>>
+	  <COND (<EQUAL? .CTR .LEN> <RETURN>)>>
+	 <PUTB ,AGAIN-LEXV .SLOT .DBEG>
+	 <PUTB ,AGAIN-LEXV <- .SLOT 1> .LEN>>
+
+;"Check whether word pointed at by PTR is the correct part of speech.
+   The second argument is the part of speech (,PS?<part of speech>). The
+   3rd argument (,P1?<part of speech>), if given, causes the value
+   for that part of speech to be returned."
+<ROUTINE WT? (PTR BIT "OPTIONAL" (B1 5) "AUX" (OFFS ,P-P1OFF) TYP)
+	<COND (<BTST <SET TYP <GETB .PTR ,P-PSOFF>> .BIT>
+	       <COND (<G? .B1 4> <RTRUE>)
+		     (T
+		      <SET TYP <BAND .TYP ,P-P1BITS>>
+		      <COND (<NOT <EQUAL? .TYP .B1>> <SET OFFS <+ .OFFS 1>>)>
+		      <GETB .PTR .OFFS>)>)>>
+
+;" Scan through a noun clause, leave a pointer to its starting location"
+<ROUTINE CLAUSE (PTR VAL WRD "AUX" OFF NUM (ANDFLG <>) (1ST? T) NW (LW 0))
+	<SET OFF <* <- ,P-NCN 1> 2>>
+	<COND (<NOT <EQUAL? .VAL 0>>
+	       <PUT ,P-ITBL <SET NUM <+ ,P-PREP1 .OFF>> .VAL>
+	       <PUT ,P-ITBL <+ .NUM 1> .WRD>
+	       <SET PTR <+ .PTR ,P-LEXELEN>>)
+	      (T <SETG P-LEN <+ ,P-LEN 1>>)>
+	<COND (<ZERO? ,P-LEN> <SETG P-NCN <- ,P-NCN 1>> <RETURN -1>)>
+	<PUT ,P-ITBL <SET NUM <+ ,P-NC1 .OFF>> <REST ,P-LEXV <* .PTR 2>>>
+	<COND (<OR <EQUAL? <GET ,P-LEXV .PTR> ,W?THE ,W?A ,W?AN>
+		   <EQUAL? <GET ,P-LEXV .PTR> ,W?$BUZZ>>
+	       <PUT ,P-ITBL .NUM <REST <GET ,P-ITBL .NUM> 4>>)>
+	<REPEAT ()
+		<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
+		       <PUT ,P-ITBL <+ .NUM 1> <REST ,P-LEXV <* .PTR 2>>>
+		       <RETURN -1>)>
+		<COND (<SET WRD <KNOWN-WORD? .PTR>>
+		       <COND (<ZERO? ,P-LEN> <SET NW 0>)
+			     (T <SET NW <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>>)>
+		       <COND (<AND <EQUAL? .WRD ,W?QUOTE>
+				   <NOT <EQUAL? ,P-ACT ,ACT?TELL ,ACT?SAY>>>
+			      <COND (<QUOTED-PHRASE .PTR ,P-ACT>
+				     <SET PTR <+ .PTR ,P-LEXELEN>>
+				     <AGAIN>)
+				    (ELSE <RFALSE>)>)
+			     (<EQUAL? .WRD ,W?AND ,W?COMMA> <SET ANDFLG T>)
+			     (<EQUAL? .WRD ,W?ALL ,W?ONE ,W?BOTH>
+			      <COND (<EQUAL? .NW ,W?OF>
+				     <SETG P-LEN <- ,P-LEN 1>>
+				     <SET PTR <+ .PTR ,P-LEXELEN>>)>)
+			     (<OR <EQUAL? .WRD ,W?THEN ,W?PERIOD>
+				  <AND <NOT <ZERO? <WT? .WRD ,PS?PREPOSITION>>>
+				       <GET ,P-ITBL ,P-VERB>
+				          ;"ADDED 4/27 FOR TURTLE,UP"
+				       <NOT .1ST?>>>
+			      <SETG P-LEN <+ ,P-LEN 1>>
+			      <PUT ,P-ITBL
+				   <+ .NUM 1>
+				   <REST ,P-LEXV <* .PTR 2>>>
+			      <RETURN <- .PTR ,P-LEXELEN>>)
+			     ;"This next clause was 2 clauses further down"
+			     ;"This attempts to fix EDDIE, TURN ON COMPUTER"
+			     (<AND .ANDFLG
+				   <EQUAL? <GET ,P-ITBL ,P-VERB> 0>>
+			      <SET PTR <- .PTR 4>>
+			      <CHANGE-LEXV <+ .PTR 2> ,W?THEN>
+			      <SETG P-LEN <+ ,P-LEN 2>>)
+			     (<NOT <ZERO? <WT? .WRD ,PS?OBJECT>>>
+			      <COND ;"First clause added 1/10/84 to fix
+				      'verb AT synonym OF synonym' bug"
+			            (<AND <G? ,P-LEN 0>
+					  <EQUAL? .NW ,W?OF>
+					  <NOT <EQUAL? .WRD ,W?ALL ,W?ONE>>>
+				     T)
+				    ;"next clause makes 'give troll red book'
+				      have only one noun clause. careful!"
+				    (<AND <NOT <ZERO? <WT? .WRD
+							   ,PS?ADJECTIVE
+							   ,P1?ADJECTIVE>>>
+					  <NOT <EQUAL? .NW 0>>
+					  <OR <WT? .NW ,PS?OBJECT>
+					      <WT? .NW ,PS?ADJECTIVE>>>)
+				    (<AND <EQUAL? .WRD ,W?FORBURN>
+					  <EQUAL? .NW ,W?THE ,W?WILY>>
+				     T)
+				    (<AND <NOT .ANDFLG>
+					  <NOT <EQUAL? .NW ,W?BUT ,W?EXCEPT>>
+					  <NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
+				     <PUT ,P-ITBL
+					  <+ .NUM 1>
+					  <REST ,P-LEXV <* <+ .PTR 2> 2>>>
+				     <RETURN .PTR>)
+				    (T <SET ANDFLG <>>)>)
+			     ;"next clause replaced by following on from games
+			       with characters"
+			     ;(<AND <OR ,P-MERGED
+				       ,P-OFLAG
+				       <NOT <EQUAL? <GET ,P-ITBL ,P-VERB> 0>>>
+				   <OR <WT? .WRD ,PS?ADJECTIVE>
+				       <WT? .WRD ,PS?BUZZ-WORD>>>)
+			     (<OR <NOT <ZERO? <WT? .WRD ,PS?ADJECTIVE>>>
+				  <NOT <ZERO? <WT? .WRD ,PS?BUZZ-WORD>>>>)
+			     (<NOT <ZERO? <WT? .WRD ,PS?PREPOSITION>>> T)
+			     (T
+			      <CANT-USE .PTR>
+			      <RFALSE>)>)
+		      (T <UNKNOWN-WORD .PTR> <RFALSE>)>
+		<SET LW .WRD>
+		<SET 1ST? <>>
+		<SET PTR <+ .PTR ,P-LEXELEN>>>>
+
+<ROUTINE NUMBER? (PTR "AUX" CNT BPTR CHR (SUM 0))
+	 <SET CNT <GETB <REST ,P-LEXV <* .PTR 2>> 2>>
+	 <SET BPTR <GETB <REST ,P-LEXV <* .PTR 2>> 3>>
+	 <REPEAT ()
+		 <COND (<L? <SET CNT <- .CNT 1>> 0> <RETURN>)
+		       (T
+			<SET CHR <GETB ,P-INBUF .BPTR>>
+			<COND (<G? .SUM 10000> <RFALSE>)
+			      (<AND <L? .CHR 58> <G? .CHR 47>>
+			       <SET SUM <+ <* .SUM 10> <- .CHR 48>>>)
+			      (T <RFALSE>)>
+			<SET BPTR <+ .BPTR 1>>)>>
+	 <CHANGE-LEXV .PTR ,W?INTNUM>
+	 <COND (<G? .SUM 10000>
+		<RFALSE>)>
+	 <SETG P-NUMBER .SUM>
+	 ,W?INTNUM>
+
+<GLOBAL P-NUMBER 0>
+
+<GLOBAL P-QWORD <>>
+
+<ROUTINE QUOTED-PHRASE (PTR VERB "AUX" LEN (1ST? T) WRD BPTR)
+	 <CHANGE-LEXV .PTR ,W?$BUZZ>
+	 <SET LEN <- ,P-LEN 1>>
+	 <SET PTR <+ .PTR ,P-LEXELEN>>
+	 <SET BPTR <REST ,P-LEXV <* .PTR 2>>>
+	 <REPEAT ()
+		 <COND (<L? .LEN 0>
+			<TELL "You forgot a second quote." CR>
+			<RFALSE>)
+		       (<EQUAL? <SET WRD <GET ,P-LEXV .PTR>> ,W?QUOTE>
+			<CHANGE-LEXV .PTR ,W?$BUZZ>
+			<RTRUE>)
+		       (.1ST?
+			<COND (<AND .WRD <EQUAL? .VERB ,ACT?SAY ,ACT?ANSWER>>
+			       T)
+			      (<QUOTED-WORD? .PTR .VERB>
+			       <SET 1ST? <>>)
+			      (ELSE
+			       <TELL "There isn't anything here with \"">
+			       <WORD-PRINT <GETB .BPTR 2> <GETB .BPTR 3>>
+			       <TELL "\" written on it." CR>
+			       <RFALSE>)>)
+		       (ELSE ;"was <NOT .WRD>"
+			<CHANGE-LEXV .PTR ,W?$BUZZ>)
+		       ;(ELSE <RETURN>)>
+		 <SET PTR <+ .PTR ,P-LEXELEN>>
+		 <SET LEN <- .LEN 1>>>>
+
+<ROUTINE QUOTED-WORD? (PTR "OPTIONAL" (VERB <>) "AUX" QPTR WRD)
+	 <COND (<AND <EQUAL? .VERB ,ACT?WRITE>
+		     <NOT ,P-QWORD>>
+		<SETG P-QWORD .PTR>
+		<SET WRD ,W?QWORD>)
+	       (<NOT <SET WRD <KNOWN-NAME? .PTR>>>
+		<RFALSE>)>
+	 <CHANGE-LEXV .PTR .WRD>
+	 .WRD>
+
+<ROUTINE KNOWN-NAME? (PTR "AUX" WRD QPTR)
+	 <SET QPTR ,P-QBUF>
+	 <REPEAT ()
+		 <COND (<ZERO? <SET WRD <GET .QPTR 0>>>
+			<RFALSE>)>
+		 <COND (<MATCH? .PTR .QPTR> <RETURN>)>
+		 <SET QPTR <REST .QPTR 10>>>
+	 .WRD>
+
+<ROUTINE MATCH? (PTR QPTR "AUX" CNT BPTR QCNT)
+	 <SET PTR <REST ,P-LEXV <* .PTR 2>>>
+	 <SET CNT <GETB .PTR 2>>
+	 <COND (<G? .CNT 6> <SET CNT 6>)>
+	 <SET BPTR <GETB .PTR 3>>
+	 <SET QCNT <GET .QPTR 1>>
+	 <SET QPTR <REST .QPTR 4>>
+	 <REPEAT ()
+		 <COND (<ZERO? .CNT>
+			<COND (<G? .QCNT 0> <RFALSE>)
+			      (ELSE <RTRUE>)>)
+		       (<NOT <EQUAL? <GETB ,P-INBUF .BPTR>
+				     <GETB .QPTR 0>>>
+			<RFALSE>)
+		       (<DLESS? QCNT 0> <RFALSE>)>
+		 <SET CNT <- .CNT 1>>
+		 <SET QPTR <REST .QPTR>>
+		 <SET BPTR <+ .BPTR 1>>>
+	 <RTRUE>>
+
+<ROUTINE QCOPY (WRD PTR QPTR "AUX" CNT BPTR (QCNT 6))
+	 <SET CNT <GETB <REST ,P-LEXV <* .PTR 2>> 2>>
+	 <COND (<G? .CNT 6> <SET CNT 6>)>
+	 <SET BPTR <GETB <REST ,P-LEXV <* .PTR 2>> 3>>
+	 <PUT .QPTR 0 .WRD>
+	 <PUT .QPTR 1 .CNT>
+	 <SET QPTR <REST .QPTR 4>>
+	 <REPEAT ()
+		 <COND (<L? <SET CNT <- .CNT 1>> 0>
+			<PUTB .QPTR 0 <>>)
+		       (ELSE
+			<PUTB .QPTR 0 <GETB ,P-INBUF .BPTR>>
+			<SET BPTR <+ .BPTR 1>>
+			<SET QPTR <REST .QPTR>>)>
+		 <SET QCNT <- .QCNT 1>>
+		 <COND (<ZERO? .QCNT> <RTRUE>)>>>
+
+<GLOBAL
+ P-QBUF
+ <TABLE <VOC "AZ" ADJ> 2 #BYTE !\x #BYTE !\1 0 0
+	<VOC "BZ" ADJ> 2 #BYTE !\x #BYTE !\2 0 0
+	<VOC "CZ" ADJ> 2 #BYTE !\x #BYTE !\3 0 0
+	<VOC "DZ" ADJ> 2 #BYTE !\x #BYTE !\4 0 0
+	<VOC "EZ" ADJ> 2 #BYTE !\x #BYTE !\5 0 0
+	<VOC "FZ" ADJ> 2 #BYTE !\x #BYTE !\6 0 0
+	<VOC "GZ" ADJ> 2 #BYTE !\x #BYTE !\7 0 0
+	<VOC "HZ" ADJ> 2 #BYTE !\x #BYTE !\8 0 0
+	<VOC "IZ" ADJ> 2 #BYTE !\x #BYTE !\9 0 0
+	<VOC "JZ" ADJ> 3 #BYTE !\x #BYTE !\1 #BYTE !\0 #BYTE 0 0
+	<VOC "KZ" ADJ> 3 #BYTE !\x #BYTE !\1 #BYTE !\1 #BYTE 0 0
+	<VOC "KQ" ADJ> 3 #BYTE !\x #BYTE !\1 #BYTE !\2 #BYTE 0 0 ;"TIME-CUBE"
+	0 0 0 0 0 ;"EARTH"
+	0 0 0 0 0 ;"WATER"
+	0 0 0 0 0 ;"AIR"
+	0 0 0 0 0 ;"FIRE"
+	0 0 0 0 0 ;"DARK"
+	0 0 0 0 0 ;"MIND"
+	0 0 0 0 0 ;"LIGHT"
+	0 0 0 0 0 ;"LIFE"
+	0 0 0 0 0 ;"DEATH"
+	0 0 0 0 0 ;"CHANGE"
+	0 0 0 0 0 ;"MAGIC"
+	0 0 0 0 0 ;"CONNECTIVITY"
+	0 >>
+<GLOBAL P-QNEXT <>>
+
+
+
+<ROUTINE ORPHAN-MERGE ("AUX" (CNT -1) TEMP VERB BEG END (ADJ <>) WRD)
+   <SETG P-OFLAG <>>
+   <COND (<OR <EQUAL? <WT? <SET WRD <GET <GET ,P-ITBL ,P-VERBN> 0>>
+			   ,PS?VERB ,P1?VERB>
+		      <GET ,P-OTBL ,P-VERB>>
+	      <NOT <ZERO? <WT? .WRD ,PS?ADJECTIVE>>>>
+	  <SET ADJ T>)
+	 (<AND <NOT <ZERO? <WT? .WRD ,PS?OBJECT ,P1?OBJECT>>>
+	       <EQUAL? ,P-NCN 0>>
+	  <PUT ,P-ITBL ,P-VERB 0>
+	  <PUT ,P-ITBL ,P-VERBN 0>
+	  <PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
+	  <PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>
+	  <SETG P-NCN 1>)>
+   <COND (<AND <NOT <ZERO? <SET VERB <GET ,P-ITBL ,P-VERB>>>>
+	       <NOT .ADJ>
+	       <NOT <EQUAL? .VERB <GET ,P-OTBL ,P-VERB>>>>
+	  <RFALSE>)
+	 (<EQUAL? ,P-NCN 2> <RFALSE>)
+	 (<EQUAL? <GET ,P-OTBL ,P-NC1> 1>
+	  <COND (<OR <EQUAL? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
+			  <GET ,P-OTBL ,P-PREP1>>
+		     <ZERO? .TEMP>>
+		 <COND (.ADJ
+			<PUT ,P-OTBL ,P-NC1 <REST ,P-LEXV 2>>
+			<COND (<ZERO? <GET ,P-ITBL ,P-NC1L>>
+			       <PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>
+			<COND (<ZERO? ,P-NCN> <SETG P-NCN 1>)>)
+		       (T
+			<PUT ,P-OTBL ,P-NC1 <GET ,P-ITBL ,P-NC1>>)>
+		 <PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)
+		(T <RFALSE>)>)
+	 (<EQUAL? <GET ,P-OTBL ,P-NC2> 1>
+	  <COND (<OR <EQUAL? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
+			  <GET ,P-OTBL ,P-PREP2>>
+		     <ZERO? .TEMP>>
+		 <COND (.ADJ
+			<PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
+			<COND (<ZERO? <GET ,P-ITBL ,P-NC1L>>
+			       <PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>)>
+		 <PUT ,P-OTBL ,P-NC2 <GET ,P-ITBL ,P-NC1>>
+		 <PUT ,P-OTBL ,P-NC2L <GET ,P-ITBL ,P-NC1L>>
+		 <SETG P-NCN 2>)
+		(T <RFALSE>)>)
+	 (,P-ACLAUSE
+	  <COND (<AND <NOT <EQUAL? ,P-NCN 1>> <NOT .ADJ>>
+		 <SETG P-ACLAUSE <>>
+		 <RFALSE>)
+		(T
+		 <SET BEG <GET ,P-ITBL ,P-NC1>>
+		 <COND (.ADJ <SET BEG <REST ,P-LEXV 2>> <SET ADJ <>>)>
+		 <SET END <GET ,P-ITBL ,P-NC1L>>
+		 <REPEAT ()
+			 <SET WRD <GET .BEG 0>>
+			 <COND (<EQUAL? .BEG .END>
+				<COND (.ADJ <ACLAUSE-WIN .ADJ> <RETURN>)
+				      (T <SETG P-ACLAUSE <>> <RFALSE>)>)
+			       (<AND <NOT .ADJ>
+				     <OR <BTST <GETB .WRD ,P-PSOFF>
+					       ,PS?ADJECTIVE> ;"same as WT?"
+					 <EQUAL? .WRD ,W?ALL ,W?ONE>>>
+				<SET ADJ .WRD>)
+			       (<EQUAL? .WRD ,W?ONE>
+				<ACLAUSE-WIN .ADJ>
+				<RETURN>)
+			       (<BTST <GETB .WRD ,P-PSOFF> ,PS?OBJECT>
+				<COND (<EQUAL? .WRD ,P-ANAM>
+				       <ACLAUSE-WIN .ADJ>)
+				      (T
+				       <NCLAUSE-WIN>)>
+				<RETURN>)>
+			 <SET BEG <REST .BEG ,P-WORDLEN>>
+			 <COND (<EQUAL? .END 0>
+				<SET END .BEG>
+				<SETG P-NCN 1>
+				<PUT ,P-ITBL ,P-NC1 <BACK .BEG 4>>
+				<PUT ,P-ITBL ,P-NC1L .BEG>)>>)>)>
+   <PUT ,P-VTBL 0 <GET ,P-OVTBL 0>>
+   <PUTB ,P-VTBL 2 <GETB ,P-OVTBL 2>>
+   <PUTB ,P-VTBL 3 <GETB ,P-OVTBL 3>>
+   <PUT ,P-OTBL ,P-VERBN ,P-VTBL>
+   <PUTB ,P-VTBL 2 0>
+   ;<AND <NOT <EQUAL? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
+   <REPEAT ()
+	   <COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN>
+		  <SETG P-MERGED T>
+		  <RTRUE>)
+		 (T <PUT ,P-ITBL .CNT <GET ,P-OTBL .CNT>>)>>
+   T>
+
+<ROUTINE ACLAUSE-WIN (ADJ)
+	<PUT ,P-ITBL ,P-VERB <GET ,P-OTBL ,P-VERB>>
+	<PUT ,P-CCTBL ,CC-SBPTR ,P-ACLAUSE>
+	<PUT ,P-CCTBL ,CC-SEPTR <+ ,P-ACLAUSE 1>>
+	<PUT ,P-CCTBL ,CC-DBPTR ,P-ACLAUSE>
+	<PUT ,P-CCTBL ,CC-DEPTR <+ ,P-ACLAUSE 1>>
+	<CLAUSE-COPY ,P-OTBL ,P-OTBL .ADJ>
+	<AND <NOT <EQUAL? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
+	<SETG P-ACLAUSE <>>
+	<RTRUE>>
+
+<ROUTINE NCLAUSE-WIN ()
+        <PUT ,P-CCTBL ,CC-SBPTR ,P-NC1>
+	<PUT ,P-CCTBL ,CC-SEPTR ,P-NC1L>
+	<PUT ,P-CCTBL ,CC-DBPTR ,P-ACLAUSE>
+	<PUT ,P-CCTBL ,CC-DEPTR <+ ,P-ACLAUSE 1>>
+	<CLAUSE-COPY ,P-ITBL ,P-OTBL>
+	<AND <NOT <EQUAL? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
+	<SETG P-ACLAUSE <>>
+	<RTRUE>>
+
+;"Print undefined word in input.
+   PTR points to the unknown word in P-LEXV"
+
+<ROUTINE WORD-PRINT (CNT BUF)
+	 <REPEAT ()
+		 <COND (<DLESS? CNT 0> <RETURN>)
+		       (ELSE
+			<PRINTC <GETB ,P-INBUF .BUF>>
+			<SET BUF <+ .BUF 1>>)>>>
+
+<ROUTINE UNKNOWN-WORD (PTR "AUX" BUF)
+	<PUT ,OOPS-TABLE ,O-PTR .PTR>
+	<TELL "I don't know the word \"">
+	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
+		    <GETB <REST ,P-LEXV .BUF> 3>>
+	<TELL ".\"" CR>
+	<SETG QUOTE-FLAG <>>
+	<SETG P-OFLAG <>>>
+
+<ROUTINE CANT-USE (PTR "AUX" BUF)
+	<TELL "You used the word \"">
+	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
+		    <GETB <REST ,P-LEXV .BUF> 3>>
+	<TELL "\" in a way that I don't understand." CR>
+	<SETG QUOTE-FLAG <>>
+	<SETG P-OFLAG <>>>
+
+;" Perform syntax matching operations, using P-ITBL as the source of
+   the verb and adjectives for this input. Returns false if no
+   syntax matches, and does it's own orphaning. If return is true,
+   the syntax is saved in P-SYNTAX."
+
+<GLOBAL P-SLOCBITS 0>
+
+<CONSTANT P-SYNLEN 8>
+
+<CONSTANT P-SBITS 0>
+
+<CONSTANT P-SPREP1 1>
+
+<CONSTANT P-SPREP2 2>
+
+<CONSTANT P-SFWIM1 3>
+
+<CONSTANT P-SFWIM2 4>
+
+<CONSTANT P-SLOC1 5>
+
+<CONSTANT P-SLOC2 6>
+
+<CONSTANT P-SACTION 7>
+
+<CONSTANT P-SONUMS 3>
+
+
+<ROUTINE SYNTAX-CHECK
+	("AUX" SYN LEN NUM OBJ (DRIVE1 <>) (DRIVE2 <>) PREP VERB TMP)
+	<COND (<ZERO? <SET VERB <GET ,P-ITBL ,P-VERB>>>
+	       <TELL "There was no verb in that sentence!" CR>
+	       <RFALSE>)>
+	<SET SYN <GET ,VERBS <- 255 .VERB>>>
+	<SET LEN <GETB .SYN 0>>
+	<SET SYN <REST .SYN>>
+	<REPEAT ()
+		<SET NUM <BAND <GETB .SYN ,P-SBITS> ,P-SONUMS>>
+		<COND (<G? ,P-NCN .NUM> T)
+		      (<AND <NOT <L? .NUM 1>>
+			    <ZERO? ,P-NCN>
+			    <OR <ZERO? <SET PREP <GET ,P-ITBL ,P-PREP1>>>
+				<EQUAL? .PREP <GETB .SYN ,P-SPREP1>>>>
+		       <SET DRIVE1 .SYN>)
+		      (<EQUAL? <GETB .SYN ,P-SPREP1> <GET ,P-ITBL ,P-PREP1>>
+		       <COND (<AND <EQUAL? .NUM 2> <EQUAL? ,P-NCN 1>>
+			      <SET DRIVE2 .SYN>)
+			     (<EQUAL? <GETB .SYN ,P-SPREP2>
+				      <GET ,P-ITBL ,P-PREP2>>
+			      <SYNTAX-FOUND .SYN>
+			      <RTRUE>)>)>
+		<COND (<DLESS? LEN 1>
+		       <COND (<OR .DRIVE1 .DRIVE2> <RETURN>)
+			     (T
+			      <TELL ,NOT-RECOGNIZED CR>
+			      <RFALSE>)>)
+		      (T <SET SYN <REST .SYN ,P-SYNLEN>>)>>
+	<COND (<AND .DRIVE1
+		    <SET OBJ
+			 <GWIM <GETB .DRIVE1 ,P-SFWIM1>
+			       <GETB .DRIVE1 ,P-SLOC1>
+			       <GETB .DRIVE1 ,P-SPREP1>>>>
+	       <PUT ,P-PRSO ,P-MATCHLEN 1>
+	       <PUT ,P-PRSO 1 .OBJ>
+	       <SYNTAX-FOUND .DRIVE1>)
+	      (<AND .DRIVE2
+		    <SET OBJ
+			 <GWIM <GETB .DRIVE2 ,P-SFWIM2>
+			       <GETB .DRIVE2 ,P-SLOC2>
+			       <GETB .DRIVE2 ,P-SPREP2>>>>
+	       <PUT ,P-PRSI ,P-MATCHLEN 1>
+	       <PUT ,P-PRSI 1 .OBJ>
+	       <SYNTAX-FOUND .DRIVE2>)
+	      (<EQUAL? .VERB ,ACT?FIND ;,ACT?WHAT>
+	       <TELL "I can't answer that question." CR>
+	       <RFALSE>)
+	      (<NOT <EQUAL? ,WINNER ,PLAYER>>
+	       <TELL ,CANT-ORPHAN CR>
+	       <RFALSE>)
+	      (T
+	       <ORPHAN .DRIVE1 .DRIVE2>
+	       <TELL "What do you want to ">
+	       <SET TMP <GET ,P-OTBL ,P-VERBN>>
+	       <COND (<EQUAL? .TMP 0>
+		      <TELL "tell">)
+		     (<ZERO? <GETB ,P-VTBL 2>>
+		      <PRINTB <GET .TMP 0>>)
+		     (T
+		      <WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
+		      <PUTB ,P-VTBL 2 0>)>
+	       <COND (.DRIVE2
+		      <TELL " ">
+		      <THING-PRINT T T>)>
+	       <SETG P-OFLAG T>
+	       <PREP-PRINT <COND (.DRIVE1 <GETB .DRIVE1 ,P-SPREP1>)
+				 (T <GETB .DRIVE2 ,P-SPREP2>)>>
+	       <TELL "?" CR>
+	       <RFALSE>)>>
+
+<GLOBAL NOT-RECOGNIZED "That sentence isn't one I recognize.">
+
+<GLOBAL CANT-ORPHAN "I don't understand. What are you referring to?">
+
+<ROUTINE ORPHAN (D1 D2 "AUX" (CNT -1))
+	<COND (<NOT ,P-MERGED>
+	       <PUT ,P-OCLAUSE ,P-MATCHLEN 0>)>
+	<PUT ,P-OVTBL 0 <GET ,P-VTBL 0>>
+	<PUTB ,P-OVTBL 2 <GETB ,P-VTBL 2>>
+	<PUTB ,P-OVTBL 3 <GETB ,P-VTBL 3>>
+	<REPEAT ()
+		<COND (<IGRTR? CNT ,P-ITBLLEN> <RETURN>)
+		      (T <PUT ,P-OTBL .CNT <GET ,P-ITBL .CNT>>)>>
+	<COND (<EQUAL? ,P-NCN 2>
+	       <PUT ,P-CCTBL ,CC-SBPTR ,P-NC2>
+	       <PUT ,P-CCTBL ,CC-SEPTR ,P-NC2L>
+	       <PUT ,P-CCTBL ,CC-DBPTR ,P-NC2>
+	       <PUT ,P-CCTBL ,CC-DEPTR ,P-NC2L>
+	       <CLAUSE-COPY ,P-ITBL ,P-OTBL>)>
+	<COND (<NOT <L? ,P-NCN 1>>
+	       <PUT ,P-CCTBL ,CC-SBPTR ,P-NC1>
+	       <PUT ,P-CCTBL ,CC-SEPTR ,P-NC1L>
+	       <PUT ,P-CCTBL ,CC-DBPTR ,P-NC1>
+	       <PUT ,P-CCTBL ,CC-DEPTR ,P-NC1L>
+	       <CLAUSE-COPY ,P-ITBL ,P-OTBL>)>
+	<COND (.D1
+	       <PUT ,P-OTBL ,P-PREP1 <GETB .D1 ,P-SPREP1>>
+	       <PUT ,P-OTBL ,P-NC1 1>)
+	      (.D2
+	       <PUT ,P-OTBL ,P-PREP2 <GETB .D2 ,P-SPREP2>>
+	       <PUT ,P-OTBL ,P-NC2 1>)>>
+
+<ROUTINE ORPHAN-VERB (WRD ACT)
+	 <PUT ,P-VTBL 0 .WRD>
+	 <PUT ,P-OTBL ,P-VERB .ACT>
+	 <PUT ,P-OTBL ,P-VERBN ,P-VTBL>
+	 <PUT ,P-OTBL ,P-PREP1 0>
+	 <PUT ,P-OTBL ,P-PREP1N 0>
+	 <PUT ,P-OTBL ,P-PREP2 0>
+	 <PUT ,P-OTBL 5 0>
+	 <PUT ,P-OTBL ,P-NC1 1>
+	 <PUT ,P-OTBL ,P-NC1L 0>
+	 <PUT ,P-OTBL ,P-NC2 0>
+	 <PUT ,P-OTBL ,P-NC2L 0>
+	 <SETG P-OFLAG T>>
+
+<ROUTINE THING-PRINT (PRSO? "OPTIONAL" (THE? <>) "AUX" BEG END)
+	 <COND (.PRSO?
+		<SET BEG <GET ,P-ITBL ,P-NC1>>
+		<SET END <GET ,P-ITBL ,P-NC1L>>)
+	       (ELSE
+		<SET BEG <GET ,P-ITBL ,P-NC2>>
+		<SET END <GET ,P-ITBL ,P-NC2L>>)>
+	 <BUFFER-PRINT .BEG .END .THE?>>
+
+<ROUTINE BUFFER-PRINT (BEG END CP "AUX" (NOSP T) WRD (1ST? T) (PN <>) (Q? <>))
+	 <REPEAT ()
+		<COND (<EQUAL? .BEG .END> <RETURN>)
+		      (T
+		       <SET WRD <GET .BEG 0>>
+		       <COND (<EQUAL? .WRD ,W?$BUZZ> T)
+			     (<EQUAL? .WRD ,W?COMMA>
+			      <TELL ", ">)
+			     (.NOSP <SET NOSP <>>)
+			     (ELSE <TELL " ">)>
+		       <COND (<EQUAL? .WRD ,W?PERIOD ,W?$BUZZ ,W?COMMA>
+			      <SET NOSP T>)
+			     (<EQUAL? .WRD ,W?ME>
+			      <PRINTD ,ME>
+			      <SET PN T>)
+			     (<EQUAL? .WRD ,W?INTNUM>
+			      <PRINTN ,P-NUMBER>
+			      <SET PN T>)
+			     (<NAME? .WRD>
+			      <CAPITALIZE .BEG>
+			      <SET PN T>)
+			     (T
+			      <COND (<AND .1ST? <NOT .PN> .CP>
+				     <TELL "the ">)>
+			      <COND (<OR ,P-OFLAG ,P-MERGED>
+				     <COND (<SET Q? <ZMEMQ .WRD ,CUBE-LIST 47>>
+					    <CUBE-NAME <GET <BACK .Q? 2> 0>>)
+					   (ELSE <PRINTB .WRD>)>)
+				    (<AND <EQUAL? .WRD ,W?IT>
+					  <ACCESSIBLE? ,P-IT-OBJECT>>
+				     <PRINTD ,P-IT-OBJECT>)
+				    (T
+				     <COND (<SET Q? <CUBE-NAME? .WRD>>
+					    <PRINTI "\"">)>
+				     <WORD-PRINT <GETB .BEG 2>
+						 <GETB .BEG 3>>
+				     <COND (.Q? <PRINTI "\"">)>)>
+			      <SET 1ST? <>>)>)>
+		<SET BEG <REST .BEG ,P-WORDLEN>>>>
+
+<ROUTINE CUBE-NAME? (WRD "AUX" QWRD QPTR)
+	 <COND (<EQUAL? .WRD ,W?QWORD> <RTRUE>)>
+	 <SET QPTR ,P-QBUF>
+	 <REPEAT ()
+		 <COND (<ZERO? <SET QWRD <GET .QPTR 0>>>
+			<RFALSE>)
+		       (<EQUAL? .QWRD .WRD>
+			<RTRUE>)>
+		 <SET QPTR <REST .QPTR 10>>>>
+
+<ROUTINE NAME? (WRD)
+	 <COND (<OR <EQUAL? .WRD ,W?BELBOZ ,W?ARDIS ,W?ORKAN>
+		    <EQUAL? .WRD ,W?GZORNENPLATZ ,W?SNEFFLE ,W?HOOBLY>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE CAPITALIZE (PTR)
+	 <COND (<OR ,P-OFLAG ,P-MERGED>
+		<PRINTB <GET .PTR 0>>)
+	       (T
+		<PRINTC <- <GETB ,P-INBUF <GETB .PTR 3>> 32>>
+		<WORD-PRINT <- <GETB .PTR 2> 1> <+ <GETB .PTR 3> 1>>)>>
+
+<ROUTINE PREP-PRINT (PREP "AUX" WRD)
+	<COND (<NOT <ZERO? .PREP>>
+	       <TELL " ">
+	       <COND (<EQUAL? .PREP ,PR?THROUGH>
+		      <TELL "through">)
+		     (T
+		      <SET WRD <PREP-FIND .PREP>>
+		      <PRINTB .WRD>)>)>>
+
+<ROUTINE CLAUSE-COPY (SRC DEST "OPTIONAL" (INSRT <>) "AUX" BEG END)
+	<SET BEG <GET .SRC <GET ,P-CCTBL ,CC-SBPTR>>>
+	<SET END <GET .SRC <GET ,P-CCTBL ,CC-SEPTR>>>
+	<PUT .DEST
+	     <GET ,P-CCTBL ,CC-DBPTR>
+	     <REST ,P-OCLAUSE
+		   <+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN> 2>>>
+	<REPEAT ()
+		<COND (<EQUAL? .BEG .END>
+		       <PUT .DEST
+			    <GET ,P-CCTBL ,CC-DEPTR>
+			    <REST ,P-OCLAUSE
+				  <+ <* <GET ,P-OCLAUSE ,P-MATCHLEN>
+					,P-LEXELEN>
+				     2>>>
+		       <RETURN>)
+		      (T
+		       <COND (<AND .INSRT <EQUAL? ,P-ANAM <GET .BEG 0>>>
+			      <CLAUSE-ADD .INSRT>)>
+		       <CLAUSE-ADD <GET .BEG 0>>)>
+		<SET BEG <REST .BEG ,P-WORDLEN>>>>
+
+
+<ROUTINE CLAUSE-ADD (WRD "AUX" PTR)
+	<SET PTR <+ <GET ,P-OCLAUSE ,P-MATCHLEN> 2>>
+	<PUT ,P-OCLAUSE <- .PTR 1> .WRD>
+	<PUT ,P-OCLAUSE .PTR 0>
+	<PUT ,P-OCLAUSE ,P-MATCHLEN .PTR>>
+
+<ROUTINE PREP-FIND (PREP "AUX" (CNT 0) SIZE)
+	<SET SIZE <* <GET ,PREPOSITIONS 0> 2>>
+	<REPEAT ()
+		<COND (<IGRTR? CNT .SIZE> <RFALSE>)
+		      (<EQUAL? <GET ,PREPOSITIONS .CNT> .PREP>
+		       <RETURN <GET ,PREPOSITIONS <- .CNT 1>>>)>>>
+
+<ROUTINE SYNTAX-FOUND (SYN)
+	<SETG P-SYNTAX .SYN>
+	<SETG PRSA <GETB .SYN ,P-SACTION>>>
+
+<GLOBAL P-GWIMBIT 0>
+
+<ROUTINE GWIM (GBIT LBIT PREP "AUX" OBJ)
+	<COND (<EQUAL? .GBIT ,RLANDBIT>
+	       <RETURN ,ROOMS>)>
+	<SETG P-GWIMBIT .GBIT>
+	<SETG P-SLOCBITS .LBIT>
+	<PUT ,P-MERGE ,P-MATCHLEN 0>
+	<COND (<GET-OBJECT ,P-MERGE <>>
+	       <SETG P-GWIMBIT 0>
+	       <COND (<EQUAL? <GET ,P-MERGE ,P-MATCHLEN> 1>
+		      <SET OBJ <GET ,P-MERGE 1>>
+		      <TELL "(">
+		      <COND (<AND <NOT <ZERO? .PREP>>
+				  <NOT ,P-END-ON-PREP>>
+			     <PRINTB <SET PREP <PREP-FIND .PREP>>>
+			     <COND (<EQUAL? .PREP ,W?OUT>
+				    <TELL " of">)>
+			     <TELL " ">
+			     <COND (<EQUAL? .OBJ ,HANDS>
+				    <TELL D .OBJ>)
+				   (ELSE
+				    <TELL THE .OBJ>)>
+			     <TELL ")" CR>)
+			    (ELSE
+			     <TELL D .OBJ ")" CR>)>
+		      .OBJ)>)
+	      (T <SETG P-GWIMBIT 0> <RFALSE>)>>
+
+<ROUTINE SNARF-OBJECTS ("AUX" OPTR IPTR L)
+	 <PUT ,P-BUTS ,P-MATCHLEN 0>
+	 <COND (<NOT <EQUAL? <SET IPTR <GET ,P-ITBL ,P-NC2>> 0>>
+		<SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC2>>
+		<OR <SNARFEM .IPTR <GET ,P-ITBL ,P-NC2L> ,P-PRSI> <RFALSE>>)>
+	 <COND (<NOT <EQUAL? <SET OPTR <GET ,P-ITBL ,P-NC1>> 0>>
+		<SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC1>>
+		<OR <SNARFEM .OPTR <GET ,P-ITBL ,P-NC1L> ,P-PRSO> <RFALSE>>)>
+	 <COND (<NOT <ZERO? <GET ,P-BUTS ,P-MATCHLEN>>>
+		<SET L <GET ,P-PRSO ,P-MATCHLEN>>
+		<COND (.OPTR <SETG P-PRSO <BUT-MERGE ,P-PRSO>>)>
+		<COND (<AND .IPTR
+			    <OR <NOT .OPTR>
+				<EQUAL? .L <GET ,P-PRSO ,P-MATCHLEN>>>>
+		       <SETG P-PRSI <BUT-MERGE ,P-PRSI>>)>)>
+	 <RTRUE>>
+
+%<DEBUG-CODE
+  <ROUTINE TELL-LIST (TBL NUM "AUX" (CNT 1))
+	   <COND (<ZERO? .NUM> <TELL "<>">)
+		 (ELSE
+		  <REPEAT ()
+			  <PRINTD <GET .TBL .CNT>>
+			  <SET CNT <+ .CNT 1>>
+			  <COND (<G? .CNT .NUM> <RETURN>)>
+			  <PRINTI ", ">>)>>>
+
+
+<ROUTINE BUT-MERGE (TBL "AUX" LEN BUTLEN (CNT 1) (MATCHES 0) OBJ NTBL)
+	<SET LEN <GET .TBL ,P-MATCHLEN>>
+	<PUT ,P-MERGE ,P-MATCHLEN 0>
+	<REPEAT ()
+		<COND (<DLESS? LEN 0> <RETURN>)
+		      (<ZMEMQ <SET OBJ <GET .TBL .CNT>> ,P-BUTS>)
+		      (T
+		       <PUT ,P-MERGE <+ .MATCHES 1> .OBJ>
+		       <SET MATCHES <+ .MATCHES 1>>)>
+		<SET CNT <+ .CNT 1>>>
+	<PUT ,P-MERGE ,P-MATCHLEN .MATCHES>
+	<SET NTBL ,P-MERGE>
+	<SETG P-MERGE .TBL>
+	.NTBL>
+
+<GLOBAL P-NAM <>>
+
+<GLOBAL P-ADJ <>>
+
+<GLOBAL P-ADVERB <>>
+
+<GLOBAL P-ADJN <>>
+
+<GLOBAL P-PRSO <ITABLE NONE 80>>
+
+<GLOBAL P-PRSI <ITABLE NONE 80>>
+
+<GLOBAL P-BUTS <ITABLE NONE 80>>
+
+<GLOBAL P-MERGE <ITABLE NONE 80>>
+
+<GLOBAL P-OCLAUSE <ITABLE NONE 80>>
+
+<GLOBAL P-MATCHLEN 0>
+
+<GLOBAL P-GETFLAGS 0>
+
+<CONSTANT P-ALL 1>
+
+<CONSTANT P-ONE 2>
+
+<CONSTANT P-INHIBIT 4>
+
+
+<ROUTINE SNARFEM (PTR EPTR TBL "AUX" (BUT <>) LEN WV WRD NW (WAS-ALL <>))
+   <SETG P-AND <>>
+   <COND (<EQUAL? ,P-GETFLAGS ,P-ALL>
+	  <SET WAS-ALL T>)>
+   <SETG P-GETFLAGS 0>
+   <PUT .TBL ,P-MATCHLEN 0>
+   <SET WRD <GET .PTR 0>>
+   <REPEAT ()
+	   <COND (<EQUAL? .PTR .EPTR>
+		  <SET WV <GET-OBJECT <OR .BUT .TBL>>>
+		  <COND (.WAS-ALL <SETG P-GETFLAGS ,P-ALL>)>
+		  <RETURN .WV>)
+		 (T
+		  <SET NW <GET .PTR ,P-LEXELEN>>
+		  <COND (<EQUAL? .WRD ,W?ALL ,W?BOTH>
+			 <SETG P-GETFLAGS ,P-ALL>
+			 <COND (<EQUAL? .NW ,W?OF>
+				<SET PTR <REST .PTR ,P-WORDLEN>>)>)
+			(<EQUAL? .WRD ,W?BUT ,W?EXCEPT>
+			 <OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+			 <SET BUT ,P-BUTS>
+			 <PUT .BUT ,P-MATCHLEN 0>)
+			(<EQUAL? .WRD ,W?A ,W?ONE>
+			 <COND (<NOT ,P-ADJ>
+				<SETG P-GETFLAGS ,P-ONE>
+				<COND (<EQUAL? .NW ,W?OF>
+				       <SET PTR <REST .PTR ,P-WORDLEN>>)>)
+			       (T
+				<SETG P-NAM ,P-ONEOBJ>
+				<OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+				<AND <ZERO? .NW> <RTRUE>>)>)
+			(<AND <EQUAL? .WRD ,W?AND ,W?COMMA>
+			      <NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
+			 <SETG P-AND T>
+			 <OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+			 T)
+			(<NOT <ZERO? <WT? .WRD ,PS?BUZZ-WORD>>>)
+			(<EQUAL? .WRD ,W?AND ,W?COMMA>)
+			(<EQUAL? .WRD ,W?OF>
+			 <COND (<ZERO? ,P-GETFLAGS>
+				<SETG P-GETFLAGS ,P-INHIBIT>)>)
+			(<AND <NOT <ZERO?
+				     <SET WV
+					  <WT? .WRD
+					       ,PS?ADJECTIVE ,P1?ADJECTIVE>>>>
+			      <NOT ,P-ADJ>>
+			 ;"make 'learn <spell>' work (pdl 5/7/85)"
+			 <SETG P-ADJ .WV>
+			 <SETG P-ADJN .WRD>)
+			(<WT? .WRD ,PS?OBJECT ,P1?OBJECT>
+			 <SETG P-NAM .WRD>
+			 <SETG P-ONEOBJ .WRD>)>)>
+	   <COND (<NOT <EQUAL? .PTR .EPTR>>
+		  <SET PTR <REST .PTR ,P-WORDLEN>>
+		  <SET WRD .NW>)>>>
+
+<CONSTANT SH 128>
+
+<CONSTANT SC 64>
+
+<CONSTANT SIR 32>
+
+<CONSTANT SOG 16>
+
+<CONSTANT STAKE 8>
+
+<CONSTANT SMANY 4>
+
+<CONSTANT SHAVE 2>
+
+<GLOBAL NOUN-MISSING "There seems to be a noun missing in that sentence.">
+
+<ROUTINE GET-OBJECT (TBL "OPTIONAL" (VRB T)
+		        "AUX" GEN BITS LEN XBITS TLEN (GCHECK <>) (OLEN 0) OBJ)
+	 <SET XBITS ,P-SLOCBITS>
+	 <SET TLEN <GET .TBL ,P-MATCHLEN>>
+	 <COND (<BTST ,P-GETFLAGS ,P-INHIBIT> <RTRUE>)>
+	 <COND (<AND <NOT ,P-NAM>
+		     ,P-ADJ
+		     <NOT <ZERO? <WT? ,P-ADJN ,PS?OBJECT ,P1?OBJECT>>>>
+		<SETG P-NAM ,P-ADJN>
+		<SETG P-ADJ <>>)>
+	 <COND (<AND <NOT ,P-NAM>
+		     <NOT ,P-ADJ>
+		     <NOT <EQUAL? ,P-GETFLAGS ,P-ALL>>
+		     <ZERO? ,P-GWIMBIT>>
+		<COND (.VRB
+		       <TELL ,NOUN-MISSING CR>)>
+		<RFALSE>)>
+	 <COND (<OR <NOT <EQUAL? ,P-GETFLAGS ,P-ALL>> <ZERO? ,P-SLOCBITS>>
+		<SETG P-SLOCBITS -1>)>
+	 <SETG P-TABLE .TBL>
+	 <PROG ()
+	       <COND (.GCHECK <GLOBAL-CHECK .TBL>)
+		     (T
+		      <COND (,LIT
+			     <FCLEAR ,PLAYER ,TRANSBIT>
+			     <DO-SL ,HERE ,SOG ,SIR>
+			     <COND (<AND <FSET? <LOC ,PLAYER> ,VEHBIT>
+					 <NOT <FSET? <LOC ,PLAYER> ,OPENBIT>>>
+				    <DO-SL <LOC ,PLAYER> ,SOG ,SIR>)>
+			     <FSET ,PLAYER ,TRANSBIT>)>
+		      <DO-SL ,PLAYER ,SH ,SC>)>
+	       <SET LEN <- <GET .TBL ,P-MATCHLEN> .TLEN>>
+	       <COND (<BTST ,P-GETFLAGS ,P-ALL> ;<AND * <NOT <EQUAL? .LEN 0>>>)
+		     (<AND <BTST ,P-GETFLAGS ,P-ONE>
+			   <NOT <ZERO? .LEN>>>
+		      <COND (<NOT <EQUAL? .LEN 1>>
+			     <PUT .TBL 1 <GET .TBL <RANDOM .LEN>>>
+			     <TELL "(How about " THE <GET .TBL 1> "?)" CR>)>
+		      <PUT .TBL ,P-MATCHLEN 1>)
+		     (<OR <G? .LEN 1>
+			  <AND <ZERO? .LEN> <NOT <EQUAL? ,P-SLOCBITS -1>>>>
+		      <COND (<EQUAL? ,P-SLOCBITS -1>
+			     <SETG P-SLOCBITS .XBITS>
+			     <SET OLEN .LEN>
+			     <PUT .TBL
+				  ,P-MATCHLEN
+				  <- <GET .TBL ,P-MATCHLEN> .LEN>>
+			     <AGAIN>)
+			    (T
+			     <COND (<ZERO? .LEN> <SET LEN .OLEN>)>
+			     <COND (<AND <G? .LEN 1>
+					 <GENERIC-OBJECT?>
+					 <GETP <GET .TBL .LEN> ,P?GENERIC>>
+				    %<DEBUG-CODE
+					     <COND (,ZDEBUG
+						    <TELL
+"[GenIn: " D <GET .TBL .LEN> "]" CR>)>>
+				    <COND (<SET GEN
+						<APPLY
+						 <GETP <GET .TBL .LEN>
+						       ,P?GENERIC>
+						 .TBL
+						 .LEN>>
+					   %<DEBUG-CODE
+					     <COND (,ZDEBUG
+						    <TELL
+"[GenOut: " D .GEN "]" CR>)>>
+					   <PUT .TBL
+						,P-MATCHLEN
+						<SET LEN <+ .TLEN 1>>>
+					   <PUT .TBL .LEN .GEN>
+					   <SETG P-XNAM ,P-NAM>
+					   <SETG P-XADJ ,P-ADJ>
+					   <SETG P-XADJN ,P-ADJN>
+					   <SETG P-NAM <>>
+					   <SETG P-ADJ <>>
+					   <RTRUE>)
+					  (ELSE
+					   <TELL
+,MORE-SPECIFIC " about which one you mean." CR>
+					   <SETG P-NAM <>>
+					   <SETG P-ADJ <>>
+					   <RFALSE>)>)
+			      	   (<AND .VRB ;".VRB added 8/14/84 by JW"
+					 <NOT <EQUAL? ,WINNER ,PLAYER>>>
+				    <TELL ,CANT-ORPHAN CR>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <RFALSE>)
+				   (<AND .VRB
+					 <OR ,P-NAM ,P-ADJ>>
+				    <WHICH-PRINT .TLEN .LEN .TBL>
+				    <SETG P-ACLAUSE
+					  <COND (<EQUAL? .TBL ,P-PRSO> ,P-NC1)
+						(T ,P-NC2)>>
+				    <SETG P-AADJ ,P-ADJ>
+				    <SETG P-ANAM ,P-NAM>
+				    <ORPHAN <> <>>
+				    <SETG P-OFLAG T>)
+				   (.VRB
+				    <TELL ,NOUN-MISSING CR>)>
+			     <SETG P-NAM <>>
+			     <SETG P-ADJ <>>
+			     <RFALSE>)>)>
+	       <COND (<AND <ZERO? .LEN> .GCHECK>
+		      <COND (.VRB
+			     <SETG P-SLOCBITS .XBITS>
+			     <COND (<OR ,LIT <VERB? TELL WHERE WHAT WHO>>
+				    ;"Changed 6/10/83 - MARC"
+				    <OBJ-FOUND ,NOT-HERE-OBJECT .TBL>
+				    <SETG P-XNAM ,P-NAM>
+				    <SETG P-XADJ ,P-ADJ>
+				    <SETG P-XADJN ,P-ADJN>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <RTRUE>)
+				   (T
+				    <TELL ,TOO-DARK>)>)>
+		      <SETG P-NAM <>>
+		      <SETG P-ADJ <>>
+		      <RFALSE>)
+		     (<ZERO? .LEN> <SET GCHECK T> <AGAIN>)>
+	       <SETG P-SLOCBITS .XBITS>
+	       <SETG P-NAM <>>
+	       <SETG P-ADJ <>>
+	       <RTRUE>>>
+
+<ROUTINE MOBY-FIND (TBL "AUX" FOO LEN GEN)
+	 <SETG P-MOBY-FLAG T>
+	 <SETG P-SLOCBITS -1>
+	 <SETG P-TABLE .TBL>
+	 <SETG P-NAM ,P-XNAM>
+	 <SETG P-ADJ ,P-XADJ>
+	 <PUT .TBL ,P-MATCHLEN 0>
+	 <SET FOO <FIRST? ,ROOMS>>
+	 <REPEAT ()
+		 <COND (<NOT .FOO> <RETURN>)
+		       (T
+			<SEARCH-LIST .FOO .TBL ,P-SRCALL>
+			<SET FOO <NEXT? .FOO>>)>>
+	 <DO-SL ,LOCAL-GLOBALS 1 1>
+	 <SEARCH-LIST ,ROOMS .TBL ,P-SRCTOP>
+	 <COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 1>
+		<SETG P-MOBY-FOUND <GET .TBL 1>>)
+	       (<AND <GENERIC-OBJECT?>
+		     <GETP <GET .TBL .LEN> ,P?GENERIC>>
+		%<DEBUG-CODE
+		  <COND (,ZDEBUG
+			 <TELL
+			  "[GenIn: " D <GET .TBL .LEN> "]" CR>)>>
+		<COND (<SET GEN
+			    <APPLY
+			     <GETP <GET .TBL .LEN>
+				   ,P?GENERIC>
+			     .TBL
+			     .LEN>>
+		       <SET LEN 1>
+		       <SETG P-MOBY-FOUND .GEN>
+		       %<DEBUG-CODE
+			 <COND (,ZDEBUG
+				<TELL
+				 "[GenOut: " D .GEN "]" CR>)>>)>)>
+	 <SETG P-MOBY-FLAG <>>
+	 <SETG P-NAM <>>
+	 <SETG P-ADJ <>>
+	 .LEN>
+
+<GLOBAL P-MOBY-FOUND <>>
+<GLOBAL P-MOBY-FLAG <>>
+<GLOBAL P-XNAM <>>
+<GLOBAL P-XADJ <>>
+<GLOBAL P-XADJN <>>
+
+<ROUTINE WHICH-PRINT (TLEN LEN TBL "AUX" OBJ RLEN)
+	 <SET RLEN .LEN>
+	 <TELL "Which ">
+         <COND (<OR ,P-OFLAG
+		    ,P-MERGED
+		    ,P-AND>
+		<PRINTB <COND (,P-NAM ,P-NAM)
+			      (,P-ADJ ,P-ADJN)
+			      (ELSE ,W?ONE)>>)
+	       (ELSE
+		<THING-PRINT <EQUAL? .TBL ,P-PRSO>>)>
+	 <TELL " do you mean, ">
+	 <REPEAT ()
+		 <SET TLEN <+ .TLEN 1>>
+		 <SET OBJ <GET .TBL .TLEN>>
+		 <TELL THE .OBJ>
+		 <COND (<EQUAL? .LEN 2>
+		        <COND (<NOT <EQUAL? .RLEN 2>>
+			       <TELL ",">)>
+		        <TELL " or ">)
+		       (<G? .LEN 2>
+			<TELL ", ">)>
+		 <COND (<L? <SET LEN <- .LEN 1>> 1>
+		        <TELL "?" CR>
+		        <RETURN>)>>>
+
+
+<ROUTINE GLOBAL-CHECK (TBL "AUX" LEN RMG RMGL (CNT 0) OBJ OBITS FOO)
+	<SET LEN <GET .TBL ,P-MATCHLEN>>
+	<SET OBITS ,P-SLOCBITS>
+	<COND (<SET RMG <GETPT ,HERE ,P?GLOBAL>>
+	       <SET RMGL <- <PTSIZE .RMG> 1>>
+	       <REPEAT ()
+		       <COND (<THIS-IT? <SET OBJ <GETB .RMG .CNT>> .TBL>
+			      <OBJ-FOUND .OBJ .TBL>)>
+		       <COND (<IGRTR? CNT .RMGL> <RETURN>)>>)>
+	<COND (<SET RMG <GETP ,HERE ,P?THINGS>>
+	       <SET RMGL <GET .RMG 0>>
+	       <SET CNT 0>
+	       <REPEAT ()
+		       <COND (<AND <EQUAL? ,P-NAM <GET .RMG <+ .CNT 1>>>
+				   <OR <NOT ,P-ADJ>
+				       <EQUAL? ,P-ADJN
+					       <GET .RMG <+ .CNT 2>>>>>
+			      <SETG P-PNAM ,P-NAM>
+			      <COND (,P-ADJ <SETG P-PADJN ,P-ADJN>)
+				    (ELSE <SETG P-PADJN <>>)>
+			      <SETG LAST-PSEUDO-LOC ,HERE>
+			      <PUTP ,PSEUDO-OBJECT
+				    ,P?ACTION
+				    <GET .RMG <+ .CNT 3>>>
+			      <SET FOO
+				   <BACK <GETPT ,PSEUDO-OBJECT ,P?ACTION> 5>>
+			      <PUT .FOO 0 <GET ,P-NAM 0>>
+			      <PUT .FOO 1 <GET ,P-NAM 1>>
+			      <OBJ-FOUND ,PSEUDO-OBJECT .TBL>
+			      <RETURN>)>
+		       <SET CNT <+ .CNT 3>>
+		       <COND (<NOT <L? .CNT .RMGL>> <RETURN>)>>)>
+	<COND (<EQUAL? <GET .TBL ,P-MATCHLEN> .LEN>
+	       <SETG P-SLOCBITS -1>
+	       <SETG P-TABLE .TBL>
+	       <DO-SL ,GLOBAL-OBJECTS 1 1>
+	       <SETG P-SLOCBITS .OBITS>
+	       ;<COND (<AND <ZERO? <GET .TBL ,P-MATCHLEN>>
+			   <EQUAL? ,PRSA ,V?LOOK-INSIDE ,V?SEARCH ,V?EXAMINE>>
+		      <DO-SL ,ROOMS 1 1>)>)>>
+
+<ROUTINE DO-SL (OBJ BIT1 BIT2 "AUX" BTS)
+	<COND (<BTST ,P-SLOCBITS <+ .BIT1 .BIT2>>
+	       <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCALL>)
+	      (T
+	       <COND (<BTST ,P-SLOCBITS .BIT1>
+		      <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCTOP>)
+		     (<BTST ,P-SLOCBITS .BIT2>
+		      <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCBOT>)
+		     (T <RTRUE>)>)>>
+
+<CONSTANT P-SRCBOT 2>
+
+<CONSTANT P-SRCTOP 0>
+
+<CONSTANT P-SRCALL 1>
+
+<ROUTINE SEARCH-LIST (OBJ TBL LVL "AUX" FLS NOBJ)
+	<COND (<SET OBJ <FIRST? .OBJ>>
+	       <REPEAT ()
+		       <COND (<AND <NOT <EQUAL? .LVL ,P-SRCBOT>>
+				   <GETPT .OBJ ,P?SYNONYM>
+				   <THIS-IT? .OBJ .TBL>>
+			      <OBJ-FOUND .OBJ .TBL>)>
+		       <COND (<AND <OR <NOT <EQUAL? .LVL ,P-SRCTOP>>
+				       <FSET? .OBJ ,SEARCHBIT>
+				       <FSET? .OBJ ,SURFACEBIT>>
+				   <SET NOBJ <FIRST? .OBJ>>>
+			      <COND (<OR ,P-MOBY-FLAG
+					 <FSET? .OBJ ,OPENBIT>
+					 <FSET? .OBJ ,TRANSBIT>>
+				     <SET FLS
+					  <SEARCH-LIST
+					   .OBJ
+					   .TBL
+					   <COND (<OR ,P-MOBY-FLAG
+						      <FSET? .OBJ ,SURFACEBIT>
+						      <FSET? .OBJ ,SEARCHBIT>>
+						  ,P-SRCALL)
+						 (T ,P-SRCTOP)>>>)>)>
+		       <COND (<SET OBJ <NEXT? .OBJ>>) (T <RETURN>)>>)>>
+
+<ROUTINE OBJ-FOUND (OBJ TBL "AUX" PTR)
+	<SET PTR <GET .TBL ,P-MATCHLEN>>
+	<PUT .TBL <+ .PTR 1> .OBJ>
+	<PUT .TBL ,P-MATCHLEN <+ .PTR 1>>>
+
+<ROUTINE TAKE-CHECK ()
+	<AND <ITAKE-CHECK ,P-PRSO <GETB ,P-SYNTAX ,P-SLOC1>>
+	     <ITAKE-CHECK ,P-PRSI <GETB ,P-SYNTAX ,P-SLOC2>>>>
+
+<ROUTINE ITAKE-CHECK (TBL IBITS "AUX" PTR OBJ TAKEN) ;"changed by MARC 11/83"
+   <COND (<AND <SET PTR <GET .TBL ,P-MATCHLEN>>
+	       <OR <BTST .IBITS ,SHAVE>
+	           <BTST .IBITS ,STAKE>>>
+	  <REPEAT ()
+	    <COND (<L? <SET PTR <- .PTR 1>> 0>
+		   <RETURN>)
+		  (T
+		   <SET OBJ <GET .TBL <+ .PTR 1>>>
+		   <COND (<EQUAL? .OBJ ,IT>
+			  <COND (<NOT <ACCESSIBLE? ,P-IT-OBJECT>>
+				 <TELL ,REFERRING CR>
+				 <RFALSE>)
+				(T
+				 <SET OBJ ,P-IT-OBJECT>)>)>
+		   <COND (<OR <HELD? .OBJ>
+			      <EQUAL? .OBJ ,ME>>
+			  T)
+			 (T
+			  <SETG PRSO .OBJ>
+			  <COND (<FSET? .OBJ ,TRYTAKEBIT>
+				 <SET TAKEN T>)
+				(<OR <NOT <EQUAL? ,WINNER ,PLAYER>>
+				     <AND <EQUAL? ,PRSO ,INTNUM>
+					  <HELD? ,ZORKMID>>>
+				 <SET TAKEN <>>)
+				(<AND <BTST .IBITS ,STAKE>
+				      <EQUAL? <ITAKE <>> T>>
+				 <SET TAKEN <>>)
+				(T
+				 <SET TAKEN T>)>
+			  <COND (<AND .TAKEN <BTST .IBITS ,SHAVE>>
+				 <COND (<L? 1 <GET .TBL ,P-MATCHLEN>>
+				        <TELL
+,YOU-ARENT "holding all those things!" CR>
+					<RFALSE>)
+				       (<EQUAL? .OBJ ,NOT-HERE-OBJECT>
+					<TELL ,YOU-CANT-SEE "that here!" CR>
+					<RFALSE>)
+				       (<EQUAL? ,WINNER ,PLAYER>
+					<TELL ,YOU-ARENT>)
+				       (T
+					<TELL "It doesn't look like ">
+					<TELL THE ,WINNER " is ">)>
+				 <TELL "holding ">
+				 <COND (<EQUAL? .OBJ ,PSEUDO-OBJECT>
+					<TELL "that">)
+				       (ELSE
+					<TELL THE .OBJ>)>
+				 <THIS-IS-IT .OBJ>
+				 <TELL ,PERIOD>
+				 <RFALSE>)
+				(<AND <NOT .TAKEN>
+				      <EQUAL? ,WINNER ,PLAYER>
+				      <NOT <EQUAL? ,PRSO ,INTNUM>>>
+				 <TELL
+"(Taking " THE .OBJ " first)" CR>)>)>)>>)
+	       (T)>>
+
+<ROUTINE MANY-CHECK ("AUX" (LOSS <>) TMP)
+	<COND (<AND <G? <GET ,P-PRSO ,P-MATCHLEN> 1>
+		    <NOT <BTST <GETB ,P-SYNTAX ,P-SLOC1> ,SMANY>>>
+	       <SET LOSS 1>)
+	      (<AND <G? <GET ,P-PRSI ,P-MATCHLEN> 1>
+		    <NOT <BTST <GETB ,P-SYNTAX ,P-SLOC2> ,SMANY>>>
+	       <SET LOSS 2>)>
+	<COND (.LOSS
+	       <TELL ,YOU-CANT "use multiple ">
+	       <COND (<EQUAL? .LOSS 2>
+		      <TELL "in">)>
+	       <TELL "direct objects with \"">
+	       <SET TMP <GET ,P-ITBL ,P-VERBN>>
+	       <COND (<ZERO? .TMP>
+		      <TELL "tell">)
+		     (<OR ,P-OFLAG ,P-MERGED>
+		      <PRINTB <GET .TMP 0>>)
+		     (T
+		      <WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>)>
+	       <TELL "\"." CR>
+	       <RFALSE>)
+	      (T)>>
+
+<ROUTINE ZMEMQ (ITM TBL "OPTIONAL" (SIZE -1) "AUX" (CNT 1))
+	<COND (<NOT .TBL> <RFALSE>)>
+	<COND (<NOT <L? .SIZE 0>> <SET CNT 0>)
+	      (ELSE <SET SIZE <GET .TBL 0>>)>
+	<REPEAT ()
+		<COND (<EQUAL? .ITM <GET .TBL .CNT>>
+		       <RETURN <REST .TBL <* .CNT 2>>>)
+		      (<IGRTR? CNT .SIZE> <RFALSE>)>>>
+
+<ROUTINE ZMEMQB (ITM TBL SIZE "AUX" (CNT 0))
+	<REPEAT ()
+		<COND (<EQUAL? .ITM <GETB .TBL .CNT>>
+		       <RTRUE>)
+		      (<IGRTR? CNT .SIZE>
+		       <RFALSE>)>>>
+
+<ROUTINE LIT? (RM "OPTIONAL" (RMBIT T) "AUX" OHERE (LIT <>))
+	<SETG P-GWIMBIT ,ONBIT>
+	<SET OHERE ,HERE>
+	<SETG HERE .RM>
+	<COND (<AND .RMBIT
+		    <FSET? .RM ,ONBIT>>
+	       <SET LIT ,HERE>)
+	      (<AND <FSET? ,WINNER ,ONBIT>
+		    <HELD? ,WINNER .RM>>
+	       <SET LIT ,WINNER>)
+	      (T
+	       <PUT ,P-MERGE ,P-MATCHLEN 0>
+	       <SETG P-TABLE ,P-MERGE>
+	       <SETG P-SLOCBITS -1>
+	       <COND (<EQUAL? .OHERE .RM>
+		      <DO-SL ,WINNER 1 1>
+		      <COND (<AND <NOT <EQUAL? ,WINNER ,PLAYER>>
+				  <IN? ,PLAYER .RM>>
+			     <DO-SL ,PLAYER 1 1>)>)>
+	       <COND (<AND <FSET? <LOC ,WINNER> ,VEHBIT>
+			   <NOT <FSET? <LOC ,WINNER> ,OPENBIT>>>
+		      <DO-SL <LOC ,WINNER> 1 1>)>
+	       <DO-SL .RM 1 1>
+	       <COND (<G? <GET ,P-TABLE ,P-MATCHLEN> 0>
+		      <SET LIT <GET ,P-TABLE 1>>)>)>
+	<COND (<AND <NOT .LIT>
+		    <EQUAL? ,CHANGED? ,GRUE>>
+	       <SET LIT ,GRUE>)>
+	<SETG HERE .OHERE>
+	<SETG P-GWIMBIT 0>
+	.LIT>
+
+;"former CRUFTY.ZIL routine"
+
+<ROUTINE THIS-IT? (OBJ TBL "AUX" SYNS)
+ <COND (<FSET? .OBJ ,INVISIBLE> <RFALSE>)
+       (<AND ,P-NAM
+	     <NOT <ZMEMQ ,P-NAM
+			 <SET SYNS <GETPT .OBJ ,P?SYNONYM>>
+			 <- </ <PTSIZE .SYNS> 2> 1>>>>
+	<RFALSE>)
+       (<AND ,P-ADJ
+	     <OR <NOT <SET SYNS <GETPT .OBJ ,P?ADJECTIVE>>>
+		 <NOT <ZMEMQB ,P-ADJ .SYNS <- <PTSIZE .SYNS> 1>>>>>
+	<RFALSE>)
+       (<AND <NOT <ZERO? ,P-GWIMBIT>> <NOT <FSET? .OBJ ,P-GWIMBIT>>>
+	<RFALSE>)>
+ <RTRUE>>
+
+<ROUTINE END-QUOTE ()
+	 <SETG QUOTE-FLAG <>>
+	 <SETG P-CONT <>>
+	 <RFATAL>>
+
+<ROUTINE GENERIC-OBJECT? ()
+	 <COND (<EQUAL? ,P-NAM ,W?CUBE ,W?CUBES>
+		<COND (<OR <NOT ,P-ADJ>
+			   <EQUAL? ,P-ADJN ,W?SMALL ,W?WHITE ,W?FEATURELESS>>
+		       <RTRUE>)>)
+	       (<EQUAL? ,P-NAM ,W?ROCK ,W?ROCKS ,W?BOULDER>
+		<COND (<OR <NOT ,P-ADJ>
+			   <EQUAL? ,P-ADJN ,W?FLAT>>
+		       <RTRUE>)>)
+	       (<EQUAL? ,P-NAM ,W?RUNE>
+		<COND (<OR <NOT ,P-ADJ>
+			   <EQUAL? ,P-ADJN ,W?SILVER ,W?LEAD>>
+		       <RTRUE>)>)
+	       (<AND <NOT ,P-ADJ>
+		     <OR <EQUAL? ,P-NAM ,W?FISH ,W?WALL ,W?CARPET>
+			 <EQUAL? ,P-NAM ,W?RUG ,W?HOLE>
+			 <EQUAL? ,P-NAM ,W?PILE ,W?PILES>>>
+		<RTRUE>)>>
diff --git a/record.zil b/record.zil
new file mode 100644
index 0000000..cce3f5d
--- /dev/null
+++ b/record.zil
@@ -0,0 +1,30 @@
+"RECORD for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+<SYNTAX \#RANDOM OBJECT = V-$RANDOM>
+<SYNTAX \#COMMAND = V-$COMMAND>
+<SYNTAX \#RECORD = V-$RECORD>
+<SYNTAX \#UNRECORD = V-$UNRECORD>
+
+<ROUTINE V-$COMMAND ()
+	 <DIRIN 1>
+	 <RTRUE>>
+
+<ROUTINE V-$RANDOM ()
+	 <COND (<NOT <EQUAL? ,PRSO ,INTNUM>>
+		<TELL "Illegal call to #RANDOM." CR>)
+	       (T
+		<RANDOM <- 0 ,P-NUMBER>>
+		<RTRUE>)>>
+
+<CONSTANT D-RECORD-ON 4>
+<CONSTANT D-RECORD-OFF -4>
+
+<ROUTINE V-$RECORD ()
+	 <DIROUT ,D-RECORD-ON> ;"all READS and INPUTS get sent to command file"
+	 <RTRUE>>
+
+<ROUTINE V-$UNRECORD ()
+	 <DIROUT ,D-RECORD-OFF>
+	 <RTRUE>>
diff --git a/syntax.zil b/syntax.zil
new file mode 100644
index 0000000..6b87847
--- /dev/null
+++ b/syntax.zil
@@ -0,0 +1,684 @@
+"SYNTAX for
+			    MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+<BUZZ $BUZZ A AN THE IS ARE AM AND OF THEN ALL ONE BUT EXCEPT \. \, \"
+      PLEASE HERE SOME G AGAIN OOPS>
+
+<SYNONYM WITH USING>
+;<SYNONYM THROUGH THRU>
+<SYNONYM ON ONTO>
+<SYNONYM IN INSIDE INTO>
+<SYNONYM UNDER BELOW BENEATH UNDERNEATH>
+<SYNONYM AROUND ALONG>
+<SYNONYM ALL BOTH>
+
+<SYNONYM NORTH N>
+<SYNONYM SOUTH S>
+<SYNONYM EAST E>
+<SYNONYM WEST W>
+<SYNONYM DOWN D>
+<SYNONYM UP U>
+
+\
+
+;"game commands"
+
+<SYNTAX VERBOSE = V-VERBOSE>
+
+<SYNTAX BRIEF = V-BRIEF>
+
+<SYNTAX SUPER = V-SUPER-BRIEF>
+<SYNONYM SUPER SUPERBRIEF>
+
+<SYNTAX DIAGNOSE = V-DIAGNOSE>
+
+<SYNTAX I = V-INVENTORY>
+<SYNONYM I INVENTORY>
+
+<SYNTAX QUIT = V-QUIT>
+<SYNONYM QUIT Q>
+
+<SYNTAX RESTAR = V-RESTART>
+
+<SYNTAX RESTOR = V-RESTORE>
+
+<SYNTAX SAVE = V-SAVE>
+
+<SYNTAX SCORE = V-SCORE>
+
+<SYNTAX SCRIPT = V-SCRIPT>
+
+<SYNTAX UNSCRIPT = V-UNSCRIPT>
+
+<SYNTAX VERSION = V-VERSION>
+
+<SYNTAX $VERIFY = V-$VERIFY>
+<SYNTAX $VERIFY OBJECT = V-$VERIFY>
+
+\
+
+;"subtitle real verbs"
+
+<SYNTAX ANSWER = V-ANSWER>
+<SYNTAX ANSWER OBJECT = V-REPLY>
+<SYNONYM ANSWER REPLY RESPOND>
+
+<SYNTAX APPLY OBJECT (HELD MANY HAVE) TO OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX ASK FOR OBJECT = V-ASK-FOR PRE-ASK-FOR>
+<SYNTAX ASK OBJECT (FIND PERSON) FOR OBJECT = V-ASK-FOR PRE-ASK-FOR>
+<SYNTAX ASK ABOUT OBJECT = V-ASK-ABOUT PRE-ASK-ABOUT>
+<SYNTAX ASK OBJECT (FIND PERSON) ABOUT OBJECT = V-ASK-ABOUT PRE-ASK-ABOUT>
+<SYNONYM ASK QUERY QUIZ>
+
+<SYNTAX ATTACK OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-ATTACK>
+<SYNTAX ATTACK OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-ATTACK>
+<SYNONYM ATTACK ASSAULT FIGHT HIT STRIKE>
+
+<SYNTAX BITE OBJECT = V-BITE>
+
+<SYNTAX BLOW UP OBJECT = V-INFLATE>
+<SYNTAX BLOW OUT OBJECT = V-LAMP-OFF>
+
+<SYNTAX BOARD OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNONYM BOARD EMBARK RIDE>
+
+<SYNTAX BURN OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+        WITH OBJECT (HELD CARRIED ON-GROUND IN-ROOM HAVE) = V-BURN>
+<SYNTAX BURN DOWN OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH OBJECT (HELD CARRIED ON-GROUND IN-ROOM HAVE) = V-BURN>
+<SYNONYM BURN IGNITE>
+
+<SYNTAX CLIMB OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-FOO>
+<SYNTAX CLIMB ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX CLIMB UP OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX CLIMB DOWN OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX CLIMB OVER OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-OVER>
+<SYNTAX CLIMB IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX CLIMB OFF OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-DISEMBARK>
+<SYNTAX CLIMB OUT OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-DISEMBARK>
+<SYNONYM CLIMB SCALE>
+
+<SYNTAX DESCEN OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+
+<SYNTAX LIE DOWN OBJECT (FIND RLANDBIT) = V-SLEEP>
+<SYNTAX LIE ON OBJECT (FIND VEHBIT) = V-BOARD>
+;<SYNONYM LIE>
+
+<SYNTAX CLOSE OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-CLOSE PRE-CLOSE>
+<SYNONYM CLOSE SHUT ZIP>
+
+<SYNTAX COMPARE OBJECT TO OBJECT = V-COMPARE>
+<SYNTAX COMPARE OBJECT WITH OBJECT = V-COMPARE>
+
+<SYNTAX COUNT OBJECT = V-COUNT>
+<SYNTAX COUNT OBJECT IN OBJECT = V-COUNT>
+;<SYNONYM COUNT>
+
+<SYNTAX CROSS OBJECT = V-CROSS>
+<SYNONYM CROSS FORD TRAVERSE>
+
+<SYNTAX CUT OBJECT WITH OBJECT (FIND WEAPONBIT) (CARRIED HELD) = V-CUT>
+<SYNTAX CUT THROUGH OBJECT WITH OBJECT (FIND WEAPONBIT) (CARRIED HELD) = V-CUT>
+<SYNONYM CUT SLICE SLASH SEVER SPLIT DIVIDE PRUNE> 
+
+<SYNTAX SHIT = V-CURSE>
+<SYNONYM SHIT DAMN FUCK>
+
+<SYNTAX CRACK OBJECT (ON-GROUND IN-ROOM) = V-MUNG>
+<SYNTAX CRACK OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	WITH OBJECT (HELD CARRIED TAKE)	= V-MUNG>
+<SYNTAX CRACK DOWN OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	WITH OBJECT (HELD CARRIED TAKE)	= V-MUNG>
+<SYNONYM CRACK DESTROY BREAK SMASH WRECK SCRATCH>
+
+<SYNTAX DIG IN OBJECT = V-DIG>
+<SYNTAX DIG WITH OBJECT = V-DIG>
+<SYNTAX DIG THROUGH OBJECT = V-DIG>
+<SYNTAX DIG OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND TOOLBIT) (HELD CARRIED HAVE) = V-DIG>
+<SYNTAX DIG IN OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND TOOLBIT) (HELD CARRIED HAVE) = V-DIG>
+<SYNONYM DIG EXCAVATE>
+
+<SYNTAX DISEMBARK = V-DISEMBARK>
+<SYNTAX DISEMBARK OBJECT (ON-GROUND IN-ROOM) = V-DISEMBARK>
+<SYNONYM DISEMBARK DEBARK>
+
+<SYNTAX DRINK OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-DRINK>
+<SYNTAX DRINK FROM OBJECT (HELD CARRIED) = V-DRINK-FROM>
+<SYNONYM DRINK SIP SWALLOW>
+
+<SYNTAX DROP OBJECT (HELD MANY HAVE) = V-DROP PRE-DROP>
+<SYNTAX DROP OBJECT (HELD MANY HAVE) DOWN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY HAVE) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY HAVE) ON OBJECT = V-PUT PRE-PUT>
+<SYNONYM DROP RELEASE DUMP>
+
+<SYNTAX EAT OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-EAT>
+<SYNONYM EAT CONSUME TASTE ;INGEST GOBBLE>
+
+<SYNTAX ENTER = V-ENTER>
+<SYNTAX ENTER OBJECT = V-THROUGH>
+
+<SYNTAX EXIT = V-EXIT>
+<SYNTAX EXIT OBJECT = V-EXIT>
+<SYNONYM EXIT DEPART WITHDRAW>
+
+<SYNTAX EXAMINE OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-EXAMINE PRE-EXAMINE>
+<SYNTAX EXAMINE IN OBJECT (HELD CARRIED IN-ROOM ON-GROUND)
+	= V-LOOK-INSIDE>
+<SYNTAX EXAMINE ON OBJECT (HELD CARRIED IN-ROOM ON-GROUND)
+	= V-LOOK-INSIDE>
+<SYNTAX EXAMINE FOR OBJECT = V-FIND>
+<SYNONYM EXAMINE INSPECT DESCRIBE CHECK OBSERVE WATCH>
+
+;<SYNTAX EXORCISE OBJECT = V-EXORCISE>
+;<SYNTAX EXORCISE OUT OBJECT (FIND PERSON) = V-EXORCISE>
+;<SYNTAX EXORCISE AWAY OBJECT (FIND PERSON) = V-EXORCISE>
+;<SYNONYM EXORCISE BANISH DRIVE>
+
+<SYNTAX EXTINGUISH OBJECT
+	(MANY HELD CARRIED ON-GROUND IN-ROOM TAKE HAVE)	= V-LAMP-OFF>
+;<SYNONYM EXTINGUISH DOUSE>
+
+<SYNTAX FILL OBJECT (FIND CONTBIT) (HELD TAKE HAVE) = V-FILL>
+<SYNTAX FILL OBJECT (FIND CONTBIT) (HELD TAKE HAVE)
+	WITH OBJECT = V-FILL>
+<SYNTAX FILL OBJECT (FIND CONTBIT) (HELD TAKE HAVE)
+	AT OBJECT = V-FILL>
+
+<SYNTAX FIND OBJECT = V-FIND>
+;<SYNONYM FIND SEEK SEE>
+
+<SYNTAX FLY = V-FLY>
+<SYNTAX FLY OBJECT = V-FLY>
+
+<SYNTAX FOLLOW = V-FOLLOW>
+<SYNTAX FOLLOW OBJECT = V-FOLLOW>
+<SYNONYM FOLLOW PURSUE CHASE>
+
+<SYNTAX FORGET OBJECT = V-FORGET>
+<SYNONYM FORGET UNLEARN ;UNMEMORIZE>
+
+<SYNTAX GIVE OBJECT (MANY HELD HAVE)
+        TO OBJECT (FIND PERSON) (ON-GROUND) = V-GIVE PRE-GIVE>
+<SYNTAX GIVE OBJECT (FIND PERSON) (ON-GROUND) OBJECT (MANY HELD HAVE)
+	= V-SGIVE PRE-SGIVE>
+<SYNTAX GIVE OBJECT (FIND PERSON) (ON-GROUND) WITH OBJECT (MANY HELD HAVE)
+	= V-SGIVE PRE-SGIVE>
+<SYNTAX GIVE OBJECT FOR OBJECT = V-OFFER>
+<SYNONYM GIVE HAND OFFER FEED ;PRESENT>
+
+<SYNTAX HELLO = V-HELLO>
+<SYNTAX HELLO OBJECT = V-HELLO>
+<SYNONYM HELLO HI ;GREETINGS>
+
+<SYNTAX HELP = V-HELP>
+<SYNTAX HELP OBJECT = V-HELP>
+<SYNONYM HELP HINT ;HINTS>
+
+<SYNTAX HIDE = V-HIDE>
+<SYNTAX HIDE OBJECT (HELD HAVE) = V-HIDE>
+<SYNTAX HIDE UNDER OBJECT = V-HIDE>
+<SYNTAX HIDE BEHIND OBJECT = V-HIDE>
+<SYNTAX HIDE OBJECT (HELD HAVE) FROM OBJECT = V-HIDE>
+<SYNTAX HIDE IN OBJECT = V-BOARD>
+<SYNTAX HIDE FROM OBJECT = V-HIDE-FROM>
+<SYNONYM HIDE CONCEAL ;STASH>
+
+<SYNTAX INFLAT OBJECT = V-INFLATE>
+
+<SYNTAX JUMP = V-LEAP>
+<SYNTAX JUMP OVER OBJECT = V-LEAP>
+<SYNTAX JUMP ACROSS OBJECT = V-LEAP>
+<SYNTAX JUMP IN OBJECT = V-LEAP>
+<SYNTAX JUMP FROM OBJECT = V-LEAP>
+<SYNTAX JUMP DOWN OBJECT (FIND RLANDBIT) = V-LEAP>
+<SYNTAX JUMP OFF OBJECT = V-LEAP>
+<SYNTAX JUMP ON OBJECT = V-CLIMB-ON>
+<SYNTAX JUMP TO OBJECT = V-CLIMB-ON>
+<SYNONYM JUMP LEAP DIVE>
+
+<SYNTAX KICK OBJECT = V-KICK PRE-OPEN>
+
+<SYNTAX KILL OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-KILL>
+<SYNTAX KILL OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-KILL>
+<SYNONYM KILL MURDER SLAY STAB>
+
+<SYNTAX KISS OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-KISS>
+
+<SYNTAX KNOCK AT OBJECT = V-KNOCK>
+<SYNTAX KNOCK ON OBJECT = V-KNOCK>
+<SYNTAX KNOCK DOWN OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-ATTACK>
+<SYNONYM KNOCK RAP>
+
+<SYNTAX LAND = V-LAND>
+
+<SYNTAX LEAN ON OBJECT (HELD HAVE) = V-LEAN-ON>
+
+<SYNTAX LEAVE = V-LEAVE>
+<SYNTAX LEAVE OBJECT = V-DROP PRE-DROP>
+
+<SYNTAX LISTEN = V-LISTEN>
+<SYNTAX LISTEN TO OBJECT = V-LISTEN>
+<SYNTAX LISTEN FOR OBJECT = V-LISTEN>
+
+<SYNTAX LOCK OBJECT (ON-GROUND IN-ROOM) WITH OBJECT
+	(HELD CARRIED ON-GROUND IN-ROOM) = V-LOCK>
+
+<SYNTAX LOOK = V-LOOK>
+<SYNTAX LOOK AROUND OBJECT (FIND RLANDBIT) = V-LOOK>
+<SYNTAX LOOK DOWN OBJECT (FIND RLANDBIT) = V-LOOK-DOWN>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-EXAMINE PRE-EXAMINE>
+<SYNTAX LOOK THROUGH OBJECT = V-LOOK-INSIDE>
+<SYNTAX LOOK UNDER OBJECT = V-LOOK-UNDER>
+<SYNTAX LOOK BEHIND OBJECT = V-LOOK-BEHIND>
+<SYNTAX LOOK ON OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-LOOK-INSIDE>
+<SYNTAX LOOK IN OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-LOOK-INSIDE>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM TAKE) THROUGH OBJECT
+	= V-READ PRE-READ>
+<SYNTAX LOOK UP OBJECT (FIND RLANDBIT) = V-LOOK-UP>
+<SYNTAX LOOK UP OBJECT IN OBJECT = V-WHAT>
+<SYNTAX LOOK FOR OBJECT = V-FIND>
+<SYNTAX LOOK OBJECT = V-CHASTISE>
+<SYNONYM LOOK L STARE GAZE>
+
+<SYNTAX LOWER OBJECT = V-LOWER>
+<SYNTAX LOWER OBJECT IN OBJECT = V-LOWER-INTO>
+<SYNTAX LOWER OBJECT DOWN OBJECT = V-LOWER-INTO>
+
+<SYNTAX MELT OBJECT WITH OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-MELT>
+<SYNONYM MELT THAW>
+
+<SYNTAX MOVE = V-WALK-AROUND>
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX ROLL UP OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNONYM MOVE SHIFT>
+
+<SYNTAX PAY OBJECT (MANY HELD HAVE) = V-PAY>
+<SYNTAX PAY OBJECT (FIND PERSON) WITH OBJECT (MANY HELD HAVE) = V-PAY>
+<SYNTAX PAY OBJECT (MANY HELD HAVE) TO OBJECT (FIND PERSON) = V-SPAY>
+<SYNTAX PAY OBJECT (FIND PERSON) OBJECT (MANY HELD HAVE) = V-PAY>
+
+<SYNTAX PLAY OBJECT = V-PLAY>
+
+<SYNTAX PULL OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX PULL ON OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX PULL DOWN OBJECT = V-LOWER>
+<SYNONYM PULL TUG DRAG>
+
+<SYNTAX OPEN OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN PRE-OPEN>
+<SYNTAX OPEN UP	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN PRE-OPEN>
+<SYNTAX OPEN OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED HAVE)
+	= V-OPEN PRE-OPEN>
+<SYNONYM OPEN UNZIP>
+
+<SYNTAX PICK OBJECT = V-PICK>
+<SYNTAX PICK OBJECT WITH OBJECT = V-PICK>
+<SYNTAX PICK UP OBJECT (FIND TAKEBIT) (ON-GROUND MANY) = V-TAKE PRE-TAKE>
+
+<SYNTAX PLUG OBJECT WITH OBJECT = V-PLUG>
+<SYNONYM PLUG CLOG BLOCK>
+
+<SYNTAX REPAIR OBJECT = V-REPAIR>
+<SYNTAX REPAIR OBJECT WITH OBJECT = V-REPAIR>
+<SYNONYM REPAIR PATCH FIX>
+
+<SYNTAX POINT AT OBJECT = V-POINT>
+<SYNTAX POINT TO OBJECT = V-POINT>
+<SYNONYM POINT GESTURE>
+
+<SYNTAX POKE OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-MUNG>
+<SYNONYM POKE JAB BLIND>
+
+<SYNTAX POUR OBJECT (HELD CARRIED) = V-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) IN OBJECT = V-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) ON OBJECT = V-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) FROM OBJECT = V-POUR>
+<SYNONYM POUR EMPTY SPILL>
+
+<SYNTAX PUMP UP OBJECT = V-PUMP>
+<SYNTAX PUMP UP OBJECT WITH OBJECT = V-PUMP>
+
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND MANY) = V-PUSH>
+<SYNTAX PUSH ON OBJECT (IN-ROOM ON-GROUND MANY) = V-PUSH>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) OBJECT = V-PUSH-TO>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) TO OBJECT = V-PUSH-TO>
+<SYNTAX PUSH OBJECT UNDER OBJECT = V-PUT-UNDER>
+<SYNONYM PUSH PRESS SHOVE>
+
+<SYNTAX PUT OBJECT (HELD MANY HAVE) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) DOWN OBJECT = V-PUT PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) ON OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) OVER OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) ACROSS OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT DOWN OBJECT (HELD MANY) = V-DROP PRE-DROP>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) UNDER OBJECT = V-PUT-UNDER> 
+<SYNTAX PUT ON OBJECT (IN-ROOM ON-GROUND CARRIED MANY) = V-WEAR>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) BEHIND OBJECT = V-PUT-BEHIND>
+<SYNONYM PUT STUFF INSERT PLACE LAY FIT WEDGE>
+
+<SYNTAX RAISE OBJECT = V-RAISE>
+<SYNTAX RAISE UP OBJECT = V-RAISE>
+<SYNONYM RAISE LIFT>
+
+<SYNTAX REACH IN OBJECT (ON-GROUND IN-ROOM) = V-REACH-IN>
+
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-READ PRE-READ>
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	THROUGH OBJECT = V-READ PRE-READ>
+<SYNTAX READ ABOUT OBJECT = V-WHAT>
+<SYNTAX READ ABOUT OBJECT IN OBJECT = V-WHAT>
+;<SYNONYM READ>
+
+<SYNTAX REMOVE OBJECT = V-TAKE-OFF>
+<SYNONYM REMOVE SHED>
+
+<SYNTAX SAY TO OBJECT (FIND PERSON) (IN-ROOM) = V-TELL>
+<SYNTAX SAY = V-SAY>
+<SYNONYM SAY TALK CALL>
+
+<SYNTAX SEARCH OBJECT = V-SEARCH>
+<SYNTAX SEARCH IN OBJECT = V-SEARCH>
+<SYNTAX SEARCH FOR OBJECT = V-FIND>
+<SYNONYM SEARCH RUMMAGE ;FRISK>
+
+<SYNTAX SEND FOR OBJECT = V-SEND>
+
+<SYNTAX SHAKE OBJECT = V-SHAKE>
+<SYNTAX SHAKE OBJECT AT OBJECT = V-WAVE-AT>
+<SYNONYM SHAKE ;JOSTLE RATTLE>
+
+<SYNTAX SHARPEN OBJECT WITH OBJECT (FIND TOOLBIT) (HAVE) = V-SHARPEN>
+;<SYNONYM SHARPEN HONE>
+
+<SYNTAX SHOOT OBJECT = V-SHOOT>
+<SYNONYM SHOOT FIRE>
+
+<SYNTAX SHOW OBJECT TO OBJECT = V-SHOW>
+<SYNTAX SHOW OBJECT OBJECT = V-SSHOW PRE-SSHOW>
+
+<SYNTAX SIT ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-SIT>
+<SYNTAX SIT DOWN OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-SIT>
+<SYNTAX SIT IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX SIT AT OBJECT = V-SIT>
+<SYNONYM SIT REST MEDITATE>
+
+<SYNTAX SLEEP = V-SLEEP>
+<SYNTAX SLEEP IN OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+<SYNTAX SLEEP ON OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+
+<SYNTAX NAP = V-SLEEP>
+<SYNTAX NAP IN OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+<SYNTAX NAP ON OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+
+<SYNTAX SNOOZE = V-SLEEP>
+<SYNTAX SNOOZE IN OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+<SYNTAX SNOOZE ON OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+
+<SYNTAX SKIP = V-SKIP>
+<SYNONYM SKIP HOP CAVORT GAMBOL>
+
+<SYNTAX SLIDE OBJECT UNDER OBJECT = V-PUT-UNDER>
+
+<SYNTAX SMELL = V-SMELL>
+<SYNTAX SMELL OBJECT = V-SMELL>
+<SYNONYM SMELL SNIFF>
+
+<SYNTAX SPIN OBJECT = V-SPIN>
+<SYNONYM SPIN WHIRL ROTATE>
+
+<SYNTAX SQUEEZE OBJECT = V-SQUEEZE>
+<SYNTAX SQUEEZE OBJECT (HELD MANY HAVE) ON OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX STAND = V-STAND>
+<SYNTAX STAND UP OBJECT (FIND RLANDBIT) = V-STAND>
+<SYNTAX STAND ON OBJECT = V-STAND-ON>
+<SYNONYM STAND RISE>
+
+<SYNTAX SWIM = V-SWIM>
+<SYNTAX SWIM IN OBJECT = V-SWIM>
+<SYNONYM SWIM BATHE WADE>
+
+<SYNTAX SWING OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-SWING>
+<SYNTAX SWING OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	AT OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-SWING>
+<SYNONYM SWING THRUST>
+
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (ON-GROUND IN-ROOM MANY) = V-TAKE PRE-TAKE>
+<SYNTAX TAKE IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX TAKE OUT OBJECT (FIND RLANDBIT) (ON-GROUND) = V-DISEMBARK>
+<SYNTAX TAKE ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX TAKE UP OBJECT (FIND RLANDBIT) = V-STAND>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OUT OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OFF OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	FROM OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	IN OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OFF OBJECT = V-TAKE-OFF>
+<SYNONYM TAKE GRAB CATCH GET HOLD CARRY SNATCH>
+
+<SYNTAX TELL OBJECT (FIND PERSON) (IN-ROOM) = V-TELL>
+<SYNTAX TELL OBJECT ABOUT OBJECT = V-TELL-ABOUT PRE-TELL-ABOUT>
+<SYNTAX TELL OBJECT OBJECT = V-REPLY>
+<SYNTAX TELL ABOUT OBJECT = V-TELL-ME-ABOUT>
+
+<SYNTAX THANK OBJECT = V-THANK>
+<SYNTAX THANK = V-THANK>
+<SYNONYM THANK THANKS>
+
+<SYNTAX THROW OBJECT (HELD CARRIED HAVE)
+	AT OBJECT (ON-GROUND IN-ROOM) = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED HAVE)
+	TO OBJECT (ON-GROUND IN-ROOM) = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED HAVE) OFF OBJECT = V-THROW-OFF>
+<SYNTAX THROW OBJECT (HELD CARRIED HAVE) OVER OBJECT = V-THROW-OFF>
+<SYNTAX THROW OBJECT (HELD CARRIED HAVE)
+	THROUGH OBJECT (ON-GROUND IN-ROOM) = V-THROW>
+<SYNTAX THROW OBJECT (HELD MANY HAVE) DOWN OBJECT = V-THROW>
+<SYNTAX THROW OBJECT (HELD MANY HAVE) IN OBJECT = V-THROW>
+<SYNTAX THROW OBJECT (HELD MANY HAVE) ON OBJECT = V-THROW>
+<SYNONYM THROW HURL TOSS PITCH>
+
+<SYNTAX TIE OBJECT TO OBJECT = V-TIE>
+<SYNTAX TIE UP OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) WITH OBJECT
+	(FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED HAVE) = V-TIE-UP>
+<SYNONYM TIE FASTEN ATTACH>
+
+<SYNTAX TIME = V-TIME>
+<SYNONYM TIME T>
+
+<SYNTAX TORTUR OBJECT = V-TORTURE>
+
+<SYNTAX TOUCH OBJECT = V-RUB>
+<SYNTAX TOUCH OBJECT WITH OBJECT = V-RUB>
+<SYNTAX TOUCH OBJECT TO OBJECT = V-SRUB PRE-SRUB>
+<SYNONYM TOUCH FEEL PAT PET RUB>
+
+<SYNTAX TURN OBJECT TO OBJECT = V-TURN>
+<SYNTAX TURN OBJECT = V-TURN>
+<SYNTAX TURN OBJECT WITH OBJECT (FIND TOOLBIT) (HAVE) = V-TURN>
+<SYNTAX TURN ON OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-LAMP-ON>
+<SYNTAX TURN OFF OBJECT
+	(HELD CARRIED ON-GROUND IN-ROOM TAKE) = V-LAMP-OFF>
+<SYNTAX TURN OVER OBJECT = V-TURN-OVER> 
+<SYNONYM TURN FLIP SHUT SET>
+
+<SYNTAX UNLOCK OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT = V-UNLOCK>
+
+<SYNTAX UNTIE OBJECT (ON-GROUND IN-ROOM HELD CARRIED) = V-UNTIE>
+<SYNTAX UNTIE OBJECT (ON-GROUND IN-ROOM HELD CARRIED) FROM OBJECT = V-UNTIE>
+<SYNONYM UNTIE FREE UNFASTEN UNATTACH>
+
+<SYNTAX WAIT = V-WAIT>
+<SYNTAX WAIT FOR OBJECT = V-WAIT-FOR>
+<SYNONYM WAIT Z>
+
+<SYNTAX WAKE OBJECT (FIND RLANDBIT) = V-ALARM>
+<SYNTAX WAKE UP OBJECT (FIND RLANDBIT) = V-ALARM>
+<SYNONYM WAKE AWAKE SURPRISE STARTLE ROUSE>
+
+<SYNTAX WALK = V-WALK-AROUND>
+<SYNTAX WALK OBJECT = V-WALK>
+<SYNTAX WALK IN OBJECT = V-THROUGH>
+<SYNTAX WALK ON OBJECT = V-BOARD>
+<SYNTAX WALK OVER OBJECT = V-LEAP>
+<SYNTAX WALK THROUGH OBJECT = V-THROUGH>
+<SYNTAX WALK AROUND OBJECT = V-WALK-AROUND>
+<SYNTAX WALK UP OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX WALK DOWN OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX WALK TO OBJECT = V-WALK-TO>
+<SYNONYM WALK GO RUN PROCEED STEP>
+
+<SYNTAX WAVE OBJECT (HELD CARRIED) = V-WAVE>
+<SYNTAX WAVE AT OBJECT = V-WAVE-AT>
+<SYNTAX WAVE TO OBJECT = V-WAVE-AT>
+<SYNTAX YELL AT OBJECT = V-WAVE-AT>
+<SYNTAX WAVE OBJECT (HELD CARRIED) AT OBJECT = V-WAVE>
+<SYNONYM WAVE ;MOTION BECKON>
+
+<SYNTAX WEAR OBJECT = V-WEAR>
+
+<SYNTAX WHAT OBJECT = V-WHAT>
+;<SYNONYM WHAT WHATS>
+
+<SYNTAX WHERE = V-WHERE>
+<SYNTAX WHERE OBJECT = V-WHERE>
+;<SYNONYM WHERE WHERES>
+
+<SYNTAX WHO = V-WHO>
+<SYNTAX WHO OBJECT = V-WHO>
+;<SYNONYM WHO WHOS>
+
+<SYNTAX YAWN = V-YAWN>
+
+<SYNTAX YELL = V-YELL>
+<SYNONYM YELL SCREAM SHOUT>
+
+\^L
+
+;"magic spell syntaxes"
+
+<SYNTAX CAST OBJECT = V-CAST>
+<SYNTAX CAST OBJECT ON OBJECT = V-CAST>
+<SYNTAX CAST OBJECT AT OBJECT = V-CAST>
+<SYNONYM CAST INCANT INVOKE>
+
+<SYNTAX LEARN OBJECT (HELD CARRIED MANY) = V-LEARN>
+<SYNONYM LEARN MEMORIZE ;KNOW>
+
+<SYNTAX SPELLS = V-SPELLS>
+
+<SYNTAX FROTZ OBJECT = V-FROTZ PRE-CAST>
+
+<SYNTAX GNUSTO OBJECT = V-GNUSTO PRE-CAST>
+
+<SYNTAX MALYON OBJECT = V-MALYON PRE-CAST>
+
+<SYNTAX REZROV OBJECT = V-REZROV PRE-CAST>
+
+<SYNTAX YOMIN OBJECT (FIND PERSON) = V-YOMIN PRE-CAST>
+
+<SYNTAX BLORPLE OBJECT (HELD CARRIED HAVE) = V-BLORPLE PRE-CAST>
+
+<SYNTAX LESOCH = V-LESOCH PRE-CAST>
+<SYNTAX LESOCH OBJECT = V-LESOCH PRE-CAST>
+
+<SYNTAX SNAVIG = V-SNAVIG PRE-CAST>
+<SYNTAX SNAVIG OBJECT = V-SNAVIG PRE-CAST>
+
+<SYNTAX GIRGOL = V-GIRGOL PRE-CAST>
+<SYNTAX GIRGOL OBJECT = V-GIRGOL PRE-CAST>
+
+<SYNTAX JINDAK = V-JINDAK PRE-CAST>
+<SYNTAX JINDAK OBJECT = V-JINDAK PRE-CAST>
+
+<SYNTAX ESPNIS OBJECT = V-ESPNIS PRE-CAST>
+
+<SYNTAX CASKLY OBJECT = V-CASKLY PRE-CAST>
+
+<SYNTAX LISKON OBJECT = V-LISKON PRE-CAST>
+
+<SYNTAX THROCK OBJECT = V-THROCK PRE-CAST>
+
+<SYNTAX TINSOT OBJECT = V-TINSOT PRE-CAST>
+
+<SYNTAX $XEROX OBJECT = V-$XEROX PRE-CAST>
+
+<SYNTAX LABEL OBJECT (HELD CARRIED) = V-SWRITE PRE-SWRITE>
+<SYNTAX LABEL OBJECT (HELD CARRIED) WITH OBJECT = V-SWRITE PRE-SWRITE>
+
+<SYNTAX WRITE OBJECT = V-WRITE PRE-WRITE>
+<SYNTAX WRITE OBJECT ON OBJECT (HELD CARRIED) = V-WRITE PRE-WRITE>
+<SYNTAX WRITE OBJECT IN OBJECT (HELD CARRIED) = V-WRITE PRE-WRITE>
+<SYNTAX WRITE ON OBJECT (HELD CARRIED) = V-WRITE-ON PRE-WRITE-ON>
+<SYNTAX WRITE IN OBJECT (HELD CARRIED) = V-WRITE-ON PRE-WRITE-ON>
+<SYNTAX WRITE ON OBJECT (HELD CARRIED)
+	WITH OBJECT (FIND TOOLBIT) = V-WRITE-ON PRE-WRITE-ON>
+<SYNTAX WRITE IN OBJECT (HELD CARRIED)
+	WITH OBJECT (FIND TOOLBIT) = V-WRITE-ON PRE-WRITE-ON>
+<SYNONYM WRITE PRINT INSCRIBE SCRIBE>
+
+<SYNTAX PRY OBJECT WITH OBJECT = V-PRY>
+<SYNTAX PRY OUT OBJECT WITH OBJECT = V-PRY>
+
+<SYNTAX PLANT OBJECT = V-PLANT>
+<SYNTAX PLANT OBJECT IN OBJECT = V-PLANT>
+<SYNONYM PLANT BURY>
+
+<SYNTAX YES = V-YES>
+<SYNONYM YES Y OKAY>
+<SYNTAX NO = V-NO>
+<SYNONYM NO NOPE>
+
+<SYNTAX BUY OBJECT FROM OBJECT (FIND PERSON) = V-BUY>
+<SYNTAX BUY OBJECT WITH OBJECT = V-BUY>
+<SYNONYM BUY PURCHASE>
+
+<SYNTAX SELL OBJECT TO OBJECT (FIND PERSON) = V-SELL>
+<SYNTAX SELL OBJECT OBJECT = V-SSELL PRE-SSELL>
+
+<SYNTAX TRADE OBJECT (HELD CARRIED HAVE) WITH OBJECT (FIND PERSON) = V-TRADE>
+<SYNTAX TRADE OBJECT (HELD CARRIED HAVE) FOR OBJECT = V-TRADE>
+<SYNTAX TRADE OBJECT (HELD CARRIED HAVE) = V-TRADE>
+
+<SYNTAX LURK = V-SLAVER>
+<SYNTAX LURK BEHIND OBJECT = V-SLAVER>
+<SYNTAX LURK IN OBJECT = V-SLAVER>
+
+<SYNTAX SLAVER = V-SLAVER>
+<SYNONYM SLAVER DROOL SALIVATE GURGLE>
+
+<SYNTAX ERASE OBJECT = V-ERASE>
+
+<SYNTAX ADMIRE OBJECT (FIND PERSON) = V-ADMIRE>
+<SYNONYM ADMIRE COMPLIMENT>
+
+<SYNTAX COPY OBJECT (FIND READBIT)
+	WITH OBJECT (FIND TOOLBIT) = V-COPY>
+<SYNTAX COPY OBJECT (FIND READBIT)
+	ON OBJECT = V-COPY>
+<SYNTAX COPY OBJECT (FIND READBIT)
+	TO OBJECT = V-COPY>
+<SYNTAX COPY OBJECT (FIND READBIT) = V-COPY>
+
+<SYNTAX BARGAIN WITH OBJECT (FIND PERSON) = V-BARGAIN>
+<SYNONYM BARGAIN HAGGLE>
diff --git a/verbs.zil b/verbs.zil
new file mode 100644
index 0000000..b669b44
--- /dev/null
+++ b/verbs.zil
@@ -0,0 +1,2390 @@
+"VERBS for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+;"stuff to try to save space"
+
+<GLOBAL PERIOD ".|">
+<GLOBAL REFERRING "I don't see what you're referring to.">
+<GLOBAL I-DONT-THINK-THAT "I don't think that ">
+<GLOBAL DOESNT-FIT "It doesn't fit.|">
+<GLOBAL NOW-BLACK "It is pitch black.">
+<GLOBAL IT-LOOKS-LIKE "It looks like ">
+<GLOBAL IT-IS-ALREADY "It's already ">
+<GLOBAL TOO-DARK "It's too dark to see!|">
+<GLOBAL LOOK-AROUND-YOU "Look around you.|">
+<GLOBAL NOTHING-HAPPENS "Nothing happens.|">
+<GLOBAL TAKEN "Taken.|">
+<GLOBAL WASTE-OF-TIME "That would be a waste of time.|">
+<GLOBAL THERE-IS-NOTHING "There is nothing ">
+<GLOBAL NO-ROOM "There's no room.">
+<GLOBAL THERES-NOTHING-TO "There's nothing to ">
+<GLOBAL WHILE-FLYING "While flying?|">
+<GLOBAL YOU-ARE "You already are">
+<GLOBAL YOU-HAVE "You already have ">
+<GLOBAL YOU-ARE-NOW "You are now ">
+<GLOBAL YOU-ARENT "You aren't ">
+<GLOBAL YOU-CANT "You can't ">
+<GLOBAL YOU-CANT-REACH "You can't reach ">
+<GLOBAL YOU-CANT-SEE "You can't see ">
+<GLOBAL YOU-DONT-HAVE "You don't have ">
+<GLOBAL YOU-HIT "You hit your head against ">
+<GLOBAL MORE-SPECIFIC "You'll have to be more specific">
+<GLOBAL YOU-HAVE-TO "You'll have to">
+
+<ROUTINE DONT-HAVE-THAT ()
+	 <TELL ,YOU-DONT-HAVE "that" ,PERIOD>>
+
+<ROUTINE CANT-GO ()
+	 <TELL ,YOU-CANT "go that way." CR>>
+
+<ROUTINE NOT-HOLDING (OBJ)
+	 <TELL ,YOU-ARENT "holding " THE .OBJ ,PERIOD>>
+
+<ROUTINE ITS-EMPTY ()
+	 <TELL CTHE ,PRSO " is empty" ,PERIOD>>
+
+<ROUTINE ALREADY-OPEN ()
+	 <TELL ,IT-IS-ALREADY "open" ,PERIOD>>
+
+<ROUTINE ALREADY-CLOSED ()
+	 <TELL ,IT-IS-ALREADY "closed" ,PERIOD>>
+
+<ROUTINE MAKE-OUT ()
+	 <TELL ,YOU-CANT "make out anything." CR>>
+
+<ROUTINE WITH-PRSI? ()
+	 <TELL "With "><A-PRSI?>>
+
+<ROUTINE TELL-OPEN-CLOSED ("OPTIONAL" (OBJ <>))
+	 <COND (.OBJ <TELL CTHE .OBJ>)
+	       (ELSE
+		<SET OBJ ,PRSO>
+		<TELL THE ,PRSO>)>
+	 <TELL " is ">
+	 <COND (<FSET? .OBJ ,OPENBIT>
+		<TELL "open">)
+	       (ELSE
+		<TELL "closed">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE THE-PRSO () <TELL THE ,PRSO ,PERIOD>>
+
+<ROUTINE A-PRSO () <TELL A ,PRSO ,PERIOD>>
+
+<ROUTINE A-PRSO? () <TELL A ,PRSO "?" CR>>
+
+<ROUTINE THE-PRSI () <TELL THE ,PRSI ,PERIOD>>
+
+<ROUTINE A-PRSI () <TELL A ,PRSI ,PERIOD>>
+
+<ROUTINE A-PRSI? () <TELL A ,PRSI "?" CR>>
+
+<ROUTINE YOU-CANT-X-THAT (STR)
+	 <TELL ,YOU-CANT .STR " that!" CR>>
+
+<ROUTINE YOU-CANT-X-PRSO (STR)
+	 <TELL ,YOU-CANT .STR " ">
+	 <COND (,PRSO <TELL THE ,PRSO>)
+	       (ELSE <TELL "that">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE YOU-CANT-X-PRSI (STR)
+	 <TELL ,YOU-CANT .STR " ">
+	 <COND (,PRSI <TELL THE ,PRSI>)
+	       (ELSE <TELL "that">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE UNINTERESTED (OBJ)
+	 <COND (<EQUAL? .OBJ ,ME>
+		<TELL-YUKS>)
+	       (ELSE
+		<TELL CTHE .OBJ " is uninterested." CR>)>>
+
+<ROUTINE CANT-REACH-THAT ()
+	 <TELL ,YOU-CANT-REACH "that." CR>>
+
+<ROUTINE CANT-REACH-IT ()
+	 <TELL ,YOU-CANT-REACH "it." CR>>
+
+;"end of space saving stuff"
+
+;"subtitle game commands"
+
+<GLOBAL VERBOSITY 1>
+
+<GLOBAL DESCRIPTIONS " descriptions">
+
+<ROUTINE V-VERBOSE ()
+	 <SETG VERBOSITY 2>
+	 <TELL "Verbose" ,DESCRIPTIONS ,PERIOD CR>
+	 <V-LOOK>>
+
+<ROUTINE V-BRIEF ()
+	 <SETG VERBOSITY 1>
+	 <TELL "Brief" ,DESCRIPTIONS ,PERIOD>>
+
+<ROUTINE V-SUPER-BRIEF ()
+	 <SETG VERBOSITY <>>
+	 <TELL "Super-brief" ,DESCRIPTIONS ,PERIOD>>
+
+<ROUTINE V-DIAGNOSE ()
+	 <TELL "You are ">
+	 <COND (,SMALL-FLAG <TELL "shrunken, ">)>
+	 <COND (,CHANGED? <TELL "transformed into a " 'CHANGED? ", ">)>
+	 <COND (<L? ,AWAKE 0>
+		<TELL "wide awake">)
+	       (T
+		<TELL <GET ,TIRED-TELL ,AWAKE>>)>
+	 <TELL ", and in ">
+	 <COND (<G? ,FREEZE-COUNT 4>
+		<TELL "danger of freezing to death">)
+	       (ELSE
+		<TELL "good health">)>
+	 <TELL ,PERIOD>>
+
+<GLOBAL TIRED-TELL
+       <PTABLE
+	"beginning to tire"
+	"feeling tired"
+	"getting more and more tired"
+	"worn out"
+	"dead tired"
+	"so tired you can barely concentrate"
+	"moving on your last reserves of strength"
+	"practically asleep"
+	"barely able to keep your eyes open"
+	"about to keel over from exhaustion">>
+
+<ROUTINE V-INVENTORY ()
+	 <COND (<FIRST? ,WINNER>
+		<PRINT-CONT ,WINNER>)
+	       (T
+		<TELL "You are empty-handed." CR>)>>
+
+<ROUTINE V-QUIT ("OPTIONAL" (ASK? T) "AUX" SCOR)
+	 %<DEBUG-CODE <TELL-C-INTS>>
+	 <V-SCORE>
+	 <COND (<OR <AND .ASK?
+			 <TELL
+"Do you wish to leave the game">
+			 <YES?>>
+		    <NOT .ASK?>>
+		<QUIT>)
+	       (T
+		<TELL ,OKAY>)>>
+
+<ROUTINE V-RESTART ()
+	 %<DEBUG-CODE <TELL-C-INTS>>
+	 <V-SCORE T>
+	 <TELL "Do you wish to restart">
+	 <COND (<YES?>
+		<TELL "Restarting." CR>
+		<RESTART>
+		<TELL ,FAILED>)>>
+
+<GLOBAL OKAY "Okay.|">
+
+<GLOBAL FAILED "Failed.|">
+
+<ROUTINE FINISH ("OPTIONAL" (REPEATING <>))
+	 <CRLF>
+	 %<DEBUG-CODE <TELL-C-INTS>>
+	 <COND (<NOT .REPEATING>
+		<V-SCORE>
+		<CRLF>)>
+	 <TELL
+"Would you like to restart the game from the beginning, restore a saved
+game position, or end this session of the game?|
+(Type RESTART, RESTORE, or QUIT):|
+>">
+	 <READ ,P-INBUF ,P-LEXV>
+	 <COND (<EQUAL? <GET ,P-LEXV 1> ,W?RESTAR>
+	        <RESTART>
+		<TELL ,FAILED>
+		<FINISH T>)
+	       (<EQUAL? <GET ,P-LEXV 1> ,W?RESTOR>
+		<COND (<RESTORE>
+		       <TELL ,OKAY>)
+		      (T
+		       <TELL ,FAILED>
+		       <FINISH T>)>)
+	       (T
+		<QUIT>)>>
+
+<ROUTINE YES? ()
+	 <PRINTI "?|
+(Y is affirmative): >">
+	 <READ ,P-INBUF ,P-LEXV>
+	 <COND (<EQUAL? <GET ,P-LEXV 1> ,W?YES ,W?Y>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE V-RESTORE ()
+	 <COND (<RESTORE> <RTRUE>)
+	       (T
+		<TELL ,FAILED>)>>
+
+<ROUTINE V-SAVE ("AUX" X)
+	 <PUTB ,OOPS-INBUF 1 0>
+	 <SET X <SAVE>>
+	 <COND (<ZERO? .X>
+	        <TELL ,FAILED>)
+	       (ELSE
+		<TELL ,OKAY>)>>
+
+<ROUTINE V-SCORE ("OPTIONAL" (ASK? T))
+	 <TELL
+"Your score is " N ,SCORE " of a possible 600, in " N ,MOVES " move">
+	 <COND (<NOT <1? ,MOVES>> <TELL "s">)>
+	 <TELL ". This puts you in the class of ">
+	 <COND (<L? ,SCORE 0>
+		<TELL "Menace to Society">)
+	       (T
+		<TELL <GET ,RANKINGS </ ,SCORE 50>>>)>
+	 <TELL ,PERIOD>
+	 ,SCORE>
+
+<GLOBAL RANKINGS
+	<PTABLE
+	 "Charlatan"		;"0-49"
+	 "Parlor Magician"	;"50-99"
+	 "Magician"		;"100-149"
+	 "Novice Enchanter"	;"150"
+	 "Enchanter"		;"200-249"
+	 "Expert Enchanter"
+	 "Novice Sorcerer"	;"300-349"
+         "Sorcerer"
+	 "Expert Sorcerer"	;"400-449"
+	 "Novice Mage"
+	 "Mage"			;"500-549"
+	 "Archimage"
+	 "Scientist" ;"600">>
+
+<ROUTINE V-SCRIPT ()
+	<PUT 0 8 <BOR <GET 0 8> 1>>
+	<TELL "Here begins" ,COPR-NOTICE CR>
+	<V-VERSION>>
+
+<ROUTINE V-UNSCRIPT ()
+	<TELL "Here ends" ,COPR-NOTICE CR>
+	<V-VERSION>
+	<PUT 0 8 <BAND <GET 0 8> -2>>
+	<RTRUE>>
+
+<GLOBAL COPR-NOTICE
+" a transcript of interaction with SPELLBREAKER.">
+
+<ROUTINE V-VERSION ("AUX" (CNT 17))
+	 <TELL <COND (<PROB 99> "SPELLBREAKER")
+		     (ELSE "MAGE")>
+"|
+An Interactive Fantasy|
+Copyright (c) 1985 by Infocom, Inc. All rights reserved.|
+SPELLBREAKER is a trademark of Infocom, Inc.|
+Release ">
+	 <PRINTN <BAND <GET 0 1> *3777*>>
+	 <TELL " / Serial number ">
+	 <REPEAT ()
+		 <COND (<G? <SET CNT <+ .CNT 1>> 23>
+			<RETURN>)
+		       (T
+			<PRINTC <GETB 0 .CNT>>)>>
+	 <CRLF>>
+
+<ROUTINE V-$VERIFY ()
+	 <COND (<AND <EQUAL? ,PRSO ,INTNUM>
+		     <EQUAL? ,P-NUMBER 1066>>
+		<TELL N ,SERIAL CR>)
+	       (,PRSO
+		<TELL ,NOT-RECOGNIZED CR>)
+	       (ELSE
+		<TELL "Verifying..." CR>
+		<COND (<VERIFY> <TELL "The disk is correct." CR>)
+		      (T <TELL CR "** Disk Failure **" CR>)>)>>
+^\L
+
+;"subtitle real verbs"
+
+<ROUTINE V-ALARM ()
+	 <COND (<EQUAL? ,PRSO ,ROOMS>
+		<PERFORM ,V?ALARM ,ME>
+		<RTRUE>)
+	       (<EQUAL? ,PRSO ,ESPNIS?>
+		<TELL
+"It would take more than that to awaken "><THE-PRSO>)
+	       (T
+		<TELL
+,I-DONT-THINK-THAT THE ,PRSO " is sleeping." CR>)>>
+
+<ROUTINE V-ANSWER ()
+	 <TELL "Nobody is awaiting your answer." CR>
+	 <END-QUOTE>>
+
+"V-ASK-ABOUT -- transform into PRSO, TELL ME ABOUT PRSI"
+
+<ROUTINE PRE-ASK-ABOUT ("AUX" P)
+	 <COND (<AND <NOT ,PRSI>
+		     <SET P <FIND-IN ,HERE ,PERSON>>>
+		<PERFORM ,PRSA .P ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-ASK-ABOUT ("AUX" OWINNER)
+	 <COND (<EQUAL? ,PRSO ,ME>
+		<PERFORM ,V?TELL ,ME>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<SET OWINNER ,WINNER>
+		<SETG WINNER ,PRSO>
+		<PERFORM ,V?TELL-ME-ABOUT ,PRSI>
+		<SETG WINNER .OWINNER>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?TELL ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE FIND-IN (WHERE WHAT "AUX" W)
+	 <SET W <FIRST? .WHERE>>
+	 <REPEAT ()
+		 <COND (<NOT .W> <RFALSE>)
+		       (<AND <FSET? .W .WHAT>
+			     <VISIBLE? .W>>
+			<RETURN .W>)>
+		 <SET W <NEXT? .W>>>>
+
+"V-ASK-FOR -- transform into PRSO, GIVE PRSI TO ME"
+
+<ROUTINE PRE-ASK-FOR ()
+	 <PRE-ASK-ABOUT>>
+
+<ROUTINE V-ASK-FOR ("AUX" OWINNER)
+	 <COND (<EQUAL? ,PRSO ,ME>
+		<PERFORM ,V?TAKE ,PRSI>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<SET OWINNER ,WINNER>
+		<SETG WINNER ,PRSO>
+		<PERFORM ,V?GIVE ,PRSI ,ME>
+		<SETG WINNER .OWINNER>
+		<RTRUE>)
+	       (T
+		<TELL
+"It's unlikely that " THE ,PRSO " will oblige." CR>)>>
+
+<ROUTINE V-ATTACK ()
+	 <IKILL "attack">>
+
+<ROUTINE V-BITE ()
+	 <HACK-HACK "Biting">>
+
+<ROUTINE PRE-BOARD ("AUX" AV)
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<COND (<EQUAL? .AV ,PRSO>
+		       <TELL ,YOU-ARE ,PERIOD>)
+		      (<AND <FSET? .AV ,VEHBIT>
+			    <HELD? ,PRSO .AV>>
+		       <TELL ,YOU-HAVE-TO " leave " THE .AV " first" ,PERIOD>)
+		      (T
+		       <RFALSE>)>)
+	       (T
+		<TELL ,YOU-CANT "get into " THE ,PRSO "!" CR>)>
+	 <RFATAL>>
+
+<ROUTINE YOU-ARE-IN (AV)
+	 <TELL ,YOU-ARE
+	       <COND (<FSET? .AV ,SURFACEBIT> " on ")
+		     (ELSE " in ")>
+	       THE .AV "!" CR>>
+
+<ROUTINE V-BOARD ("AUX" AV)
+	 <TELL ,YOU-ARE-NOW "in ">
+	 <THE-PRSO>
+	 <MOVE ,WINNER ,PRSO>
+	 %<DEBUG-CODE <D-APPLY "Get in" <GETP ,PRSO ,P?ACTION> ,M-ENTER>
+		      <APPLY <GETP ,PRSO ,P?ACTION> ,M-ENTER>>
+	 <RTRUE>>
+
+<ROUTINE V-BURN ()
+	 <COND (<NOT ,PRSI>
+		<TELL "Your blazing gaze is insufficient." CR>)
+	       (T
+		<WITH-PRSI?>)>>
+
+<ROUTINE V-CHASTISE ()
+	 <TELL
+"Use prepositions instead: LOOK AT the object, LOOK INSIDE it,
+LOOK UNDER it, etc." CR>>
+
+<ROUTINE V-CLIMB-DOWN ()
+	 <COND (<EQUAL? ,PRSO ,ROOMS>
+		<DO-WALK ,P?DOWN>)
+	       (T
+		<V-SQUEEZE>)>>
+
+<ROUTINE V-CLIMB-FOO ()
+	 <COND (<EQUAL? ,PRSO ,ROOMS>
+		<DO-WALK ,P?UP>)
+	       (T
+		<V-SQUEEZE>)>>
+
+<ROUTINE V-CLIMB-ON ()
+	 <COND (<AND <FSET? ,PRSO ,VEHBIT>
+		     <FSET? ,PRSO ,SURFACEBIT>>
+		<PERFORM ,V?BOARD ,PRSO>
+		<RTRUE>)
+	       (T
+		<TELL ,YOU-CANT "climb onto "><A-PRSO>)>>
+
+<ROUTINE V-CLIMB-OVER ()
+	 <YOU-CANT-X-THAT "do">>
+
+<ROUTINE V-CLIMB-UP ()
+	 <COND (<EQUAL? ,PRSO ,ROOMS>
+		<DO-WALK ,P?UP>)
+	       (T
+		<V-SQUEEZE>)>>
+
+<ROUTINE PRE-CLOSE ()
+	 <COND (<IMMOBILIZED?> <RTRUE>)>>
+
+<ROUTINE V-CLOSE ()
+	 <COND (<FSET? ,PRSO ,SURFACEBIT>
+		<TELL "There's no way to close "><THE-PRSO>)
+	       (<AND <NOT <FSET? ,PRSO ,CONTBIT>>
+		     <NOT <FSET? ,PRSO ,DOORBIT>>>
+		<PERFORM ,V?OPEN ,PRSO>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "Huh?" CR>)
+	       (<AND <NOT <FSET? ,PRSO ,SURFACEBIT>>
+		     <NOT <EQUAL? <GETP ,PRSO ,P?CAPACITY> 0>>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <FCLEAR ,PRSO ,OPENBIT>
+		       <TELL "Closed.">
+		       <SETG LIT <LIT? ,HERE>>
+		       <COND (<NOT ,LIT>
+			      <TELL " ">
+			      <TELL ,NOW-BLACK>)>
+		       <CRLF>)
+		      (T
+		       <ALREADY-CLOSED>)>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <OKAY-THE-PRSO-IS-NOW "closed">
+		       <FCLEAR ,PRSO ,OPENBIT>)
+		      (T
+		       <ALREADY-CLOSED>)>)
+	       (T
+		<TELL "You cannot close that." CR>)>>
+
+<ROUTINE OKAY-THE-PRSO-IS-NOW (STR)
+	 <TELL "Okay, " THE ,PRSO " is now " .STR ,PERIOD>>
+
+<ROUTINE V-COMPARE ()
+	 <TELL ,WASTE-OF-TIME>>
+
+<ROUTINE V-COUNT ()
+	 <TELL ,WASTE-OF-TIME>>
+
+<ROUTINE V-CROSS ()
+	 <YOU-CANT-X-THAT "cross">>
+
+<ROUTINE V-CURSE ()
+	 <TELL
+"Moral turpitude is grounds for expulsion from the Circle!" CR>>
+
+<ROUTINE V-CUT ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<PERFORM ,V?KILL ,PRSO ,PRSI>
+		<RTRUE>)
+	       (<AND <FSET? ,PRSI ,WEAPONBIT>
+		     <OR <FSET? ,PRSO ,SCROLLBIT>
+			 <EQUAL? ,PRSO ,CARPET-LABEL>>>
+		<REMOVE ,PRSO>
+		<TELL
+"Skillfully wielding the " 'PRSI ", you slice "
+THE ,PRSO " into slivers, which vanish." CR>)
+	       (<NOT <FSET? ,PRSI ,WEAPONBIT>>
+		<TELL
+"I doubt that the \"cutting edge\" of " THE ,PRSI " is adequate." CR>)
+	       (T
+		<TELL
+"Strange concept, cutting "> <A-PRSO>)>>
+
+<ROUTINE V-DIG ()
+	 <COND (<AND <IN? ,WINNER ,MAGIC-CARPET>
+		     <G? ,UD-COUNT 0>>
+		<TELL ,WHILE-FLYING>)
+	       (T
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-DISEMBARK ("AUX" AV)
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<OR <NOT ,PRSO>
+		    <EQUAL? ,PRSO ,ROOMS>>
+		<COND (<AND .AV <FSET? .AV ,VEHBIT>>
+		       <PERFORM ,V?DISEMBARK .AV>
+		       <RTRUE>)
+		      (<FSET? ,HERE ,RWATERBIT>
+		       <DO-WALK ,P?UP>)
+		      (ELSE
+		       <TELL ,YOU-ARENT "in anything." CR>)>)
+	       (<AND .AV
+		     <FSET? .AV ,VEHBIT>>
+		<COND (<AND <NOT <EQUAL? .AV ,PRSO>>
+			    <NOT <HELD? .AV ,PRSO>>>
+		       <YOU-ARE-IN .AV>
+		       <RFATAL>)
+		      (T
+		       <MOVE ,WINNER <LOC ,PRSO>> ;"for vehicle in vehicle"
+		       <TELL ,YOU-ARE-NOW "on your feet." CR>)>)
+	       (<LOC ,PRSO>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL "It's not in anything." CR>)>>
+
+<ROUTINE V-DRINK ("AUX" S)
+	 <YOU-CANT-X-THAT "drink">>
+
+<ROUTINE V-DRINK-FROM ("AUX" X)
+	 <COND (<EQUAL? ,PRSO ,WATER>
+		<PERFORM ,V?DRINK ,PRSO>
+		<RTRUE>)
+	       (T
+		<HOW-DO-YOU>
+		<A-PRSO?>)>>
+
+<ROUTINE PRE-DROP ()
+	 <COND (<EQUAL? ,PRSO <LOC ,WINNER>>
+		<PERFORM ,V?DISEMBARK ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-DROP ()
+	 <COND (<IDROP>
+		<TELL "Dropped." CR>)
+	       (ELSE <RTRUE>)>>
+
+<ROUTINE V-EAT ("AUX" OLIT)
+	 <COND (<EQUAL? ,PRSO ,FISH ,BREAD>
+		<SET OLIT ,LIT>
+		<REMOVE ,PRSO>
+		<TELL
+"Yum! That was pretty good, considering that it's a leftover from
+the luncheon.">
+		<GOT-DARK? .OLIT>
+		<CRLF>)
+	       (ELSE
+		<TELL
+"Did they teach you to eat that in survival school?" CR>)>>
+
+<ROUTINE GOT-DARK? (OLIT)
+	 <SETG LIT <LIT? ,HERE>>
+	 <COND (<AND .OLIT <NOT ,LIT>>
+		<TELL " ">
+		<COND (<OR <EQUAL? ,HERE ,DARK-CAVE ,GRUE-CAVE ,LIGHT-POOL>
+			   <EQUAL? ,HERE ,PILLAR-ROOM>>
+		       <TELL "It's now darker.">)
+		      (ELSE
+		       <TELL ,NOW-BLACK>)>)>>
+
+<ROUTINE V-ENTER ("AUX" VEHICLE)
+	 <COND (<SET VEHICLE <FIND-IN ,HERE ,VEHBIT>>
+		<PERFORM ,V?BOARD .VEHICLE>
+		<RTRUE>)
+	       (<GETPT ,HERE ,P?IN>
+		<DO-WALK ,P?IN>)
+	       (ELSE <V-WALK-AROUND>)>>
+
+<ROUTINE PRE-EXAMINE ()
+	 <COND (<NOT ,LIT>
+		<TELL ,TOO-DARK>)>>
+
+<ROUTINE V-EXAMINE ()
+	 <COND (<AND <OR <FSET? ,PRSO ,READBIT>
+			 <FSET? ,PRSO ,SPELLBIT>>
+		     <GETP ,PRSO ,P?TEXT>>
+		<PERFORM ,V?READ ,PRSO>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<V-LOOK-INSIDE>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <V-LOOK-INSIDE>)
+		      (T
+		       <TELL "It's closed." CR>)>)
+	       (<FSET? ,PRSO ,ONBIT>
+		<TELL
+"Someone must have cast " THE ,FROTZ-SPELL " on " THE ,PRSO ", because it
+is glowing brightly." CR>)
+	       (T
+		<PRSO-NOTHING-SPECIAL>)>>
+
+<ROUTINE PRSO-NOTHING-SPECIAL ()
+	 <TELL "You see nothing special about "><THE-PRSO>>
+
+<ROUTINE V-EXIT ()
+	 <COND (<AND ,PRSO <FSET? ,PRSO ,VEHBIT>>
+		<PERFORM ,V?DISEMBARK ,PRSO>
+		<RTRUE>)
+	       (<GETPT ,HERE ,P?OUT>
+		<DO-WALK ,P?OUT>)
+	       (ELSE
+		<V-WALK-AROUND>)>>
+
+;<ROUTINE V-EXORCISE ()
+	 <TELL ,YOU-CANT "do that with mere words!" CR>>
+
+<ROUTINE V-FILL ()
+	 <COND (<NOT ,PRSI>
+		<COND (<GLOBAL-IN? ,WATER ,HERE>
+		       <PERFORM ,V?FILL ,PRSO ,WATER>
+		       <RTRUE>)
+		      (T
+		       <TELL ,THERES-NOTHING-TO "fill it with" ,PERIOD>)>)
+	       (T
+		<TELL "Huh?" CR>)>>
+
+<ROUTINE V-FIND ("OPTIONAL" (WHERE <>) "AUX" (L <LOC ,PRSO>))
+	 <COND (<EQUAL? ,PRSO ,ME ,HANDS ,EYES>
+		<TELL
+"Somewhere nearby, I'm sure">)
+	       (<IN? ,PRSO ,PLAYER>
+		<TELL "You have it">)
+	       (<OR <IN? ,PRSO ,HERE>
+		    <EQUAL? ,PRSO ,PSEUDO-OBJECT>>
+		<COND (<FSET? ,PRSO ,PERSON>
+		       <COND (<EQUAL? ,PRSO ,ROC>
+			      <TELL "She">)
+			     (ELSE
+			      <TELL "He">)>)
+		      (T
+		       <TELL "It">)>
+		<TELL "'s right in front of you">)
+	       (<IN? ,PRSO ,LOCAL-GLOBALS>
+		<TELL "You're the magician">)
+	       (<AND <FSET? .L ,PERSON>
+		     <VISIBLE? .L>>
+		<TELL "I think " THE .L " has it">)
+	       (<AND <FSET? .L ,CONTBIT>
+		     <VISIBLE? .L>>
+		<TELL "It's in " THE .L>)
+	       (.WHERE
+		<TELL "Beats me">)
+	       (T
+		<TELL ,YOU-HAVE-TO " do that yourself">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE V-FLY ()
+	 <COND (<EQUAL? ,PRSO <> ,ME>
+		<COND (<AND <IN? ,WINNER ,MAGIC-CARPET>
+			    <G? ,UD-COUNT 0>>
+		       <TELL "You are!" CR>)
+	              (T
+		       <TELL "Perhaps some magical assistance?" CR>)>)
+	       (<EQUAL? ,PRSO ,P-WALK-DIR>
+		<DO-WALK ,PRSO>
+		<RTRUE>)
+	       (T
+		<TELL ,YOU-CANT "make " A ,PRSO " fly!" CR>)>>
+
+<ROUTINE V-FOLLOW ()
+	 <COND (<AND ,PRSO <IN? ,PRSO ,HERE>>
+		<TELL "But " THE ,PRSO " is right here!" CR>)
+	       (T
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-FORGET ()
+	 <TELL
+"You can never forget, uh, whatever it was." CR>>
+
+<ROUTINE PRE-GIVE ()
+	 <COND (<AND <EQUAL? ,PRSO ,INTNUM>
+		     <HELD? ,ZORKMID>>
+		<RFALSE>)
+	       (<NOT <HELD? ,PRSO>>
+		<TELL
+,YOU-HAVE-TO " get it first." CR>)
+	       (<FSET? ,PRSO ,SPELLBIT>
+		<TELL
+"Spells are intangible." CR>)>>
+
+<ROUTINE V-GIVE ()
+	 <COND (<NOT <FSET? ,PRSI ,PERSON>>
+		<TELL ,YOU-CANT "give " A ,PRSO " to " A ,PRSI "!" CR>)
+	       (T
+		<UNINTERESTED ,PRSI>)>>
+
+<ROUTINE V-HELLO ("AUX" OWINNER)
+       <COND (,PRSO
+	      <COND (<FSET? ,PRSO ,PERSON>
+		     <SET OWINNER ,WINNER>
+		     <SETG WINNER ,PRSO>
+		     <PERFORM ,V?HELLO>
+		     <SETG WINNER .OWINNER>)
+		    (T
+		     <TELL
+"Mages never say \"Hello\" to "><A-PRSO>)>)
+	     (T
+	      <TELL "Cheery, aren't you?" CR>)>>
+
+<ROUTINE V-HELP ()
+	 <TELL
+"If you're really stuck, you can order maps and InvisiClues Hint
+Booklets using the order form that came in your package." CR>>
+
+<ROUTINE V-HIDE ()
+	 <COND (<NOT ,PRSO>
+		<TELL "There's no place to hide here." CR>
+		<RFATAL>)
+	       (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+		<UNINTERESTED ,PRSI>)
+	       (<NOT ,PRSI>
+		<V-SQUEEZE> ;"useless")>>
+
+<ROUTINE V-HIDE-FROM ()
+	 <TELL ,YOU-HAVE-TO " decide where." CR>>
+
+<ROUTINE V-INFLATE ()
+	 <HOW-DO-YOU> <A-PRSO?>>
+
+<ROUTINE V-KICK ()
+	 <HACK-HACK "Kicking">>
+
+<ROUTINE V-KILL ()
+	 <IKILL "kill">>
+
+<ROUTINE IKILL (STR)
+	 <COND (<NOT ,PRSO>
+		<TELL ,THERES-NOTHING-TO .STR " here." CR>)
+	       (<AND <NOT ,PRSI>
+		     <IN? ,KNIFE ,WINNER>>
+		<SETG PRSI ,KNIFE>
+		<TELL "(with " THE ,PRSI ")" CR>
+		<PERFORM ,V?KILL ,PRSO ,PRSI>
+		<RTRUE>)>
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<TELL
+"Pounding on a door is of little use." CR>)
+	       (<NOT <FSET? ,PRSO ,PERSON>>
+		<TELL
+"How strange. Fighting "> <A-PRSO?>)
+	       (<OR <EQUAL? ,PRSI <> ,HANDS>
+		    <NOT <FSET? ,PRSI ,WEAPONBIT>>>
+		<TELL
+"Trying to " .STR " " THE ,PRSO " with ">
+		<COND (<NOT <EQUAL? ,PRSI <> ,HANDS>>
+		       <TELL A ,PRSI>)
+		      (ELSE <TELL "your bare hands">)>
+		<TELL " is suicidal." CR>)
+	       (<NOT <IN? ,PRSI ,WINNER>>
+		<NOT-HOLDING ,PRSI>)
+	       (T
+		<NOT-TRAINED>)>>
+
+<ROUTINE NOT-TRAINED ()
+	 <TELL
+"You miss. (Mages aren't given a lot of training in this sort of thing.)" CR>>
+
+<ROUTINE V-KNOCK ()
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<TELL "Nobody's home." CR>)
+	       (T
+		<TELL "Why knock on "> <A-PRSO?>)>>
+
+<ROUTINE V-KISS ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<UNINTERESTED ,PRSO>)
+	       (ELSE <V-SQUEEZE>)>>
+
+<ROUTINE V-LAMP-OFF ()
+	 <COND (<FSET? ,PRSO ,ONBIT>
+		<FCLEAR ,PRSO ,ONBIT>
+		<COND (<EQUAL? ,PRSO ,ME>
+		       <FCLEAR ,PLAYER ,ONBIT>)>
+		<TELL "The magical glow fades">
+		<SETG LIT <LIT? ,HERE>>
+		<COND (<NOT ,LIT>
+		       <TELL ", leaving you in the dark">)>
+		<TELL ,PERIOD>)
+	       (T
+		<HOW-DO-YOU> <A-PRSO?>)>>
+
+<ROUTINE V-LAMP-ON ()
+	 <HOW-DO-YOU> <A-PRSO?>>
+
+<ROUTINE V-LAND ()
+	 <COND (<IN? ,WINNER ,MAGIC-CARPET>
+		<DO-WALK ,P?DOWN>)
+	       (T
+		<TELL ,LOOK-AROUND-YOU>)>>
+
+<ROUTINE V-LEAN-ON ()
+	 <TELL "Tired?" CR>>
+
+<ROUTINE V-LEAP ()
+	 <COND (<AND <IN? ,WINNER ,MAGIC-CARPET>
+		     <G? ,UD-COUNT 0>>
+		<TELL ,WHILE-FLYING>)
+	       (<AND <EQUAL? ,PRSO <> ,ROOMS>
+		     <EQUAL? ,HERE ,CLIFF-MIDDLE ,BOULDER-1 ,BOULDER-2>>
+		<JIGS-UP
+"This was not a safe place to try jumping. You should have looked
+before you leaped.">)
+	       (<AND ,PRSO <IN? ,PRSO ,HERE>>
+		<V-SKIP>)
+	       (T
+		<TELL "That would be a good trick." CR>)>>
+
+<ROUTINE V-LEAVE ()
+	 <DO-WALK ,P?OUT>>
+
+<ROUTINE V-LISTEN ()
+	 <COND (<AND <EQUAL? ,PRSO <> ,GLOBAL-ROCKS>
+		     <QUEUED? I-AVALANCHE>
+		     <NOT <TIME-FROZEN?>>
+		     <OR <EQUAL? ,HERE ,MOUNTAIN-TOP ,CAVE-ENTRANCE ,CLIFF-TOP>
+			 <EQUAL? ,HERE ,CLIFF-MIDDLE ,CLIFF-BOTTOM>>>
+		<HEAR-AVALANCHE>)
+	       (ELSE
+		<TELL "At the moment, ">
+		<COND (<NOT ,PRSO>
+		       <TELL
+			"you hear nothing unsettling">)
+		      (ELSE
+		       <TELL
+			THE ,PRSO " makes no sound">)>)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE V-LOCK ()
+	 <COND (<AND <FSET? ,PRSO ,DOORBIT>
+		     <EQUAL? ,PRSI ,KEY>>
+		<TELL ,DOESNT-FIT>)
+	       (ELSE
+		<TELL-YUKS>)>>
+
+<ROUTINE V-FIRST-LOOK ()
+	 <COND (<DESCRIBE-ROOM>
+		<COND (,VERBOSITY <DESCRIBE-OBJECTS>)>)>>
+
+<ROUTINE V-LOOK ()
+	 <COND (<DESCRIBE-ROOM T>
+		<DESCRIBE-OBJECTS T>)>>
+
+<ROUTINE V-LOOK-BEHIND ()
+	 <TELL ,THERE-IS-NOTHING "behind "><THE-PRSO>>
+
+<ROUTINE V-LOOK-DOWN ()
+	 <COND (<NOT ,LIT>
+		<TELL ,TOO-DARK>)
+	       (<EQUAL? ,PRSO <> ,ROOMS ,GLOBAL-HOLE>
+		<COND (<GLOBAL-IN? ,GLOBAL-HOLE ,HERE>
+		       <PERFORM ,V?LOOK-INSIDE ,GLOBAL-HOLE>)
+		      (ELSE
+		       <PERFORM ,V?EXAMINE ,GROUND>)>
+		<RTRUE>)>>
+
+<ROUTINE WHAT-CONTENTS ()
+	 <COND (<NOT <PRINT-CONTENTS ,PRSO>>
+		<TELL "nothing">
+		<COND (<IN? ,PLAYER ,PRSO>
+		       <TELL " (other than you)">)>)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE V-LOOK-INSIDE ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<PRSO-NOTHING-SPECIAL>)
+	       (<FSET? ,PRSO ,SURFACEBIT>
+		<TELL "On " THE ,PRSO " is ">
+		<WHAT-CONTENTS>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<THIS-IS-IT ,PRSO>
+		<TELL "All you can tell is that ">
+		<TELL-OPEN-CLOSED>)
+	       (<FSET? ,PRSO ,SCROLLBIT>
+		<PERFORM ,V?READ ,PRSO>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<EQUAL? ,PRSO <LOC ,WINNER>>
+		       <MOVE ,PLAYER ,ROOMS>
+		       <TELL "Aside from you, there's ">
+		       <WHAT-CONTENTS>
+		       <MOVE ,PLAYER ,PRSO>)
+		      (<SEE-INSIDE? ,PRSO>
+		       <TELL CTHE ,PRSO " contains ">
+		       <WHAT-CONTENTS>)
+		      (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+			    <FIRST? ,PRSO>>
+		       <PERFORM ,V?OPEN ,PRSO>
+		       <RTRUE>)
+		      (T
+		       <THIS-IS-IT ,PRSO>
+		       <TELL "It seems ">
+		       <TELL-OPEN-CLOSED>)>)
+	       (T
+		<YOU-CANT-X-PRSO "look inside">)>>
+
+<ROUTINE V-LOOK-UNDER ()
+	 <COND (<HELD? ,PRSO>
+		<TELL "You're already holding it!" CR>)
+	       (T
+		<TELL ,THERE-IS-NOTHING "there." CR>)>>
+
+<ROUTINE V-LOWER ()
+	 <V-RAISE>>
+
+<ROUTINE V-LOWER-INTO ()
+	 <V-RAISE>>
+
+<ROUTINE V-MELT ()
+	 <TELL "I'm not sure that " THE ,PRSO " can be melted." CR>>
+
+<ROUTINE V-MOVE ()
+	 <COND (<HELD? ,PRSO>
+		<TELL "Why juggle objects?" CR>)
+	       (<AND <FSET? ,PRSO ,TAKEBIT>
+		     <NOT <FSET? ,PRSO ,PERSON>>>
+		<V-TURN-OVER>)
+	       (T
+		<YOU-CANT-X-PRSO "move">)>>
+
+<ROUTINE HOSTILE-VERB? ()
+	 <VERB? ATTACK BITE KICK KILL MUNG RUB PUSH MOVE THROW>>
+
+<ROUTINE V-MUNG ()
+	 <HACK-HACK "Trying to break">>
+
+<ROUTINE PRE-OPEN ()
+	 <COND (<IMMOBILIZED?>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "What a grisly idea." CR>)>>
+
+<ROUTINE V-OPEN ("AUX" F STR)
+	 <COND (<OR <AND <NOT <FSET? ,PRSO ,CONTBIT>>
+		         <NOT <FSET? ,PRSO ,DOORBIT>>>
+		    <FSET? ,PRSO ,SCROLLBIT>>
+		<TELL "You must tell me how to do that to ">
+		<A-PRSO>)
+	       (<NOT <EQUAL? <GETP ,PRSO ,P?CAPACITY> 0>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <ALREADY-OPEN>)
+		      (T
+		       <FSET ,PRSO ,OPENBIT>
+		       <FSET ,PRSO ,TOUCHBIT>
+		       <COND (<OR <NOT <FIRST? ,PRSO>>
+				  <FSET? ,PRSO ,TRANSBIT>>
+			      <TELL "Opened." CR>)
+			     ;(<AND <SET F <FIRST? ,PRSO>>
+				   <NOT <NEXT? .F>>
+				   <SET STR <GETP .F ,P?FDESC>>>
+			      <OKAY-THE-PRSO-IS-NOW "open">
+			      <TELL .STR CR>)
+			     (T
+			      <TELL "Opening ">
+			      <TELL THE ,PRSO " reveals ">
+			      <WHAT-CONTENTS>)>)>)
+	       (T ;"door"
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <ALREADY-OPEN>)
+		      (<FSET? ,PRSO ,LOCKED>
+		       <TELL "It's locked." CR>)
+		      (T
+		       <FSET ,PRSO ,OPENBIT>
+		       <OKAY-THE-PRSO-IS-NOW "open">)>)>>
+
+<ROUTINE V-PAY ()
+	 <COND (<NOT ,PRSI>
+		<TELL "Pay with what?" CR>
+		<RTRUE>)
+	       (T
+		<WITH-PRSI?>)>>
+
+<ROUTINE V-PICK ()
+	 <YOU-CANT-X-THAT "pick">>
+
+<ROUTINE V-PLAY ()
+         <TELL "How peculiar!" CR>>
+
+<ROUTINE V-PLUG ()
+	 <V-TURN> ;"no effect">
+
+<ROUTINE V-POINT ()
+	 <TELL "It's impolite to point." CR>>
+
+<ROUTINE V-POUR ()
+	 <COND (<AND <FSET? ,PRSO ,CONTBIT>
+		     <HELD? ,PRSO>>
+		<EMPTY-ALL ,PRSO ,PRSI>)
+	       (ELSE
+		<YOU-CANT-X-THAT "pour">)>>
+
+<ROUTINE EMPTY-ALL (FROM TO "AUX" (F <FIRST? .FROM>) N R)
+	 <COND (<NOT .F>
+		<TELL CTHE .FROM " is empty." CR>)
+	       (ELSE
+		<REPEAT ()
+			<COND (.F
+			       <SET N <NEXT? .F>>
+			       <TELL D .F ": ">
+			       <SET R
+				    <COND (.TO
+					   <PERFORM ,V?PUT .F .TO>)
+					  (ELSE
+					   <PERFORM ,V?DROP .F>)>>
+			       <COND (<EQUAL? .R ,M-FATAL> <RTRUE>)
+				     (ELSE <SET F .N>)>)
+			      (T
+			       <RTRUE>)>>)>>
+
+<ROUTINE V-PUMP ()
+	 <TELL "It's not clear how." CR>>
+
+<ROUTINE V-PUSH ()
+	 <HACK-HACK "Pushing">>
+
+<ROUTINE V-PUSH-TO ()
+	 <YOU-CANT-X-THAT "push things to">>
+
+<ROUTINE PRE-PUT ("AUX" (L <LOC ,PRSO>))
+	 <COND (<OR <IN? ,PRSO ,GLOBAL-OBJECTS>
+		    <NOT <FSET? ,PRSO ,TAKEBIT>>>
+		<TELL "Nice try." CR>)
+	       (<AND <VERB? PUT>
+		     <FSET? ,PRSO ,WEAPONBIT>
+		     <FSET? ,PRSI ,PERSON>>
+		<PERFORM ,V?ATTACK ,PRSI ,PRSO>
+		<RTRUE>)
+	       (<IN? ,PRSO ,PRSI>
+		<TAKE-OUT-FIRST ,PRSO ,PRSI>)
+	       (<IN? ,PRSI ,PRSO>
+		<TAKE-OUT-FIRST ,PRSI ,PRSO>)
+	       (<AND <FSET? .L ,CONTBIT>
+		     <NOT <FSET? .L ,OPENBIT>>>
+		<TAKE-OUT-FIRST ,PRSO .L>)>>
+
+<ROUTINE TAKE-OUT-FIRST (OBJ CONT)
+	 <TELL
+"You should take " THE .OBJ " out of " THE .CONT " first." CR>>
+
+<ROUTINE V-PUT ("AUX" W)
+	 <COND (<AND <NOT <FSET? ,PRSI ,OPENBIT>>
+		     <NOT <FSET? ,PRSI ,DOORBIT>>
+		     <NOT <FSET? ,PRSI ,CONTBIT>>
+		     <NOT <FSET? ,PRSI ,SURFACEBIT>>
+		     <NOT <FSET? ,PRSI ,VEHBIT>>>
+		<YOU-CANT-X-THAT "do">
+		<RTRUE>)
+	       (<AND <FSET? ,PRSI ,DOORBIT>
+		     <EQUAL? ,PRSO ,KEY>>
+		<PERFORM ,V?UNLOCK ,PRSI ,PRSO>
+		<RTRUE>)
+	       (<AND <NOT <FSET? ,PRSI ,OPENBIT>>
+		     <NOT <FSET? ,PRSI ,SURFACEBIT>>>
+		<TELL "Inspection reveals that ">
+		<TELL THE ,PRSI " isn't open." CR>
+		<THIS-IS-IT ,PRSI>)
+	       (<EQUAL? ,PRSI ,PRSO>
+		<HOW-DO-YOU> <A-PRSO?>)
+	       (<IN? ,PRSO ,PRSI>
+		<TELL "I think ">
+		<TELL THE ,PRSO " is already in ">
+		<THE-PRSI>)
+	       (<AND <FSET? <SET W <LOC ,PRSI>> ,PERSON>
+		     <NOT <EQUAL? .W ,WINNER>>>
+		<TELL
+"Don't you think you should ask " THE .W " first?" CR>)
+	       (<G? <- <+ <WEIGHT ,PRSI> <WEIGHT ,PRSO>>
+		       <GETP ,PRSI ,P?SIZE>>
+		    <GETP ,PRSI ,P?CAPACITY>>
+		<TELL ,NO-ROOM CR>)
+	       (<AND <NOT <HELD? ,PRSO>>
+		     <EQUAL? <ITAKE> ,M-FATAL <>>>
+		<RTRUE>)
+	       (T
+		<MOVE ,PRSO ,PRSI>
+		<FSET ,PRSO ,TOUCHBIT>
+		<TELL "Done." CR>)>>
+
+<ROUTINE V-PUT-BEHIND ()
+	 <TELL "That hiding place is too obvious." CR>>
+
+<ROUTINE V-PUT-ON ()
+	 <COND (<EQUAL? ,PRSI ,ME>
+		<PERFORM ,V?WEAR ,PRSO>
+		<RTRUE>)
+	       (<EQUAL? ,PRSI ,GROUND>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (<FSET? ,PRSI ,SURFACEBIT>
+		<V-PUT>)
+	       (T
+		<TELL "There's no good surface on ">
+		<THE-PRSI>)>>
+
+<ROUTINE V-PUT-UNDER ()
+         <YOU-CANT-X-THAT "put anything under">>
+
+<ROUTINE V-RAISE ()
+	 <HACK-HACK "Lifting">>
+
+<ROUTINE V-REACH-IN ("AUX" OBJ)
+	 <COND (<OR <NOT <FSET? ,PRSO ,CONTBIT>>
+		    <FSET? ,PRSO ,PERSON>>
+		<HOW-DO-YOU> <A-PRSO?>)
+	       (<NOT <FSET? ,PRSO ,OPENBIT>>
+		<TELL "It's not open." CR>)
+	       (<OR <NOT <SET OBJ <FIRST? ,PRSO>>>
+		    <FSET? .OBJ ,INVISIBLE>
+		    <NOT <FSET? .OBJ ,TAKEBIT>>>
+		<ITS-EMPTY>)
+	       (T
+		<TELL
+"You reach into " THE ,PRSO " and feel something." CR>
+		<RTRUE>)>>
+
+<ROUTINE PRE-READ ()
+	 <COND (<EQUAL? ,PRSO ,SPELL-BOOK>
+		<RFALSE> ;"special case")
+	       (<AND <FSET? ,PRSO ,SPELLBIT>
+		     <IN? ,PRSO ,SPELL-BOOK>>
+		<RFALSE> ;"same special case")
+	       (<NOT ,LIT>
+		<TELL "You can't read in the dark." CR>)
+	       (<AND ,PRSI <NOT <FSET? ,PRSI ,TRANSBIT>>>
+		<HOW-DO-YOU> <A-PRSI?>)>>
+
+<ROUTINE HOW-DO-YOU ()
+	 <TELL "How do you do that with ">>
+
+<ROUTINE V-READ ()
+	 <COND (<OR <FSET? ,PRSO ,READBIT>
+                    <FSET? ,PRSO ,SPELLBIT>>
+		<TELL <GETP ,PRSO ,P?TEXT> CR>)
+               (T
+                <HOW-DO-YOU> <A-PRSO?>)>>
+
+<ROUTINE V-REPLY ()
+	 <COND (<AND <EQUAL? ,HERE ,RETREAT>
+		     <NOT <EQUAL? ,PRSO ,BELBOZ>>
+		     <NOT ,PRSI>>
+		<PERFORM ,V?REPLY ,BELBOZ ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL "Your reply is ignored." CR>
+		<END-QUOTE>)>>
+
+<ROUTINE PRE-SRUB ()
+	 <PERFORM ,V?RUB ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SRUB ()
+	 <RTRUE>>
+
+<ROUTINE V-RUB ()
+	 <HACK-HACK "Fiddling with">>
+
+<ROUTINE V-SAY ("AUX" V)
+	 <COND (<SET V <FIND-IN ,HERE ,PERSON>>
+		<TELL "You must address ">
+		<TELL THE .V " directly." CR>
+		<END-QUOTE>)
+	       (<EQUAL? <GET ,P-LEXV ,P-CONT> ,W?HELLO>
+		<SETG QUOTE-FLAG <>>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?TELL ,ME>
+		<END-QUOTE>)>>
+
+<ROUTINE V-SEARCH ()
+	 <COND (<AND <FSET? ,PRSO ,PERSON>
+		     <NOT <EQUAL? ,ESPNIS? ,PRSO>>
+		     <NOT <TIME-FROZEN?>>>
+		<TELL
+CTHE ,PRSO " refuses to let you search him." CR>)
+	       (ELSE
+		<TELL ,THERE-IS-NOTHING "there" ,PERIOD>)>>
+
+<ROUTINE V-SEND ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL "Why would you send for ">
+		<A-PRSO?>)
+	       (T
+		<TELL-YUKS>)>>
+
+<ROUTINE PRE-SGIVE ()
+	 <PERFORM ,V?GIVE ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SGIVE ()
+	 <RTRUE>>
+
+<ROUTINE V-SHAKE ("AUX" X)
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL "Be real." CR>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<TELL ,YOU-CANT "take it; thus, you can't shake it!" CR>)
+	       (T
+		<TELL "There's no point in shaking that." CR>)>>
+
+<ROUTINE V-SHARPEN ()
+	 <TELL "You'll never sharpen anything with that!" CR>>
+
+<ROUTINE V-SHOOT ()
+	 <TELL
+"Don't ever bother applying for a job as an armaments expert." CR>>
+
+<ROUTINE V-SHOW ()
+	 <UNINTERESTED ,PRSI>>
+
+<ROUTINE V-SIT ()
+	 <TELL ,WASTE-OF-TIME>>
+
+<ROUTINE V-SKIP ()
+	 <TELL "Wasn't that fun?" CR>>
+
+<ROUTINE IMPOSSIBLE-TO-SLEEP ()
+	 <TELL
+"It's impossible to sleep at a time like this!" CR>>
+
+<ROUTINE V-SLEEP ("OPTIONAL" (FORCE? <>))
+	 <COND (<OR <EQUAL? <LOC ,WINNER> ,ROC>
+		    <EQUAL? ,HERE ,ROC-NEST>>
+		<COND (.FORCE?
+		       <TELL
+"You fall asleep and then awaken as you">
+		       <COND (<FSET? <LOC ,WINNER> ,VEHBIT>
+			      <TELL " and " CTHE <LOC ,WINNER>>)>
+		       <TELL " are eaten by a roc chick.">
+		       <JIGS-UP>)
+		      (ELSE
+		       <IMPOSSIBLE-TO-SLEEP>)>)
+	       (<EQUAL? ,HERE ,CASTLE>
+		<COND (<VERB? ESPNIS>
+		       <SETG SCORE -99>
+		       <TELL
+"You fall asleep and miss the end of the world.">
+		       <FINISH>)
+		      (ELSE
+		       <QUEUE I-TIRED 150>
+		       <SETG AWAKE -1>
+		       <IMPOSSIBLE-TO-SLEEP>)>)
+	       (<AND <NOT .FORCE?> <EQUAL? ,AWAKE -1>>
+		<TELL
+"You settle down to sleep, but you really aren't tired, so you
+thrash around for a while and then give up." CR>)
+	       (<OR <EQUAL? ,HERE ,OCEAN-ROOM ,OCEAN-FLOOR ,LOST-IN-OCEAN>
+		    <EQUAL? ,HERE ,IN-CHANNEL ,IN-PIPE ,IN-PIPE-2>
+		    <EQUAL? ,HERE ,RUINS-CHANNEL>
+		    <AND <EQUAL? ,HERE ,OUBLIETTE>
+			 <G? ,WATER-FLAG 0>>>
+		<COND (.FORCE?
+		       <JIGS-UP
+"You fall asleep and then drown.">)
+		      (ELSE
+		       <IMPOSSIBLE-TO-SLEEP>)>)
+	       (<EQUAL? ,HERE ,OGRE-CAVE ,OGRE-BEDROOM>
+		<COND (.FORCE?
+		       <JIGS-UP
+"You fall into a blissful sleep, yawning lazily, and while you are resting,
+the ogre destroys you.">)
+		      (ELSE
+		       <TELL
+"I'd think twice before going to sleep in an ogre's cave." CR>)>)
+	       (,FALLING?
+		<COND (.FORCE?
+		       <JIGS-UP
+"Not a good idea, but when you hit, you are asleep and
+don't know how much it hurt.">)
+		      (ELSE
+		       <IMPOSSIBLE-TO-SLEEP>)>)
+	       (T
+		<COND (<EQUAL? ,HERE ,GLACIER-ROOM>
+		       <SETG FREEZE-COUNT 9>)>
+		<COND (<L? ,REAL-SPELL-MAX 8>
+		       <SETG REAL-SPELL-MAX <+ ,REAL-SPELL-MAX 1>>)>
+		<SETG SPELL-MAX ,REAL-SPELL-MAX>
+		<SETG SPELL-ROOM ,SPELL-MAX>
+		<SETG MOVES <+ ,MOVES 50>>
+		<SETG LAST-SLEPT ,MOVES>
+		<SETG LOAD-ALLOWED ,LOAD-MAX>
+		<SETG FUMBLE-NUMBER 8>
+		<QUEUE I-TIRED 150>
+		<SETG AWAKE -1>
+		<FORGET-ALL>
+		<TELL
+"Ah, sleep! It's been a long day, and rest will do you good. ">
+		<COND (<AND <EQUAL? <LOC ,PLAYER> ,MAGIC-CARPET>
+			    <G? ,UD-COUNT 0>>
+		       <TELL
+"It's not the best of beds, but at least it's air cushioned. You">)
+		      (ELSE
+		       <TELL
+"You stretch out ">
+		       <COND (<IN? ,PLAYER ,IDOL>
+			      <TELL "in the arms of " THE ,IDOL>)
+			     (<EQUAL? <LOC ,PLAYER> ,ROCK ,OTHER-ROCK>
+			      <TELL "on the back of " THE <LOC ,PLAYER>>)
+			     (<IN? ,PLAYER ,ZIPPER>
+			      <TELL "in the nothingness">)
+			     (ELSE
+			      <MOVE ,PLAYER ,HERE>
+			      <TELL "on the floor">)>
+		       <TELL " and">)>
+		<TELL " drift off, renewing your powers and
+refreshing your mind. Time passes as you snore blissfully." CR CR>
+		<COND (<PROB 50>
+		       <TELL
+"You sleep uneventfully and awake refreshed.">)
+	              (T
+		       <TELL "You dream of " <PICK-ONE ,DREAMS>>
+		       <TELL " You awaken.">)>
+		<COND (<IN? ,PLAYER ,ROCK>
+		       <TELL
+" The rock says, \"You've been quiet a long time. Are you estivating?\"">)
+		      (<AND <EQUAL? ,HERE ,BAZAAR>
+			    <PROB 75>>
+		       <COND (<ROB ,PLAYER <>>
+			      <TELL
+" During your nap, some unscrupulous person absconded with your
+possessions!">)>)>
+		<CRLF>
+		<WEAR-OFF-SPELLS>
+		<RTRUE>)>>
+
+
+<GLOBAL DREAMS
+	<LTABLE 0	 
+"a group of mages clustered around a magic mirror in which
+scenes of terrible violence are visible."
+
+"a great hard-eyed monster, its insectile arms dipping and
+turning to the commands of a sorcerer who stands fearless in front of
+it."
+
+"an alchemist bent over his retorts, alembics, stinks and
+smokes."
+
+"strangely garbed magicians floating in midair.">>
+
+<ROUTINE V-SMELL ()
+	 <COND (,PRSO
+		<TELL "It smells just like ">
+		<A-PRSO>)
+	       (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<PERFORM ,PRSA <LOC ,WINNER>>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"There's no noticeable smell here." CR>)>>
+
+<ROUTINE V-SPAY ()
+	 <PERFORM ,V?PAY ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SPIN ()
+	 <YOU-CANT-X-THAT "spin">>
+
+<ROUTINE V-SQUEEZE ()
+	 <TELL "How singularly useless." CR>>
+
+<ROUTINE PRE-SSHOW ()
+	 <PERFORM ,V?SHOW ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SSHOW ()
+	 <RTRUE>>
+
+<ROUTINE V-STAND ()
+	 <COND (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<PERFORM ,V?DISEMBARK <LOC ,WINNER>>
+		<RTRUE>)
+	       (<NOT <EQUAL? ,PRSO <> ,ROOMS>> 
+		<HACK-HACK "Holding up">)
+	       (<AND <IN? ,WINNER ,MAGIC-CARPET>
+		     <G? ,UD-COUNT 0>>
+		<TELL ,WHILE-FLYING>)
+	       (T
+		<TELL ,YOU-ARE " standing." CR>)>>
+
+<ROUTINE V-STAND-ON ()
+	 <TELL ,WASTE-OF-TIME>>
+
+<ROUTINE V-SWING ()
+	 <COND (<NOT ,PRSI>
+		<TELL "Whoosh!" CR>)
+	       (T
+		<PERFORM ,V?ATTACK ,PRSI ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-SWIM ()
+	 <COND (,PRSO
+		<PERFORM ,V?THROUGH ,PRSO>
+		<RTRUE>)
+	       (<GLOBAL-IN? ,WATER ,HERE>
+		<PERFORM ,V?THROUGH ,WATER>
+		<RTRUE>)
+	       (T
+		<TELL ,THERES-NOTHING-TO "swim in" ,PERIOD>)>>
+
+<ROUTINE IMMOBILIZED? ()
+	 <COND (<AND <TIME-FROZEN?>
+		     <NOT <HELD? ,PRSO>>>
+		<IMMOBILE>)>>
+
+<ROUTINE IMMOBILE ()
+	 <TELL "It's immobilized." CR>>
+
+<ROUTINE TIME-FROZEN? ()
+	 <COND (<AND ,TIME-STOPPED?
+		     <OR <EQUAL? ,TIME-STOPPED? ,HERE>
+			 <AND <EQUAL? ,TIME-STOPPED? ,OGRE-CAVE ,OGRE-BEDROOM>
+			      <EQUAL? ,HERE ,OGRE-BEDROOM ,OGRE-CAVE>>
+			 <AND <EQUAL? ,TIME-STOPPED?
+				      ,CLIFF-TOP ,CLIFF-MIDDLE>
+			      <EQUAL? ,HERE
+				      ,CLIFF-TOP ,CLIFF-MIDDLE
+				      ,CLIFF-BOTTOM>>>>
+		<RETURN ,HERE>)>>
+
+<ROUTINE PRE-TAKE ()
+	 <COND (<IN? ,PRSO ,WINNER>
+		<TELL "You already have it." CR>)
+	       (<AND <FSET? ,PRSO ,SPELLBIT>
+		     <FSET? <LOC ,PRSO> ,SCROLLBIT>
+		     <ACCESSIBLE? <LOC ,PRSO>>>
+		<PERFORM ,V?TAKE <LOC ,PRSO>>
+		<RTRUE>)
+	       (<AND <NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		     <FSET? <LOC ,PRSO> ,CONTBIT>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<CANT-REACH-THAT>
+		<RTRUE>)
+	       (<IMMOBILIZED?> <RTRUE>)
+	       (,PRSI
+		<COND (<EQUAL? ,PRSO ,ME>
+		       <PERFORM ,V?DROP ,PRSI>
+		       <RTRUE>)
+		      (<NOT <EQUAL? ,PRSI <LOC ,PRSO>>>
+		       <TELL "But ">
+		       <TELL THE ,PRSO " isn't in ">
+		       <THE-PRSI>)
+		      (T
+		       <SETG PRSI <>>
+		       <RFALSE>)>)
+	       (<EQUAL? ,PRSO <LOC ,WINNER>>
+		<TELL "You are ">
+		<COND (<FSET? ,PRSO ,PERSON> <TELL "being carried by">)
+		      (<FSET? ,PRSO ,SURFACEBIT> <TELL "on">)
+		      (ELSE <TELL "in">)>
+		<TELL " it!" CR>)>>
+
+<ROUTINE NOT-IN-VEHICLE? ("AUX" (V <LOC ,WINNER>))
+	 <AND ,PRSO
+	      <NOT <EQUAL? ,PRSO .V>>
+	      <NOT <HELD? ,PRSO>>
+	      <NOT <HELD? ,PRSO .V>>>>
+
+<ROUTINE V-TAKE ()
+	 <COND (<EQUAL? <ITAKE> T>
+		<TELL ,TAKEN>)>>
+
+<ROUTINE V-TAKE-OFF ()
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<PERFORM ,V?DISEMBARK ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-TELL ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<COND (,P-CONT
+		       <SETG WINNER ,PRSO>
+		       ;<COND (<IN? <LOC ,WINNER> ,ROOMS>
+			      <SETG HERE <LOC ,WINNER>>)>)
+		      (T
+		       <TELL
+"Hmmm ... " THE ,PRSO " waits for you to say something." CR>)>
+		<RTRUE>)
+	       (T
+		<YOU-CANT-X-PRSO "talk to">
+		<END-QUOTE>)>>
+
+<ROUTINE V-THANK ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<UNINTERESTED ,PRSO>)
+	       (T
+		<HOW-DO-YOU> <A-PRSO?>)>>
+
+<ROUTINE V-THROUGH ("AUX" M)
+	<COND (<FSET? ,PRSO ,VEHBIT>
+	       <PERFORM ,V?BOARD ,PRSO>
+	       <RTRUE>)
+	      (<NOT <FSET? ,PRSO ,TAKEBIT>>
+	       <TELL
+,YOU-HIT THE ,PRSO " as you attempt this feat." CR>)
+	      (<IN? ,PRSO ,WINNER>
+	       <TELL "That would involve quite a contortion!" CR>)
+	      (T
+	       <TELL-YUKS>)>>
+
+<ROUTINE V-THROW ()
+	 <COND (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+	        <COND (<IN? ,PRSO ,WINNER>
+		       <COND (<IDROP>
+			      <NOT-TRAINED>)>)
+		      (ELSE
+		       <PERFORM ,V?ATTACK ,PRSI ,PRSO>
+		       <RTRUE>)>)
+	       (<AND ,PRSI
+		     <NOT <FSET? ,PRSI ,DOORBIT>>
+		     <FSET? ,PRSI ,CONTBIT>>
+		<PERFORM ,V?PUT ,PRSO ,PRSI>
+		<RTRUE>)
+	       (<IDROP>
+		<TELL "Thrown." CR>)>>
+
+<ROUTINE V-THROW-OFF ()
+	 <YOU-CANT-X-THAT "throw anything off">>
+
+<ROUTINE V-TIE ()
+	 <HOW-DO-YOU> <A-PRSI?>>
+
+<ROUTINE V-TIE-UP ()
+	 <HOW-DO-YOU> <A-PRSO?>>
+
+<ROUTINE V-TIME ("AUX" X)
+	 <SET X <- ,MOVES ,LAST-SLEPT>>
+	 <TELL "It's ">
+	 <COND (<L? .X 15>
+		<TELL "early morning">)
+	       (<L? .X 30>
+		<TELL "mid-morning">)
+	       (<L? .X 50>
+		<TELL "mid-day">)
+	       (<L? .X 65>
+		<TELL "late afternoon">)
+	       (<L? .X 80>
+		<TELL "early evening">)
+	       (T
+		<TELL "late evening">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE V-TORTURE ()
+	 <TELL "An appalling idea!" CR>>
+
+<ROUTINE V-TURN () ;"used by others"
+	 <TELL "This has no effect." CR>>
+
+<ROUTINE V-TURN-OVER ()
+	 <TELL "Moving " THE ,PRSO " reveals nothing." CR>>
+
+<ROUTINE V-UNLOCK ()
+	 <V-LOCK>>
+
+<ROUTINE V-UNTIE ()
+	 <HOW-DO-YOU> <A-PRSO?>>
+
+<ROUTINE V-WALK ("AUX" PT PTS STR OBJ RM)
+	 <COND (<NOT ,P-WALK-DIR>
+		<PERFORM ,V?WALK-TO ,PRSO>
+		<RTRUE>)
+	       (<SET PT <GETPT ,HERE ,PRSO>>
+		<COND (<EQUAL? <SET PTS <PTSIZE .PT>> ,UEXIT>
+		       <GOTO <GETB .PT ,REXIT>>)
+		      (<EQUAL? .PTS ,NEXIT>
+		       <TELL <GET .PT ,NEXITSTR> CR>
+		       <RFATAL>)
+		      (<EQUAL? .PTS ,FEXIT>
+		       <COND (<SET RM <APPLY <GET .PT ,FEXITFCN>>>
+			      <GOTO .RM>)
+			     (T
+			      <RFATAL>)>)
+		      (<EQUAL? .PTS ,CEXIT>
+		       <COND (<VALUE <GETB .PT ,CEXITFLAG>>
+			      <GOTO <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,CEXITSTR>>
+			      <TELL .STR CR>
+			      <RFATAL>)
+			     (T
+			      <CANT-GO>
+			      <RFATAL>)>)
+		      (<EQUAL? .PTS ,DEXIT>
+		       <COND (<FSET? <SET OBJ <GETB .PT ,DEXITOBJ>> ,OPENBIT>
+			      <GOTO <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,DEXITSTR>>
+			      <TELL .STR CR>
+			      <THIS-IS-IT .OBJ>
+			      <RFATAL>)
+			     (T
+			      <TELL CTHE .OBJ " is closed." CR>
+			      <THIS-IS-IT .OBJ>
+			      <RFATAL>)>)>)
+	       ;(<AND ,FLYING
+		     <EQUAL? ,PRSO ,P?UP>>
+		     <TELL "You're already flying as high as you can." CR>
+		     <RFATAL>)
+	       (T
+		<CANT-GO>
+		<RFATAL>)>>
+
+<ROUTINE V-WALK-AROUND ()
+	 <TELL "Please use compass directions instead." CR>>
+
+<ROUTINE V-WALK-TO ()
+	 <COND (<AND ,PRSO
+		     <OR <IN? ,PRSO ,HERE>
+			 <GLOBAL-IN? ,PRSO ,HERE>>>
+		<TELL "It's here!" CR>)
+	       (T
+		<V-WALK-AROUND>)>>
+
+<ROUTINE V-WAIT ("OPTIONAL" (NUM 3))
+	 <TELL "Time passes..." CR>
+	 <REPEAT ()
+		 <COND (<L? <SET NUM <- .NUM 1>> 0>
+			<RETURN>)
+		       (<CLOCKER>
+			<RETURN>)>>
+	 <SETG CLOCK-WAIT T>>
+
+<ROUTINE V-WAIT-FOR ()
+	 <COND (<EQUAL? <LOC ,PRSO> ,HERE ,WINNER>
+		<TELL "It's already here!" CR>)
+	       (T
+		<TELL "You may well wait quite a while." CR>)>>
+
+<ROUTINE V-WAVE ()
+	 <HACK-HACK "Waving">>
+
+<ROUTINE V-WAVE-AT ()
+	 <TELL
+"Despite your friendly nature, " THE ,PRSO " isn't likely to respond." CR>>
+
+<ROUTINE V-WEAR ()
+	 <YOU-CANT-X-PRSO "wear">>
+
+<ROUTINE V-WHAT ()
+	 <TELL "An excellent question." CR>>
+
+<ROUTINE V-WHERE ()
+	 <COND (<NOT ,PRSO>
+		<COND (,P-IT-OBJECT
+		       <PERFORM ,V?WHERE ,P-IT-OBJECT>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "Why?" CR>)>)
+	       (ELSE
+		<V-FIND T>)>>
+
+<ROUTINE V-WHO ()
+	 <COND (<NOT ,PRSO> <V-WHAT>)
+	       (<FSET? ,PRSO ,PERSON>
+		<PERFORM ,V?WHAT ,PRSO>
+		<RTRUE>)
+	       (T
+		<TELL "That's not a person!" CR>)>>
+
+<ROUTINE V-YAWN ()
+	 <V-LEAN-ON>>
+
+<ROUTINE V-YELL ()
+	 <TELL "Aarrrgggghhhhh!" CR>>
+
+;"subtitle object manipulation"
+
+<GLOBAL FUMBLE-NUMBER 8>
+
+<ROUTINE ITAKE ("OPTIONAL" (VB T) "AUX" CNT OBJ)
+	 <COND (<IMMOBILIZED?> <RFALSE>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<COND (.VB
+		       <TELL-YUKS>)>
+		<RFALSE>)
+	       (<IN? ,PRSO ,WINNER>
+		<TELL ,YOU-HAVE "it" ,PERIOD>
+		<RFALSE>)
+	       (<AND <NOT <IN? <LOC ,PRSO> ,WINNER>>
+		     <G? <+ <WEIGHT ,PRSO> <WEIGHT ,WINNER>> ,LOAD-ALLOWED>>
+		<COND (.VB
+		       <COND (<FIRST? ,PLAYER>
+			      <TELL "Your load is too heavy">)
+			     (T
+			      <TELL "It's a little too heavy">)>
+		       <COND (<L? ,LOAD-ALLOWED ,LOAD-MAX>
+			      <TELL
+", especially in light of your exhaustion.">)
+			     (T
+			      <TELL ".">)>
+		       <CRLF>)>
+		<RFATAL>)
+	       (<G? <SET CNT <CCOUNT ,WINNER>> ,FUMBLE-NUMBER>
+		<COND (.VB
+		       <TELL
+"You're holding too many things and can't quite get them all arranged
+to take it as well." CR>)>
+		<RFATAL>)
+	       (T
+		<MOVE ,PRSO ,WINNER>
+		<COND (<NOT <EQUAL? ,PRSO ,TIME-CUBE>>
+		       <SCORE-OBJECT>)>
+		<FCLEAR ,PRSO ,NDESCBIT>
+		<RTRUE>)>>
+
+<ROUTINE SCORE-OBJECT ("OPTIONAL" (OBJ <>))
+	 <COND (<NOT .OBJ> <SET OBJ ,PRSO>)>
+	 <COND (<FSET? .OBJ ,TOUCHBIT> <RTRUE>)>
+	 <FSET .OBJ ,TOUCHBIT>
+	 <COND (<GETP .OBJ ,P?CUBE>
+		<SETG SCORE <+ ,SCORE 25>>)
+	       (<FSET? .OBJ ,SCROLLBIT>
+		<SETG SCORE <+ ,SCORE 10>>)
+	       (<FSET? .OBJ ,MAGICBIT>
+		<SETG SCORE <+ ,SCORE 10>>)>>
+
+<ROUTINE IDROP ()
+	 <COND (<NOT <HELD? ,PRSO>>
+		<TELL ,YOU-ARENT "carrying ">
+		<THE-PRSO>
+		<RFALSE>)
+	       (<AND <NOT <IN? ,PRSO ,WINNER>>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<THIS-IS-IT ,PRSO>
+		<TELL-OPEN-CLOSED <LOC ,PRSO>>
+		<RFALSE>)
+	       (T
+		<MOVE ,PRSO <LOC ,WINNER>>
+		<RTRUE>)>>
+
+<ROUTINE CCOUNT (OBJ "AUX" (CNT 0) X)
+	 <COND (<SET X <FIRST? .OBJ>>
+		<REPEAT ()
+			<SET CNT <+ .CNT 1>>
+			<COND (<NOT <SET X <NEXT? .X>>>
+			       <RETURN>)>>)>
+	 .CNT>
+
+;"WEIGHT: Gets sum of SIZEs of supplied object, recursing to nth level."
+
+<ROUTINE WEIGHT (OBJ "AUX" CONT (WT 0))
+	 <COND (<EQUAL? .OBJ ,ZIPPER ,SPELL-BOOK> T)
+	       (<SET CONT <FIRST? .OBJ>>
+		<REPEAT ()
+			<SET WT <+ .WT <WEIGHT .CONT>>>
+			<COND (<NOT <SET CONT <NEXT? .CONT>>> <RETURN>)>>)>
+	 <+ .WT <GETP .OBJ ,P?SIZE>>>
+
+^\L
+
+;"subtitle describers"
+
+<GLOBAL DESCRIBED-ROOM? <>>
+
+<ROUTINE DESCRIBE-ROOM ("OPTIONAL" (LOOK? <>) "AUX" V? STR AV)
+	 <COND (<AND <NOT ,LIT>
+		     <NOT <EQUAL? ,HERE ,GRUE-CAVE ,LIGHT-POOL ,PILLAR-ROOM>>>
+		<TELL ,NOW-BLACK CR>
+		<RFALSE>)>
+	 <COND (<IN? ,HERE ,ROOMS> <TELL 'HERE>)>
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<FSET? .AV ,VEHBIT>
+		<COND (<FSET? .AV ,SURFACEBIT>
+		       <TELL ", on ">)
+		      (ELSE
+		       <TELL ", in ">)>
+		<TELL THE .AV>
+		<COND (<EQUAL? .AV ,ROC>
+		       <TELL "'s talons">)>)>
+	 <CRLF>
+	 <SET V? <OR .LOOK? <EQUAL? ,VERBOSITY 2>>>
+	 <COND (<NOT <FSET? ,HERE ,TOUCHBIT>>
+		<FSET ,HERE ,TOUCHBIT>
+		<COND (,VERBOSITY <SET V? T>)>)>
+	 <SETG DESCRIBED-ROOM? .V?>
+	 <COND (.V?
+		<COND (<AND <NOT <EQUAL? ,HERE .AV>>
+			    <FSET? .AV ,VEHBIT>
+			    <APPLY <GETP .AV ,P?ACTION> ,M-LOOK>>
+		       <RTRUE>)
+		      (<APPLY <GETP ,HERE ,P?ACTION> ,M-LOOK>
+		       <RTRUE>)
+		      (<SET STR <GETP ,HERE ,P?LDESC>>
+		       <TELL .STR CR>)>)>
+	 T>
+
+<ROUTINE DESCRIBE-OBJECTS ("OPTIONAL" (V? <>) "AUX" L)
+	 <COND (<AND <EQUAL? ,HERE ,BELWIT-SQUARE>
+		     <NOT <FSET? ,CLOUD ,INVISIBLE>>>
+		<RTRUE>)
+	       (,LIT
+		<COND (<IN? ,PLAYER ,ZIPPER>
+		       <SET L ,ZIPPER>)
+		      (ELSE <SET L ,HERE>)>
+		<COND (<FIRST? .L>
+		       <PRINT-CONT .L <SET V? <OR .V? ,VERBOSITY>> -1>)>)
+	       (<EQUAL? ,HERE ,LIGHT-POOL ,PILLAR-ROOM ,GRUE-CAVE>
+		<RTRUE>)
+	       (T
+		<TELL ,TOO-DARK>)>>
+
+"DESCRIBE-OBJECT -- takes object and flag. if flag is true will print a
+long description (fdesc or ldesc), otherwise will print short."
+
+<GLOBAL DESC-OBJECT <>>
+
+<ROUTINE DESCRIBE-OBJECT (OBJ V? LEVEL "AUX" (STR <>) AV (VEH? <>))
+	 <SETG DESC-OBJECT .OBJ>
+	 <COND (<AND <SET AV <LOC ,WINNER>>
+		     <FSET? .AV ,VEHBIT>>
+		<SET VEH? T>
+		<COND (<AND <NOT <FSET? .AV ,OPENBIT>>
+			    <NOT <HELD? .OBJ .AV>>>
+		       <RFALSE>)>)>
+	 <COND (<ZERO? .LEVEL>
+		<COND (<APPLY <GETP .OBJ ,P?DESCFCN> ,M-OBJDESC .OBJ>
+		       <RTRUE>)
+		      (<SET STR <GETP .OBJ ,P?LDESC>>
+		       ;<OR <AND <NOT <FSET? .OBJ ,TOUCHBIT>>
+				 <SET STR <GETP .OBJ ,P?FDESC>>>
+			    <SET STR <GETP .OBJ ,P?LDESC>>>
+		       <TELL .STR>)
+		      (ELSE
+		       <TELL "There is ">
+		       <TELL A .OBJ " here">
+		       <COND (<FSET? .OBJ ,ONBIT>
+			      <TELL ,PROVIDING-LIGHT>)>
+		       <TELL ".">)>
+		<COND (.VEH? <TELL " (outside " THE .AV ")">)>)
+	       (T
+		<TELL <GET ,INDENTS .LEVEL>>
+		<TELL A .OBJ>
+		<COND (<FSET? .OBJ ,ONBIT>
+		       <TELL ,PROVIDING-LIGHT>)>)>
+	 <CRLF>
+	 <COND (<AND <SEE-INSIDE? .OBJ> <FIRST? .OBJ>>
+		<PRINT-CONT .OBJ .V? .LEVEL>)>>
+
+<GLOBAL PROVIDING-LIGHT " (providing light)">
+
+<ROUTINE PRINT-CONT (OBJ "OPTIONAL" (V? <>) (LEVEL 0)
+		     "AUX" Y 1ST? AV STR (PV? <>) (INV? <>))
+	 <COND (<NOT <SET Y <FIRST? .OBJ>>>
+		<RTRUE>)>
+	 <COND (<AND <SET AV <LOC ,WINNER>>
+		     <FSET? .AV ,VEHBIT>>
+		T)
+	       (T
+		<SET AV <>>)>
+	 <SET 1ST? T>
+	 <COND (<EQUAL? ,WINNER .OBJ <LOC .OBJ>>
+		<SET INV? T>)>
+	 <SET Y <FIRST? .OBJ>>
+	 <REPEAT ()
+		 <COND (<NOT .Y>
+			<COND (<AND .PV? .AV <FIRST? .AV>>
+			       <PRINT-CONT .AV .V? .LEVEL>)>
+			<RETURN <NOT .1ST?>>)
+		       (<EQUAL? .Y .AV> <SET PV? T>)
+		       (<EQUAL? .Y ,PLAYER>)
+		       (<NOT <FSET? .Y ,INVISIBLE>>
+			<COND (<OR <NOT <FSET? .Y ,NDESCBIT>>
+				   <AND <FSET? .Y ,BRIEFBIT>
+					<EQUAL? ,VERBOSITY 1>
+					<NOT ,DESCRIBED-ROOM?>>>
+			       <COND (.1ST?
+				      <COND (<FIRSTER .OBJ .LEVEL>
+					     <COND (<L? .LEVEL 0>
+						    <SET LEVEL 0>)>)>
+				      <SET LEVEL <+ 1 .LEVEL>>
+				      <SET 1ST? <>>)>
+			       <DESCRIBE-OBJECT .Y .V? .LEVEL>)
+			      (<AND <FIRST? .Y> <SEE-INSIDE? .Y>>
+			       <PRINT-CONT .Y .V? .LEVEL>)>)>
+		 <SET Y <NEXT? .Y>>>>
+
+<ROUTINE PRINT-CONTENTS (OBJ "AUX" F N (1ST? T) (IT? <>) (TWO? <>))
+	 <COND (<SET F <FIRST? .OBJ>>
+		<REPEAT ()
+			<SET N <NEXT? .F>>
+			<COND (<AND <NOT <EQUAL? .F ,PLAYER>>
+				    <NOT <FSET? .F ,INVISIBLE>>>
+			       <COND (.1ST? <SET 1ST? <>>)
+				     (T
+				      <TELL ", ">
+				      <COND (<NOT .N>
+					     <TELL "and ">)>)>
+			       <TELL A .F>
+			       <COND (<AND <NOT .IT?>
+					   <NOT .TWO?>>
+				      <SET IT? .F>)
+				     (T
+				      <SET TWO? T>
+				      <SET IT? <>>)>)>
+			<SET F .N>
+			<COND (<NOT .F>
+			       <COND (<AND .IT? <NOT .TWO?>>
+				      <THIS-IS-IT .IT?>)>
+			       <RETURN>)>>
+		<NOT .1ST?>)>>
+
+<ROUTINE CLEVER-CONTENTS (OBJ STR "OPTIONAL" (IGNORE <>)
+			  "AUX" (F <FIRST? .OBJ>) (N <>) (1ST? T))
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<COND (.N
+			       <COND (.1ST?
+				      <SET 1ST? <>>
+				      <TELL .STR>
+				      <TELL " is ">)
+				     (ELSE
+				      <TELL " and ">)>
+			       <TELL A .N ".">)>
+			<RETURN <NOT .1ST?>>)
+		       (<AND <NOT <EQUAL? .F ,PLAYER>>
+			     <NOT <FSET? .F ,INVISIBLE>>
+			     <NOT <EQUAL? .F .IGNORE>>>
+			<COND (.N
+			       <COND (.1ST?
+				      <SET 1ST? <>>
+				      <TELL .STR>
+				      <TELL " are ">)
+				     (ELSE
+				      <TELL ", ">)>
+			       <TELL A .N>)>
+			<SET N .F>)>
+		 <SET F <NEXT? .F>>>>
+
+<ROUTINE FIRSTER (OBJ LEVEL)
+	 <COND (<EQUAL? .OBJ ,WINNER>
+		<TELL "You are carrying:" CR>)
+	       (<NOT <IN? .OBJ ,ROOMS>>
+		<COND (<G? .LEVEL 0>
+		       <TELL <GET ,INDENTS .LEVEL>>)>
+		<COND (<FSET? .OBJ ,SURFACEBIT>
+		       <TELL "Sitting on " THE .OBJ " you see:" CR>)
+		      (<FSET? .OBJ ,PERSON>
+		       <TELL CTHE .OBJ " is holding:" CR>)
+		      (T
+		       <TELL CTHE .OBJ " contains:" CR>)>)>>
+
+^\L
+
+;"subtitle movement"
+
+<CONSTANT REXIT 0>
+<CONSTANT UEXIT 1>
+<CONSTANT NEXIT 2>
+<CONSTANT FEXIT 3>
+<CONSTANT CEXIT 4>
+<CONSTANT DEXIT 5>
+
+<CONSTANT NEXITSTR 0>
+<CONSTANT FEXITFCN 0>
+<CONSTANT CEXITFLAG 1>
+<CONSTANT CEXITSTR 1>
+<CONSTANT DEXITOBJ 1>
+<CONSTANT DEXITSTR 1>
+
+;<ROUTINE LKP (ITM TBL "AUX" (CNT 0) (LEN <GET .TBL 0>))
+	 <REPEAT ()
+		 <COND (<G? <SET CNT <+ .CNT 1>> .LEN>
+			<RFALSE>)
+		       (<EQUAL? <GET .TBL .CNT> .ITM>
+			<COND (<EQUAL? .CNT .LEN> <RFALSE>)
+			      (T
+			       <RETURN <GET .TBL <+ .CNT 1>>>)>)>>>
+
+<GLOBAL OHERE <>>
+
+<ROUTINE GOTO (RM "OPTIONAL" (V? T) "AUX" OLIT)
+	 %<DEBUG-CODE <D-APPLY "Leave" <GETP ,HERE ,P?ACTION> ,M-LEAVE>
+		      <APPLY <GETP ,HERE ,P?ACTION> ,M-LEAVE>>
+	 <SETG OHERE ,HERE>
+	 <SET OLIT ,LIT>
+	 <COND (<NOT <EQUAL? <LOC ,WINNER> ,HERE>>
+		<MOVE <LOC ,WINNER> .RM>)
+	       (ELSE
+		<MOVE ,WINNER .RM>)>
+	 <SETG HERE .RM>
+	 <SETG LIT <LIT? ,HERE>>
+	 <COND (<AND <NOT .OLIT>
+		     <NOT ,LIT>
+		     <NOT <EQUAL? ,HERE ,PILLAR-ROOM ,LIGHT-POOL>>
+		     <NOT <VERB? BLORPLE>>
+		     <PROB 80>>
+		<JIGS-UP
+"Oh, no! Something lurking nearby snuck up and devoured you!">
+		<RTRUE>)>
+	 %<DEBUG-CODE <D-APPLY "Enter" <GETP ,HERE ,P?ACTION> ,M-ENTER>
+		      <APPLY <GETP ,HERE ,P?ACTION> ,M-ENTER>>
+	 <COND (<NOT <EQUAL? ,HERE .RM>>
+		<RTRUE>)
+	       (.V?
+		<V-FIRST-LOOK>)>
+	 <RTRUE>>
+
+\
+
+;"subtitle death and stuff"
+
+<ROUTINE JIGS-UP ("OPTIONAL" (DESC <>))
+	 <SETG WINNER ,PLAYER>
+	 <COND (.DESC <TELL .DESC>)>
+	 <FORGET-ALL>
+	 <SETG FALLING? <>>
+	 <TELL "|
+|    ****  You have died  ****|" CR>
+	 <WEAR-OFF-SPELLS <>>
+	 <TELL
+"You are floating in a dark, silent realm of nothingness. You don't know
+how much time passes, but eventually you hear the sound of soft footsteps.
+A figure in a dark cloak comes near. In a voice
+like ashes, it speaks: \"" <GET ,DEATH-SPEECHES ,DEATHS> "\"|
+|
+You find yourself falling down a deep well of darkness, as the figure
+recedes into infinite distances">
+	 <COND (<G? <SETG DEATHS <+ ,DEATHS 1>> 3>
+		<TELL
+", and mocking laughter haunts you for eternity." CR>
+		<FINISH>)>
+	 <TELL ,PERIOD>
+	 <CRLF>
+	 <MOVE ,PLAYER ,HERE> ;"GET OUT OF VEHICLE"
+	 <COND (<IN? ,PLAYER ,MAGIC-CARPET>
+		<MOVE ,MAGIC-CARPET ,PLAYER>)>
+	 <SETG DEAD? T>
+	 <GOTO ,DEATH-ROOM>
+	 <SETG DEAD? <>>
+	 <SETG P-CONT <>>
+	 <RFATAL>>
+
+<GLOBAL DEAD? <>>
+
+<GLOBAL DEATHS 0>
+
+<GLOBAL DEATH-SPEECHES
+	<PTABLE
+"How nice to see you again.
+Unfortunately, I still have need of you, so this foolishness can't be
+allowed. You'll have to go back."
+
+"You really don't seem to
+be able to take care of yourself, do you? A little more circumspection and
+prudence might be in order, don't you think?"
+
+"I think I may have chosen improperly after all. I warn you, this is
+your last chance."
+
+"You're obviously not the right choice. What a waste. I'll have to
+start all over with someone else. All this effort, too.">>
+
+<ROUTINE ROB (FROM TO "OPTIONAL" (IGNORE <>)
+	      "AUX" (F <FIRST? .FROM>) N (1ST? <>))
+	 <REPEAT ()
+		 <COND (.F
+			<SET N <NEXT? .F>>
+			<COND (<AND <FSET? .F ,TAKEBIT>
+				    <NOT <EQUAL? .F .IGNORE>>> 
+			       <SET 1ST? T>
+			       <COND (.TO <MOVE .F .TO>)
+				     (ELSE <REMOVE .F>)>)>
+			<SET F .N>)
+		       (T
+			<RETURN>)>>
+	 .1ST?>
+
+^\L
+
+;"subtitle useful utility routines"
+
+<ROUTINE THIS-IS-IT (OBJ)
+	 <COND (<NOT <EQUAL? .OBJ ,IT>>
+		<SETG P-IT-OBJECT .OBJ>)>>
+
+<ROUTINE ACCESSIBLE? (OBJ "AUX" (L <LOC .OBJ>)) ;"can player TOUCH object?"
+	 ;"revised 5/2/84 by SEM and SWG"
+	 <COND (<FSET? .OBJ ,INVISIBLE>
+		<RFALSE>)
+	       (<EQUAL? .OBJ ,PSEUDO-OBJECT>
+		<COND (<EQUAL? ,LAST-PSEUDO-LOC ,HERE>
+		       <RTRUE>)
+		      (T
+		       <RFALSE>)>)
+	       (<NOT .L>
+		<RFALSE>)
+	       (<EQUAL? .L ,GLOBAL-OBJECTS>
+		<RTRUE>)
+	       (<AND <EQUAL? .L ,LOCAL-GLOBALS>
+		     <GLOBAL-IN? .OBJ ,HERE>>
+		<RTRUE>)
+	       (<NOT <EQUAL? <META-LOC .OBJ> ,HERE <LOC ,WINNER>>>
+		<RFALSE>)
+	       (<EQUAL? .L ,WINNER ,HERE <LOC ,WINNER>>
+		<RTRUE>)
+	       (<AND <FSET? .L ,OPENBIT>
+		     <ACCESSIBLE? .L>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE VISIBLE? (OBJ "AUX" (L <LOC .OBJ>)) ;"can player SEE object"
+	 ;"revised 5/2/84 by SEM and SWG"
+	 <COND (<ACCESSIBLE? .OBJ>
+		<RTRUE>)
+	       (<AND <SEE-INSIDE? .L>
+		     <VISIBLE? .L>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE META-LOC (OBJ)
+	 <REPEAT ()
+		 <COND (<NOT .OBJ>
+			<RFALSE>)
+		       (<IN? .OBJ ,GLOBAL-OBJECTS>
+			<RETURN ,GLOBAL-OBJECTS>)>
+		 <COND (<IN? .OBJ ,ROOMS>
+			<RETURN .OBJ>)
+		       (T
+			<SET OBJ <LOC .OBJ>>)>>>
+
+<ROUTINE HELD? (OBJ "OPTIONAL" (WHO <>))
+	 ;"is object carried, or in something carried, by player?"
+	 <COND (<NOT .WHO> <SET WHO ,PLAYER>)>
+	 <COND (<NOT .OBJ>
+		<RFALSE>)
+	       (<IN? .OBJ .WHO>
+		<RTRUE>)
+	       (<IN? .OBJ ,ROOMS>
+		<RFALSE>)
+	       (<IN? .OBJ ,GLOBAL-OBJECTS>
+		<RFALSE>)
+	       (T
+		<HELD? <LOC .OBJ> .WHO>)>>
+
+<ROUTINE SEE-INSIDE? (OBJ)
+	 <AND .OBJ
+	      <NOT <FSET? .OBJ ,INVISIBLE>>
+	      <OR <FSET? .OBJ ,TRANSBIT>
+	          <FSET? .OBJ ,OPENBIT>>>>
+
+<ROUTINE GLOBAL-IN? (OBJ1 OBJ2 "AUX" TEE)
+	 <COND (<AND .OBJ2
+		     <SET TEE <GETPT .OBJ2 ,P?GLOBAL>>>
+		<ZMEMQB .OBJ1 .TEE <- <PTSIZE .TEE> 1>>)>>
+
+<ROUTINE DO-WALK (DIR)
+	 <SETG P-WALK-DIR .DIR>
+	 <PERFORM ,V?WALK .DIR>>
+
+<ROUTINE SOAK-STUFF (OBJ "OPTIONAL" (RECURSE? T)
+		     "AUX" (F <FIRST? .OBJ>) (1ST? T))
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN <NOT .1ST?>>)
+		       (<SOAK-OBJ? .F>
+			<SET 1ST? <>>)
+		       (<AND <NOT .RECURSE?>
+			     <EQUAL? .F ,PLAYER>>
+			T)
+		       (<AND <FSET? .F ,CONTBIT>
+			     <FSET? .F ,OPENBIT>
+			     <FIRST? .F>>
+			<COND (<SOAK-STUFF .F>
+			       <SET 1ST? <>>)>)>
+		 <SET F <NEXT? .F>>>>
+
+<ROUTINE SOAK-OBJ? (F)
+	 <COND (<FSET? .F ,RMUNGBIT> <RFALSE>)
+	       (<OR <EQUAL? .F ,SPELL-BOOK>
+		    <FSET? .F ,SCROLLBIT>>
+		<FSET .F ,RMUNGBIT>
+		<RTRUE>)>>
+
+<ROUTINE HACK-HACK (STR)
+	 <TELL .STR " " THE ,PRSO " has no effect." CR>>
+
+<ROUTINE TELL-YUKS ()
+	 <TELL <PICK-ONE ,YUKS> CR>>
+
+<GLOBAL YUKS
+	<LTABLE 0
+	 "Not likely!"
+	 "That would never work!"
+	 "You can't be serious."
+	 "You must have had a silliness spell cast upon you.">>
+
+<ROUTINE OPEN-CLOSE ()
+	 <COND (<AND <VERB? OPEN>
+		     <FSET? ,PRSO ,OPENBIT>>
+		<ALREADY-OPEN>
+		<RTRUE>)
+	       (<AND <VERB? CLOSE>
+		     <NOT <FSET? ,PRSO ,OPENBIT>>>
+		<ALREADY-CLOSED>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE PRE-SWRITE ()
+	 <COND (<AND ,PRSO ,PRSI>
+		<PERFORM ,V?WRITE ,PRSI ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-SWRITE ()
+	 <TELL "Write what on " THE ,PRSO "?" CR>>
+
+<ROUTINE PRE-WRITE-ON () ;"WRITE ON FOO WITH BAR"
+	 <COND (<NOT ,PRSI>
+		<TELL
+,YOU-HAVE-TO " write on " THE ,PRSO " with something." CR>)
+	       (<EQUAL? ,PRSI ,BURIN>
+		<V-SWRITE> ;"what would you like to write?")
+	       (ELSE
+		<NO-BURIN>)>>
+
+<ROUTINE V-WRITE-ON () ;"WRITE ON FOO WITH BAR"
+	 <TELL
+CTHE ,PRSO ,HAS-NO-SURFACE ,PERIOD>>
+
+<GLOBAL HAS-NO-SURFACE " has no suitable surface to write on">
+
+<ROUTINE PRE-WRITE ()
+	 <COND (<NOT ,PRSI>
+		<COND (<EQUAL? ,PRSO ,QWORD>
+		       <TELL
+,YOU-HAVE-TO " write that on something." CR>)
+		      (<OR <FSET? ,PRSO ,SPELLBIT>
+			   <FSET? ,PRSO ,SCROLLBIT>>
+		       <TELL
+"You have to copy the spell onto something." CR>)
+		      (ELSE
+		       <TELL
+,YOU-CANT "write " A ,PRSO ". Try writing a word,
+such as \"purple\", instead." CR>)>)
+	       (<NOT <IN? ,BURIN ,WINNER>>
+		<NO-BURIN>)
+	       (<OR <FSET? ,PRSO ,SPELLBIT>
+		    <FSET? ,PRSO ,SCROLLBIT>>
+		<PERFORM ,V?COPY ,PRSO ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE V-WRITE ()
+	 <TELL
+CTHE ,PRSI ,HAS-NO-SURFACE ,PERIOD>>
+
+<ROUTINE V-PRY ()
+	 <V-TURN>>
+
+<ROUTINE V-PLANT ()
+	 <TELL
+,I-DONT-THINK-THAT THE ,PRSO " is going to sprout." CR>>
+
+<ROUTINE V-YES ()
+	 <TELL "That was a rhetorical question." CR>>
+
+<ROUTINE V-NO ()
+	 <V-YES>>
+
+<ROUTINE V-BUY ()
+	 <UNINTERESTED ,PRSI>>
+
+<ROUTINE PRE-SSELL ()
+	 <PERFORM ,V?SELL ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SSELL () <RTRUE>>
+
+<ROUTINE V-SELL ()
+	 <UNINTERESTED ,PRSI>>
+
+<ROUTINE PRE-TELL-ABOUT ()
+	 <COND (<EQUAL? ,PRSO ,ME>
+		<PERFORM ,V?TELL-ME-ABOUT ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE V-TELL-ABOUT ()
+	 <UNINTERESTED ,PRSO>>
+
+<ROUTINE V-TELL-ME-ABOUT ()
+	 <COND (<EQUAL? ,WINNER ,PLAYER>
+		<TELL "Talking to yourself?" CR>)
+	       (ELSE
+		<UNINTERESTED ,WINNER>)>>
+
+<ROUTINE V-OFFER ()
+	 <V-TRADE>>
+
+<ROUTINE V-TRADE ()
+	 <COND (<AND <IN? ,MERCHANT ,HERE>
+		     <EQUAL? ,PRSO ,MAGIC-CARPET ,RANDOM-CARPET>
+		     <HELD? ,PRSO>>
+		<ASK-ABOUT-CARPET
+		 <COND (<EQUAL? ,PRSO ,RANDOM-CARPET> ,MAGIC-CARPET)
+		       (ELSE ,RANDOM-CARPET)>>)
+	       (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+		<UNINTERESTED ,PRSI>)
+	       (ELSE
+		<TELL "Perhaps it isn't for sale." CR>)>>
+
+<ROUTINE V-SLAVER ()
+	 <TELL "You're not very convincing." CR>>
+
+<ROUTINE V-ERASE ()
+	 <COND (<NOT <ZERO? <GETP ,PRSO ,P?NAME>>>
+		<YOU-CANT-X-PRSO "erase the lettering from">)
+	       (<GETPT ,PRSO ,P?NAME>
+		<TELL ,THERES-NOTHING-TO "erase" ,PERIOD>)
+	       (ELSE
+		<TELL-YUKS>)>>
+
+<ROUTINE V-ADMIRE ()
+	 <TELL "Your taste is unusual." CR>>
+
+<ROUTINE V-COPY ()
+	 <COND (<NOT ,PRSI>
+		<TELL ,YOU-HAVE-TO " copy it onto something." CR>)
+	       (<EQUAL? ,PRSI ,BURIN>
+		<TELL
+"You should copy something onto something else." CR>)
+	       (<FSET? ,PRSI ,TOOLBIT>
+		<NOT-WRITING-TOOL>)
+	       (<EQUAL? ,PRSI ,SPELL-BOOK>
+		<TELL
+"You have to \"gnusto\" spells into "> <A-PRSI>)
+	       (<OR <NOT <FSET? ,PRSO ,SPELLBIT>>
+		    <NOT <FSET? ,PRSO ,SCROLLBIT>>
+		    <NOT <FSET? ,PRSI ,SCROLLBIT>>>
+		<TELL
+,YOU-CANT "copy " A ,PRSO " onto "> <A-PRSI>)
+	       (<NOT <IN? ,BURIN ,WINNER>>
+		<NO-BURIN>)
+	       (ELSE
+		<ALREADY-USED>)>>
+
+<ROUTINE ALREADY-USED ("AUX" (F <FIRST? ,PRSI>))
+	 <TELL
+"That scroll already has " THE .F " written on it." CR>>
+
+<ROUTINE NOT-WRITING-TOOL ()
+	 <TELL
+,I-DONT-THINK-THAT A ,PRSI " makes a very good writing instrument." CR>>
+
+<ROUTINE NO-BURIN ()
+	 <TELL ,YOU-DONT-HAVE "anything to write with." CR>>
+
+<ROUTINE V-BARGAIN ()
+	 <TELL "Perhaps you should go to a bazaar." CR>>
+
+<ROUTINE V-REPAIR ()
+	 <COND (<FSET? ,PRSO ,RMUNGBIT>
+		<TELL "I don't know how." CR>)
+	       (ELSE
+		<TELL CTHE ,PRSO " isn't broken." CR>)>>
+
+<ROUTINE V-LOOK-UP ()
+	 <COND (<EQUAL? ,PRSO ,ROOMS>
+		<TELL "Don't get a sore neck." CR>)
+	       (ELSE <PERFORM ,V?WHAT ,PRSO> <RTRUE>)>>
diff --git a/z6.xzap b/z6.xzap
new file mode 100644
index 0000000..33f5b3b
--- /dev/null
+++ b/z6.xzap
@@ -0,0 +1,18 @@
+	.INSERT "Z6FREQ"
+	.INSERT "Z6DAT"			; DATA IS IN THIS FILE
+	.INSERT "MISC"
+	.INSERT "PARSER"
+	.INSERT "SYNTAX"
+	.INSERT "DEBUG"
+	.INSERT "RECORD"
+	.INSERT "INTERRUPTS"
+	.INSERT "VERBS"
+	.INSERT "MAGIC"
+	.INSERT "GLOBALS"
+	.INSERT "GUILD"
+	.INSERT "C1"
+	.INSERT "C2"
+	.INSERT "C3"
+	.INSERT "C4"
+	.INSERT "Z6STR"
+	.END
diff --git a/z6.zil b/z6.zil
new file mode 100644
index 0000000..e4e2b6f
--- /dev/null
+++ b/z6.zil
@@ -0,0 +1,63 @@
+"Z6 for
+				MAGE
+	(c) Copyright 1985 Infocom, Inc. All Rights Reserved."
+
+<COND (<GASSIGNED? ZILCH>
+       <SETG ZDEBUGGING? <>>)
+      (ELSE
+       <SETG ZDEBUGGING? T>)>
+
+<PRINC "
+*** MAGE: Interactive Fantasy ***
+">
+
+ON!-INITIAL
+OFF!-INITIAL
+
+;<REPEAT (CHR)
+	<PRINC "Debugging? (Y or N): " ,OUTCHAN>
+	<SET CHR <TYI>>
+	<COND (<MEMQ .CHR "Yy ">
+	       <PRINC " Debugging!
+" ,OUTCHAN>
+	       <RETURN <SETG ZDEBUGGING? T>>)
+	      (<MEMQ .CHR "Nn">
+	       <PRINC " No debugging!
+" ,OUTCHAN>
+	       <RETURN <SETG ZDEBUGGING? <>>>)
+	      (ELSE
+	       <PRINC " ??
+" ,OUTCHAN>)>>
+
+<DEFINE DEBUG-CODE ('X "OPTIONAL" ('Y T))
+	<COND (,ZDEBUGGING? .X)(ELSE .Y)>>
+
+<SNAME "Z6">
+
+<SET REDEFINE T>
+
+<COND (<NOT <GASSIGNED? ZILCH>>
+       <SETG WBREAKS <STRING !\" !,WBREAKS>>)>
+
+<COND (<GASSIGNED? ZILCH>
+       <ID 0>)>
+
+<CONSTANT SERIAL 0>
+
+<INSERT-FILE "MISC" T>
+<INSERT-FILE "PARSER" T>
+<INSERT-FILE "SYNTAX" T>
+<INSERT-FILE "DEBUG" T>
+<INSERT-FILE "RECORD" T>
+<INSERT-FILE "INTERRUPTS" T>
+<INSERT-FILE "VERBS" T>
+<INSERT-FILE "MAGIC" T>
+<INSERT-FILE "GLOBALS" T>
+<INSERT-FILE "GUILD" T>
+<INSERT-FILE "C1" T>
+<INSERT-FILE "C2" T>
+<INSERT-FILE "C3" T>
+<INSERT-FILE "C4" T>
+
+<PROPDEF SIZE 5>
+<PROPDEF CAPACITY 0>
diff --git a/z6.zip b/z6.zip
new file mode 100644
index 0000000..ab860a9
Binary files /dev/null and b/z6.zip differ
diff --git a/z6freq.xzap b/z6freq.xzap
new file mode 100644
index 0000000..1755a88
--- /dev/null
+++ b/z6freq.xzap
@@ -0,0 +1,200 @@
+	.FSTR FSTR?1,"the "	;1880	941
+	.FSTR FSTR?2,"The "	;1005	336
+	.FSTR FSTR?3,"and "	;962	482
+	.FSTR FSTR?4,", "	;955	956
+	.FSTR FSTR?5,"You "	;840	281
+	.FSTR FSTR?6,"you "	;736	369
+	.FSTR FSTR?7,". "	;686	687
+	.FSTR FSTR?8,"is "	;525	526
+	.FSTR FSTR?9,"of "	;489	490
+	.FSTR FSTR?10,"are "	;440	221
+	.FSTR FSTR?11,"to "	;427	428
+	.FSTR FSTR?12,"your "	;426	143
+	.FSTR FSTR?13,"There "	;370	75
+	.FSTR FSTR?14,"that "	;366	123
+	.FSTR FSTR?15,"This "	;356	90
+	.FSTR FSTR?16,"with "	;336	113
+	.FSTR FSTR?17,"It's "	;325	66
+	.FSTR FSTR?18,"in "	;279	280
+	.FSTR FSTR?19,"It "	;234	118
+	.FSTR FSTR?20,"something "	;232	30
+	.FSTR FSTR?21,"have "	;228	77
+	.FSTR FSTR?22,"from "	;222	75
+	.FSTR FSTR?23,"spell "	;204	52
+	.FSTR FSTR?24,"but "	;194	98
+	.FSTR FSTR?25,"into "	;192	65
+	.FSTR FSTR?26,"about "	;176	45
+	.FSTR FSTR?27,"for "	;172	87
+	.FSTR FSTR?28,"which "	;168	43
+	.FSTR FSTR?29,"small "	;168	43
+	.FSTR FSTR?30,"water "	;160	41
+	.FSTR FSTR?31,"can't "	;160	33
+	.FSTR FSTR?32,"around "	;160	33
+	.FSTR FSTR?33,"it "	;158	159
+	.FSTR FSTR?34,"like "	;150	51
+	.FSTR FSTR?35,"doesn't "	;147	22
+	.FSTR FSTR?36,"its "	;144	73
+	.FSTR FSTR?37,"has "	;142	72
+	.FSTR FSTR?38,"looks "	;136	35
+	.FSTR FSTR?39,"There's "	;136	18
+	.FSTR FSTR?40,"can "	;126	64
+	.FSTR FSTR?41,"very "	;123	42
+	.FSTR FSTR?42,"would "	;120	31
+	.FSTR FSTR?43,"Your "	;120	31
+	.FSTR FSTR?44,"begins "	;120	25
+	.FSTR FSTR?45,"here"	;116	59
+	.FSTR FSTR?46,"large "	;116	30
+	.FSTR FSTR?47,"you"	;114	115
+	.FSTR FSTR?48,"through "	;114	20
+	.FSTR FSTR?49,"don't "	;110	23
+	.FSTR FSTR?50,"almost "	;110	23
+	.FSTR FSTR?51,"on "	;109	110
+	.FSTR FSTR?52,"as "	;108	109
+	.FSTR FSTR?53,"light "	;108	28
+	.FSTR FSTR?54,"That "	;104	27
+	.FSTR FSTR?55,"was "	;100	51
+	.FSTR FSTR?56,"this "	;99	34
+	.FSTR FSTR?57,"spell"	;99	34
+	.FSTR FSTR?58,"see "	;98	50
+	.FSTR FSTR?59,"I "	;96	97
+	.FSTR FSTR?60,"out "	;96	49
+	.FSTR FSTR?61,"there "	;96	25
+	.FSTR FSTR?62,"Belboz "	;96	17
+	.FSTR FSTR?63,"before "	;95	20
+	.FSTR FSTR?64,"been "	;93	32
+	.FSTR FSTR?65,"not "	;92	47
+	.FSTR FSTR?66,"nothing "	;90	16
+	.FSTR FSTR?67,"already "	;90	16
+	.FSTR FSTR?68,"at "	;88	89
+	.FSTR FSTR?69,"an "	;86	87
+	.FSTR FSTR?70,"only "	;84	29
+	.FSTR FSTR?71,"They "	;84	22
+	.FSTR FSTR?72,"glowing "	;84	15
+	.FSTR FSTR?73,"something"	;84	13
+	.FSTR FSTR?74,"anything "	;84	13
+	.FSTR FSTR?75,"You're "	;84	13
+	.FSTR FSTR?76,"just "	;81	28
+	.FSTR FSTR?77,"their "	;80	21
+	.FSTR FSTR?78,"still "	;80	21
+	.FSTR FSTR?79,"little "	;80	17
+	.FSTR FSTR?80,"enough "	;80	17
+	.FSTR FSTR?81,"too "	;76	39
+	.FSTR FSTR?82,"cube"	;76	39
+	.FSTR FSTR?83,"He "	;76	39
+	.FSTR FSTR?84,"rock "	;75	26
+	.FSTR FSTR?85,"look "	;75	26
+	.FSTR FSTR?86,"even "	;75	26
+	.FSTR FSTR?87,"down "	;75	26
+	.FSTR FSTR?88,"isn't "	;75	16
+	.FSTR FSTR?89,"carpet "	;75	16
+	.FSTR FSTR?90,"all "	;72	37
+	.FSTR FSTR?91,"more "	;72	25
+	.FSTR FSTR?92,"Room"	;72	25
+	.FSTR FSTR?93,"grues "	;72	19
+	.FSTR FSTR?94,"Octagonal "	;72	9
+	.FSTR FSTR?95,"one "	;70	36
+	.FSTR FSTR?96,"Nothing "	;70	11
+
+
+;word frequency table of 96 most common words
+
+WORDS::	.TABLE
+	FSTR?1
+	FSTR?2
+	FSTR?3
+	FSTR?4
+	FSTR?5
+	FSTR?6
+	FSTR?7
+	FSTR?8
+	FSTR?9
+	FSTR?10
+	FSTR?11
+	FSTR?12
+	FSTR?13
+	FSTR?14
+	FSTR?15
+	FSTR?16
+	FSTR?17
+	FSTR?18
+	FSTR?19
+	FSTR?20
+	FSTR?21
+	FSTR?22
+	FSTR?23
+	FSTR?24
+	FSTR?25
+	FSTR?26
+	FSTR?27
+	FSTR?28
+	FSTR?29
+	FSTR?30
+	FSTR?31
+	FSTR?32
+	FSTR?33
+	FSTR?34
+	FSTR?35
+	FSTR?36
+	FSTR?37
+	FSTR?38
+	FSTR?39
+	FSTR?40
+	FSTR?41
+	FSTR?42
+	FSTR?43
+	FSTR?44
+	FSTR?45
+	FSTR?46
+	FSTR?47
+	FSTR?48
+	FSTR?49
+	FSTR?50
+	FSTR?51
+	FSTR?52
+	FSTR?53
+	FSTR?54
+	FSTR?55
+	FSTR?56
+	FSTR?57
+	FSTR?58
+	FSTR?59
+	FSTR?60
+	FSTR?61
+	FSTR?62
+	FSTR?63
+	FSTR?64
+	FSTR?65
+	FSTR?66
+	FSTR?67
+	FSTR?68
+	FSTR?69
+	FSTR?70
+	FSTR?71
+	FSTR?72
+	FSTR?73
+	FSTR?74
+	FSTR?75
+	FSTR?76
+	FSTR?77
+	FSTR?78
+	FSTR?79
+	FSTR?80
+	FSTR?81
+	FSTR?82
+	FSTR?83
+	FSTR?84
+	FSTR?85
+	FSTR?86
+	FSTR?87
+	FSTR?88
+	FSTR?89
+	FSTR?90
+	FSTR?91
+	FSTR?92
+	FSTR?93
+	FSTR?94
+	FSTR?95
+	FSTR?96
+	.ENDT
+
+	.ENDI