scratchy/game/game.ink

// She's a Ghoul of Toreador clan with one point in Celerity and three points in True Faith.

VAR showed_mace = false
VAR preparedness = 0

He came to you in a night dream. A monster is terrorising the city, he said, and only a pure maiden can become a magical girl and save us. He promised great power and opened a new world to you.

* That was ten years ago.
-> start2

=== show_the_mace ===

{ showed_mace:
    <> It was not made for this, but you weren't either.
- else:
    It is strapped to your hip. It's solid iron, thirty centimeter handle with leather grip, four-ridged head.
    The ridges look like butterfly wings.
    And there's a pair of white bird wings on the pommel.
    Weighs about seven kilos but it's light in <b>your</b> hands.
}

~ showed_mace = true

->->

=== start2 ===

// The moon never sets on a British vampire.

You don't know when He watches your night fights but he does. It has to look perfect.

You still don't know His name, only the surname: Toreador. He's foreign.
// after the jam we can drop more subtle hints? "He is a patron of arts" that way

<em>Your</em> name is Tabitha, and today you feel like…
-> clothing

= clothing
* <ell> Red sport costume with stripes for speed[. <st>Pause icon means this choice won't drive the plot forwards.</st>]? Never on your life you would be caught in <b>that.</b>
-> clothing
* <ell> Casual shirt and some jeans[. ]? Too drab.
-> clothing
* <ell> Long yellow evening flower dress[. ]? Okay for day walks, but just <em>not enough</em> for the nights.
-> clothing
* A pink dress with three underskirts, white blouse with ruffles and three-inch heels. -> start3

=== start3 ===

Just right.

He sends you a message with an address, no details. It's the other side of the city, but you quickly find a ride.

It's a long trip in an old blue Prius.

<q>Sis, you can trust me, right? You know I've seen that nasty bruise on you on Monday.</q>

The driver is your older sister Natalie.

* [It's not your secret.]
<q>I trust you, but I can't tell.</q>

<q>So you don't.</q>

<q>It's not my secret, okay?</q>

She gives you a side-eye. You ride in silence for a while.
->taxi
* [Deflect the question.]
<q>It wasn't that nasty. I was literally fine the next day.</q>
<q>It was big and yellow!</q>
  * * [Lie.]
  <q>No it wasn't.</q>

  Tabitha, the master liar. (Not.) Natalie says nothing with a pointy inflection.
  ->taxi
  * * [Show her your back.]
  You strip off your skirt and raise the back of the shirt. No bruise.
  ->taxi
* [Tell her the truth.]
<q>I'm here to smite some dangerous punk with my holy mace because my Lord said so,</q> and you show her the mace.

-> show_the_mace -> truth2

=== truth2 ===
<q>So we're driving for you to harass and beat down someone?! Tabi, are you in a cult? Is that QAnon thing or something?</q>
* [Joke.]
<q>Haven't you heard? Pink dresses against the system.</q>

Natalie doesn't laugh. You have to explain:

<q>No, it's not political or anything. And they're going to be fine too, the holiness stings more than anything I could actually use in a fight.
But I gotta do it.</q>

She gives you a side-eye and digests what you said. You ride in silence for a while.
->taxi

* [No cult. I'm a lone warrior.]
<q> No cult. I'm all alone here. </q>

<q> That's not <em>better,</em> you know. Especially in this part of town. </q>

<q> Don't worry, I'm not going to get in trouble. </q>

You ride in silence for a while.

->taxi

=== taxi ===

The car enters a dark parking lot near an abandoned mall. There's a loud car party here. Natalie parks and turns to you.

<q>How are you going back then? Should I wait for you to finish whatever you're doing?</q>

<q>No, I'll call a taxi. See?</q>

You show the phone in your secret skirt pocket. Natalie sighs.

<q>Take care, sis.</q>

<q>Thanks, Nat. See you at home.</q>

And you're off to see… some sad old guys loudly arguing about their cars. You feel a faint scent of something <em>evil</em> nearby.

->choices

= choices
{You look like a skinny teenager among some tall white dudes.|"Hey! We're starting in a three!" The guys suddenly stop arguing.}

* [<ell> (Follow the scent.)] You can't track it, you just know it's near.
-> choices
* [<ell> Tap one of the guys on a shoulder.] <q>Excuse me&mdash;</q>
<q>Get lost, kid.</q>
-> choices
* -> start4

=== start4 ===

You wander around. Why did He send you here?

There's a crowd now, and a guy shouts from inside:

<q>To the end of this street and back here! Go! <q>

The feeling of <em>wrongness</em> rises in you. The lot is filled with roar of the cars speeding away.
The crowd cheers.

You see a figure across the street jumping four stories right on top of an office building. This is your target.

-> choices2

= choices2
* [<ell> Smash your way in and use the stairs]
You can't just smash the doors and enter.
There will be an alarm and you don't want to be on camera.
-> choices2
* [<ell> Jump straight to the roof]
You're a good acrobat, but not pure <em>magic.</em> You can barely jump two stories, and here's four.
-> choices2
* [Climb the building] You do have to catch the guy quickly. You look at your mace.

-> show_the_mace -> climb2

=== climb2 ===

You hit the wall with the pommel. The sturdy wings leave a nice impression in the render. Just right to use as a handhold. And you make another one near.

It's a quick climb to the roof. And here's your guy.

He's hunched over a body of some old man, you hear the <em>slurping</em> sounds, he's still drinking blood from the body.
That's good, that means the victim is still alive and you got here on time.

* [Pose and start a full speech]

~ preparedness = 2

You take a step, do a twirl and shout.

// TODO - not a rhyme enough
<q>My name is Pretty Soldier of the Night and I will smite you in the name of the night!</q>

Then you pose with the mace. Now you feel truly confident.

And you get a heavy fist to the stomach. You lower your hands, snagging the mace on his hand – he <em>screetches</em> and jumps back.

He screams, and I have to paraphrase everything except the pronouns here:
<q>Who the hell are you, crazy woman grabbing my precious flesh with her dirty hot hands?</q>

-> explain

* [Attack now, speech later]
~ preparedness = 1
You twirl, raise your weapon and hit him while shouting:

// I have an unhealthy relationship with this meter. Sorry.
<q>I call the generous Night: give me strength for this battle.</q>

The attack throws him off the victim, but then he just shrugs and starts to stand.

-> attack

= explain

  * * Explain what he's doing is wrong
  ->explain
  * * Explain you don't want him anywhere near the city
  ->explain
  * * Explain your Lord wants him out
  ->explain

= attack

  * * Try to push him to the end of the roof
  -> attack
  * * Jump straight over him
  -> attack
  * * [<ell> Climb down]
  You think about climbing back down the wall, just to meet him on a safe ground. Not your best idea.
  -> attack

=== battleends ===
Clap. Clap. Clap.

Oh shit, it's Him. He was here and He watched. Drat.

<q>Thou art the most gracious person, dear.</q>

* [State your pride]
<q>I am proud to be the best, my lord. This man won't try this again.</q> -> battleends2
* [State your mission] 
<q>I could not let this vermin to go free.</q> -> battleends2

=== battleends2 ===

<q>Oh, he's certainly learned his lesson. Now, I think this was a nice fight. You can rest for the night.</q>

<q>But I'm not…</q>

<q>I never give you any presents, don't I? Here, take this.</q>

He throws you something small and you greedily catch it. Your fingers trace his fingerprints like you're touching his hands.

<q>I'm sure the city will be safe tonight.</q>

You skip on the way out, throwing a last glance at the scene. He's hunched above the unconscious girl. You know she will be fine, now that your lord is here.

And you spend the night sleeping with his locket, tight in your arms.

<h1>THE END</h1>

// You can outrun and jump over anyone, even in your puffy skirts. (He's obsessed with nice clothing, and honestly you caught a bit of this too. You can't go out in anything <em>drab.</em>)

// The monsters you fight are not human, not entirely. You usually catch them eating people alive in some dark alleys - turns out, there are a lot of different ways of doing that, and they usually don't even bother with hiding.

/*
You have to say the Word of Pure Heart and bash them with your Magic Mace. Even the straight hit on the skull won't kill the bad guy, but it's enough to drive him away, and maybe leave a nasty scar. 

* It would take much less from them to kill you, though. -> start4

=== start4 ===

You wouldn't stand in a fair fight even with your speed and practice.

Today is a special day.

*/

-> END